Wolfram 语言与系统参考资料中心

Set

lhs=rhs

计算 rhs 并把结果赋给 lhs. lhs 将总是被 rhs 替换.

{l₁,l₂,…}={r₁,r₂,…}

计算 r_i，并将结果赋给对应的 l_i.

背景

Set 是一个函数，对表达式求值并将结果作为变量的值. 表达式通常用简化语法表示成的形式. 在 Set 被求值后，当 lhs 出现时会被替换成 rhs. 根据 lhs 的形式，结果会被存储为与其关联的 OwnValues、DownValues 或特殊的数据结构.
Set 通常在左侧 lhs 包含模式，用于被赋值为右侧 rhs 指定的转换后的值，例如，. 会对 rhs 立刻进行求值，这样在需要 rhs 只在应用规则后才被求值的场合，应该用 SetDelayed（简写为 :=）代替.
查看给定符号关联的赋值可以用 Definition[f]. 可以用 Unset 把单独的赋值从符号中移除；Clear 和 ClearAll 可以一次性移除全部的定义.

范例

打开所有单元关闭所有单元

基本范例 (2)

设置的一个值：

Wolfram Language code: x = a + b

使用该值：

Wolfram Language code: 1 + x ^ 2

恢复：

Wolfram Language code: x=.

设置多个值：

Wolfram Language code: {x, y, z} = Range[3]

用这些值计算表达式：

Wolfram Language code: x + y ^ 2 + z ^ 3

范围 (15)

左侧： (7)

普通的程序变量：

Wolfram Language code:

i = 1;
While[Prime[i] < 100, i = i + 1];i

设置“指标变量”的值：

Wolfram Language code: a[1] = x;a[2] = y;

Wolfram Language code: {a[1], a[2], a[3]}

按一个表达式定义一个函数：

Wolfram Language code: Expand[(1 + x) ^ 3]

Wolfram Language code: f[x_] = %

Wolfram Language code: f[a + b]

用 Block 临时设置变量：

Wolfram Language code: Block[{$RecursionLimit = 20}, x = x + 1]

设置列表的子集：

Wolfram Language code: v = {a, b, c, d}

Wolfram Language code: v[[2]] = x

Wolfram Language code: v

设置表达式的子集：

Wolfram Language code: v = 1 + x ^ 5

Wolfram Language code: v[[2, 2]] = 77777

Wolfram Language code: v

Wolfram Language code:

mat = (|   |   |   |
| - | - | - |
| 1 | 2 | 3 |
| 4 | 5 | 6 |
| 7 | 8 | 9 |);

替换矩阵的一行：

Wolfram Language code:

mat[[2]] = mat[[2]] + 10;
MatrixForm[mat]

替换矩阵的一列：

Wolfram Language code:

mat[[All, 3]] = {100, 101, 102};
MatrixForm[mat]

不同类型的值： (8)

本值:

Wolfram Language code: x = 7;

Wolfram Language code: OwnValues[x]

下值（downvalue）：

Wolfram Language code: a[1] = 17;

Wolfram Language code: DownValues[a]

此值：

Wolfram Language code: derivative[1][f] = fg;

Wolfram Language code: SubValues[derivative]

上值（upvalue）：

Wolfram Language code: sq/:area[sq] = s ^ 2;

Wolfram Language code: UpValues[sq]

缺省值和选项：

Wolfram Language code: Default[f] = 0;

Wolfram Language code: Options[f] = {opt1 -> def1, opt2 -> def2};

Wolfram Language code: DefaultValues[f]

数值值：

Wolfram Language code: N[const] = Product[1 - 2 ^ -i, {i, 2, 10}];

Wolfram Language code: NValues[const]

Wolfram Language code: N[const]

格式值：

Wolfram Language code: Format[a] = α;

Wolfram Language code: FormatValues[a]

Wolfram Language code: a

与相关的 Attributes 的定义，而不是 Attributes：

Wolfram Language code: Attributes[f] = HoldAll

Wolfram Language code: Definition[f]

推广和延伸 (5)

赋给和相同的值：

Wolfram Language code: x = y = 77

检查：

Wolfram Language code: {x, y}

赋给和不同的值：

Wolfram Language code: {x, y} = {a, b}

交换值：

Wolfram Language code: {x, y} = {y, x}

查看是否被交换：

Wolfram Language code: {x, y}

一个稀疏数组：

Wolfram Language code: v = SparseArray[{1 -> 1, 4 -> 4}]

设置其中的一个值：

Wolfram Language code: v[[2]] = 3

v 依然是一个稀疏矩阵，但第二个元素的值已被改变：

Wolfram Language code: {v, Normal[v]}

将函数返回的多个值赋给各个变量：

Wolfram Language code: {time, res} = Timing[N[Catalan, 100000]];

查看结果：

Wolfram Language code: {time, N[res]}

有特定标头的模式的定义与该标头关联在一起：

Wolfram Language code: _a = α

显示定义：

Wolfram Language code: Definition[a]

计算：

Wolfram Language code: {a, a[1]}

应用 (6)

计算 2 个数的最大公约数：

Wolfram Language code:

{a, b} = {27, 6};
While[b ≠ 0, {a, b} = {b, Mod[a, b]}];
a

求出一个固定点：

Wolfram Language code:

x = 1.0;
While[Cos[x] ≠ x, x = Cos[x]];
x

用牛顿方法计算：

Wolfram Language code:

x = 1.0;
Do[x = (x + 2 / x) / 2, {5}];
x

使用一个变量作为一个复杂表达式的缩写，并不止调用一次：

Wolfram Language code: x = (a + b)^2;

Wolfram Language code: 1 + x + 1 / x

