WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

PointProcessFitTest[pdata]

点の集合 pdata がポアソン(Poisson)点過程でモデル化できるかどうかを検定する．

PointProcessFitTest[pdata,pproc]

点の集合が点過程 pproc でモデル化できるかどうかを検定する．

PointProcessFitTest[pdata,pproc,"property"]

"property"の値を返す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
検定  
レポート  
オプション  
SignificanceLevel  
MaxIterations  
特性と関係  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

PointProcessFitTest

PointProcessFitTest[pdata]

点の集合 pdata がポアソン(Poisson)点過程でモデル化できるかどうかを検定する．

PointProcessFitTest[pdata,pproc]

点の集合が点過程 pproc でモデル化できるかどうかを検定する．

PointProcessFitTest[pdata,pproc,"property"]

"property"の値を返す．

詳細とオプション

  • PointProcessFitTestは，pdata は点過程 pproc から抽出されたという帰無仮説 とそうではないという対立仮説 で適合度仮説検定を行う．
  • デフォルトで，確率の値，つまり 値が返される．
  • 小さい 値は pdata が pproc からのものである可能性が低いことを示唆している．
  • 点データ pdata は次の形でよい．
  • {p1,p2,…}点 pi
    GeoPosition[…],GeoPositionXYZ[…],…地理上の点
    SpatialPointData[…]空間点集合
    {pts,reg}点集合 pts と観測領域 reg
  • 観測領域 reg は，与えられていなければRipleyRassonRegionを使って自動的に計算される．
  • 帰無仮説 の下では，pdata 内の点は pproc からのものとなる．これは，特に，どの点も同じBesagL関数を持つことを意味する．
  • 次は，使用可能な検定である．
  • "BesagL"pproc と pdata のシミュレーションでBesagLを計算する
    "ChiSquare"標準ビン数の残差がカイ平方分布に従い，高速で近似的であると想定されるビン分割に基づく
    "ModifiedChiSquare"数が多項分布に従っていると予想される，小さいサンプル数については，厳密で大きいデータには"ChiSquare"を使うビン分割に基づく
  • PointProcessFitTest[data,proc,"HypothesisTestData"]は，htd["property"]の形で追加的な検定結果と特性の抽出に使えるHypothesisTestDataオブジェクト htd を返す．
  • PointProcessFitTest[data,pproc,"property"]を使って"property"の値を直接与えることができる．
  • 次は，検定結果の報告に関連した特性である．
  • "AllTests"適用可能な全検定のリスト
    "AutomaticTest"Automaticのときに選択される検定
    "PValue" 値のリスト
    "PValueTable" 値のフォーマットされた表
    "ShortTestConclusion"検定の結論の短い説明
    "TestConclusion"検定の結論の説明
    "TestData"検定統計と 値のペアのリスト
    "TestDataTable"検定統計と 値のフォーマットされた表
    "TestStatistic"検定統計のリスト
    "TestStatisticTable"検定統計のフォーマットされた表
  • 次は，使用可能なオプションである．
  • SignificanceLevel 0.05診断と報告のためのカットオフ
    MethodAutomaticBesagL法はサブオプションを取る

例題

すべて開く すべて閉じる

例  (2)

円板上の一様点分布：

Wolfram Language code: proc = PoissonPointProcess[20, 2]; data = RandomPointConfiguration[proc, Disk[]];
Wolfram Language code: ListPlot[data]

データは強度が均質な点過程からのものである：

Wolfram Language code: PointProcessFitTest[data, proc, "TestConclusion"]

地理領域上に分布した点：

Wolfram Language code: reg = Entity["Country", "Poland"];
Wolfram Language code: pts = RandomPointConfiguration[PoissonPointProcess[Quantity[.005, 1 / "Kilometers" ^ 2], 2], reg]

推定されたPoissonPointProcess：

Wolfram Language code: proc = EstimatedPointProcess[pts, PoissonPointProcess[λ, 2]]

適合度を検定する：

Wolfram Language code: PointProcessFitTest[pts, proc, "ChiSquare"]

スコープ  (10)

検定  (7)

検定：

