---
title: "ParabolicCylinderD"
language: "en"
type: "Symbol"
summary: "ParabolicCylinderD[\\[Nu], z] gives the parabolic cylinder function \\[Nu]."
keywords: 
- parabolic cylinder d
- parabolic cylinder function
- Weber differential equation
canonical_url: "https://reference.wolfram.com/language/ref/ParabolicCylinderD.html"
source: "Wolfram Language Documentation"
related_guides: 
  - 
    title: "Hypergeometric Functions"
    link: "https://reference.wolfram.com/language/guide/HypergeometricFunctions.en.md"
related_functions: 
  - 
    title: "WhittakerW"
    link: "https://reference.wolfram.com/language/ref/WhittakerW.en.md"
  - 
    title: "HypergeometricU"
    link: "https://reference.wolfram.com/language/ref/HypergeometricU.en.md"
  - 
    title: "Hypergeometric1F1"
    link: "https://reference.wolfram.com/language/ref/Hypergeometric1F1.en.md"
  - 
    title: "HermiteH"
    link: "https://reference.wolfram.com/language/ref/HermiteH.en.md"
related_tutorials: 
  - 
    title: "Special Functions"
    link: "https://reference.wolfram.com/language/tutorial/MathematicalFunctions.en.md#21909"
---
# ParabolicCylinderD

ParabolicCylinderD[ν, z] gives the parabolic cylinder function $D_{\nu }(z)$.

## Details

* Mathematical function, suitable for both symbolic and numerical manipulation.

* $D_{\nu }(z)$ satisfies the Weber differential equation $y''+\left(\nu +\frac{1}{2}-\frac{1}{4}z^2\right)y=0$.

* For certain special arguments, ``ParabolicCylinderD`` automatically evaluates to exact values.

* ``ParabolicCylinderD`` can be evaluated to arbitrary numerical precision.

* ``ParabolicCylinderD`` automatically threads over lists.

* ``ParabolicCylinderD[ν, z]`` is an entire function of ``z`` with no branch cut discontinuities.

* ``ParabolicCylinderD`` can be used with ``Interval`` and ``CenteredInterval`` objects.  »

---

## Examples (50)

### Basic Examples (5)

Evaluate numerically:

```wl
In[1]:= ParabolicCylinderD[0, 1.5]

Out[1]= 0.569783
```

---

Plot $D_5(x)$ over a subset of the reals:

```wl
In[1]:= Plot[ParabolicCylinderD[5, x], {x, -10, 10}]

Out[1]= [image]
```

---

Plot over a subset of the complexes:

```wl
In[1]:= ComplexPlot3D[ParabolicCylinderD[5, z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

Out[1]= [image]
```

---

Series expansion at the origin:

```wl
In[1]:= Series[ParabolicCylinderD[5, x], {x, 0, 10}]

Out[1]=
SeriesData[x, 0, {15, 0, Rational[-55, 4], 0, Rational[127, 32], 0, Rational[-77, 128], 0, 
  Rational[367, 6144]}, 1, 11, 1]
```

---

Series expansion at ``Infinity`` :

```wl
In[1]:= Series[ParabolicCylinderD[5, x], {x, ∞, 5}]//Normal

Out[1]= E^-(x^2/4) (15 x - 10 x^3 + x^5)
```

### Scope (36)

#### Numerical Evaluation (7)

Evaluate numerically:

```wl
In[1]:= ParabolicCylinderD[7., 5]

Out[1]= 48.4544

In[2]:= ParabolicCylinderD[.51, .87]//Chop

Out[2]= 0.848114
```

---

Evaluate to high precision:

```wl
In[1]:= N[ParabolicCylinderD[1 / 3, 8 / 7], 50]//Chop

Out[1]= 0.79640361906637374821456788145333511628909960014930
```

The precision of the output tracks the precision of the input:

