Wolfram言語＆システムドキュメントセンター

TourVideo

TourVideo[input,{step₁,step₂,…}]

graphics の周りで刻み幅 step_iのツアーを行うことで動画を生成する．

TourVideo[input,{{t₁,step₁},{t₂,step₂},…}]

graphics の周りで時点 t_iにおける刻み幅 step_iのツアーを行う．

TourVideo[input,func]

関数 func のサンプルを取って各フレームの刻み幅指定を生成する．

詳細とオプション

TourVideoはグラフィックスの周りを巡ることで動画を生成する．グラフィックスの周りでズームイン，ズームアウト，パンすることで，関心領域が探検できる．

次は，input の可能な設定である．

	graphics	Graphicsオブジェクト
	image	Imageオブジェクト
	geographics	GeoGraphicsオブジェクト
	video	Videoオブジェクト

位置指定 step_iは以下のいずれかでよい．

	{x,y}	グラフィックスの座標系における絶対位置
	Scaled[{x,y}]	各方向で0から1にスケールされた座標
	Rectangle[…]	明示的な長方形
	Rectangle[Scaled[…],Scaled[…]]	スケールされた座標系での長方形
	Rotate[Rectangle[…],…]	回転された長方形
	<\|prop₁val₁,…\|>	連想の刻み幅特性

刻み幅が特性の連想として与えられた場合は，以下のキーを指定することができる．

	"Position"	{x,y}で与えられる関心領域の中心位置
	"DwellTime"	秒（またはその他の時間量）で与えられた滞留時間
	"Rotation"	場所の周りボックスの回転
	"Width"	関心領域の幅

次は，フレーム作成を制御するオプションである．

AspectRatio	9/16	使用する縦横比
DefaultDuration	Automatic	推奨時間（単位：秒）
InterpolationOrder	1	使用する補間次数

パネル内にフレームを生成したければParallelize[TourVideo[…]]を使うとよい．
デフォルトで，TourVideoは新規動画を$WolframDocumentsDirectoryの"Video"ディレクトリに置く．
次は，動画の出力の特性を制御するオプションである．

BitRate	Automatic	使用するおおよそのビットレート
CompressionLevel	Automatic	使用する圧縮レベル
FrameRate	Automatic	使用するフレームレート
GeneratedAssetFormat	Automatic	結果の形式
GeneratedAssetLocation	$GeneratedAssetLocation	結果の場所
OverwriteTarget	False	既存ファイルに上書きするかどうか
RasterSize	Automatic	出力動画のラスターサイズ
VideoEncoding	Automatic	使用する動画の符号化
VideoTransparency	False	出力動画が透明度チャンネルを持つべきかどうか

例題

すべて開くすべて閉じる

例 (2)

画像全体が入るようにパンする：

Wolfram Language code: i = ExampleData[{"TestImage", "Volubilis"}]

Wolfram Language code: TourVideo[i, {Rectangle[Scaled[{.1, .4}], Scaled[{.2, .5}]], Rectangle[Scaled[{.8, .4}], Scaled[{.9, .5}]]}]

画像の一部にズームインする：

Wolfram Language code: TourVideo[i, {<|"Position" -> {2700, 1800}, "Width" -> 1500|>, <|"Position" -> {2700, 1800}, "Width" -> 200|>}]

ズームアウトする：

Wolfram Language code: TourVideo[i, {<|"Position" -> {2700, 1800}, "Width" -> 200|>, <|"Position" -> {2700, 1800}, "Width" -> 1500|>}]

パンとズーム：

Wolfram Language code: TourVideo[i, {<|"Position" -> {5000, 2000}, "Width" -> 3000|>, <|"Position" -> {2700, 1800}, "Width" -> 200|>}]

ドイツの地図を探索する動画を生成する：

Wolfram Language code:

TourVideo[GeoGraphics[], {Entity["City", {"Munich", "Bavaria", "Germany"}], Entity["City", {"Wurzburg", "Bavaria", "Germany"}]}]

スコープ (6)

データ (4)

