WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

SymmetricMatrix[smat]

対称行列 smat を構造化配列に変換する．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
TargetStructure  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

SymmetricMatrix

SymmetricMatrix[smat]

対称行列 smat を構造化配列に変換する．

詳細とオプション

  • 対称行列は，構造化配列として表されているときは，便利に指定することができる．
  • 対称行列は，通常，最適化や共分散で使用されるヘッセ(Hesse)行列，統計における相関行列，二次形式や無向グラフの行列表現から得られる．
  • 対称行列の場合，アプリケーションに出現する固有問題を非常に低いコストで解くことができる．
  • 対称行列 は sij=sjiを満足するが，これは両者が対角線について対称であることを意味している．
  • 要素 sij は数値ではなくてもよい．
  • 対称行列の逆行列と，一般に，対称行列の任意の行列関数もまた対称である．
  • SymmetricMatrix sa については，sa["prop"]で次の特性"prop"にアクセスすることができる．
  • "Matrix"完全配列として表される対称行列
    "Properties"サポートされる特性のリスト
    "Structure"構造化配列の型
    "StructuredData"構造化配列に保存されている内部データ
    "StructuredAlgorithms"構造化配列について特別なメソッドを持つ関数のリスト
    "Summary"Datasetとして表される要約情報
  • Normal[SymmetricMatrix[…]]は，対称行列を通常の行列として与える．
  • SymmetricMatrix[…,TargetStructure->struct]は対称行列を struct で指定された形式で返す．以下は，使用可能な設定である．
  • Automatic返す表現を自動的に選択する
    "Dense"行列を密な行列として表す
    "Structured"行列を構造化配列として表す
  • SymmetricMatrix[…,TargetStructureAutomatic]はSymmetricMatrix[…,TargetStructure"Structured"]に等しい．

例題

すべて開く すべて閉じる

例  (1)

対称行列を構築する：

Wolfram Language code: sm = SymmetricMatrix[{{8, 1, 7}, {1, 5, 2}, {7, 2, 3}}]

要素を表示する：

Wolfram Language code: MatrixForm[sm]

NormalはSymmetricMatrixをその通常の表現に変換できる：

Wolfram Language code: Normal[sm]

スコープ  (5)

対称行列をその上三角成分から構築する：

Wolfram Language code: SymmetricMatrix[{{8, 1, 7}, {5, 2}, {3}}]

要素を表示する：

Wolfram Language code: MatrixForm[%]

この行列はその下三角成分から構築することもできる：

Wolfram Language code: SymmetricMatrix[{{8}, {1, 5}, {7, 2, 3}}]

ヒルベルト(Hilbert)行列は対称行列である：

Wolfram Language code: hm = SymmetricMatrix[HilbertMatrix[4]]

実数の反射行列は対称行列であり直交行列でもある：

Wolfram Language code: rm = ReflectionMatrix[{1, -1, 1}]
Wolfram Language code: {SymmetricMatrix[rm], OrthogonalMatrix[rm]}

複素対称行列：

Wolfram Language code: cs = SymmetricMatrix[(⁠| | | | | | - | -- | -- | -- | | 1 | 1 | 1 | 1 | | 1 | -I | -1 | I | | 1 | -1 | 1 | -1 | | 1 | I | -1 | -I |⁠)]

この行列は対称行列ではあるがハミルトン行列ではない：

Wolfram Language code: {SymmetricMatrixQ[cs], HermitianMatrixQ[cs]}

SymmetricMatrixオブジェクトは，行列についての情報を与える特性を含んでいる：

Wolfram Language code: sm = SymmetricMatrix[(⁠| | | | | | | -- | -- | -- | -- | -- | | 11 | 12 | 13 | 14 | 15 | | 12 | 22 | 23 | 24 | 25 | | 13 | 23 | 33 | 34 | 35 | | 14 | 24 | 34 | 44 | 45 | | 15 | 25 | 35 | 45 | 55 |⁠)]
Wolfram Language code: sm["Properties"]


"Summary"特性は行列についての簡単な要約を与える：

Wolfram Language code: sm["Summary"]

"StructuredAlgorithms"特性は構造化アルゴリズムを持つ関数を列挙する：

Wolfram Language code: sm["StructuredAlgorithms"]

オプション  (1)

TargetStructure  (1)

対称行列を密な行列として返す：

Wolfram Language code: SymmetricMatrix[(⁠| | | | | - | - | - | | 1 | 1 | 1 | | 1 | 2 | 2 | | 1 | 2 | 3 |⁠), TargetStructure -> "Dense"]

対称行列を構造化配列として返す：

Wolfram Language code: SymmetricMatrix[(⁠| | | | | - | - | - | | 1 | 1 | 1 | | 1 | 2 | 2 | | 1 | 2 | 3 |⁠), TargetStructure -> "Structured"]

アプリケーション  (8)

連続二次偏導関数を含む多変量関数のヘッセ行列は対称行列である（Schwarzの定理）：

Wolfram Language code: SymmetricMatrix[D[f[x, y, z], {{x, y, z}, 2}]]
Wolfram Language code: MatrixForm[%]

共分散行列と相関行列は対称行列である：

Wolfram Language code: data = RandomReal[1, {20, 5}];
Wolfram Language code: SymmetricMatrix[Covariance[data]]
Wolfram Language code: SymmetricMatrix[Correlation[data]]

対称行列は二次形式から得ることができる：

Wolfram Language code: SymmetricMatrix[Last[CoefficientArrays[a x^2 + b x y + c y^2 + d x + e y + f, {x, y}, "Symmetric" -> True]]]
Wolfram Language code: MatrixForm[%]