Wolfram Language code: spd1 = RandomPointConfiguration[PoissonPointProcess[100, 2], Disk[]]; spd2 = RandomPointConfiguration[ThomasPointProcess[10, 30, .05, 2], Disk[]];
Wolfram Language code: ListPlot[#, AspectRatio -> 1]& /@ {spd1, spd2}

値は，一般に，点が一様分布している場合は大きくなる：

Wolfram Language code: PointProcessFitTest[spd1, PoissonPointProcess[100, 2]]

値は，一般に，空間的不均一性がある場合は小さくなる：

Wolfram Language code: PointProcessFitTest[spd2, PoissonPointProcess[100, 2]]

空間的ランダム性について特定の検定を行う：

Wolfram Language code: proc = MaternPointProcess[5, 10, .5, 2];data = RandomPointConfiguration[proc, Disk[]];
Wolfram Language code: PointProcessFitTest[data, proc, "ChiSquare"]

Automaticを使うと"BesagL"検定が適用される：

Wolfram Language code: proc = PoissonPointProcess[130, 2];data = RandomPointConfiguration[proc, Disk[]];
Wolfram Language code: PointProcessFitTest[data, proc, Automatic]

特性"AutomaticTest"を使って使用する検定を選ぶことができる：

Wolfram Language code: PointProcessFitTest[data, proc, "AutomaticTest"]

データに適したすべての検定を同時に実行する：

Wolfram Language code: proc = PoissonPointProcess[10, 2]; data = RandomPointConfiguration[proc, Disk[]];
Wolfram Language code: PointProcessFitTest[data, proc, All]

特性"AllTests"を使ってどの検定が使用可能かを見る：

Wolfram Language code: PointProcessFitTest[data, proc, "AllTests"]

特性を繰り返し抽出するためにHypothesisTestDataオブジェクトを作成する：

Wolfram Language code: data = RandomPointConfiguration[PoissonPointProcess[30, 2], Disk[]];
Wolfram Language code: ℋ = PointProcessFitTest[data, Automatic, "HypothesisTestData"]

次は，抽出に使用可能な特性である：

Wolfram Language code: ℋ["Properties"]

HypothesisTestDataオブジェクトからいくつかの特性を抽出する：

Wolfram Language code: proc = PoissonPointProcess[130, 2];data = RandomPointConfiguration[proc, Disk[]];
Wolfram Language code: ℋ = PointProcessFitTest[data, proc, "HypothesisTestData"];

次は，"BesagL"検定からの 値と検定統計である：

Wolfram Language code: ℋ["PValue", "BesagL"]
Wolfram Language code: ℋ["TestStatistic", "BesagL"]

任意の数の特性を一度に抽出する：

Wolfram Language code: proc = PoissonPointProcess[130, 2];data = RandomPointConfiguration[proc, Disk[]];
Wolfram Language code: ℋ = PointProcessFitTest[data, proc, "HypothesisTestData"];

"BesagL"検定からの 値と検定統計：

Wolfram Language code: ℋ[{"PValue", "BesagL"}, {"TestStatistic", "BesagL"}]

レポート  (3)

検定選択の結果を表にする：

Wolfram Language code: proc = PoissonPointProcess[10, 2]; data = RandomPointConfiguration[proc, Disk[]];
Wolfram Language code: ℋ = PointProcessFitTest[data, proc, "HypothesisTestData"];

使用可能な全検定結果の完全な表：

Wolfram Language code: ℋ["TestDataTable", All]

選択された検定結果の表：

Wolfram Language code: ℋ["TestDataTable", "BesagL"]

報告をカスタマイズするために検定表から項目を取り出す：

Wolfram Language code: proc = PoissonPointProcess[8, 2]; data = RandomPointConfiguration[proc, Disk[]];
Wolfram Language code: ℋ = PointProcessFitTest[data, proc, "HypothesisTestData"];
Wolfram Language code: res = ℋ["TestData", All];
Wolfram Language code: tests = ℋ["AllTests"]

値は0.05を超えているので，このレベルで を棄却するに足る証拠はない：

Wolfram Language code: Show[BarChart[res[[All, 2]], ChartLabels -> Placed[tests, Center], BarOrigin -> Left], Graphics[Line[{{.05, 0}, {.05, Length[tests] + 1}}]]]

検定または検定集合のために 値を表にする：

Wolfram Language code: proc = PoissonPointProcess[10, 2]; data = RandomPointConfiguration[proc, Disk[]];
Wolfram Language code: ℋ = PointProcessFitTest[data, proc, "HypothesisTestData"];
Wolfram Language code: ℋ["PValueTable", "BesagL"]

表からの 値：

Wolfram Language code: ℋ["PValue", "BesagL"]

使用可能な全検定からの 値の表：

Wolfram Language code: ℋ["PValueTable", All]

オプション  (2)

SignificanceLevel  (1)

有意水準は"TestConclusion"と"ShortTestConclusion"に使われる：

Wolfram Language code: SeedRandom["J23"]; proc = ThomasPointProcess[20, 13, .23, 2]; data = RandomPointConfiguration[proc, Disk[]];
Wolfram Language code: ℋ1 = PointProcessFitTest[data, proc, "HypothesisTestData", SignificanceLevel -> .001];
Wolfram Language code: ℋ2 = PointProcessFitTest[data, proc, "HypothesisTestData", SignificanceLevel -> .005];

検定の結果は異なるかもしれない：

Wolfram Language code: {ℋ1["ShortTestConclusion", "ChiSquare"], ℋ2["ShortTestConclusion", "ChiSquare"]}

完全な検定の結論：

Wolfram Language code: ℋ1["TestConclusion", "ChiSquare"]
Wolfram Language code: ℋ2["TestConclusion", "ChiSquare"]

MaxIterations  (1)

サブオプションMaxIterationsを使ってシミュレーションの数が制御できる：

Wolfram Language code: SeedRandom[1];data = RandomPointConfiguration[ThomasPointProcess[30, 20, .05, 2], Disk[]];
Wolfram Language code: PointProcessFitTest[data, PoissonPointProcess[50, 2], Method -> {Automatic, MaxIterations -> 100}]
Wolfram Language code: PointProcessFitTest[data, PoissonPointProcess[50, 2], Method -> {Automatic, MaxIterations -> 500}]

特性と関係  (1)

PointProcessFitTestを使って完全な空間ランダム性の等価性が検定できる：

Wolfram Language code: data = RandomPointConfiguration[BinomialPointProcess[35, Disk[]], Disk[]];
Wolfram Language code: PointProcessFitTest[data, Automatic, "TestConclusion"]

SpatialRandomnessTestには，組込みのより具体的な検定がある：

Wolfram Language code: SpatialRandomnessTest[data, {"TestConclusion", All}]//Column
Wolfram Language code: SpatialRandomnessTest[data, "AllTests"]

おもしろい例題  (1)

帰無仮説のもとでの"ChiSquare"検定統計の分布：

Wolfram Language code: proc = PoissonPointProcess[10, 2]; sample = Table[data = RandomPointConfiguration[proc, Disk[]];PointProcessFitTest[data, proc, "ChiSquare"], {500}];
Wolfram Language code: SmoothHistogram[sample, Automatic, PDF]
Wolfram Research (2020), PointProcessFitTest, Wolfram言語関数， https://reference.wolfram.com/language/ref/PointProcessFitTest.html.

テキスト

Wolfram Research (2020), PointProcessFitTest, Wolfram言語関数， https://reference.wolfram.com/language/ref/PointProcessFitTest.html.

CMS

Wolfram Language. 2020. "PointProcessFitTest." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/PointProcessFitTest.html.

APA

Wolfram Language. (2020). PointProcessFitTest. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/PointProcessFitTest.html

BibTeX

@misc{reference.wolfram_2026_pointprocessfittest, author="Wolfram Research", title="{PointProcessFitTest}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/PointProcessFitTest.html}", note=[Accessed: 02-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_pointprocessfittest, organization={Wolfram Research}, title={PointProcessFitTest}, year={2020}, url={https://reference.wolfram.com/language/ref/PointProcessFitTest.html}, note=[Accessed: 02-November-2026]}