WOLFRAM

Wolfram 语言与系统参考资料中心

RegionDistance[reg,p]

给出从点 p 到区域 reg 的最小距离.

RegionDistance[reg1,reg2]

给出区域 reg1 和 reg2 中的点之间最小的距离.

RegionDistance[reg]

给出一个可以重复应用于不同点的 RegionDistanceFunction[…].

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
特殊区域  
公式区域  
网格区域  
导出区域  
CSG 区域  
细分区域  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

RegionDistance

RegionDistance[reg,p]

给出从点 p 到区域 reg 的最小距离.

RegionDistance[reg1,reg2]

给出区域 reg1 和 reg2 中的点之间最小的距离.

RegionDistance[reg]

给出一个可以重复应用于不同点的 RegionDistanceFunction[…].

更多信息和选项

  • RegionDistance 也称为点到区域的距离，距离变换，距离场和最小区域距离.
  • RegionDistance 测量两个区域之间的距离有多近.
  • 点 q 与 p 之间的距离被视为 Norm[p-q].
  • 实际上，RegionDistance[reg,p] 由 MinValue[{Norm[p-q],q∈reg},q] 给出.
  • 实际上，RegionDistance[reg1,reg2] 由 MinValue[Norm[p-q],{p∈reg1,q∈reg2}] 给出.
  • 除非区域是闭合的，否则最近距离可能不是通过区域中的点而是通过区域的闭包获得的.

范例

打开所有单元 关闭所有单元

基本范例  (2)

找到从一个点到单位圆盘的距离：

Wolfram Language code: RegionDistance[Disk[], {3, 3}]

绘制距离（作为位置的函数）：

Wolfram Language code: Plot3D[RegionDistance[Disk[], {x, y}], {x, -2, 2}, {y, -2, 2}]

找到从一个点到一个 MeshRegion 的距离：

Wolfram Language code: DelaunayMesh[RandomReal[1, {25, 2}]]

用一个参数，得到一个 RegionDistanceFunction：

Wolfram Language code: df = RegionDistance[%]

应用点的距离函数列表来计算许多距离：

Wolfram Language code: df[RandomReal[2, {5, 2}]]

范围  (17)

特殊区域  (9)

点：

Wolfram Language code: RegionDistance[Point[{{1, 1}, {1, 2}}], {3, 4}]
Wolfram Language code: RegionDistance[Point[{{0, 0, 0}, {1, 2, 3}}], {1, 1, 1}]

绘制到三点集的距离：