無向グラフの隣接行列は疎な対称行列である：

Wolfram Language code: g = PetersenGraph[]
Wolfram Language code: SymmetricMatrix[AdjacencyMatrix[g]]

GaussianOrthogonalMatrixDistributionから導かれた行列は対称行列である：

Wolfram Language code: SymmetricMatrix[RandomVariate[GaussianOrthogonalMatrixDistribution[9]]]

CircularOrthogonalMatrixDistributionから導かれた行列は対称ユニタリ行列である：

Wolfram Language code: SymmetricMatrix[RandomVariate[CircularOrthogonalMatrixDistribution[4]]]

対称正定値行列 を使うことで によって内積が定義できる：

Wolfram Language code: g = SymmetricMatrix[{{7, 2, 0}, {2, 6, -2}, {0, -2, 5}}]
Wolfram Language code: ip[u_, v_] := u.g.v

が正定値行列であることを確認する：

Wolfram Language code: PositiveDefiniteMatrixQ[g]

TemplateBox[{}, Reals]^nの標準基底を直交化して正規直交基底を求める：

Wolfram Language code: {Subscript[e, 1], Subscript[e, 2], Subscript[e, 3]} = Orthogonalize[IdentityMatrix[3], ip]

この基底が内積について正規直交であることを確認する：

Wolfram Language code: Table[ip[Subscript[e, i], Subscript[e, j]], {i, 3}, {j, 3}]//Simplify

慣性モーメントテンソルは回転運動の質量に相当する．例えば，運動エネルギーは，ただし， は式の質量 の位置を，角速度 は線形速度 の位置を占める． は正定値対称行列で表すことができる．端点が原点と正の座標軸にある四面体の慣性モーメントを計算する：

Wolfram Language code: MomentOfInertia[Tetrahedron[{{0, 0, 0}, {a, 0, 0}, {0, b, 0}, {0, 0, c}}], Assumptions -> {a, b, c}∈PositiveReals]//SymmetricMatrix

角速度がのときの運動エネルギーを計算する：

Wolfram Language code: (1/2){Subscript[ω, x], Subscript[ω, y], Subscript[ω, z]}.%.{Subscript[ω, x], Subscript[ω, y], Subscript[ω, z]}//FullSimplify

が非零であれば運動エネルギーは正であり，行列は正定値であることを示している：

Wolfram Language code: Resolve[Subscript[∀, {Subscript[ω, x], Subscript[ω, y], Subscript[ω, z], a, b, c}, {a, b, c}∈PositiveReals && {Subscript[ω, x], Subscript[ω, y], Subscript[ω, z]} ≠ {0, 0, 0}]% > 0]

特性と関係  (4)

対称行列の転置はもとの行列と等しい：

Wolfram Language code: sm = SymmetricMatrix[HilbertMatrix[3]]
Wolfram Language code: Transpose[sm] === sm

対称行列は対称Symmetric[{1,2}]を持つ：

Wolfram Language code: TensorSymmetry[SymmetricMatrix[StructuredArray`StructuredData[{3, 3}, {{{1, 1/2, 1/3}, {1/2, 1/3, 1/4}, {1/3, 1/4, 1/5}}, 0}]]]

対称行列はSymmetrizedArrayまたはSymmetricMatrixで表すことができる：

Wolfram Language code: array = SymmetrizedArray[{{1, 3} -> a, {2, 2} -> b}, {3, 3}, Symmetric[All]]
Wolfram Language code: matrix = SymmetricMatrix[{{0, 0, a}, {0, b, 0}, {a, 0, 0}}]

この2つの表現は等価であるが，異なるアルゴリズムをサポートする：

Wolfram Language code: array == matrix

SymmetrizedArrayは，D，Flatten，Inner，Outer等のテンソル操作をサポートする：

Wolfram Language code: array["StructuredAlgorithms"]

SymmetricMatrixは，KroneckerProductのような行列特有の操作をサポートする：

Wolfram Language code: matrix["StructuredAlgorithms"]

実対称行列はHermitianMatrixで表すことができる：

Wolfram Language code: HermitianMatrix[SymmetricMatrix[(| | | | - | - | | 1 | 2 | | 2 | 3 |)]]

これは，複素対称行列にはあてはまらない：

Wolfram Language code: HermitianMatrix[SymmetricMatrix[(| | | | ----- | ----- | | 1 | 2 + I | | 2 + I | 3 |)]]
Wolfram Research (2024), SymmetricMatrix, Wolfram言語関数， https://reference.wolfram.com/language/ref/SymmetricMatrix.html.

テキスト

Wolfram Research (2024), SymmetricMatrix, Wolfram言語関数， https://reference.wolfram.com/language/ref/SymmetricMatrix.html.

CMS

Wolfram Language. 2024. "SymmetricMatrix." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/SymmetricMatrix.html.

APA

Wolfram Language. (2024). SymmetricMatrix. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/SymmetricMatrix.html

BibTeX

@misc{reference.wolfram_2026_symmetricmatrix, author="Wolfram Research", title="{SymmetricMatrix}", year="2024", howpublished="\url{https://reference.wolfram.com/language/ref/SymmetricMatrix.html}", note=[Accessed: 05-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_symmetricmatrix, organization={Wolfram Research}, title={SymmetricMatrix}, year={2024}, url={https://reference.wolfram.com/language/ref/SymmetricMatrix.html}, note=[Accessed: 05-November-2026]}