RollPitchYawMatrix[{α,β,γ}]
初期
軸の周りで α 分回転させ,次に初期
軸の周りで β 分回転させ,次に初期
軸の周りで γ 分回転させて得られる3D回転行列を与える.
RollPitchYawMatrix[{α,β,γ},{a,b,c}]
固定 a 軸の周りで α 分回転させ,次に固定 b 軸の周りで β 分回転させ,次に固定 c 軸の周りで γ 分回転させて得られる3D回転行列を与える.
RollPitchYawMatrix
RollPitchYawMatrix[{α,β,γ}]
初期
軸の周りで α 分回転させ,次に初期
軸の周りで β 分回転させ,次に初期
軸の周りで γ 分回転させて得られる3D回転行列を与える.
RollPitchYawMatrix[{α,β,γ},{a,b,c}]
固定 a 軸の周りで α 分回転させ,次に固定 b 軸の周りで β 分回転させ,次に固定 c 軸の周りで γ 分回転させて得られる3D回転行列を与える.
詳細とオプション
- RollPitchYawMatrixはCardan行列としても知られている.{α,β,γ}は,しばしばCardan角,Tait–Bryan角,航海角,ロールピッチヨー角等として言及される.
- RollPitchYawMatrixは,各回転が初期あるいは外側からの座標フレームに言及している座標軸の周りの基本回転の連続として回転を指定する際によく使われる.
- RollPitchYawMatrix[{α,β,γ}]はRollPitchYawMatrix[{α,β,γ},{3,2,1}]に等しい.
- RollPitchYawMatrix[{α,β,γ},{a,b,c}]は,Rα,a=RotationMatrix[α,UnitVector[3,a]]等である
に等しい. - デフォルトの z-y-x 回転RollPitchYawMatrix[{α,β,γ},{3,2,1}]
- 回転軸 a,b,c は,任意の整数1,2または3でよい.しかし,任意の3D回転を指定するために十分一般的である組合せは12しかない.
- 最初と最後の軸が繰り返されている回転
-
{3,2,3} z-y-z 回転 
{3,1,3} z-x-z 回転 
{2,3,2} y-z-y 回転 
{2,1,2} y-x-y 回転 
{1,3,1} x-z-x 回転 
{1,2,1} x-y-x 回転 
- 3軸すべてが異なる回転
-
{1,2,3} x-y-z 回転 
{1,3,2} x-z-y 回転 
{2,1,3} y-x-z 回転 
{2,3,1} y-z-x 回転 
{3,1,2} z-x-y 回転 
{3,2,1} z-y-x 回転(デフォルト) 
- 続く軸が繰り返されている回転でも回転行列を生むが,この回転はRollPitchYawAnglesを使って一意的に反転させることはできない.
- RollPitchYawMatrixは,返す行列の構造を指定するオプションTargetStructureをサポートする.次は, TargetStructureの可能な設定である.
-
Automatic 返す表現を自動選択する "Dense" 行列を密な行列として表す "Orthogonal" 行列を直交行列として表す "Unitary" 行列をユニタリ行列として表す - RollPitchYawMatrix[…,TargetStructureAutomatic]はRollPitchYawMatrix[…,TargetStructure"Dense"]に等しい.
例題
すべて開く すべて閉じる例 (2)
RollPitchYawMatrix[{α, β, γ}] /. {Cos[x_] :> Subscript[c, x], Sin[x_] :> Subscript[s, x]}//MatrixFormm = RollPitchYawMatrix[{(π/4), (π/3), (3π/4)}];Graphics3D[GeometricTransformation[Cuboid[], m]]スコープ (5)
(m = RollPitchYawMatrix[{(3π/4), (π/3), (π/3)}])//MatrixFormv1 = {1, 0, 0};
v2 = m.v1Graphics3D[{Arrow[{{0, 0, 0}, v1}], Red, Arrow[{{0, 0, 0}, v2}]}]第2引数を指定することで,x-y-zロールピッチヨー回転行列を与える:
m = RollPitchYawMatrix[{(3π/4), (π/3), (π/3.)}, {1, 2, 3}]v1 = {1, 0, 0}; v2 = m.v1;Graphics3D[{Arrow[{{0, 0, 0}, v1}], Red, Arrow[{{0, 0, 0}, v2}]}]GeometricTransformationを使って3Dグラフィックスのプリミティブを回転させる:
m = RollPitchYawMatrix[{(π/4), (π/3), (3π/4)}];before = {Blue, Cuboid[], Green, Point[{1, 1, 1}]};
after = {Red, GeometricTransformation[Cuboid[], m], Green, GeometricTransformation[Point[{1, 1, 1}], m]};Graphics3D[{PointSize[.05], before, after}]TransformedRegionを使って領域を回転させる:
s1 = [image];m = RollPitchYawMatrix[{Pi / 4, -Pi / 2, -Pi / 4}];s2 = TransformedRegion[s1, AffineTransform@m];{s1, s2}ImageTransformationを使って3D画像を回転させる:
r1 = ExampleData[{"TestImage3D", "Orbits"}];m = RollPitchYawMatrix[{Pi / 4, -Pi / 4, -Pi / 4}];r2 = ImageTransformation[r1, InverseFunction@AffineTransform@m, PlotRange -> All];{r1, r2}オプション (1)
TargetStructure (1)
RollPitchYawMatrix[{(3π/4), (π/3), (π/3)}, TargetStructure -> "Dense"]RollPitchYawMatrix[{(3π/4), (π/3), (π/3)}, TargetStructure -> "Orthogonal"]RollPitchYawMatrix[{(3π/4), (π/3), (π/3)}, TargetStructure -> "Unitary"]アプリケーション (6)
図解 (1)
$scene = First@[image];RollPitchYawRotationIllustration[{α_, β_, γ_}, {a_, b_, c_}] :=
Map[Graphics3D[GeometricTransformation[$scene, #], PlotRange -> 1.2, ImageSize -> 110, BoxStyle -> LightGray]&,
{RollPitchYawMatrix[{0, 0, 0}, {a, b, c}], RollPitchYawMatrix[{α, 0, 0}, {a, b, c}], RollPitchYawMatrix[{α, β, 0}, {a, b, c}], RollPitchYawMatrix[{α, β, γ}, {a, b, c}]}
]次は,a-b-c軸の6つすべての回転である.最初は基本的なz-y-xロールピッチヨー回転である:
RollPitchYawRotationIllustration[{Pi / 2, Pi / 2, Pi / 2}, {3, 2, 1}]RollPitchYawRotationIllustration[{Pi / 2, Pi / 2, Pi / 2}, {1, 2, 3}]RollPitchYawRotationIllustration[{Pi / 2, Pi / 2, Pi / 2}, {1, 3, 2}]RollPitchYawRotationIllustration[{Pi / 2, Pi / 2, Pi / 2}, {2, 1, 3}]RollPitchYawRotationIllustration[{Pi / 2, Pi / 2, Pi / 2}, {2, 3, 1}]RollPitchYawRotationIllustration[{Pi / 2, Pi / 2, Pi / 2}, {3, 1, 2}]この他に,6つのa-b-a軸回転がある.最初はx-y-xロールピッチヨー回転である:
RollPitchYawRotationIllustration[{Pi / 2, Pi / 2, Pi / 2}, {1, 2, 1}]RollPitchYawRotationIllustration[{Pi / 2, Pi / 2, Pi / 2}, {1, 3, 1}]RollPitchYawRotationIllustration[{Pi / 2, Pi / 2, Pi / 2}, {2, 1, 2}]RollPitchYawRotationIllustration[{Pi / 2, Pi / 2, Pi / 2}, {2, 3, 2}]RollPitchYawRotationIllustration[{Pi / 2, Pi / 2, Pi / 2}, {3, 1, 3}]RollPitchYawRotationIllustration[{Pi / 2, Pi / 2, Pi / 2}, {3, 2, 3}]ジンバル (5)
ジンバルとは,オブジェクトそれ自体が任意の方向を向くことを許すピボットリングの系である.これは,さまざまなナビや画像アプリに使用されている:
ring3 = {Red, CapForm -> None, Tube[{{-.1, 0, 0}, {.1, 0, 0}}, 3], Line[{{{0, 0, 4}, {0, 0, 3}}, -{{0, 0, 4}, {0, 0, 3}}}]};
ring2 = {Blue, CapForm -> None, Tube[{{-.1, 0, 0}, {.1, 0, 0}}, 2], Line[{{{0, 3, 0}, {0, 2, 0}}, -{{0, 3, 0}, {0, 2, 0}}}]};
ring1 = {Green, CapForm -> None, Tube[{{-.1, 0, 0}, {.1, 0, 0}}, 1], Line[{{{0, 0, 1}, {0, 0, 2}}, -{{0, 0, 1}, {0, 0, 2}}}], Orange, Arrow[{{-1, 0, 0}, {1, 0, 0}}]};ジンバル内のオブジェクトの向きは,RollPitchYawMatrixを使って,リングの最も外側のリングから最も内側のリングまでの回転の角度でモデル化することができる.a-b-a軸の系が使われることに注意:
gimbal[{α_, β_, γ_}] := With[{},
Graphics3D[{GeometricTransformation[ring3, RollPitchYawMatrix[{0, 0, γ}, {3, 2, 3}]], GeometricTransformation[ring2, RollPitchYawMatrix[{0, β, γ}, {3, 2, 3}]], GeometricTransformation[ring1, RollPitchYawMatrix[{α, β, γ}, {3, 2, 3}]]},
ViewPoint -> {1.3, -2.4, 2.}, PlotRange -> 3.5, PlotLabel -> NumberForm[MatrixForm[{{α, β, γ}}], 2]]]Manipulate[gimbal[{α, β, γ}], {{α, 0}, 0, 2Pi, Pi / 32}, {{β, 0}, 0, 2Pi, Pi / 32}, {{γ, 0}, 0, 2Pi, Pi / 32}, SaveDefinitions -> True]a-b-c軸の回転のあるジンバルは,すべてのリングの軸がお互いに垂直である初期状態のジンバルの系をモデル化する:
ring3 = {Red, CapForm -> None, Tube[{{-.1, 0, 0}, {.1, 0, 0}}, 3], Line[{{{0, 0, 4}, {0, 0, 3}}, -{{0, 0, 4}, {0, 0, 3}}}]};
ring2 = {Blue, CapForm -> None, Tube[{{0, 0, -.1}, {0, 0, .1}}, 2], Line[{{{0, 3, 0}, {0, 2, 0}}, -{{0, 3, 0}, {0, 2, 0}}}]};
ring1 = {Green, CapForm -> None, Tube[{{0, -.1, 0}, {0, .1, 0}}, 1], Line[{{{1, 0, 0}, {2, 0, 0}}, -{{1, 0, 0}, {2, 0, 0}}}], Orange, Arrow[{{0, -1, 0}, {0, 1, 0}}]};gimbal[{α_, β_, γ_}] :=
Graphics3D[{GeometricTransformation[ring3, RollPitchYawMatrix[{0, 0, γ}, {1, 2, 3}]], GeometricTransformation[ring2, RollPitchYawMatrix[{0, β, γ}, {1, 2, 3}]], GeometricTransformation[ring1, RollPitchYawMatrix[{α, β, γ}, {1, 2, 3}]]},
ViewPoint -> {1.3, -2.4, 2.}, PlotRange -> 3.5, PlotLabel -> NumberForm[MatrixForm[{{α, β, γ}}], 2]]Manipulate[gimbal[{α, β, γ}], {{α, 0}, 0, 2Pi, Pi / 32}, {{β, 0}, 0, 2Pi, Pi / 32}, {{γ, 0}, 0, 2Pi, Pi / 32}, SaveDefinitions -> True]回転形が,特定の角度の値が系の自由度を低下させるジンバルロックに陥ることがある.通常の,ロックされていないケースは次を生成する:
(m1 = RollPitchYawMatrix[{α, β, γ}] /. {β -> π / 3})//MatrixFormベクトル{1,1,0}を曲面上の任意の点まで回転させることができる:
ParametricPlot3D[m1.{1, 1, 0}, {α, 0, 2π}, {γ, 0, 2π}](m2 = RollPitchYawMatrix[{α, β, γ}] /. {β -> Pi / 2})//TrigReduce//MatrixFormParametricPlot3D[m2.{1, 1, 0}, {α, 0, 2π}, {γ, 0, 2π}]軸が
のとき,ジンバルロックは
のときに起こる.次はx-y-x 回転の例である:
axes = {1, 2, 1};これはロックされていない m1とロックされた m2のケースである:
m1 = RollPitchYawMatrix[{α, β, γ}, axes] /. {β -> Pi / 2};
m2 = RollPitchYawMatrix[{α, β, γ}, axes] /. {β -> Pi};{ParametricPlot3D[m1.{1, 1, 1}, {α, 0, 2π}, {γ, 0, 2π}], ParametricPlot3D[m2.{1, 1, 1}, {α, 0, 2π}, {γ, 0, 2π}]}z-y-z回転についての,アンロックされた m1とロックされた m2のケース:
axes = {3, 2, 3};m1 = RollPitchYawMatrix[{α, β, γ}, axes] /. {β -> Pi / 3};
m2 = RollPitchYawMatrix[{α, β, γ}, axes] /. {β -> Pi};{ParametricPlot3D[m1.{1, 1, 1}, {α, 0, 2π}, {γ, 0, 2π}], ParametricPlot3D[m2.{1, 1, 1}, {α, 0, 2π}, {γ, 0, 2π}]}軸がすべて異なる
のとき,ジンバルロックは
のときに起こる.次はx-y-z回転の場合である:
axes = {1, 2, 3};m1 = RollPitchYawMatrix[{α, β, γ}, axes] /. {β -> Pi / 2};
m2 = RollPitchYawMatrix[{α, β, γ}, axes] /. {β -> Pi};{ParametricPlot3D[m1.{1, 1, 1}, {α, 0, 2π}, {γ, 0, 2π}],
ParametricPlot3D[m2.{1, 1, 1}, {α, 0, 2π}, {γ, 0, 2π}]}y-x-z回転についての,ロックされた m1とアンロックされた m2のケース:
axes = {2, 1, 3};m1 = RollPitchYawMatrix[{α, β, γ}, axes] /. {β -> Pi / 2};
m2 = RollPitchYawMatrix[{α, β, γ}, axes] /. {β -> Pi / 3};{ParametricPlot3D[m1.{1, 1, 1}, {α, 0, 2π}, {γ, 0, 2π}],
ParametricPlot3D[m2.{1, 1, 1}, {α, 0, 2π}, {γ, 0, 2π}]}特性と関係 (11)
RollPitchYawMatrixは3回転に相当する:
rα = RotationMatrix[α, {0, 0, 1}];
rβ = RotationMatrix[β, {0, 1, 0}];
rγ = RotationMatrix[γ, {1, 0, 0}];Simplify[rγ.rβ.rα == RollPitchYawMatrix[{α, β, γ}]]rollpitchyawMatrix[{α_, β_, γ_}, {i_, j_, k_}] :=
RotationMatrix[γ, UnitVector[3, k]].RotationMatrix[β, UnitVector[3, j]].RotationMatrix[α, UnitVector[3, i]];Simplify[rollpitchyawMatrix[{α, β, γ}, {1, 2, 3}] == RollPitchYawMatrix[{α, β, γ}, {1, 2, 3}]]RollPitchYawAnglesを使って同じ回転行列を生成する角度を返す:
m1 = RollPitchYawMatrix[{π / 3, π / 2, π / 4}];m2 = RollPitchYawMatrix[RollPitchYawAngles[m1, {3, 2, 1}]];m1 == m2a1 = {π / 2, π, π / 3};
m1 = RollPitchYawMatrix[a1];a2 = RollPitchYawAngles[m1, {3, 2, 1}]RollPitchYawMatrix[a1] == RollPitchYawMatrix[a2]RollPitchYawMatrixは,各ステップで大局的軸(固定枠)について回転する:
Graphics3D[GeometricTransformation[Cuboid[], RollPitchYawMatrix[{π / 2, π / 2, π / 2}, {1, 2, 3}]], PlotRange -> 1]EulerMatrixは,各ステップで局所的軸(移動枠)について回転する:
Graphics3D[GeometricTransformation[Cuboid[], EulerMatrix[{π / 2, π / 2, π / 2}, {1, 2, 3}]], PlotRange -> 1]連続する2つの回転軸が等しいとき,つまり,
あるいは
であるとき,その系の自由度はx-y-y回転を行うときのように2度である:
axes = {1, 2, 2};
m = RollPitchYawMatrix[{α, β, γ}, axes] /. {β -> #}& /@ Range[0, 3Pi / 2, Pi / 2];ParametricPlot3D[#.{1, 1, 1}, {α, 0, 2π}, {γ, 0, 2π}]& /@ mすべての回転軸が等しいとき,つまり,
のとき,その系の自由度はx-x-x回転を行うときのように1度である:
axes = {1, 1, 1};
m = RollPitchYawMatrix[{α, β, γ}, axes] /. {β -> #}& /@ Range[0, 3Pi / 2, Pi / 2];ParametricPlot3D[#.{1, 1, 1}, {α, 0, 2π}, {γ, 0, 2π}]& /@ mEulerMatrix[{α,β,γ},{a,b,c}]はRollPitchYawMatrix[{γ,β,α},{c,b,a}]に等しい:
RollPitchYawMatrix[{α, β, γ}, {1, 2, 3}] == EulerMatrix[{γ, β, α}, {3, 2, 1}]RollPitchYawMatrixは,3つの軸志向回転によって任意の表記をパラメータ化する:
v = {1, 0, 0};RollPitchYawMatrix[{Pi / 4, -Pi / 4, 0}].v一般的な軸の周りの回転についてはRotationMatrixを使う:
RotationMatrix[Pi / 2, {1, 0, 1}].vRollPitchYawMatrixは
でのみ適用される:
RollPitchYawMatrix[{Pi / 4, 0, 0}].{1, 0, 0}一般的な次元についてはRotationMatrixを使う:
RotationMatrix[Pi / 4].{1, 0}RotationMatrix[Pi / 4, {{1, 0, 0, 0}, {0, 1, 0, 0}}].{1, 0, 0, 0}RollPitchYawMatrixは行列式が1の直交行列である:
m = RollPitchYawMatrix[{α, β, γ}];OrthogonalMatrixQ[m]Det[m]//SimplifyRollPitchYawMatrixの逆は転置行列である:
m = RollPitchYawMatrix[{α, β, γ}];Simplify[Transpose[m] == Inverse[m]]RollPitchYawMatrix[{α,β,γ},{a,b,c}]の逆はRollPitchYawMatrix[{-γ,-β,-α},{c,b,a}]である:
Simplify[Inverse[RollPitchYawMatrix[{α, β, γ}, {1, 2, 3}]] == RollPitchYawMatrix[{-γ, -β, -α}, {3, 2, 1}]]考えられる問題 (1)
RollPitchYawMatrixでは,連続する回転軸が等しくてもよく,これが回転行列を生成する:
m = RollPitchYawMatrix[{Pi, Pi / 2, Pi / 8}, {1, 1, 2}]{OrthogonalMatrixQ[m], Det[m]}//Simplifyしかし,RollPitchYawAnglesでは連続する軸は異なっていなければならない:
RollPitchYawAngles[m, {1, 1, 2}]これは,連続する回転軸が等しいと,回転行列の中には表現できないものがあるためである:
m1 = RollPitchYawMatrix[{Pi / 3, 0, 0}, {3, 2, 1}]m2 = RollPitchYawMatrix[{α, β, γ}, {1, 1, 2}]FindInstance[And@@Thread[m1 == m2], {α, β, γ}]おもしろい例題 (2)
GeometricTransformationを使って角度範囲で球の回転を可視化する:
Graphics3D[GeometricTransformation[{Hue[# / 4Pi], Sphere[{5, 0, 0}, 1]}, RollPitchYawMatrix[{#, Pi / 4, # * 4}]]& /@ Range[0, 2Pi, Pi / 64]]Graphics3D[GeometricTransformation[{Hue[Total@# / 6Pi], Tetrahedron[{{-1, -(3 Sqrt[3]/8), -(3/8)}, {1, -(3 Sqrt[3]/8), -(3/8)}, {0, (5 Sqrt[3]/8), -(3/8)}, {0, (Sqrt[3]/8), (9/8)}}]}, RollPitchYawMatrix[#]]& /@ RandomReal[{0, 2Pi}, {10, 3}]]テキスト
Wolfram Research (2015), RollPitchYawMatrix, Wolfram言語関数, https://reference.wolfram.com/language/ref/RollPitchYawMatrix.html (2024年に更新).
CMS
Wolfram Language. 2015. "RollPitchYawMatrix." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2024. https://reference.wolfram.com/language/ref/RollPitchYawMatrix.html.
APA
Wolfram Language. (2015). RollPitchYawMatrix. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/RollPitchYawMatrix.html
BibTeX
@misc{reference.wolfram_2026_rollpitchyawmatrix, author="Wolfram Research", title="{RollPitchYawMatrix}", year="2024", howpublished="\url{https://reference.wolfram.com/language/ref/RollPitchYawMatrix.html}", note=[Accessed: 16-November-2026]}
BibLaTeX
@online{reference.wolfram_2026_rollpitchyawmatrix, organization={Wolfram Research}, title={RollPitchYawMatrix}, year={2024}, url={https://reference.wolfram.com/language/ref/RollPitchYawMatrix.html}, note=[Accessed: 16-November-2026]}