グラフィックスオブジェクトを調べる：

Wolfram Language code: TourVideo[[image], {{8, 41}, {10, 43}, {14, 41}, {13, 46}, {8, 41}}]

フラクタルメッシュを調べる：

Wolfram Language code:

TourVideo[[image], Table[<|"Position" -> Scaled[{.5, 1 - 1 / (i + 1)}], "Width" -> Scaled[1 / i]|>, {i, 1, 5}], AspectRatio -> 1]

GeoGraphicsオブジェクトを調査する：

Wolfram Language code:

TourVideo[GeoGraphics[], {Entity["City", {"Paris", "IleDeFrance", "France"}], Entity["City", {"Rome", "Lazio", "Italy"}]}]

GeoGraphicsオブジェクトをカスタムスタイリングで使う：

Wolfram Language code:

TourVideo[GeoGraphics[{GeoStyling[{"Image", SetAlphaChannel[CountryData[#, "Flag"], .3]}], Polygon[Entity["Country", #]]}& /@ {"France", "Germany", "Italy", "Spain"}], 
	{Entity["City", {"Rome", "Lazio", "Italy"}], Entity["City", {"Paris", "IleDeFrance", "France"}]}]

動画の中心にズームする：

Wolfram Language code: v = Video["ExampleData/bullfinch.mkv"];

Wolfram Language code: TourVideo[v, {Full, <|"Position" -> Scaled[{.5, .5}], "Width" -> Scaled[.2]|>}]

ステップ指定 (2)

場所のリストを使ってツアーを指定する：

Wolfram Language code: i = [image];

Wolfram Language code: TourVideo[i, {{243, 650}, {760, 460}, {1170, 640}}]

場所を訪れる回数を指定する：

Wolfram Language code: TourVideo[i, {{1, {243, 650}}, {3, {760, 460}}, {6, {1170, 640}}}]

連想のリストを使ってツアーを指定する：

Wolfram Language code:

TourVideo[i, {<|"Position" -> {243, 650}, "Width" -> 100|>, <|"Position" -> {760, 460}, "Width" -> 300|>, <|"Position" -> {1170, 640}, "Width" -> 200|>}]

場所を訪れる回数を指定する：

Wolfram Language code:

TourVideo[i, {{0, <|"Position" -> {243, 650}, "Width" -> 100|>}, {2, <|"Position" -> {760, 460}, "Width" -> 300|>}, {6, <|"Position" -> {1170, 640}, "Width" -> 200|>}}]

矩形のリストを使ってツアーを指定する：

Wolfram Language code:

TourVideo[i, {Rectangle[{200, 600}, {400, 700}], Rectangle[{700, 400}, {900, 500}], Rectangle[{1000, 600}, {1200, 700}]}]

場所を訪れる回数を指定する：

Wolfram Language code:

TourVideo[i, {{0, Rectangle[{200, 600}, {400, 700}]}, {1, Rectangle[{700, 400}, {900, 500}]}, {5, Rectangle[{1000, 600}, {1200, 700}]}}]

場所を返す関数を使ってツアーを指定する：

Wolfram Language code: path[time_] := 400 + {time * 100, 100 * Sin[2 * time]}

Wolfram Language code: TourVideo[i, path]

連想を返す関数を使う：

Wolfram Language code:

pathAssoc[time_] := 
	<|"Position" -> 400 + {time * 100, 100 * Sin[2 * time]}, "Width" -> 200 + 100Cos[time]|>

Wolfram Language code: TourVideo[i, pathAssoc]

矩形を返す関数を使う：

Wolfram Language code:

pathRectangle[time_] := With[{pos = 400 + {time * 100, 100 * Sin[2 * time]}}, 
	Rectangle[pos - {100, 50}, pos + {100, 50}]]

Wolfram Language code: TourVideo[i, pathRectangle]

GeoDiskを使ってツアーを指定する：

Wolfram Language code:

TourVideo[GeoGraphics[], {GeoDisk[Entity["City", {"Munich", "Bavaria", "Germany"}], Quantity[100, "Kilometers"]], GeoDisk[Entity["City", {"Wurzburg", "Bavaria", "Germany"}], Quantity[200, "Kilometers"]]}]

連想を使ってツアーを指定する：

Wolfram Language code:

TourVideo[GeoGraphics[], {<|"Position" -> Entity["City", {"Munich", "Bavaria", "Germany"}], "Width" -> Quantity[100, "Kilometers"]|>, <|"Position" -> Entity["City", {"Wurzburg", "Bavaria", "Germany"}], "Width" -> Quantity[200, "Kilometers"]|>}]

純関数を使う：

Wolfram Language code: TourVideo[GeoGraphics[Entity["Country", "Italy"]], GeoPosition[{41.9 + #, 12.5}]&]

アプリケーション (5)

非常に大きい画像の各部分を調べる：

Wolfram Language code:

TourVideo[
	ExampleData[{"TestImage", "Volubilis"}], 
	{
	<|"Position" -> {480, 1750}, "Time" -> 1, "Width" -> 600|>, 
	<|"Position" -> {2700, 1830}, "Time" -> 2, "Width" -> 400|>, 
	<|"Position" -> {2700, 1830}, "Time" -> 3, "Width" -> 400|>, 
	<|"Position" -> {8130, 2200}, "Time" -> 5, "Width" -> 800|>, 
	<|"Position" -> {8130, 2200}, "Time" -> 7, "Width" -> 800|>
	}]

写真の中のすべての顔にズームインする：

Wolfram Language code: image = [image];

Wolfram Language code:

faces = FindFaces[image, {"Position", "BoundingBox"}, PaddingSize -> 20];
faces = faces[[Last@FindShortestTour[faces[[All, "Position"]]]]];

Wolfram Language code: HighlightImage[image, faces[[All, "BoundingBox"]]]

Wolfram Language code: TourVideo[image, faces[[All, "BoundingBox"]], DefaultDuration -> Length@faces]

イタリアの国境に沿って進む：

Wolfram Language code: Graphics[italy = Entity["Country", "Italy"][EntityProperty["Country", "Polygon"]]]

Wolfram Language code:

pts = ArrayResample[italy[[1, 1, 1]], 50, Resampling -> "Nearest"];
Short[pts]

Wolfram Language code:

TourVideo[Graphics[italy], Table[<|"Position" -> p, "Width" -> 7|>, {p, Reverse /@ pts}], FrameRate -> 10, RasterSize -> 250]

画像のコンテンツを訪れることで動画を作成する：

Wolfram Language code: ImageBoundingBoxes[[image], Entity["Concept", "Elephant::72b52"] | Entity["Concept", "Zebra::nx5qr"]]

Wolfram Language code: TourVideo[[image], ArrayPad[%, 1, Full]]

画像のツアーをする複雑なパスを定義してプロットする：

Wolfram Language code: path = time |-> With[{t = 10 - 2time}, <|"Position" -> {400, 210} + {18, 10} t {Cos[t], Sin[t]}, "Width" -> 60 + 25t|>];

Wolfram Language code: ParametricPlot[path[t]["Position"], {t, 0, 5}]

画像の上にパスを描く：

Wolfram Language code:

i = [image];
HighlightImage[i, ParametricPlot[path[t]["Position"], {t, 0, 5}, {PlotStyle -> Directive[Thick, Yellow]}]]

Wolfram Language code: TourVideo[i, path]

Top

その他のラーニングリソース

テクニカルサポート

データサイエンス，金融，ビジネス

工学

科学とテクノロジー

教育のためのテクノロジー

教育イニシアチブ

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

TourVideo

詳細とオプション

例題

例 (2)

スコープ (6)

データ (4)

ステップ指定 (2)

アプリケーション (5)

テキスト

CMS

APA

BibTeX

BibLaTeX

TourVideo

詳細とオプション

例題

例 (2)

スコープ (6)

データ (4)

ステップ指定 (2)

アプリケーション (5)

関連項目

関連するガイド

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX