WOLFRAM

Wolfram 语言与系统参考资料中心

StadiumShape[{{x1,y1},{x2,y2}},r]

代表一个半径为 r 的在点 {x1,y1} 和 {x2,y2} 之间的体育场形.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
图形  
规范  
样式  
坐标  
区域  
应用  
属性和关系  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

StadiumShape

StadiumShape[{{x1,y1},{x2,y2}},r]

代表一个半径为 r 的在点 {x1,y1} 和 {x2,y2} 之间的体育场形.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (5)

一个标准体育场形：

Wolfram Language code: StadiumShape[]
Wolfram Language code: Graphics[%]

不同半径：

Wolfram Language code: Graphics[{Orange, StadiumShape[3]}]

不同定点：

Wolfram Language code: Graphics[{Orange, StadiumShape[{{0, 0}, {2, 3}}, 2]}]

不同风格的体育场形：

Wolfram Language code: {Graphics[{Pink, StadiumShape[]}], Graphics[{EdgeForm[Thick], Pink, StadiumShape[]}], Graphics[{EdgeForm[Dashed], Pink, StadiumShape[]}], Graphics[{EdgeForm[Directive[Thick, Dashed, Blue]], Pink, StadiumShape[]}]}

获取一个体育场形的 Area：

Wolfram Language code: Area[StadiumShape[]]

体育场形的面积：

Wolfram Language code: Area[StadiumShape[{{0, 0}, {x, y}}, 3]]

范围  (16)

图形  (6)

规范  (3)

指定半径：

Wolfram Language code: Graphics[{Red, StadiumShape[3], Green, StadiumShape[2], Blue, StadiumShape[1]}]

指定点：

Wolfram Language code: Graphics[{Red, StadiumShape[{{0, 0}, {2, 2}}, 1], Green, StadiumShape[{{-2, 2}, {0, 0}}, 1], Blue, StadiumShape[{{0, 0}, {0, -Sqrt[4]}}, 1]}]

在原点的标准体育场形的简易格式：

Wolfram Language code: Graphics[StadiumShape[], Frame -> True]

样式  (2)

用于指定体育场形的表面颜色的颜色指令：

Wolfram Language code: Table[Graphics[{c, StadiumShape[]}], {c, {Red, Green, Blue, Yellow}}]

FaceForm 和 EdgeForm 可用于指定内部和边界的风格：

Wolfram Language code: Graphics[{FaceForm[Pink], EdgeForm[Directive[Dashed, Thick, Blue]], StadiumShape[]}]

体育场形的边界：

Wolfram Language code: Graphics[{Yellow, EdgeForm[Directive[Thick, Blue]], StadiumShape[{{0, 0}, {3, 2}}, 1 / 2]}]

坐标  (1)

点可以是 Dynamic：

Wolfram Language code: DynamicModule[{x}, {Slider[Dynamic[x], {0, 2}], Graphics[{StadiumShape[{Dynamic[{x, x}], {-1, -1}}, 1]}, PlotRange -> 3]}]

区域  (10)

嵌入维度：

Wolfram Language code: RegionEmbeddingDimension[StadiumShape[{{Subscript[x, 1], Subscript[y, 1]}, {Subscript[x, 2], Subscript[y, 2]}}, r]]

几何维度：

Wolfram Language code: RegionDimension[StadiumShape[{{Subscript[x, 1], Subscript[y, 1]}, {Subscript[x, 2], Subscript[y, 2]}}, r]]

判断点是否为区域的成员：

Wolfram Language code: {RegionMember[StadiumShape[], {0, 0}], RegionMember[StadiumShape[], {0, 2}]}

获取成为该区域成员的条件：

Wolfram Language code: RegionMember[StadiumShape[{{Subscript[x, 1], Subscript[y, 1]}, {Subscript[x, 2], Subscript[y, 2]}}, r], {x, y}]

面积：

Wolfram Language code: ℛ = StadiumShape[];
Wolfram Language code: {Area[ℛ], RegionMeasure[ℛ]}

几何中心：

Wolfram Language code: c = RegionCentroid[ℛ]
Wolfram Language code: Graphics[{{Pink, ℛ}, {Black, Point[c]}}]

到一个点的距离：

Wolfram Language code: ℛ = StadiumShape[];
Wolfram Language code: {RegionDistance[ℛ, {1, 2}], RegionDistance[ℛ, {0, 0}]}

到标准体育场形中最近点的距离：