```wl
In[2]:= ParabolicCylinderD[5.30000000000000000000000000, 8]//Chop

Out[2]= 0.0056923252252761491666952526
```

---

Complex number input:

```wl
In[1]:= ParabolicCylinderD[1.3 + I, .8 + I]

Out[1]= 0.224195  + 0.110438 I
```

---

Evaluate efficiently at high precision:

```wl
In[1]:= ParabolicCylinderD[34 / 3, 8 / 7`100]//Timing//Chop

Out[1]= {0, 1140.762937151487596244339638670052453900628113805084584092878774235122127384912399201021376212934556}

In[2]:= ParabolicCylinderD[11 / 3, 1 / 7`1000];//Timing

Out[2]= {0.125, Null}
```

---

``ParabolicCylinderD`` can be used with ``Interval`` and ``CenteredInterval`` objects:

```wl
In[1]:= ParabolicCylinderD[1, Interval[{2.1, 2.2}]]

Out[1]= Interval[{0.624501, 0.731402}]

In[2]:= ParabolicCylinderD[1, CenteredInterval[2 / 3, 1 / 100]]

Out[2]= CenteredInterval[{{320277273, -29, 754673857, -36}, 30}]
```

---

Compute average-case statistical intervals using ``Around``:

```wl
In[1]:= ParabolicCylinderD[ 1, Around[2, 0.01]]

Out[1]= Around[0.7357588823428848, 0.003678794411714422]
```

---

Compute the elementwise values of an array:

```wl
In[1]:= ParabolicCylinderD[{{1 / 2, -1}, {0, 1 / 2}}, 0]

Out[1]= {{(2^1 / 4 Sqrt[π]/Gamma[(1/4)]), Sqrt[(π/2)]}, {1, (2^1 / 4 Sqrt[π]/Gamma[(1/4)])}}
```

Or compute the matrix ``ParabolicCylinderD`` function using ``MatrixFunction``:

```wl
In[2]:= MatrixFunction[ParabolicCylinderD[#, 0]&, {{1 / 2, -1}, {0, 1 / 2}}]//FullSimplify

Out[2]= {{(2^1 / 4 Sqrt[π]/Gamma[(1/4)]), -(Sqrt[π] (Log[2] + PolyGamma[0, (1/4)])/2^3 / 4 Gamma[(1/4)])}, {0, (2^1 / 4 Sqrt[π]/Gamma[(1/4)])}}
```

#### Specific Values (5)

``ParabolicCylinderD`` for symbolic parameters:

```wl
In[1]:= ParabolicCylinderD[2, x]//FunctionExpand

Out[1]= (1/2) E^-(x^2/4) (-2 + 2 x^2)

In[2]:= ParabolicCylinderD[n, 0]

Out[2]= (2^n / 2 Sqrt[π]/Gamma[(1 - n/2)])

In[3]:= ParabolicCylinderD[-1, x]//FunctionExpand

Out[3]= E^-(x^2/4) Sqrt[(π/2)] (E^(x^2/2) - E^(x^2/2) Erf[(x/Sqrt[2])])
```

---

Value at zero:

```wl
In[1]:= ParabolicCylinderD[0, 0]

Out[1]= 1
```

---

Limiting value at infinity:

```wl
In[1]:= Limit[ParabolicCylinderD[n, x], x -> Infinity]

Out[1]= 0
```

---

Find the first positive maximum of ``ParabolicCylinderD`` :

```wl
In[1]:= xmax = x /. FindRoot[D[ParabolicCylinderD[3, x ], x] == 0, {x, 3}]//Chop

Out[1]= 2.87662

In[2]:= Plot[ParabolicCylinderD[3, x ], {x, -2, 10}, Epilog -> Style[Point[{xmax, ParabolicCylinderD[3, xmax ]}], PointSize[Large], Red]]

Out[2]= [image]
```

---

Evaluate for half-integer parameters:

```wl
In[1]:= ParabolicCylinderD[1 / 2, x]//FunctionExpand

Out[1]= (E^-(x^2/4) HermiteH[(1/2), (x/Sqrt[2])]/2^1 / 4)
```

#### Visualization (4)

Plot the ``ParabolicCylinderD`` function for integer ($n=1, n=2,n=3$) and half-integer ($n=\frac{1}{2}$) orders:

```wl
In[1]:= Plot[{ParabolicCylinderD[1, x], ParabolicCylinderD[2, x], ParabolicCylinderD[3, x], ParabolicCylinderD[1 / 2, x]}, {x, -2, 4}]

Out[1]= [image]
```

---

Plot the real part of $\text{\textit{$D_{10}(z)$}}$ :

```wl
In[1]:= ComplexContourPlot[Re[ParabolicCylinderD[10, z]], {z, -1 - I, 1 + I}, Contours -> 24]

Out[1]= [image]
```

Plot the imaginary part of $\text{\textit{$D_{10}(z)$}}$ :

```wl
In[2]:= ComplexContourPlot[Im[ParabolicCylinderD[10, z]], {z, -1 - I, 1 + I}, Contours -> 24]

Out[2]= [image]
```

---

Plot as real parts of two parameters vary:

```wl
In[1]:= Plot3D[Re[ParabolicCylinderD[k, z]], {k, 0, 3}, {z, 0, 2}]

Out[1]= [image]
```

---

Types 2 and 3 of ``ParabolicCylinderD`` function have different branch cut structures:

```wl
In[1]:= Plot3D[Im[ParabolicCylinderD[2, x + I y]], {x, -2, 2}, {y, -2, 2}, Exclusions -> {{y == 0, Abs[x] > 1}}, PlotRange -> All]

Out[1]= [image]

In[2]:= Plot3D[Im[ParabolicCylinderD[3, x + I y]], {x, -2, 2}, {y, -2, 2}, Exclusions -> {{y == 0, -1 < x < 1}}, PlotRange -> All]

Out[2]= [image]
```

#### Function Properties (10)

``ParabolicCylinderD`` is defined for all real and complex values:

```wl
In[1]:= FunctionDomain[ParabolicCylinderD[ν, z], z]

Out[1]= True

In[2]:= FunctionDomain[ParabolicCylinderD[ν, z], z, Complexes]

Out[2]= True
```

---

``ParabolicCylinderD`` threads elementwise over lists:

```wl
In[1]:= ParabolicCylinderD[{1, 2, 3}, 2.5]

Out[1]= {0.524028, 1.10046, 1.70309}
```

---

$D_v(x)$ is an analytic function of $x$ :

```wl
In[1]:= FunctionAnalytic[ParabolicCylinderD[ν, x], x, Assumptions -> ν∈ℝ]

Out[1]= True
```

---

$D_n(x)$ is neither non-decreasing nor non-increasing for $n\geq 0$ :

```wl
In[1]:= Table[FunctionMonotonicity[ParabolicCylinderD[n, x], x], {n, -3, 3}]

Out[1]= {-1, -1, -1, Indeterminate, Indeterminate, Indeterminate, Indeterminate}
```

---

$D_n(x)$ is not injective for $n\geq 0$ :

```wl
In[1]:= Table[FunctionInjective[ParabolicCylinderD[n, x], x], {n, -3, 3}]

Out[1]= {True, True, True, False, False, False, False}

In[2]:= Plot[{ParabolicCylinderD[1, x], ParabolicCylinderD[2, x], .6}, {x, -5, 5}]

Out[2]= [image]
```

---

``ParabolicCylinderD`` is not surjective:

```wl
In[1]:= Table[FunctionSurjective[ParabolicCylinderD[n, x], x], {n, -3, 3}]

Out[1]= {False, False, False, False, False, False, False}

In[2]:= Plot[{ParabolicCylinderD[3, x], ParabolicCylinderD[4, x], -5}, {x, -5, 5}]

Out[2]= [image]
```

---

$D_n(x)$ is neither non-negative nor non-positive for $n>0$ :

```wl
In[1]:= Table[FunctionSign[ParabolicCylinderD[n, x], x], {n, -3, 3}]

Out[1]= {1, 1, 1, 1, Indeterminate, Indeterminate, Indeterminate}
```

---

``ParabolicCylinderD`` has no singularities or discontinuities:

```wl
In[1]:= Table[FunctionSingularities[ParabolicCylinderD[n, x], x], {n, 4}]

Out[1]= {False, False, False, False}

In[2]:= Table[FunctionDiscontinuities[ParabolicCylinderD[n, x], x], {n, 4}]

Out[2]= {False, False, False, False}
```

---

$D_n(x)$ is neither convex nor concave for $n\geq 0$ :

```wl
In[1]:= Table[FunctionConvexity[ParabolicCylinderD[n, x], x], {n, 5}]

Out[1]= {Indeterminate, Indeterminate, Indeterminate, Indeterminate, Indeterminate}

In[2]:= Table[FunctionConvexity[ParabolicCylinderD[n, x], x], {n, -3, 3}]

Out[2]= {1, 1, 1, Indeterminate, Indeterminate, Indeterminate, Indeterminate}
```

---

``TraditionalForm`` formatting:

```wl
In[1]:= ParabolicCylinderD[ν, x]//TraditionalForm

Out[1]//TraditionalForm= $$D_{\nu }(x)$$
```

#### Differentiation (3)

First derivative with respect to ``z`` :

```wl
In[1]:= D[ParabolicCylinderD[``ν, z``], z]

Out[1]= (1/2) z ParabolicCylinderD[ν, z] - ParabolicCylinderD[1 + ν, z]
```

---

Higher derivatives with respect to ``z``

```wl
In[1]:= Table[D[ParabolicCylinderD[``ν, z``], {z, k}], {k, 1, 4}]//FullSimplify

Out[1]= {(1/2) z ParabolicCylinderD[ν, z] - ParabolicCylinderD[1 + ν, z], (1/4) (-2 + z^2 - 4 ν) ParabolicCylinderD[ν, z], (1/8) z (2 + z^2 - 4 ν) ParabolicCylinderD[ν, z] + ((1/2) - (z^2/4) + ν) ParabolicCylinderD[1 + ν, z], (1/16) (12 + z^4 + z^2 (4 - 8 ν) + 16 ν (1 + ν)) ParabolicCylinderD[ν, z] - z ParabolicCylinderD[1 + ν, z]}
```

Plot the higher derivatives with respect to ``z`` when ``ν = 2`` :

```wl
In[2]:= Plot[Evaluate[% /. ν -> 2], {z, -5, 5}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

Out[2]= [image]
```

---

Formula for the $k$$$^{\text{th}}$$ derivative with respect to ``z`` :

```wl
In[1]:= D[ParabolicCylinderD[``ν, z``], {z, k}]// FullSimplify

Out[1]=
k! DifferenceRoot[Function[{\[FormalY], \[FormalN]}, 
  {-\[FormalY][\[FormalN]] - (2*z)*\[FormalY][1 + \[FormalN]] + (2 - z^2 + 4*ν)*\[FormalY][2 + \[FormalN]] + 
     ((4*(3 + \[FormalN]))*(4 + \[FormalN]))*\[FormalY][4 + \[FormalN]] == 0, \[FormalY][0] == ParabolicCylinderD[ν, z], 
   \[FormalY][1] == (Rational[1, 2]*z)*ParabolicCylinderD[ν, z] - ParabolicCylinderD[1 + ν, z], 
   \[FormalY][2] == (Rational[1, 8]*(-2 + z^2 - 4*ν))*ParabolicCylinderD[ν, z], 
   \[FormalY][3] == Rational[1, 48]*((z*(2 + z^2 - 4*ν))*ParabolicCylinderD[ν, z] - 
      (2*(-2 + z^2 - 4*ν))*ParabolicCylinderD[1 + ν, z])}]][k]
```

#### Series Expansions (5)

Find the Taylor expansion using ``Series``:

```wl
In[1]:= Series[ParabolicCylinderD[y, x], {x, 0, 3}]//Normal//FullSimplify

Out[1]= (2^-3 - (y/2) (Sqrt[2] x (-12 + x^2 (1 + 2 y)) Gamma[(1/2) - (y/2)] - 3 (-4 + x^2 (1 + 2 y)) Gamma[-(y/2)])/3 Gamma[-y])
```

Plots of the first three approximations around $x=0$ :

```wl
In[2]:=
terms = Normal@Table[Series[ParabolicCylinderD[2, x], {x, 0, m}], {m, 1, 5, 2}];
Plot[{ParabolicCylinderD[2, x], terms}, {x, -5, 5}]

Out[2]= [image]
```

---

General term in the series expansion using ``SeriesCoefficient`` :

```wl
In[1]:= SeriesCoefficient[ParabolicCylinderD[y, x], {x, 1, m}]

Out[1]=
Piecewise[
 {{DifferenceRoot[Function[{\[FormalY], \[FormalN]}, {-\[FormalY][\[FormalN]] - 2*\[FormalY][1 + \[FormalN]] + (1 + 4*y)*
          \[FormalY][2 + \[FormalN]] + ((4*(3 + \[FormalN]))*(4 + \[FormalN]))*\[FormalY][4 + \[FormalN]] == 0, 
       \[FormalY][0] == ParabolicCylinderD[y, 1], 
       \[FormalY][1] == Rational[1, 2]*ParabolicCylinderD[y, 1] - 
         P ... y))*ParabolicCylinderD[y, 1], 
       \[FormalY][3] == Rational[1, 48]*(3*ParabolicCylinderD[y, 1] - 
          (4*y)*ParabolicCylinderD[y, 1] + 
          2*ParabolicCylinderD[1 + y, 1] + (8*y)*
           ParabolicCylinderD[1 + y, 1])}]][m], m >= 0}}, 0]
```

---

Find the series expansion at ``Infinity`` :

```wl
In[1]:= Series[ParabolicCylinderD[y, x], {x, Infinity, 1}]//Normal

Out[1]= I^y E^-(x^2/4) x^y (Cos[(π y/2)] - I Sin[(π y/2)])
```

---

Find series expansion for an arbitrary symbolic direction $z$ :

```wl
In[1]:= Series[ParabolicCylinderD[y, x], {x, DirectedInfinity[z], 1}, Assumptions -> x > 0]//Normal// FullSimplify

Out[1]= (1/2 Gamma[-y])(-1 + (-1)^Floor[(1/2) - (Arg[z]/π)]) E^(x^2/4) - I π y (2 Floor[(π + Arg[z]/2 π)] + Floor[(1/2) - (Arg[z]/π)]) Sqrt[(π/2)] x^-3 - y (2 x^2 + (1 + y) (2 + y)) + I^y E^-(x^2/4) - I π y (Ceiling[(Arg[z]/π)] - 2 Floor[(π + Arg[z]/2 π)]) x^y (Cos[(π y/2)] - I (-1)^Ceiling[(Arg[z]/π)] Sin[(π y/2)])
```

---

Taylor expansion at a generic point:

```wl
In[1]:= Series[ParabolicCylinderD[y, x], {x, x0, 2}]// Normal//FullSimplify

Out[1]= ParabolicCylinderD[y, x0] + (1/8) (x - x0)^2 (-2 + x0^2 - 4 y) ParabolicCylinderD[y, x0] + (1/2) (x - x0) (x0 ParabolicCylinderD[y, x0] - 2 ParabolicCylinderD[1 + y, x0])
```

#### Function Identities and Simplifications (2)

Function identity:

```wl
In[1]:= ParabolicCylinderD[n, x] == Power[2, -n / 2] Exp[-x ^ 2 / 4] HermiteH[n, x / Sqrt[2]]//FullSimplify

Out[1]= True
```

---

Recurrence identities:

```wl
In[1]:= ParabolicCylinderD[n, x] == (1/n + 1)(x ParabolicCylinderD[n + 1, x] - ParabolicCylinderD[n + 2, x])//FullSimplify

Out[1]= True

In[2]:= ParabolicCylinderD[n, x] == (1/x)(n ParabolicCylinderD[n - 1, x] + ParabolicCylinderD[n + 1, x])//FullSimplify

Out[2]= True
```

### Generalizations & Extensions (2)

Series expansion for symbolic first argument:

```wl
In[1]:= Series[ParabolicCylinderD[n, x], {x, 0, 3}]

Out[1]=
SeriesData[x, 0, {2^(Rational[1, 2]*n)*(Sqrt[Pi]/Gamma[Rational[1, 2] + Rational[-1, 2]*n]), 
  (-2^(Rational[1, 2] + Rational[1, 2]*n))*(Sqrt[Pi]/Gamma[Rational[-1, 2]*n]), 
  ((-2^(-2 + Rational[1, 2]*n))*(1 + 2*n))*(Sqrt[Pi]/Gamma[Rational[1, 2] + Rational[-1, 2]*n]), 
  ((Rational[1, 3]*2^(Rational[-3, 2] + Rational[1, 2]*n))*(1 + 2*n))*
   (Sqrt[Pi]/Gamma[Rational[-1, 2]*n])}, 0, 4, 1]
```

---

Series expansion at infinity:

```wl
In[1]:= Series[ParabolicCylinderD[n, x], {x, Infinity, 4}]

Out[1]=
E^-(x^2/4) x^n (SeriesData[x, Infinity, {Complex[0, 1]^n*(Cos[(Rational[1, 2]*n)*Pi] + 
    (Complex[0, -1])*Sin[(Rational[1, 2]*n)*Pi]), 0, 
  (((Rational[-1, 2]*Complex[0, 1]^n)*(-1 + n))*n)*(Cos[(Rational[1, 2]*n)*Pi] + 
    (Complex[0, -1])*Sin[(Rational[1, 2]*n)*Pi]), 0, 
  (((Rational[1, 8]*Complex[0, 1]^n)*n)*(-6 + 11*n - 6*n^2 + n^3))*
   (Cos[(Rational[1, 2]*n)*Pi] + (Complex[0, -1])*Sin[(Rational[1, 2]*n)*Pi])}, 0, 5, 1])
```

### Applications (2)

Find the solution of the Schrödinger equation for a quadratic oscillator for arbitrary energies:

```wl
In[1]:= DSolve[-y''[x] + (1/4) x ^ 2 y[x] == ℰ y[x], y[x], x]

Out[1]= {{y[x] -> C[2] ParabolicCylinderD[(1/2) (-1 - 2 ℰ), I x] + C[1] ParabolicCylinderD[(1/2) (-1 + 2 ℰ), x]}}
```

---

``ParabolicCylinderD`` solves the Weber equation:

```wl
In[1]:= DSolve[-y''[x] + (1/4) x ^ 2 y[x] + 1 / 2 y[x] == 0, y[x], x]

Out[1]= {{y[x] -> C[1] ParabolicCylinderD[-1, x] + C[2] ParabolicCylinderD[0, I x]}}
```

### Properties & Relations (5)

Use ``FunctionExpand`` to expand ``ParabolicCylinderD`` into other functions:

```wl
In[1]:= FunctionExpand[ParabolicCylinderD[2, x]]

Out[1]= (1/2) E^-(x^2/4) (-2 + 2 x^2)

In[2]:= FunctionExpand[ParabolicCylinderD[-2, x]]//Simplify

Out[2]= E^-(x^2/4) - E^(x^2/4) Sqrt[(π/2)] x + E^(x^2/4) Sqrt[(π/2)] x Erf[(x/Sqrt[2])]
```

---

Integrate expressions involving ``ParabolicCylinderD`` :

```wl
In[1]:= Table[Integrate[ParabolicCylinderD[n, x] ^ 2, {x, -Infinity, Infinity}], {n, 5}]

Out[1]= {Sqrt[2 π], 2 Sqrt[2 π], 6 Sqrt[2 π], 24 Sqrt[2 π], 120 Sqrt[2 π]}

In[2]:= FindSequenceFunction[%, n]

Out[2]= Sqrt[2 π] Pochhammer[1, n]
```

---

``ParabolicCylinderD`` can be represented as a ``DifferentialRoot`` :

```wl
In[1]:= DifferentialRootReduce[ParabolicCylinderD[n, x], x]

Out[1]=
DifferentialRoot[Function[{\[FormalY], \[FormalX]}, {(2 - \[FormalX]^2 + 4*n)*\[FormalY][\[FormalX]] + 4*Derivative[2][\[FormalY]][\[FormalX]] == 0, 
   \[FormalY][0] == 2^(Rational[1, 2]*n)*(Sqrt[Pi]/Gamma[Rational[1, 2]*(1 - n)]), 
   Derivative[1][\[FormalY]][0] == (-2^(Rational[1, 2]*(1 + n)))*(Sqrt[Pi]/Gamma[Rational[-1, 2]*n])}]][x]
```

---

``ParabolicCylinderD`` can be represented as a ``DifferenceRoot`` :

```wl
In[1]:= DifferenceRootReduce[ParabolicCylinderD[k, z], k]

Out[1]=
DifferenceRoot[Function[{\[FormalY], \[FormalN]}, {(1 + \[FormalN])*\[FormalY][\[FormalN]] - z*\[FormalY][1 + \[FormalN]] + \[FormalY][2 + \[FormalN]] == 0, 
   \[FormalY][0] == ParabolicCylinderD[0, z], \[FormalY][1] == ParabolicCylinderD[1, z], 
   \[FormalY][2] == ParabolicCylinderD[2, z]}]][k]
```

---

The exponential generating function for ``ParabolicCylinderD`` :

```wl
In[1]:= ExponentialGeneratingFunction[ParabolicCylinderD[n, k], n, x]

Out[1]=
DifferentialRoot[Function[{\[FormalY], \[FormalX]}, 
  {(\[FormalX] - k)*\[FormalY][\[FormalX]] + k*ParabolicCylinderD[0, k] - ParabolicCylinderD[1, k] + 
     Derivative[1][\[FormalY]][\[FormalX]] == 0, \[FormalY][0] == ParabolicCylinderD[0, k]}]][x]
```

## See Also

* [`WhittakerW`](https://reference.wolfram.com/language/ref/WhittakerW.en.md)
* [`HypergeometricU`](https://reference.wolfram.com/language/ref/HypergeometricU.en.md)
* [`Hypergeometric1F1`](https://reference.wolfram.com/language/ref/Hypergeometric1F1.en.md)
* [`HermiteH`](https://reference.wolfram.com/language/ref/HermiteH.en.md)

## Tech Notes

* [Special Functions](https://reference.wolfram.com/language/tutorial/MathematicalFunctions.en.md#21909)

## Related Guides

* [Hypergeometric Functions](https://reference.wolfram.com/language/guide/HypergeometricFunctions.en.md)

## Related Links

* [MathWorld](https://mathworld.wolfram.com/ParabolicCylinderFunction.html)

## History

* [Introduced in 2007 (6.0)](https://reference.wolfram.com/language/guide/SummaryOfNewFeaturesIn60.en.md)