WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

NetExtract[layer,"param"]

指定されたネット層についてのパラメータの値を取り出す．

NetExtract[net,lspec]

lspec で特定された層を，net 中のNetGraphオブジェクトあるいはNetChainオブジェクトの中から取り出す．

NetExtract[net,{lspec,"param"}]

パラメータ param の値を net 中の lspec で特定された層から取り出す．

NetExtract[net,NetArray[spec]]

ネットワークあるいは層の中の共有配列の値を抽出する．

NetExtract[coder,"param"]

指定されたNetEncoderあるいはNetDecoderのパラメータの値を抽出する．

NetExtract[…,{spec1,spec2,…}]

各 speciがリストである要素の集合を抽出する．

NetExtract[spec]

式に適用可能なNetExtractの演算子形を表す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
特性と関係  
考えられる問題  
関連項目
関連するガイド
履歴
引用書式

NetExtract

NetExtract[layer,"param"]

指定されたネット層についてのパラメータの値を取り出す．

NetExtract[net,lspec]

lspec で特定された層を，net 中のNetGraphオブジェクトあるいはNetChainオブジェクトの中から取り出す．

NetExtract[net,{lspec,"param"}]

パラメータ param の値を net 中の lspec で特定された層から取り出す．

NetExtract[net,NetArray[spec]]

ネットワークあるいは層の中の共有配列の値を抽出する．

NetExtract[coder,"param"]

指定されたNetEncoderあるいはNetDecoderのパラメータの値を抽出する．

NetExtract[…,{spec1,spec2,…}]

各 speciがリストである要素の集合を抽出する．

NetExtract[spec]

式に適用可能なNetExtractの演算子形を表す．

詳細

  • NetExtractは，NetGraphあるいはNetChain内のすべてのネット層，ネット層の全特性，あるいはNetEncoderおよびNetDecoderが与えられたときに連想が返されるべきであることを示すレベル指定Allをサポートする．
  • 層指定は，n 番目の層を示す整数か名前付きの層を示す文字列でよい．
  • パラメータ指定は任意の配列の名前または層に含まれるオプションの名前でよい．
  • NetExtractは，学習されたパラメータがまだ初期化されていない，あるいは学習していないパラメータがまだ参照されていない場合はAutomaticを返す．
  • NetExtract[net,{spec1,spec2,…}]は，speciがリストではない場合は net[[spec1,spec2,…]]に等しい．
  • NetChain，NetGraph，NetEncoder，NetDecoderおよび層については，Normal[net]はNetExtract[net,All]と等価である．

例題

すべて開く すべて閉じる

例  (4)

ランダムに初期化された層を作る：

Wolfram Language code: layer = NetInitialize @ LinearLayer[2, "Input" -> 2]

重み行列を層から取り出す：

Wolfram Language code: NetExtract[layer, "Weights"]//Normal

NetChainを作る：

Wolfram Language code: chain = NetChain[{1, 2, 3}]

第3層を取り出す：

Wolfram Language code: NetExtract[chain, 3]

ネットを含む演算子を作る：

Wolfram Language code: op = NetMapOperator[LinearLayer[5]]

演算子の中からネットを取り出す：

Wolfram Language code: NetExtract[op, "Net"]

NetEncoderを作成する：

Wolfram Language code: encoder = NetEncoder["Image"]

エンコーダのタイプを抽出する：

Wolfram Language code: NetExtract[encoder, "Type"]

エンコーダの出力次元を抽出する：

Wolfram Language code: NetExtract[encoder, "Output"]

エンコーダの色空間を抽出する：

Wolfram Language code: NetExtract[encoder, "ColorSpace"]

スコープ  (7)

名前付きの層でNetChainを作る：

Wolfram Language code: chain = NetChain[<|"x" -> LinearLayer[5], "y" -> Ramp, "z" -> LinearLayer[10]|>]

第1層を取り出す：

Wolfram Language code: NetExtract[chain, 1]

最終層を取り出す：

Wolfram Language code: NetExtract[chain, -1]

名前付きの層を取り出す：

Wolfram Language code: NetExtract[chain, "y"]

要素ごとの層で使われている関数を取り出す：

Wolfram Language code: NetExtract[chain, {2, "Function"}]

複数の層を取り出す：

Wolfram Language code: NetExtract[chain, {{1}, {3}}]