Wolfram Language code: {Plot3D[RegionDistance[ℛ, {x, y}], {x, -2, 2}, {y, -2, 2}, MeshFunctions -> {#3&}, Mesh -> 5, Exclusions -> Norm[{x, y}] == 1], ContourPlot[RegionDistance[ℛ, {x, y}], {x, -3, 3}, {y, -3, 3}, Contours -> {{0.5, Red}, {1, Green}, {1.5, Blue}}]}

到一个点的有符号距离：

Wolfram Language code: ℛ = StadiumShape[];
Wolfram Language code: {SignedRegionDistance[ℛ, {1, 2}], SignedRegionDistance[ℛ, {0, 0}]}

到标准体育场形的有符号距离：

Wolfram Language code: Plot3D[SignedRegionDistance[ℛ, {x, y}], {x, -2, 2}, {y, -2, 2}, MeshFunctions -> {#3&}, Mesh -> {{0}}, MeshShading -> {Red, Green}, Exclusions -> Norm[{x, y}] == 1]

区域内的最近点：

Wolfram Language code: ℛ = StadiumShape[{{0, 0}, {2, 2}}, 2];
Wolfram Language code: RegionNearest[ℛ, {0, 6}]

最近点：

Wolfram Language code: pts = Table[{1, 2} + 5{Cos[k 2 π / 16], Sin[k 2π / 16]}, {k, 0., 15}]; nst = RegionNearest[ℛ, #]& /@ pts;
Wolfram Language code: Legended[Graphics[{{Gray, ℛ}, {Thin, Gray, Line[Transpose[{pts, nst}]]}, {Red, Point[pts]}, {Blue, Point[nst]}}], PointLegend[{Red, Blue}, {"start", "nearest"}]]

一个体育场形是有界的：

Wolfram Language code: ℛ = StadiumShape[{{0, 0}, {2, 1}}, 1];
Wolfram Language code: BoundedRegionQ[ℛ]

获取其范围：

Wolfram Language code: rr = RegionBounds[ℛ]//Quiet
Wolfram Language code: Graphics[{Black, ℛ, {EdgeForm[{Dashed, Red}], Opacity[0.1, Yellow], Cuboid@@Transpose[rr]}}]

在体育场形上积分：

Wolfram Language code: ℛ = StadiumShape[{{0, 0}, {1, 1}}, 1];
Wolfram Language code: Integrate[x y, {x, y}∈ℛ]

在体育场形上最优化：

Wolfram Language code: ℛ = StadiumShape[];
Wolfram Language code: {MinValue[{x y - x, {x, y}∈ℛ}, {x, y}], ArgMin[{x y - x, {x, y}∈ℛ}, {x, y}]}

在一个体育场形中解方程：

Wolfram Language code: ℛ = StadiumShape[2];
Wolfram Language code: Solve[x^2 + y^2 == 7 && x y == 1 && {x, y}∈ℛ, {x, y}]
Wolfram Language code: Show[{Graphics[{{Green, ℛ}, {Blue, Circle[{0, 0}, Sqrt[7]]}}], Plot[1 / x, {x, -3, 5}, PlotRange -> {{-3, 5}, {-3, 6}}], Graphics[{PointSize[Large], Red, Point[{x, y}] /. %}]}, Axes -> True]

应用  (4)

在体育场形上画出函数：

Wolfram Language code: Plot3D[Sin[x + Cos[y]], {x, y}∈StadiumShape[]]

用 RegionProduct 创建一个三维体育场形的压成品：

Wolfram Language code: ℛ = RegionProduct[StadiumShape[], Line[{{0}, {1}}]];
Wolfram Language code: Region[ℛ]

用一组体育场形（和一个圆盘）来创建一个火柴人：

Wolfram Language code: p0 = {0, 0};p1 = {-6, -6};p2 = {-5, -15};p3 = {-1, -8}; p4 = {1, -16};p5 = {0, 20};p6 = {0, 28}; p7 = {-5, 17};p8 = {-15, 15};p9 = {-7, 22}; p10 = {-14, 21};
Wolfram Language code: leg1 = {StadiumShape[{p0, p1}, 1], StadiumShape[{p1, p2}, 1]}; leg2 = {StadiumShape[{p0, p3}, 1], StadiumShape[{p3, p4}, 1]}; back = StadiumShape[{p0, p5}, 1]; neck = {StadiumShape[{p5, p6}, 1], Disk[p6, 5]}; arm1 = {StadiumShape[{p5, p7}, 1], StadiumShape[{p7, p8}, 1]}; arm2 = {StadiumShape[{p5, p9}, 1], StadiumShape[{p9, p10}, 1]};
Wolfram Language code: Graphics[{back, leg1, leg2, neck, arm1, arm2}, ImageSize -> {Automatic, 150}]

用 RotationTransform 转动火柴人的四肢：

Wolfram Language code: r[region_, point_, angle_] := GeometricTransformation[region, RotationTransform[angle, point]]
Wolfram Language code: Manipulate[Graphics[{back, r[leg1, p0, a1], r[leg2, p0, a2], r[neck, p5, a5], r[arm1, p5, a3], r[arm2, p5, a4]}], {{a1, 0, "Left Leg"}, -Pi, Pi}, {{a2, 0, "Right Leg"}, -Pi, Pi}, {{a3, 0, "Lower Arm"}, -Pi, Pi}, {{a4, 0, "Higher Arm"}, -Pi, Pi}, {{a5, 0, "Neck"}, -Pi, Pi}, SaveDefinitions -> True]

利用一组体育场形组成一个弹簧. 假定各个体育场形有水平分量 ，做出一个生成弹簧正面部分的体育场形集合的函数，再做出一个生成弹簧后面部分的体育场形集合的函数：

Wolfram Language code: topstadiums[x_] := Table[StadiumShape[{{(i - 1) * x, -Sqrt[4 - x ^ 2 / 4]}, {(i - 1 / 2) * x, Sqrt[4 - x ^ 2 / 4]}}, .5], {i, 5}];
Wolfram Language code: bottomstadiums[x_] = Table[StadiumShape[{{(i - 1 / 2) * x, Sqrt[4 - x ^ 2 / 4]}, {i * x, -Sqrt[4 - x ^ 2 / 4]}}, .5], {i, 5}];

设定弹簧的正面为比后面浅的灰色，并利用 Manipulate 使其可以交互式伸缩：

Wolfram Language code: Manipulate[Graphics[{GrayLevel[.5], bottomstadiums[x], GrayLevel[.7], topstadiums[x]}, PlotRange -> {{-1, 21}, {-3, 3}}, ImageSize -> Medium], {{x, 2, "Push/Pull:"}, 1, 4}, SaveDefinitions -> True]

属性和关系  (6)

Disk 是 StadiumShape 的 p1 靠近 p2 的极限：

Wolfram Language code: Manipulate[Graphics[{Disk[], StadiumShape[{{2, 0}, {2 + n, 0}}, 1]}, PlotRange -> {{-1, 5}, {-1, 1}}, ImageSize -> Small], {{n, 2}, 2, .00001}]

StadiumShape 的三维版本是 CapsuleShape：

Wolfram Language code: Graphics3D[CapsuleShape[]]

StadiumShape 形成于圆盘和矩形的 RegionUnion：

Wolfram Language code: stadium = RegionUnion[Disk[{0, 0}, 1], Rectangle[{0, -1}, {2, 1}], Disk[{2, 0}, 1]];
Wolfram Language code: Region[stadium]

面积是圆盘和四边形面积的和：

Wolfram Language code: Area[stadium]
Wolfram Language code: Area[Disk[{0, 0}, 1]] + Area[Rectangle[{0, -1}, {2, 1}]]

StadiumShape 是到 Line 距离不超过 的所有点：

Wolfram Language code: Subscript[ℛ, 1] = Line[{{-1, 0}, {1, 0}}]; Subscript[ℛ, 2] = StadiumShape[];
Wolfram Language code: Reduce[RegionDistance[Subscript[ℛ, 1], {x, y}] ≤ 1⧦RegionMember[Subscript[ℛ, 2], {x, y}], {x, y}, Reals]

ImplicitRegion 可以表示任意 StadiumShape：

Wolfram Language code: Subscript[ℛ, 1] = ImplicitRegion[(x | y)∈Reals && r > 0 && ((1 + x)^2 + y^2 ≤ r^2 || (-1 + x)^2 + y^2 ≤ r^2 || (-2 (-1 + x) ≥ 0 && -2 (1 + x) ≤ 0 && -2 r ≤ -2 y ≤ 2 r)), {x, y}];
Wolfram Language code: Subscript[ℛ, 2] = StadiumShape[r];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

一个粗的圆的 Line 看起来就像一个 StadiumShape：

Wolfram Language code: Graphics[{CapForm["Round"], Thickness[1], Line[{{-1, 0}, {1, 0}}]}]

巧妙范例  (3)

随意排列的体育场形：

Wolfram Language code: Graphics[Table[{EdgeForm[Black], Hue[RandomReal[]], StadiumShape[RandomReal[10, {2, 2}], RandomReal[1]]}, {40}]]

体育场形族：

Wolfram Language code: Graphics[Table[{Hue[t / 30, 1, .9, .3], StadiumShape[{{0, 0}, {3Cos[2Pi t / 30], 3Sin[2Pi t / 30]}}, 1]}, {t, 30}]]

数字花瓣：

Wolfram Language code: Graphics[Table[{EdgeForm[Opacity[.6]], Hue[(-11 + q + 10 r) / 72], StadiumShape[{{0, 0}, (8 - r){Cos[2Pi q / 12], Sin[2Pi q / 12]}}, (8 - r) / 3]}, {r, 6}, {q, 12}]]
Wolfram Research (2015)，StadiumShape，Wolfram 语言函数，https://reference.wolfram.com/language/ref/StadiumShape.html.

文本

Wolfram Research (2015)，StadiumShape，Wolfram 语言函数，https://reference.wolfram.com/language/ref/StadiumShape.html.

CMS

Wolfram 语言. 2015. "StadiumShape." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/StadiumShape.html.

APA

Wolfram 语言. (2015). StadiumShape. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/StadiumShape.html 年

BibTeX

@misc{reference.wolfram_2026_stadiumshape, author="Wolfram Research", title="{StadiumShape}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/StadiumShape.html}", note=[Accessed: 03-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_stadiumshape, organization={Wolfram Research}, title={StadiumShape}, year={2015}, url={https://reference.wolfram.com/language/ref/StadiumShape.html}, note=[Accessed: 03-November-2026]}