在线性方程组中回代的标量执行：

Wolfram Language code:

upperTriangularLinearSolve[ U_, v_ ]  := 
	Module[ {x, m, n}, 
	{m, n} = Dimensions[U]; x = Range[n];
	Do[x[[i]] = (v[[i]] - Subsuperscript[∑, j = i + 1, n]U[[i, j]] x[[j]]) / U[[i, i]], {i, n, 1, -1}];
	x
	]

Wolfram Language code: upperTriangularLinearSolve[{{1, 2}, {0, 3}}, {1, 2} ]

在线性方程组中回代的向量执行：

Wolfram Language code:

upperTriangularLinearSolve[ U_, v_ ]  := 
	Module[ {x, m, n}, 
	{m, n} = Dimensions[U]; x = Range[n];
	Do[x[[i]] = (v[[i]] - U[[i, i + 1 ;; n]].x[[i + 1 ;; n]]) / U[[i, i]], {i, n, 1, -1}];
	x
	];

Wolfram Language code: upperTriangularLinearSolve[{{1, 2}, {0, 3}}, {1, 2} ]

属性和关系 (9)

立即定义的右侧会在定义时被计算：

Wolfram Language code: x = RandomReal[];

多个副本具有相同的值：

Wolfram Language code: {x, x, x}

延迟定义的右侧在每次使用该定义时都会被计算：

Wolfram Language code: y := RandomReal[];

被计算三次：

Wolfram Language code: {y, y, y}

定义左边的参数在定义前计算：

Wolfram Language code: x = 5;

Wolfram Language code: f[x] = 17

Wolfram Language code: Definition[f]

具有相同左边的定义会覆盖较早的定义：

Wolfram Language code: a = 5;

重新定义：

Wolfram Language code: a = 6;

现在有新的值：

Wolfram Language code: a

用立即赋值和延迟赋值执行特殊定义和普通定义：

Wolfram Language code:

fact[1] = 1;
fact[n_] := n fact[n - 1]
fact[10]

将特殊定义放在普通定义前：

Wolfram Language code:

fact[n_] := n fact[n - 1];
fact[1] = 1;
Definition[fact]

使用 fact 的定义：

Wolfram Language code: fact[10]

如果有必要，模式变量将在嵌套作用域内被重新命名：

Wolfram Language code:

makedef[z_] := (f[x_] = z ^ 2;)
makedef[x]

查看定义：

Wolfram Language code: Definition[f]

使用该定义：

Wolfram Language code: f[5]

Module 引入新的符号，这与全局符号不同：

Wolfram Language code:

x = 5;
Module[{x}, x = 17;x]

检查 x 的全局值是否被保留：

Wolfram Language code: x

设置 a 的值：

Wolfram Language code: a = Sqrt[2]

Definition 显示与符号关联的定义：

Wolfram Language code: Definition[a]

Information 输出关于符号的变量信息，包括任何定义：

Wolfram Language code: ? a

OwnValues 返回与定义的任何下值 (downvalue) 对应的规则列表：

Wolfram Language code: OwnValues[a]

定义计算阶乘的函数 fact：

Wolfram Language code:

fact[1] = 1;
fact[n_] := n fact[n - 1]

用 Unset (=.) 清除具有特定左侧的定义：

Wolfram Language code: fact[1]=.

检查已清除的定义是否不再存在：

Wolfram Language code: Definition[fact]

清除所有定义：

Wolfram Language code: Clear[fact]

Wolfram Language code: Definition[fact]

可能存在的问题 (4)

存在全局变量时，模式变量可能表现异常：

Wolfram Language code: x = 5;

使用非延迟赋值意味着在执行 Set 之前会先计算右侧的表达式：

Wolfram Language code: f[x_] = x ^ 2;

所以计算使用的是全局设置，而不是 f 的实际输入：

Wolfram Language code: f[2]

延迟赋值则按预期进行计算：

Wolfram Language code: g[x_] := x ^ 2

检查是否使用的时 2，而不是全局值 5：

Wolfram Language code: g[2]

超出限制的定义：

Wolfram Language code: x = x + 1

设置初值，避免这种情况的发生：

Wolfram Language code:

y = 5;
y = y + 1

非符号的模式变量通常不能被赋值：

Wolfram Language code:

wrong[x_] := (x = x ^ 2)
wrong[5]

因此使用的局部变量：

Wolfram Language code:

right[x0_] := Module[{x}, x = x0 ^ 2]
right[5]

将上值 (upvalue) 赋给下标变量：

Wolfram Language code:

a/:Subscript[a, 1] = 5;
FullForm[UpValues[a]]

下标变量和指标变量不同：

Wolfram Language code:

a[1] = 6;
FullForm[DownValues[a]]

巧妙范例 (1)

计算两个数的算术-几何均值 [更多信息]：

Wolfram Language code:

{x, y} = N[{1, 2}, 20];
While[x ≠ y, {x, y} = {(x + y/2), Sqrt[x y]}];x

Top

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

Set

更多信息

背景

范例

基本范例 (2)

范围 (15)

左侧： (7)

不同类型的值： (8)

推广和延伸 (5)

应用 (6)

属性和关系 (9)

可能存在的问题 (4)

巧妙范例 (1)

文本

CMS

APA

BibTeX

BibLaTeX

Set

更多信息

背景

范例

基本范例 (2)

范围 (15)

左侧： (7)

不同类型的值： (8)

推广和延伸 (5)

应用 (6)

属性和关系 (9)

可能存在的问题 (4)

巧妙范例 (1)

参见

技术笔记

相关指南

相关链接

历史

文本

CMS

APA

BibTeX

BibLaTeX