WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

SelectionMove[obj,dir,unit]

フロントエンドの開いた状態にあるノートブックにおいて，現在の選択範囲を dir 方向に指定された単位の距離だけ移動する．

SelectionMove[obj,dir,unit,n]

移動操作を n 回繰り返す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
AutoScroll  
特性と関係  
考えられる問題  
関連項目
テクニカルノート
関連するガイド
関連するワークフロー
履歴
引用書式

SelectionMove

SelectionMove[obj,dir,unit]

フロントエンドの開いた状態にあるノートブックにおいて，現在の選択範囲を dir 方向に指定された単位の距離だけ移動する．

SelectionMove[obj,dir,unit,n]

移動操作を n 回繰り返す．

詳細とオプション

  • SelectionMoveの第1引数は，NotebookObject，CellObject，BoxObjectでよい．
  • 指定可能な方向
  • Next指定型の後方の単位を選択範囲とする
    Previous指定型の前方の単位を選択範囲とする
    After現在の単位の直後の点を選択範囲とする
    Before現在の単位の直前の点を選択範囲とする
    All現在の単位の全体を選択範囲とする
  • 指定可能な単位
  • Character個々の文字
    Word単語やトークン
    Expression式や項全体
    TextLine行
    GraphicsContentsグラフィックスオブジェクトの内容
    Graphicsグラフィックスオブジェクト全体
    CellContentsセルの内容
    Cellセル全体
    CellGroupセルグループ
    GeneratedCell現在の評価処理により生成されるセル
    Notebookノートブック全体
  • AutoScroll->Falseのオプション設定が有効でない限り，フロントエンドは，SelectionMoveの評価結果を表示できる位置までノートブックをスクロールする． »
  • また，フロントエンドは，通常結果に対応した範囲をハイライト表示する．
  • AfterとBeforeの方向指定があるとき，SelectionMoveは，指定された型の2単位の中間点を新たな現行選択位置とする． »
  • SelectionMoveは，ユーザの要求通りに選択範囲を移動できないとき$Failedを返す．
  • GeneratedCellは，出力の要素に対応する．
  • SelectionMove[{cellobj1,cellobj2,…},All,Cell]は複数のセルオブジェクトを，例えそれらがノートブック内で連続していなくても，選択する． »

例題

すべて開く すべて閉じる

例  (4)

最初の選択位置の後の最初のセルを選ぶ：

Wolfram Language code: nb = NotebookPut[Notebook[{Cell["サブセクション見出し", "Subsection"], Cell["テキスト．", "Text"]}]]; SelectionMove[nb, Next, Cell]

最初の選択位置の後の3番目のセルを選ぶ：

Wolfram Language code: nb = NotebookPut[Notebook[{Cell["サブセクション見出し", "Subsection"], Cell["テキスト．", "Text"], Cell["さらにテキスト．", "Text"]}]]; SelectionMove[nb, Next, Cell, 3]

選択範囲をセルに移す：

Wolfram Language code: obj = EvaluationCell[]; SelectionMove[obj, All, Cell]

評価を引き起こすボタンを選ぶ：

Wolfram Language code: Button["クリック", SelectionMove[EvaluationBox[], All, Expression]]

スコープ  (2)

ノートブックを作る：

Wolfram Language code: nb = CreateWindow[DocumentNotebook[{CellGroup[{TextCell["テキストグループ", "Section"], TextCell["メリーさんのひつじ", "Text"], TextCell["真っ白ね", "Text"]}], CellGroup[{TextCell["グラフィックスグループ", "Section"], ExpressionCell[ Plot[Exp[-x ^ 2], {x, -3, 3}], "Output"]}]}]];

選択位置を最初の文字に移動する：

Wolfram Language code: SelectionMove[nb, Before, CellContents]; SelectionMove[nb, All, Character]

選択位置をセルグループ(CellGroup)に移動する：

Wolfram Language code: SelectionMove[nb, All, CellGroup]

選択位置をセル内のグラフィックスに移動する：

Wolfram Language code: SelectionMove[nb, Next, CellContents, 2]

選択位置をノートブックの最後に移動する：

Wolfram Language code: SelectionMove[nb, After, Notebook]

いくつかのセルがあるノートブックを作成する：

Wolfram Language code: nb = CreateDocument[Table[ExpressionCell[i], {i, 5}]]

ノートブックの最初と最後のセルを同時に選択する：

Wolfram Language code: cells = Cells[nb]; SelectionMove[{First[cells], Last[cells]}, All, Cell]

オプション  (1)

AutoScroll  (1)

一般に，選択されたものはその位置にかかわらずノートブックウィンドウに可視的に表示される：

Wolfram Language code: nb = NotebookPut[Notebook[{Cell["サブセクション見出し", "Subsection"], Sequence@@Table[Cell["テキスト", "Text"], {50}]}]]; SelectionMove[nb, Next, Cell, 30]

AutoScrollをFalseに設定すると，選択位置がスクリーンの外になることがある：

Wolfram Language code: nb = NotebookPut[Notebook[{Cell["サブセクション見出し", "Subsection"], Sequence@@Table[Cell["テキスト．", "Text"], {50}]}]]; SelectionMove[nb, Next, Cell, 30, AutoScroll -> False]

特性と関係  (1)

SelectionMoveはインラインセルを単語と同じものとみなす：

Wolfram Language code: nb = NotebookPut[Notebook[{Cell[TextData[{Cell["インライン", "Subsection"], " サブセクションセルで始まるテキスト．"}], "Text"]}]]; SelectionMove[nb, Before, CellContents]
Wolfram Language code: SelectionMove[nb, Next, Word]

キーボードはカーソルの動きを模倣するのに"MoveNext"のようなフロントエンドトークンを使う：

Wolfram Language code: FrontEndExecute[FrontEndToken[nb, "MoveNext"]]

考えられる問題  (1)

SelectionMoveはCellGroupユニット指定の一部として複数のセルのみを選択する：

Wolfram Language code: nb = NotebookPut[Notebook[{Cell["サブセクション見出し", "Subsection"], Cell["テキスト．", "Text"], Cell["さらにテキスト．", "Text"]}]]; SelectionMove[nb, Next, CellGroup]

一連の個々のセルを選択するためには，"SelectNextLine"のようなフロントエンドトークンを使う：

Wolfram Language code: nb = NotebookPut[Notebook[{Cell["サブセクション見出し", "Subsection"], Cell["テキスト．", "Text"], Cell["さらにテキスト．", "Text"]}]]; SelectionMove[nb, Next, Cell]; FrontEndExecute[FrontEndToken[nb, "SelectNextLine"]]
Wolfram Research (1996), SelectionMove, Wolfram言語関数， https://reference.wolfram.com/language/ref/SelectionMove.html （2025年に更新）.

テキスト

Wolfram Research (1996), SelectionMove, Wolfram言語関数， https://reference.wolfram.com/language/ref/SelectionMove.html （2025年に更新）.

CMS

Wolfram Language. 1996. "SelectionMove." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2025. https://reference.wolfram.com/language/ref/SelectionMove.html.

APA

Wolfram Language. (1996). SelectionMove. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/SelectionMove.html

BibTeX

@misc{reference.wolfram_2026_selectionmove, author="Wolfram Research", title="{SelectionMove}", year="2025", howpublished="\url{https://reference.wolfram.com/language/ref/SelectionMove.html}", note=[Accessed: 12-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_selectionmove, organization={Wolfram Research}, title={SelectionMove}, year={2025}, url={https://reference.wolfram.com/language/ref/SelectionMove.html}, note=[Accessed: 12-November-2026]}