SurvivalModelFit[{e1,e2,…}]
创建一个对应于事件时间 ei 的生存模型.
SurvivalModelFit
SurvivalModelFit[{e1,e2,…}]
创建一个对应于事件时间 ei 的生存模型.
更多信息和选项
- SurvivalModelFit 用于生存、可靠性和耐久性分析. 给出非参数生存分布以及直接来自于不完全数据的置信测量.
- SurvivalModelFit 返回一个符号式 SurvivalModel 对象表示它所构建的生存模式. 可以从 model["property"] 获得模型的属性和诊断.
- 事件 ei 的形式遵循 EventData 中使用的形式.
- 通过指定 model[h] 中的形式 h 获取生存模式的不同函数形式. 可以用以下形式:
-
"CDF" 累积分布函数 "CHF" 累积风险函数 "SF" 生存函数 - 在特殊时间 t 来自 SurvivalModelFit 的拟合函数 h 的值可以从 model[h][t] 中求得. model[t] 等同于 model["SF"][t].
- 指定 Normal[model] 给出估计生存函数的纯函数形式.
- 可用模型属性的列表可用 model["Properties"] 获取.
- 模型拟合函数 h 的属性可用 model["property",h] 获取. 表达式 model["property"] 等同于 model["property","SF"].
- 与拟合函数相关的某些属性可用 model["property"] 获取:
-
"EventTable" 总结拟合函数的格式化表格 "EventTableEntries" 事件表格的项 "FittedFunction" 拟合函数的纯函数形式 "FullEventTable" 扩展的事件表格 "FullEventTableEntries" 完全事件表格的项 "MeanSurvival" 平均生存时间 "MedianSurvival" 中位数生存时间 "StandardErrorFunction" 拟合函数的标准误差的函数形式 "StandardErrors" 每个时间点的标准误差列表 "SurvivalDistribution" 拟合中使用的 DataDistribution 对象 - 拟合函数的置信区间是由对应于由 model["EstimationPoints"] 给出的每个时间点的成对值 {{h1,min,h1,max},…} 列表给出.
- 以纯函数形式给出置信带,等同于在 model["EstimationPoints"] 中所有时间点计算的置信区间.
- 与置信区间和置信带相关的属性包括:
-
"PointwiseBands" 逐点置信带 "PointwiseIntervals" 逐点置信区间 "EqualPrecisionBands" 同步置信带 "EqualPrecisionIntervals" 同步置信间隔 "HallWellnerBands" 同步 Hall–Wellner置信带 "HallWellnerIntervals" 同步 Hall–Wellner置信间隔 - 与事件数据相关的属性:
-
"EstimationPoints" 估计中使用的时间点 "EventData" 估计中使用的 EventData 对象 "EventMatrix" 表明可能的事件位置的矩阵 "EventMatrixPlot" 事件矩阵自定义的矩阵图 "TruncationMatrix" 表明在哪单位可观察的矩阵 "TruncationMatrixPlot" 截断矩阵的自定义矩阵图 - 与观察的不同类型计数相关的属性:
-
"AtRisk" 每个时间点的高危个体数目 "EventCounts" 每个时间点的事件数目 "LeftCensoringCounts" 每个时间点的左删失事件数目 "ObservationCount" 试验单位的有效数目 "RightCensoringCounts" 每个时间点的右删失事件数目 - SurvivalModelFit 接受以下选项:
-
ConfidenceLevel 95/100 用于置信区间和置信带的置信水平 » ConfidenceRange All 同步置信带的范围 » ConfidenceTransform "LogLog" 使用的置信变换 » Method Automatic 模型拟合使用的方法 » - 当 ConfidenceLevel->p 时,概率 p 置信区间和置信带用于计算各种函数形式.
- ConfidenceRange->{tmin,tmax} 为 tmin 与 tmax 之间的拟合函数给出概率 p 同步置信区间和置信带.
- ConfidenceTransform 的可能设置包括 "Linear"、"LogLog"、"ArcSinSqrt"、"Log"、"Logit" 或一个纯函数 g.
- SurvivalModelFit 自动选择最适合数据的方法. Kaplan–Meier 估计器被用于右删失数据. 对于其他删失类型,使用自我一致性构建估计. 不同的方法可能只支持某些类型的删失或截断.
- 设置 Method->estimator 指定用于分布函数的估计器. 可能的设置包括:
-
"KaplanMeier" 右删失数据的乘积极限估计器 "NelsonAalen" 基于 Nelson–Aalen的累积风险估计器 "Turnbull" 区间删失数据的 Turnbull 算法 "Noncensored" 删失被忽略,使用区间中点 "SelfConsistency" 用于双删失数据的 Turnbull 算法 - 其他方法设置可以在范例中的选项部分找到. »
范例
打开所有单元 关闭所有单元基本范例 (1)
t = {7, 23, 22, 6, 25, 20, 19, 6, 17, 6, 13};
i = {0, 0, 0, 0, 1, 1, 1, 0, 1, 0, 0};𝒮 = SurvivalModelFit[EventData[t, i]]𝒮[20]Normal[𝒮][x]//PiecewiseExpandPlot[{𝒮[x], 𝒮["PointwiseBands"][x]}, {x, 5, 30}]范围 (29)
基本用途 (4)
data = {30, 32, 26, {37, ∞}, 29, {32, ∞}, 24, {31, ∞}, {31, ∞}, 42};𝒮 = SurvivalModelFit[data];Normal[𝒮][x]//PiecewiseExpand𝒮[24]data = {30, 32, 26, {37, ∞}, 29, {32, ∞}, 24, {31, ∞}, {31, ∞}, 42};𝒮 = SurvivalModelFit[data];𝒮["EventTable"]绘制模型的估计的 CDF:
data = {30, 32, 26, {37, ∞}, 29, {32, ∞}, 24, {31, ∞}, {31, ∞}, 42};𝒮 = SurvivalModelFit[data];Plot[𝒮["CDF"][x], {x, 20, 45}, Exclusions -> None]data = {30, 32, 26, {37, ∞}, 29, {32, ∞}, 24, {31, ∞}, {31, ∞}, 42};𝒮 = SurvivalModelFit[data];𝒮["Properties"]模型属性 (16)
data = {30, 32, 26, {37, ∞}, 29, {32, ∞}, 24, {31, ∞}, {31, ∞}, 42};𝒮 = SurvivalModelFit[data];𝒮["PointwiseIntervals"]data = {30, 32, 26, {37, ∞}, 29, {32, ∞}, 24, {31, ∞}, {31, ∞}, 42};𝒮 = SurvivalModelFit[data];𝒮["EqualPrecisionIntervals"]data = {30, 32, 26, {37, ∞}, 29, {32, ∞}, 24, {31, ∞}, {31, ∞}, 42};𝒮 = SurvivalModelFit[data];在每个时间点的关于生存函数的 95% Hall–Wellner 区间:
𝒮["HallWellnerIntervals"]data = BlockRandom[SeedRandom[1];EventData[RandomChoice[Range[25, 35], 150], RandomChoice[{.8, .1, .1} -> {0, 1, -1}, 150]]];𝒮 = SurvivalModelFit[data];Plot[{𝒮[x], 𝒮["PointwiseBands"][x]}, {x, 22, 40}, PlotStyle -> {Automatic, Dashed}, AxesOrigin -> {22, 0}]𝒮["PointwiseBands"][𝒮["EstimationPoints"]] == 𝒮["PointwiseIntervals"]data = BlockRandom[SeedRandom[1];EventData[RandomChoice[Range[25, 35], 150], RandomChoice[{.8, .1, .1} -> {0, 1, -1}, 150]]];𝒮 = SurvivalModelFit[data];Plot[{𝒮[x], 𝒮["EqualPrecisionBands"][x]}, {x, 22, 40}, PlotStyle -> {Automatic, Dashed}, AxesOrigin -> {22, 0}]𝒮["EqualPrecisionBands"][𝒮["EstimationPoints"]] == 𝒮["EqualPrecisionIntervals"]data = BlockRandom[SeedRandom[1];EventData[RandomChoice[Range[25, 35], 150], RandomChoice[{.8, .1, .1} -> {0, 1, -1}, 150]]];𝒮 = SurvivalModelFit[data];Plot[{𝒮[x], 𝒮["HallWellnerBands"][x]}, {x, 22, 40}, PlotStyle -> {Automatic, Dashed}, AxesOrigin -> {22, 0}]𝒮["HallWellnerBands"][𝒮["EstimationPoints"]] === 𝒮["HallWellnerIntervals"]data = {30, 32, 26, {37, ∞}, 29, {32, ∞}, 24, {31, ∞}, {31, ∞}, 42};𝒮 = SurvivalModelFit[data];ListPlot[Transpose[{𝒮["EstimationPoints"], 𝒮["StandardErrors"]}], Filling -> Axis]𝒮["StandardErrorFunction"][𝒮["EstimationPoints"]] === 𝒮["StandardErrors"]对估计的 SurvivalFunction 的总结制表:
data = BlockRandom[SeedRandom[1];EventData[RandomChoice[Range[25, 35], 150], RandomChoice[{.8, .2} -> {0, -1}, 150]]];𝒮 = SurvivalModelFit[data];𝒮["FullEventTable"]𝒮["FullEventTableEntries"]data = BlockRandom[SeedRandom[1];EventData[RandomChoice[Range[25, 35], 150], RandomChoice[{.8, .2} -> {0, -1}, 150]]];𝒮 = SurvivalModelFit[data];𝒮["EventTableFunction"][Range[25, 30]]时间介于 25 和 35 之间,步长为 5 的具有事件历史数据的事件表格:
𝒮["FullEventTableFunction"][Range[25, 35, 5]]𝒮["FullEventTableEntriesFunction"][Range[25, 35, 5]]data = {30, 32, 26, {-∞, 42}, 29, {32, ∞}, 24, {31, ∞}, {31, ∞}, 42};𝒮 = SurvivalModelFit[data];𝒮["EventMatrixPlot"]𝒮["EventCounts"]𝒮["RightCensoringCounts"]𝒮["LeftCensoringCounts"]data = {10, 12, 12, 12, {-∞, 13}, {15, ∞}, {12, 14}};𝒮 = SurvivalModelFit[data];𝒮["EventMatrix"]//MatrixFormMax /@ 𝒮["EventMatrix"]{-∞}~Join~𝒮["EstimationPoints"]~Join~{∞}TableForm[𝒮["EventMatrix"], TableHeadings -> {None, {-∞}~Join~𝒮["EstimationPoints"]~Join~{∞}}, TableSpacing -> {1, 1}]使用 "TruncationMatrix" 显示哪里的单位是可观察的:
data = {5, 6, 7, 8};
tr = {{4, ∞}, {5, 7}, {6, ∞}, {7, ∞}};𝒮 = SurvivalModelFit[EventData[data, None, tr]];𝒮["TruncationMatrix"]//MatrixForm{-∞}~Join~𝒮["EstimationPoints"]~Join~{∞}data = {10, 12, 12, 12, {-∞, 13}, {15, ∞}, {12, 14}};𝒮 = SurvivalModelFit[data];𝒮["EventMatrixPlot"]data = {5, 6, 6, 7, 8};
tr = {{4, ∞}, {5, 7}, {5, 7}, {6, ∞}, {7, ∞}};𝒮 = SurvivalModelFit[EventData[data, None, tr]];𝒮["TruncationMatrixPlot"]data = {30, 32, 26, {-∞, 25}, 29, {32, ∞}, 24, {31, ∞}, {31, ∞}, 42};𝒮 = SurvivalModelFit[data];{{"t", "SubscriptBox[d, t]", "SubscriptBox[c, t]", "SubscriptBox[r, t]"}}~Join~Transpose[𝒮[{"EstimationPoints", "EventCounts", "LeftCensoringCounts", "RightCensoringCounts"}]]//Griddata = BlockRandom[SeedRandom[1];EventData[RandomChoice[Range[25, 35], 150], RandomChoice[{.8, .1, .1} -> {0, 1, -1}, 150]]];𝒮 = SurvivalModelFit[data];𝒮["EventTable", "CHF"]数据类型 (9)
删失 (7)
t1 = {10, 15, 16, 18, 21};
t2 = {{10, 10}, {15, 15}, {16, 16}, {18, 18}, {21, 21}};𝒮1 = SurvivalModelFit[t1];
𝒮2 = SurvivalModelFit[t2];Table[Plot[𝒮[x], {x, 5, 25}, Exclusions -> None], {𝒮, {𝒮1, 𝒮2}}]t = {10, 15, 16, 18, 21};
Subscript[t, c] = {10, 15, {16, ∞}, 18, 21};𝒮1 = SurvivalModelFit[t];
𝒮2 = SurvivalModelFit[Subscript[t, c]];Table[Plot[𝒮[x], {x, 5, 25}, Exclusions -> None], {𝒮, {𝒮1, 𝒮2}}]t = {10, 15, 16, 18, 21};
Subscript[t, c] = {10, 15, {-∞, 16}, 18, 21};𝒮1 = SurvivalModelFit[t];
𝒮2 = SurvivalModelFit[Subscript[t, c]];Table[Plot[𝒮[x], {x, 5, 25}, Exclusions -> None], {𝒮, {𝒮1, 𝒮2}}]t = {10, 15, 16, 18, 21};
Subscript[t, c] = {10, 15, {16, 20}, 18, 21};𝒮1 = SurvivalModelFit[t];
𝒮2 = SurvivalModelFit[Subscript[t, c]];Table[Plot[𝒮[x], {x, 5, 25}, Exclusions -> None], {𝒮, {𝒮1, 𝒮2}}]t = {10, 15, 16, 18, 21};
Subscript[t, c] = {10, {-∞, 15}, 16, {18, ∞}, 21};𝒮1 = SurvivalModelFit[t];
𝒮2 = SurvivalModelFit[Subscript[t, c]];Table[Plot[𝒮[x], {x, 5, 25}, Exclusions -> None], {𝒮, {𝒮1, 𝒮2}}]t = {10, 15, 16, 18, 21};
Subscript[t, c] = {10, {-∞, 15}, {14, 17}, {18, ∞}, 21};𝒮1 = SurvivalModelFit[t];
𝒮2 = SurvivalModelFit[Subscript[t, c]];Table[Plot[𝒮[x], {x, 5, 25}, Exclusions -> None], {𝒮, {𝒮1, 𝒮2}}]使用具有状态指示器的 EventData 表明删失观察:
event = {10, 15, 16, 18, 21};right = {0, 1, 1, 0, 0};
left = {0, -1, -1, 0, 0};
double = {0, 1, -1, 0, 0};sRight = SurvivalModelFit[EventData[event, right]];
sLeft = SurvivalModelFit[EventData[event, left]];
sDouble = SurvivalModelFit[EventData[event, double]];MapThread[Plot[#1[x], {x, 5, 25}, Exclusions -> None, PlotLabel -> #2]&, {{sRight, sLeft, sDouble}, {"right", "left", "double"}}]删截 (2)
使用 EventData 指定截断观察:
event = {10, 15, 16, 18, 21};tLeft = {0, 4, 3, 1, 0};
tInterval = {{4, 20}, {13, 16}, {10, 18}, {18, 26}, {0, 25}};sLeft = SurvivalModelFit[EventData[event, None, tLeft]];
sInterval = SurvivalModelFit[EventData[event, None, tInterval]];MapThread[Plot[#1[x], {x, 5, 25}, Exclusions -> None, PlotLabel -> #2]&, {{sLeft, sInterval}, {"left", "interval"}}]EventData 可用于混合删失和截断:
event = {10, 15, 16, 18, 21};
cens = {0, 0, 1, 0, 1};
tr = {0, 4, 3, 1, 0};𝒮 = SurvivalModelFit[EventData[event, cens, tr]];Plot[𝒮[x], {x, 5, 25}, Exclusions -> None]选项 (10)
ConfidenceLevel (3)
data = {30, 32, 26, {37, ∞}, 29, {32, ∞}, 24, {31, ∞}, {31, ∞}, 42};𝒮 = SurvivalModelFit[data, ConfidenceLevel -> .9]𝒮["PointwiseIntervals"]𝒮["PointwiseIntervals", ConfidenceLevel -> .9]data = {30, 32, 26, {37, ∞}, 29, {32, ∞}, 24, {31, ∞}, {31, ∞}, 42};𝒮 = SurvivalModelFit[data];𝒮["PointwiseIntervals"] === 𝒮["PointwiseIntervals", ConfidenceLevel -> 95 / 100]data = {{10, 12}, {11, 13}, {15, 18}, 16, {18, 20}, 20, 21};𝒮 = SurvivalModelFit[data]clev = {.7, .75, .8, .85, .9, .95};Grid[Table[{i, 𝒮["PointwiseBands", ConfidenceLevel -> i][16]}, {i, clev}], Alignment -> Left]ConfidenceRange (1)
data = {{2081, ∞}, {1602, ∞}, {1496, ∞}, {1462, ∞}, {1433, ∞}, {1377, ∞}, {1330, ∞}, {996, ∞}, {226, ∞}, {1199, ∞}, {1111, ∞}, {530, ∞}, {1182, ∞}, {1167, ∞}, 418, 383, 276, 104, 609, 172, 487, 662, 194, 230, 526, 122, 129, 74, 122, 86, 466, 192, 109, 55, 1, 107, 110, 332};𝒮 = SurvivalModelFit[data]Plot[{𝒮[x], 𝒮["EqualPrecisionBands", ConfidenceRange -> {172, 383}][x]}, {x, 100, 500}, PlotRange -> {0, 1}]默认情况下,范围设为 All:
Plot[{𝒮[x], 𝒮["EqualPrecisionBands", ConfidenceRange -> All][x]}, {x, 0, 2081}, PlotRange -> {0, 1}]设置范围为 Full:
Plot[{𝒮[x], 𝒮["EqualPrecisionBands", ConfidenceRange -> Full][x]}, {x, 0, 2081}, PlotRange -> {0, 1}]ConfidenceTransform (3)
data = {30, 32, 26, {37, ∞}, 29, {32, ∞}, 24, {31, ∞}, {31, ∞}, 42};𝒮 = SurvivalModelFit[data]tr = {"Linear", "LogLog", "ArcSinSqrt", "Log", "Logit"};Grid[Table[{i, 𝒮["PointwiseBands", ConfidenceTransform -> i][40]}, {i, tr}], Alignment -> Left]𝒮["PointwiseBands", ConfidenceTransform -> "LogLog"] === 𝒮["PointwiseBands"]data = {30, 32, 26, {37, ∞}, 29, {32, ∞}, 24, {31, ∞}, {31, ∞}, 42};𝒮 = SurvivalModelFit[data]𝒮["EventTable", ConfidenceTransform -> "Linear"]𝒮["EventTable", ConfidenceTransform -> "LogLog"]data = {30, 32, 26, {37, ∞}, 29, {32, ∞}, 24, {31, ∞}, {31, ∞}, 42};𝒮 = SurvivalModelFit[data]tr = {"Linear", "LogLog", "ArcSinSqrt", "Log", "Logit"};
trans = {#&, Log[Log[#]]&, ArcSin[Sqrt[#]]&, Log[#]&, Log[(#/1 - #)]&};Grid[(ints = MapThread[{#1, 𝒮["PointwiseBands", ConfidenceTransform -> #2][40]}&, {tr, trans}]), Alignment -> Left]ints[[All, 2]] == Table[𝒮["PointwiseBands", ConfidenceTransform -> i][40], {i, tr}]Method (3)
t = RandomReal[ExponentialDistribution[1 / 7], 5000]~Join~{{6, 8}};
i = RandomChoice[{.9, .1} -> {0, 1}, 5000]~Join~{0};(𝒮1 = SurvivalModelFit[EventData[t, i]])//AbsoluteTiming(𝒮2 = SurvivalModelFit[EventData[t, i], Method -> "KaplanMeier"])//AbsoluteTimingPlot[(𝒮1[x] - 𝒮2[x]/𝒮1[x]), {x, 0, 30}, Exclusions -> None, PlotRange -> All]如果上次观察是删失的,超过那点的生存会是 Indeterminate:
data = {10, 7, {32, ∞}, 23, 22, 6, 16, {34, ∞}, {32, ∞}, {6, ∞}, {10, ∞}};𝒮 = SurvivalModelFit[data]Plot[𝒮[x], {x, 0, 50}, Exclusions -> None, PlotRange -> {0, 1}]tailMods = {"Censored", "Exponential", "Weibull", "Gamma", "Normal", "LogNormal", "GompertzMakeham", "InverseGaussian", "LogLogistic"};models = Table[SurvivalModelFit[data, Method -> "TailModel" -> i]["FittedFunction"], {i, tailMods}];MapThread[Plot[#1[x], {x, 0, 70}, PlotLabel -> ToString@#2, Ticks -> None, Exclusions -> None, PlotRange -> {0, 1}]&, {models, tailMods}]Plot[Evaluate@SurvivalModelFit[data, Method -> "TailModel" -> WeibullDistribution[a, b]][t], {t, 0, 70}, Exclusions -> None]子选项 "StandardErrorMethod" 可用于控制标准误差计算:
data = {10, 7, 23, 22, 6, {25, ∞}, {20, ∞}, {19, ∞}, 6, {17, ∞}, 6, 13};𝒮 = SurvivalModelFit[data]设置 Automatic 通过插入方法尝试计算标准误差:
Plot[𝒮["StandardErrorFunction", Method -> "StandardErrorMethod" -> Automatic][x], {x, 0, 25}, PlotRange -> All, AxesOrigin -> {0, 0}]Plot[𝒮["StandardErrorFunction", Method -> "StandardErrorMethod" -> "Bootstrap"][x], {x, 0, 25}, PlotRange -> All, AxesOrigin -> {0, 0}]Plot[𝒮["StandardErrorFunction", Method -> "StandardErrorMethod" -> {"Bootstrap", "PrecisionGoal" -> 1, "AccuracyGoal" -> ∞, "RandomSeed" -> 9}][x], {x, 0, 25}, PlotRange -> All, AxesOrigin -> {0, 0}]应用 (8)
对一组26个精神病人进行跟踪调查直至死亡或者研究结束. 在研究结束后这些病人的寿命呈右删失分布. 比较病人存活的非参数和参数模型:
ExampleData[{"Statistics", "Psychiatric"}, "LongDescription"]d = EventData@@(ExampleData[{"Statistics", "Psychiatric"}][[All, {3, 4}]]);𝒮 = SurvivalModelFit[d]gm = EstimatedDistribution[d, GompertzMakehamDistribution[a, b]]在 95% 每一点的置信带和 Gompertz–Makeham模型下,Kaplan–Meier估值:
Plot[{𝒮[t], 𝒮["PointwiseBands"][t], SurvivalFunction[gm, t]}, {t, 0, 40}, PlotPoints -> 500, Exclusions -> None, PlotStyle -> {Automatic, Dotted, Automatic}, PlotRange -> {0, 1}]𝒮["MedianSurvival"]Median[gm]下面数据包含70台电子发电机的连续运转时间(以小时为单位). 在给定最低限度的维修策略下,感兴趣的是各种运转时间下期望的平均失效数目. 有些发电机在观察器没有失效,并且是右删失的:
fanTimes = EventData[Automatic, {{4500., 4600., 11500., 11500., 15600., 16000., 16600., 18500., 18500.,
18500., 18500., 18500., 20300., 20300., 20300., 20700., 20700., 20800., 22000, 30000., 30000,
30000, 30000, 31000, 32000, 34500., 37500., 37500., 4 ... 101000, 115000},
{0, 1, 0, 0, 1, 0, 1, 1, 1, 1, 1, 1, 1, 1, 1, 0, 0, 0, 1, 1, 1, 1, 1, 0, 1, 0, 1, 1, 1, 1, 1, 1,
1, 1, 1, 1, 0, 1, 1, 1, 1, 1, 1, 1, 1, 0, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 0, 1,
1, 1, 1, 1, 1, 1}, None}];mod = SurvivalModelFit[fanTimes, Method -> "NelsonAalen"]Plot[Evaluate@{mod["CHF"][x], mod["PointwiseBands", "CHF"][x]}, {x, 0, 120000}, PlotPoints -> 100, AxesLabel -> {"Hours in Use", "Cumulative Hazard"}]mod["FullEventTable", "CHF"]平均而言,在 87,500 个小时的运行时间内,失败了 0.337 次:
mod["CHF"][87500]为缓解白血病人的痛苦,在临床试验中使用 6-巯基嘌呤或安慰剂. 比较两组的存活率:
sixmp = {10, 7, 32, 23, 22, 6, 16, 34, 32, 25, 11, 20, 19, 6, 17, 35, 6, 13, 9, 6, 10};
ci = {0, 0, 1, 0, 0, 0, 0, 1, 1, 1, 1, 1, 1, 0, 1, 1, 0, 0, 1, 1, 1};placebo = {1, 22, 3, 12, 8, 17, 2, 11, 8, 12, 2, 5, 4, 15, 8, 23, 5, 11, 4, 1, 8};treatment = SurvivalModelFit[EventData[sixmp, ci]];
control = SurvivalModelFit[placebo];#["EventMatrixPlot"]& /@ {treatment, control}Table[model["MedianSurvival"], {model, {treatment, control}}]Plot[{treatment[x], control[x]}, {x, 0, 40}, Exclusions -> None, PlotLegends -> {"treatment", "control"}]具有 Tarone–Ware 加权的LogRankTest 与上面的发现是一致的:
LogRankTest[{treatment["EventData"], control["EventData"]}, "TaroneWare", "TestDataTable"]191 名高中男孩被问及,他们第一次尝试大麻是什么年龄. 可能的回答包括,“我第一次尝试大麻是在年龄
”,“我从没有抽过大麻”,或“我不记得何时第一次尝试大麻”:
times = {10, 11, 12, 13, 14, 15, 16, 17, 18};
censoring = {{4, 0, 0}, {12, 0, 0}, {19, 2, 0}, {24, 15, 1}, {20, 24, 2}, {13, 18, 3}, {3, 14, 2}, {1, 6, 3}, {0, 4, 1}};model = SurvivalModelFit[EventData[times, censoring]];model["EventTable"]Table[With[{et = model["EstimationPoints"]}, Show[ListLinePlot[Table[{t, model[i][t]}, {t, et}], Mesh -> All, MeshStyle -> Directive[PointSize[.04], Orange]], Graphics[Table[Line[Transpose[{{t, t}, model["PointwiseBands", i][t]}]], {t, et}]], PlotRange -> All, PlotLabel -> i]], {i, {"SF", "CHF"}}]model["PointwiseBands", ConfidenceLevel -> .9][14]一组38例急性淋巴细胞白血病的个人分别给予骨髓移植. 患者随访直至死亡,复发,或研究结束. 下面的数据可以被解释为无病存活时间:
data = {{2081, ∞}, {1602, ∞}, {1496, ∞}, {1462, ∞}, {1433, ∞}, {1377, ∞}, {1330, ∞}, {996, ∞}, {226, ∞}, {1199, ∞}, {1111, ∞}, {530, ∞}, {1182, ∞}, {1167, ∞}, 418, 383, 276, 104, 609, 172, 487, 662, 194, 230, 526, 122, 129, 74, 122, 86, 466, 192, 109, 55, 1, 107, 110, 332};model = SurvivalModelFit[data, ConfidenceRange -> {100, 600}];Plot[{model[x], model["HallWellnerBands"][x], model["EqualPrecisionBands"][x], model["PointwiseBands"][x]}, {x, 100, 600}, Exclusions -> None, PlotLegends -> {"Model", "Hall-Wellner Bands", "Equal Precision Bands", "Pointwise Bands"}]survProbTest[h0_, t_, lev_] := IntervalMemberQ[Interval[model["PointwiseBands", ConfidenceLevel -> 1 - lev][400]], h0] /. {True -> Row[{"Do not reject at the ", 100 lev, "% level"}], False -> Row[{"Reject at the ", 100 lev, "% level"}]}model[400]survProbTest[1 / 2, 400, .05]感兴趣研究狒狒睡眠习惯的研究人员记录了有一半狒狒睡眠后从树上掉下来的所经过的时间. 在某些日子里,研究人员到达的时间足够早,可以精确记录这些时间. 在其他时候,他们在下降时间的中位数时间后到达,因此一天的观测被左删截了:
ExampleData[{"Statistics", "Baboon"}, "ColumnDescriptions"]baboon = EventData[Sequence@@(ExampleData[{"Statistics", "Baboon"}])];𝒮 = SurvivalModelFit[baboon];在7到9个小时时间段内,95% Hall–Wellner生存置信包(survival confidence envelope):
Plot[{𝒮[t], 𝒮["HallWellnerBands", ConfidenceRange -> {7, 9}, ConfidenceTransform -> "Linear"][t]}, {t, 6, 11}, Exclusions -> None, PlotRange -> {0, 1}, PlotLegends -> {"𝒮", "Hall-Wellner Bands"}]𝒮[7] - 𝒮[9]𝒮[{"MedianSurvival", "MeanSurvival"}]跟踪肾功能不全患者到第一导管出口处感染. 每个患者有两种类型的导管放置(手术或经皮). 最令人感兴趣的是导管的位置是最重要的,可以防止感染:
ExampleData[{"Statistics", "KidneyInfection"}, "ColumnDescriptions"]{s, i, x} = ExampleData[{"Statistics", "KidneyInfection"}];
surgical = EventData@@(Pick[#, x, 1]& /@ {s, i});
percutaneous = EventData@@(Pick[#, x, 2]& /@ {s, i});surg = SurvivalModelFit[EventData@@(Pick[#, x, 1]& /@ {s, i})];
perc = SurvivalModelFit[EventData@@(Pick[#, x, 2]& /@ {s, i})];Plot[{surg[t], perc[t]}, {t, 0, 40}, Exclusions -> None, PlotLegends -> {"Surgical", "Percutaneous"}]wSurg = EstimatedDistribution[surgical, WeibullDistribution[a, b]];
wPerc = EstimatedDistribution[percutaneous, WeibullDistribution[a, b], ParameterEstimator -> {"MaximumLikelihood", Method -> "NMaximize"}];Plot[{surg[t], perc[t], SurvivalFunction[wSurg, t], SurvivalFunction[wPerc, t]}, {t, 0, 40}, Exclusions -> None, PlotStyle -> {{Opacity[.5]}, {Opacity[.5]}, {Thick, ColorData[97, 1], Dashed}, {Thick, ColorData[97, 2], Dashed}}, PlotLegends -> {"Surgical: Kaplan–Meier", "Percutaneous: Kaplan–Meier", "Surgical: Weibull", "Percutaneous: Weibull"}]诊所招收了30个糖尿名患者并随访至死亡或研究结束. 并记录了患者在研究开始和结束时的年龄. 使用这些假设数据,比较60和65岁糖尿病患者的条件存活率和糖尿病存活率,忽略左截断:
exit = {60, 63, 69, 62, 65, 72, 69, 73, 66, 65, 68, 74, 71, 68, 69, 70, 77, 69, 72, 79, 72, 70, 76, 71, 78, 79, 76, 73, 80, 74};
entry = {58, 58, 59, 60, 60, 61, 61, 62, 62, 62, 63, 63, 64, 66, 66, 67, 67, 67, 68, 69, 69, 69, 70, 70, 70, 71, 72, 72, 73, 73};
cens = {0, 0, 1, 0, 0, 1, 1, 1, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 1, 0, 1, 1, 0, 0, 1, 0};dUC = SurvivalModelFit[EventData[exit, cens]];Min[exit]d60 = SurvivalModelFit[EventData[exit, cens, entry]];d65 = SurvivalModelFit[EventData@@(Pick[#, exit, x_ /; x ≥ 65]& /@ {exit, cens, entry})];Plot[{dUC[x], d60[x], d65[x]}, {x, 55, 85}, Exclusions -> None, PlotPoints -> 100, PlotLegends -> {"dUC", "d60", "d65"}]d60[70]d65["PointwiseBands", ConfidenceLevel -> .9][70]属性和关系 (7)
对于右删失数据,默认情况下使用 Kaplan–Meier 估计器:
data = {30, 32, 26, {37, ∞}, 29, {32, ∞}, 24, {31, ∞}, {31, ∞}, 42};𝒮 = SurvivalModelFit[data];t = 𝒮["EstimationPoints"];km[j_] := With[{d = 𝒮["EventCounts"], y = 𝒮["AtRisk"]}, Underoverscript[∏, i = 1, j](1 - (d[[i]]/y[[i]]))]Chop[𝒮["SF"][t] - Table[km[i], {i, Length[t]}]]data = {30, 32, 26, {37, ∞}, 29, {32, ∞}, 24, {31, ∞}, {31, ∞}, 42};𝒮 = SurvivalModelFit[data, Method -> "NelsonAalen"];t = 𝒮["EstimationPoints"];na[j_] := With[{d = 𝒮["EventCounts"], y = 𝒮["AtRisk"]}, Underoverscript[∑, i = 1, j](d[[i]]/y[[i]])]Chop[𝒮["CHF"][t] - Table[na[i], {i, Length[t]}]]Chop[𝒮["SF"][t] - Table[Exp[-na[i]], {i, Length[t]}]]data = {10, {-∞, 7}, 7, 23, {22, ∞}, 25, 20, {19, ∞}, 6, 17, {-∞, 12}, 13};𝒮 = SurvivalModelFit[data]TableForm[Table[{i, Apply[EuclideanDistance, 𝒮["PointwiseBands", ConfidenceLevel -> i][20]]}, {i, Range[.1, .9, .1]}], TableHeadings -> {None, {"clev", "width"}}]data = {30, 32, 26, {37, ∞}, 29, {32, ∞}, 24, {31, ∞}, {31, ∞}, 42};fun = {"SF", "CDF", "CHF"};Table[Plot[Evaluate@{SurvivalModelFit[data][i][x], SurvivalModelFit[data]["PointwiseBands", i][x]}, {x, 24, 42}, PlotStyle -> {Automatic, Dashed}, PlotLabel -> i], {i, fun}]data = {6, 7, 7, 8};
tr = {5, 5, 6, 7};𝒮tr = SurvivalModelFit[EventData[data, None, tr]];𝒮ntr = SurvivalModelFit[EventData[data, None, None]];𝒮tr["EstimationPoints"]𝒮ntr["EstimationPoints"]{𝒮tr["EventMatrixPlot"], 𝒮tr["TruncationMatrixPlot"]}{𝒮ntr["EventMatrixPlot"], 𝒮ntr["TruncationMatrixPlot"]}使用 CoxModelFit 估计协变量出现的生存概率:
y = EventData[{8, 22, 6, 4, 12, 11, 2, 34, 25, 15, 8, 6, 34, 6, 32, 1, 15, 9, 9, 6}, {0, 0, 0, 0, 0, 0, 0, 1, 1, 0, 0, 0, 1, 1, 1, 0, 0, 1, 1, 0}];
x = {{67, 1}, {11, 0}, {32, 0}, {50, 1}, {65, 1}, {44, 1}, {20, 1}, {26, 0}, {69, 1}, {50, 1}, {25, 1}, {18, 0}, {63, 1}, {41, 0}, {30, 0}, {32, 1}, {46, 1}, {35, 0}, {33, 0}, {22, 0}};mod = CoxModelFit[{x, y}, {a, b}, {a, b}]mod["ParameterTable"]mod["TestTable"]Plot[Evaluate@{mod["SF"][{50, 0}][t], mod["SF"][{50, 1}][t]}, {t, 0, 40}, Exclusions -> None, PlotPoints -> 100]使用 LogRankTest 比较多组的风险率:
e1 = EventData[{32, 34, 28, 26, 31, 25, 29, 31, 28, 25}, {0, 0, 0, 0, 0, 0, 0, 0, 0, 1}];
e2 = EventData[{30, 19, 28, 35, 35, 29, 33, 32, 31, 29}, {0, 0, 1, 0, 0, 1, 0, 1, 0, 1}];𝒮1 = SurvivalModelFit[e1];
𝒮2 = SurvivalModelFit[e2];Plot[{𝒮1[t], 𝒮2[t]}, {t, 20, 40}, Exclusions -> None]使用 LogRankTest 比较风险率:
wspec = {"AndersenPeto", "Gehan", "Equal", "TaroneWare"};Grid[Table[{w, LogRankTest[{e1, e2}, w]}, {w, wspec}], Alignment -> Left]相关指南
-
▪
- 精算计算 ▪
- 生存分析 ▪
- 非参数统计分布 ▪
- 可靠性 ▪
- 表格建模 ▪
- 用于可靠性分析中的分布 ▪
- 科学数据分析 ▪
- 生命科学和医学:数据与计算 ▪
- 概率和统计
文本
Wolfram Research (2012),SurvivalModelFit,Wolfram 语言函数,https://reference.wolfram.com/language/ref/SurvivalModelFit.html.
CMS
Wolfram 语言. 2012. "SurvivalModelFit." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/SurvivalModelFit.html.
APA
Wolfram 语言. (2012). SurvivalModelFit. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/SurvivalModelFit.html 年
BibTeX
@misc{reference.wolfram_2026_survivalmodelfit, author="Wolfram Research", title="{SurvivalModelFit}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/SurvivalModelFit.html}", note=[Accessed: 15-November-2026]}
BibLaTeX
@online{reference.wolfram_2026_survivalmodelfit, organization={Wolfram Research}, title={SurvivalModelFit}, year={2012}, url={https://reference.wolfram.com/language/ref/SurvivalModelFit.html}, note=[Accessed: 15-November-2026]}