Wolfram Language code: ℛ = Point[{{1, 2}, {3, 4}, {5, 6}}];
Wolfram Language code: {Plot3D[RegionDistance[ℛ, {x, y}], {x, 0, 7}, {y, 0, 7}, MeshFunctions -> {#3&}, Mesh -> 5], ContourPlot[RegionDistance[ℛ, {x, y}], {x, -1, 7}, {y, 0, 8}, Contours -> {{0.5, Red}, {1, Green}, {1.5, Blue}}]}

线：

Wolfram Language code: RegionDistance[Line[{{0, 0}, {1, 1}}], {3, 4}]
Wolfram Language code: RegionDistance[Line[{{0, 0, 0}, {1, 1, 1}, {0, 0, 1}}], {1, 2, 3}]

绘图：

Wolfram Language code: ℛ = Line[{{0, 0}, {1, 1}}];
Wolfram Language code: {Plot3D[RegionDistance[ℛ, {x, y}], {x, -1, 2}, {y, -1, 2}, MeshFunctions -> {#3&}, Mesh -> 5], ContourPlot[RegionDistance[ℛ, {x, y}], {x, -1, 2}, {y, -1, 2}, Contours -> {{0.5, Red}, {1, Green}, {1.5, Blue}}]}

长方体：

Wolfram Language code: RegionDistance[Rectangle[{0, 0}, {1, 2}], {3, 4}]
Wolfram Language code: RegionDistance[Cuboid[{0, 0, 0}, {1, 2, 3}], {4, 5, 6}]

绘制到一个矩形的距离：

Wolfram Language code: ℛ = Rectangle[{0, 0}, {1, 2}];
Wolfram Language code: {Plot3D[RegionDistance[ℛ, {x, y}], {x, -1, 2}, {y, -1, 3}, MeshFunctions -> {#3&}, Mesh -> 5], ContourPlot[RegionDistance[ℛ, {x, y}], {x, -2, 3}, {y, -2, 4}, Contours -> {{0.5, Red}, {1, Green}, {1.5, Blue}}]}

单纯形：

Wolfram Language code: RegionDistance[Simplex[1], {2}]
Wolfram Language code: RegionDistance[Simplex[2], {1, 1}]
Wolfram Language code: RegionDistance[Simplex[3], {1, 1, 1}]

绘制到二维单纯形的距离：

Wolfram Language code: ℛ = Simplex[2];
Wolfram Language code: {Plot3D[RegionDistance[ℛ, {x, y}], {x, -1, 2}, {y, -1, 2}, MeshFunctions -> {#3&}, Mesh -> 5], ContourPlot[RegionDistance[ℛ, {x, y}], {x, -2, 3}, {y, -2, 3}, Contours -> {{0.5, Red}, {1, Green}, {1.5, Blue}}]}

球体：

Wolfram Language code: RegionDistance[Disk[{0, 0}, 1], {1, 2}]
Wolfram Language code: RegionDistance[Ball[{0, 0, 0}, 1], {1, 2, 3}]

绘制到一个圆盘的距离：

Wolfram Language code: ℛ = Disk[];
Wolfram Language code: {Plot3D[RegionDistance[ℛ, {x, y}], {x, -2, 2}, {y, -2, 2}, MeshFunctions -> {#3&}, Mesh -> 5], ContourPlot[RegionDistance[ℛ, {x, y}], {x, -3, 3}, {y, -3, 3}, Contours -> {{0.5, Red}, {1, Green}, {1.5, Blue}}]}

椭球：

Wolfram Language code: RegionDistance[Disk[{0, 0}, {1, 2}], {0, 4}]
Wolfram Language code: RegionDistance[Ellipsoid[{0, 0, 0}, {1, 2, 3}], {0, 3, 4}]

绘制到一个二维椭球的距离：

Wolfram Language code: ℛ = Disk[{0, 0}, {1, 2}];
Wolfram Language code: {Plot3D[RegionDistance[ℛ, {x, y}], {x, -2, 2}, {y, -3, 3}, MeshFunctions -> {#3&}, Mesh -> 5, Exclusions -> Norm[{x, y / 2}] == 1], ContourPlot[RegionDistance[ℛ, {x, y}], {x, -3, 3}, {y, -4, 4}, Contours -> {{0.5, Red}, {1, Green}, {1.5, Blue}}]}

圆和椭圆：

Wolfram Language code: RegionDistance[Circle[{0, 0}, 1], {1, 2}]
Wolfram Language code: RegionDistance[Circle[{0, 0}, {1, 2}], {0, 4}]

绘制到一个圆的距离：

Wolfram Language code: ℛ = Circle[];
Wolfram Language code: {Plot3D[RegionDistance[ℛ, {x, y}], {x, -2, 2}, {y, -2, 2}, MeshFunctions -> {#3&}, Mesh -> 5, Exclusions -> Norm[{x, y}] == 1], ContourPlot[RegionDistance[ℛ, {x, y}], {x, -3, 3}, {y, -3, 3}, Contours -> {{0.5, Red}, {1, Green}, {1.5, Blue}}]}

圆柱和圆锥体：

Wolfram Language code: RegionDistance[Cylinder[{{0, 0, 0}, {0, 0, 2}}, 1], {1, 1, 1}]//Simplify
Wolfram Language code: RegionDistance[Cone[{{0, 0, 0}, {0, 0, 2}}, 1], {1, 1, 1}]//Simplify

圆柱的等距线：

Wolfram Language code: ℛ = Cylinder[{{0, 0, 0}, {0, 0, 2}}];
Wolfram Language code: ContourPlot3D[Evaluate@RegionDistance[ℛ, {x, y, z}], {x, -3, 3}, {y, -3, 3}, {z, -2, 4}, Contours -> {0.5, 1.0, 1.5}, PlotTheme -> "Minimal", BaseStyle -> Opacity[0.5]]

在 的区域：

Wolfram Language code: RegionDistance[Simplex[{{1, 0, 0, 0}, {0, 1, 0, 0}, {0, 0, 1, 0}, {0, 0, 0, 1}}], {1, 2, 3, 4}]
Wolfram Language code: RegionDistance[Cuboid[{1, 2, 3, 4, 5}, {6, 7, 8, 9, 10}], {11, 12, 13, 14, 15}]
Wolfram Language code: RegionDistance[Ball[{1, 2, 3, 4, 5, 6, 7}, 8], {9, 10, 11, 12, 13, 14, 15}]

公式区域  (2)

表示为 ImplicitRegion 的到圆盘的距离：

Wolfram Language code: ℛ = ImplicitRegion[x^2 + y^2 ≤ 1, {x, y}];
Wolfram Language code: RegionPlot[ℛ]
Wolfram Language code: RegionDistance[ℛ, {3, 4}]

圆柱：

Wolfram Language code: ℛ = ImplicitRegion[x^2 + y^2 ≤ 1.5, {x, y, {z, 0, 2}}];
Wolfram Language code: RegionDistance[ℛ, {3, 4, 5}]

表示为 ParametricRegion 的到圆盘的距离：

Wolfram Language code: ℛ = ParametricRegion[{r Cos[θ], r Sin[θ]}, {{r, 0, 1}, {θ, 0, 2π}}];
Wolfram Language code: RegionDistance[ℛ, {3, 4}]

使用圆盘的有理参数化：

Wolfram Language code: ℛ = ParametricRegion[{r(1 - t^2/1 + t^2), r(2t/1 + t^2)}, {t, {r, 0, 1}}];
Wolfram Language code: RegionDistance[ℛ, {3, 4}]

圆柱：

Wolfram Language code: ℛ = ParametricRegion[{r Cos[θ], r Sin[θ], z}, {{r, 0, 1}, {θ, 0, 2π}, {z, 0, 2}}];
Wolfram Language code: RegionDistance[ℛ, {3, 4, 5}]

网格区域  (1)

到一维 BoundaryMeshRegion 的距离：

Wolfram Language code: ℛ = BoundaryMeshRegion[{{0}, {1}}, Point[{{1}, {2}}]]
Wolfram Language code: RegionDistance[ℛ, {2}]

二维：

Wolfram Language code: ℛ = ConvexHullMesh[RandomReal[1, {10, 2}]];
Wolfram Language code: Show[ℛ, Graphics[{Red, Point[{1, 1}]}]]
Wolfram Language code: RegionDistance[ℛ, {1, 1}]

三维：

Wolfram Language code: ℛ = ConvexHullMesh[RandomReal[1, {20, 3}]];
Wolfram Language code: Show[ℛ, Graphics3D[{Red, Point[{1, 1, 1}]}]]
Wolfram Language code: RegionDistance[ℛ, {1, 1, 1}]

导出区域  (3)

到 RegionIntersection 的距离：

Wolfram Language code: ℛ = RegionIntersection[Disk[{0, 0}, 1], Disk[{0, 1}, 1]];
Wolfram Language code: RegionDistance[ℛ, {1, 1}]
Wolfram Language code: Show[Graphics[{Red, Point[{1, 1}]}], RegionPlot[ℛ]]

到 TransformedRegion 的距离：

Wolfram Language code: ℛ = TransformedRegion[Disk[], ScalingTransform[{3, 2}]];
Wolfram Language code: RegionDistance[ℛ, {4, 3}]
Wolfram Language code: Show[DiscretizeRegion[ℛ, {{-3, 3}, {-2, 2}}], Graphics[{Red, Point[{4, 3}]}]]

到 RegionBoundary 的距离：

Wolfram Language code: ℛ = RegionBoundary[Disk[]];
Wolfram Language code: RegionDistance[ℛ, {1 / 2, 1 / 2}]
Wolfram Language code: Graphics[{ℛ, Red, Point[{1 / 2, 1 / 2}]}]

CSG 区域  (1)

到二维 CSGRegion 的距离：

Wolfram Language code: ℛ = CSGRegion["Difference", {Disk[], Disk[{1 / 2, 1 / 2}]}];
Wolfram Language code: RegionDistance[ℛ, {1 / 2, 1 / 2}]
Wolfram Language code: Show[ℛ, Graphics[{Red, Point[{1 / 2, 1 / 2}]}]]

三维：

Wolfram Language code: ℛ = CSGRegion["Difference", {Cube[2], Cylinder[{{1, 1, 1}, {1, -1, 1}}]}];
Wolfram Language code: RegionDistance[ℛ, {1 / 2, 1, 1 / 2}]
Wolfram Language code: Show[ℛ, Graphics3D[{Red, Point[{1 / 2, 1, 1 / 2}]}]]

细分区域  (1)

到 SubdivisionRegion 的距离：

Wolfram Language code: ℛ = SubdivisionRegion[Rectangle[]];
Wolfram Language code: RegionDistance[ℛ, {1, 1}]
Wolfram Language code: Show[ℛ, Graphics[{Red, Point[{1, 1}]}]]

三维：

Wolfram Language code: ℛ = SubdivisionRegion[Cuboid[]];
Wolfram Language code: RegionDistance[ℛ, {1, 1, 1}]
Wolfram Language code: Show[ℛ, Graphics3D[{Red, Point[{1, 1, 1}]}]]

应用  (5)

计算一个三角形的高：

Wolfram Language code: {a, b, c} = {{1, 0}, {4, 0}, {0, 2}};
Wolfram Language code: base = InfiniteLine[{a, b}];
Wolfram Language code: RegionDistance[base, c]

可视化这个三角形：

Wolfram Language code: Graphics[Triangle[{a, b, c}], Axes -> {False, True}, Epilog -> {Red, base}]

生成一个离一个圆距离为 的区域：

Wolfram Language code: circle = Circle[{0, 0}, 5];
Wolfram Language code: d = RegionDistance[circle, {x, y}];
Wolfram Language code: ℛ[r_] = ImplicitRegion[d ≤ r, {x, y}]

可视化该区域和圆：

Wolfram Language code: RegionPlot[ℛ[2], Epilog -> {Red, circle}, PlotRange -> {{-8, 8}, {-8, 8}}]

计算一个区域的膨胀：

Wolfram Language code: Subscript[ℛ, 1] = BoundaryDiscretizeGraphics@CountryData["France", "Shape"];
Wolfram Language code: Subscript[ℛ, 2] = Quiet@DiscretizeRegion[ImplicitRegion[Evaluate[RegionDistance[Subscript[ℛ, 1], {x, y}] ≤ 0.005], {x, y}]];
Wolfram Language code: {Subscript[ℛ, 1], Subscript[ℛ, 2]}

从区域 到 的豪斯多夫有向距离被定义为 . 用 RegionDistance 计算从 =Triangle[{{0,0},{2,0},{0,1}}] 到 ℬ=Triangle[{{0,0},{1,0},{0,3/2}}] 的豪斯多夫有向距离：

Wolfram Language code: 𝒜 = Triangle[{{0, 0}, {2, 0}, {0, 1}}]; ℬ = Triangle[{{0, 0}, {1, 0}, {0, 3 / 2}}];
Wolfram Language code: Legended[Graphics[{Opacity[0.5], {Red, 𝒜}, {Blue, ℬ}}], SwatchLegend[{Red, Blue}, {"𝒜", "ℬ"}]]

找出离在的 任意一点最近的距离：

Wolfram Language code: d1 = RegionDistance[𝒜, {x, y}]

不出所料，对于在 的与 重叠的点，该距离为零：

Wolfram Language code: Plot3D[d1, {x, y}∈ℬ, PlotRange -> All]

通过在 上做最大化来找到豪斯多夫有向距离：

Wolfram Language code: MaxValue[d1, {x, y}∈ℬ]

如果 ，可以得出结论 ，其中 是 的闭包和 . 证明对于这个例子中的区域，：

Wolfram Language code: Show[RegionPlot[d1 ≤ 1 / 2, {x, -1, 3}, {y, -1, 5 / 2}], Graphics[{Opacity[0.5], {Red, 𝒜}, {Blue, ℬ}}]]

区域 和 之间的豪斯多夫距离被定义为 ，其中 是前一个例子中的豪斯多夫有向距离. 用 RegionDistance 计算 =Triangle[{{0,0},{2,0},{0,1}}] 和 ℬ=Triangle[{{0,0},{1,0},{0,3/2}}] 之间的豪斯多夫距离：

Wolfram Language code: 𝒜 = Triangle[{{0, 0}, {2, 0}, {0, 1}}]; ℬ = Triangle[{{0, 0}, {1, 0}, {0, 3 / 2}}];
Wolfram Language code: Legended[Graphics[{Opacity[0.5], {Red, 𝒜}, {Blue, ℬ}}], SwatchLegend[{Red, Blue}, {"𝒜", "ℬ"}]]

找到豪斯多夫有向距离：

Wolfram Language code: hAB = MaxValue[RegionDistance[𝒜, {x, y}], {x, y}∈ℬ]
Wolfram Language code: hBA = MaxValue[RegionDistance[ℬ, {x, y}], {x, y}∈𝒜]
Wolfram Language code: dH = Max[hAB, hBA]

如果 ，可以得出结论 和 ，就如在前一个例子中一样. 证明对于这个例子中的区域， 且 ：

Wolfram Language code: d1 = RegionDistance[𝒜, {x, y}]; d2 = RegionDistance[ℬ, {x, y}];
Wolfram Language code: Show[RegionPlot[{d1 ≤ 1, d2 ≤ 1}, {x, -1, 3}, {y, -1, 5 / 2}], Graphics[{Opacity[0.5], {Red, 𝒜}, {Blue, ℬ}}]]

属性和关系  (4)

一个点是 RegionMember 如果它到区域的距离为0：

Wolfram Language code: ℛ = Disk[{0, 0}, {3, 2}];
Wolfram Language code: Reduce[RegionMember[ℛ, {x, y}]⧦RegionDistance[ℛ, {x, y}] == 0, {x, y}, Reals]

RegionDistance 是到区域任意一点的距离的 MinValue：

Wolfram Language code: ℛ = Disk[{0, 0}, {3, 2}];
Wolfram Language code: d1 = RegionDistance[ℛ, {5, 5}]; d2 = MinValue[Norm[{5 - x, 5 - y}], {x, y}∈ℛ];
Wolfram Language code: FullSimplify[d1 == d2]

RegionNearest 给出一个离输入距离最近的点：

Wolfram Language code: ℛ = Disk[];
Wolfram Language code: Norm[{5, 5} - RegionNearest[ℛ, {5, 5}]] == RegionDistance[ℛ, {5, 5}]//FullSimplify

对一个在区域外的点，RegionDistance 与 SignedRegionDistance 相同：

Wolfram Language code: ℛ = Disk[];
Wolfram Language code: RegionDistance[ℛ, {2, 2}] == SignedRegionDistance[ℛ, {2, 2}]
Wolfram Research (2014)，RegionDistance，Wolfram 语言函数，https://reference.wolfram.com/language/ref/RegionDistance.html （更新于 2023 年）.

文本

Wolfram Research (2014)，RegionDistance，Wolfram 语言函数，https://reference.wolfram.com/language/ref/RegionDistance.html （更新于 2023 年）.

CMS

Wolfram 语言. 2014. "RegionDistance." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2023. https://reference.wolfram.com/language/ref/RegionDistance.html.

APA

Wolfram 语言. (2014). RegionDistance. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/RegionDistance.html 年

BibTeX

@misc{reference.wolfram_2026_regiondistance, author="Wolfram Research", title="{RegionDistance}", year="2023", howpublished="\url{https://reference.wolfram.com/language/ref/RegionDistance.html}", note=[Accessed: 03-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_regiondistance, organization={Wolfram Research}, title={RegionDistance}, year={2023}, url={https://reference.wolfram.com/language/ref/RegionDistance.html}, note=[Accessed: 03-November-2026]}