すべての層を取り出す：

Wolfram Language code: NetExtract[chain, All]

初期化されたNetChainを作る：

Wolfram Language code: chain = NetInitialize @ NetChain[<|"a" -> 2, "b" -> 2, "c" -> 2|>, "Input" -> 2]

特定の層から重みを得る：

Wolfram Language code: NetExtract[chain, {2, "Weights"}]

すべての層から重みを取り出す：

Wolfram Language code: NetExtract[chain, {All, "Weights"}]

名前付きの層のあるNetGraphオブジェクトを作る：

Wolfram Language code: graph = NetGraph[<|"linear1" -> LinearLayer[2], "linear2" -> LinearLayer[5]|>, {"linear1" -> "linear2"}]

名前付きの層を取り出す：

Wolfram Language code: NetExtract[graph, "linear1"]

すべての層を取り出す：

Wolfram Language code: NetExtract[graph, All]

特定の入力次元の層を作る：

Wolfram Language code: net = FlattenLayer["Input" -> {5, 5}]

入力次元を取り出す：

Wolfram Language code: NetExtract[net, "Input"]

出力次元を取り出す：

Wolfram Language code: NetExtract[net, "Output"]

エンコーダを付けて層を作る：

Wolfram Language code: net = PoolingLayer[5, "Input" -> NetEncoder["Image"]]

入力エンコーダを取り出す：

Wolfram Language code: NetExtract[net, "Input"]

入力エンコーダのパラメータを抽出する：

Wolfram Language code: NetExtract[net, {"Input", "ImageSize"}]

入力エンコーダのタイプと出力次元を抽出する：

Wolfram Language code: NetExtract[net, {"Input", {"Type", "Output"}}]

ネットワーク中のすべての共有配列の値を抽出する：

Wolfram Language code: net = NetInitialize[NetChain[{NetInsertSharedArrays[EmbeddingLayer[3]], NetInsertSharedArrays[LinearLayer[2]]}]]
Wolfram Language code: NetExtract[net, NetArray[All]]
Wolfram Language code: NetExtract[net, NetArray["Weights"]]

この例では，NetArray["Weights"]はすべての層の重みの値に相当する：

Wolfram Language code: NetExtract[net, {All, "Weights"}]

NetExtract演算子を使う：

Wolfram Language code: NetExtract[1]@NetChain[{ElementwiseLayer[Sin], SummationLayer[]}]

特性と関係  (1)

NetExtractがサポートする部分指定はNetReplacePartが使うものと同じである．NetChainの第3層の重みを抽出する：

Wolfram Language code: partSpec = {3, "Weights"};
Wolfram Language code: net = NetInitialize@NetChain[{LinearLayer[2], Ramp, LinearLayer[3], Ramp}, "Input" -> {3}];
Wolfram Language code: NetExtract[net, partSpec]

同じ指定を使って重みを置き換える：

Wolfram Language code: NetReplacePart[net, partSpec -> {{1, 2}, {3, 4}, {5, 6}}]

考えられる問題  (1)

ConvolutionLayerを作る：

Wolfram Language code: conv = ConvolutionLayer[3, {2, 2}]

この初期化されていない層の重みを取り出そうとするとAutomaticが返される：

Wolfram Language code: NetExtract[conv, "Weights"]

既知のパラメータは取り出すことができる：

Wolfram Language code: NetExtract[conv, "KernelSize"]
Wolfram Research (2016), NetExtract, Wolfram言語関数， https://reference.wolfram.com/language/ref/NetExtract.html （2020年に更新）.

テキスト

Wolfram Research (2016), NetExtract, Wolfram言語関数， https://reference.wolfram.com/language/ref/NetExtract.html （2020年に更新）.

CMS

Wolfram Language. 2016. "NetExtract." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2020. https://reference.wolfram.com/language/ref/NetExtract.html.

APA

Wolfram Language. (2016). NetExtract. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/NetExtract.html

BibTeX

@misc{reference.wolfram_2026_netextract, author="Wolfram Research", title="{NetExtract}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/NetExtract.html}", note=[Accessed: 05-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_netextract, organization={Wolfram Research}, title={NetExtract}, year={2020}, url={https://reference.wolfram.com/language/ref/NetExtract.html}, note=[Accessed: 05-November-2026]}