WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

VideoIntervals[video,crit]

基準 crit を満足する動画の時間区間を返す．

VideoIntervals[video,crit,n]

n 個の動画ブレームのパーティション上で基準 crit を評価する．

VideoIntervals[video,crit,n,d]

crit をオフセット d のパーティション上で評価する．

VideoIntervals[{video1,video2,…},crit,…]

各 videoiから抽出した入力リストに crit を適用する．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
MaxItems  
VideoPadding  
アプリケーション  
関連項目
関連するガイド
履歴
引用書式

VideoIntervals

VideoIntervals[video,crit]

基準 crit を満足する動画の時間区間を返す．

VideoIntervals[video,crit,n]

n 個の動画ブレームのパーティション上で基準 crit を評価する．

VideoIntervals[video,crit,n,d]

crit をオフセット d のパーティション上で評価する．

VideoIntervals[{video1,video2,…},crit,…]

各 videoiから抽出した入力リストに crit を適用する．

詳細とオプション

  • VideoIntervalsを使って，固定フレーム，無音区間，特定のオブジェクトを含む区間等の動画の中の関心区間を検出することができる．
  • 単一の引数の基準 crit が画像フレームまたは画像フレームのリストに適用される．
  • 純関数 crit は，次の引数を使って動画データと音声データおよび時間にアクセスできる．
  • #ImageImageオブジェクトとしての動画フレーム
    #AudioAudioオブジェクトとしての音声のチャンク
    #Time動画の始まりからの時間
    #TimeInterval現在のパーティションの始まりと終りのタイムスタンプ
    #FrameIndex現行出力フレームの指標
    #InputFrameIndex現行入力フレームの指標
  • VideoIntervals[{video1,video2,…},crit,…]で各引数に与えられるデータは，i 番目の要素が videoiから抽出されたデータに対応するリストである．
  • デフォルトで，パーティションには1フレーム分のオフセットがある．
  • VideoIntervalsは，$VideoDecodersによって指定された動画コンテナとコーデックをサポートする．
  • 次は，使用可能なオプションである．
  • MaxItems Infinity返す区間の最大数
    VideoPadding Automatic最終フレームを超えたフレームに使う充填

例題

すべて開く すべて閉じる

例  (2)

固定フレームで動画の区間を求める：

Wolfram Language code: v = Video["ExampleData/Caminandes.mp4"];
Wolfram Language code: VideoIntervals[v, Max[#Image] - Min[#Image] < .01&]

音が大きい動画の区間を求める：

Wolfram Language code: v = Video["ExampleData/bullfinch.mkv"];
Wolfram Language code: VideoIntervals[v, First@Mean[Abs@#Audio] > .1&]

スコープ  (6)

基準を純関数として指定する：

Wolfram Language code: v = VideoTrim[Video["ExampleData/bullfinch.mkv"], {1, 2}];
Wolfram Language code: VideoIntervals[v, ImageMeasurements[#Image, "MeanIntensity"] < .47&]

基準を正規関数として指定する：

Wolfram Language code: crit[assoc_] := ImageMeasurements[assoc["Image"], "MeanIntensity"] < .47
Wolfram Language code: VideoIntervals[v, crit]

基準関数への入力は， （もしあれば）"Time"，"TimeInterval"，"Image"，"FrameIndex"，"InputFrameIndex"，"Audio"のキーを持つ連想である：

Wolfram Language code: v = VideoTrim[Video["ExampleData/bullfinch.mkv"], {1, 2}];
Wolfram Language code: inputs = {}; VideoIntervals[v, (AppendTo[inputs, #];False)&]; inputs[[1]]

5つのフレームのバッファーについて基準を評価する：

Wolfram Language code: v = VideoTrim[Video["ExampleData/bullfinch.mkv"], {1, 2}];
Wolfram Language code: VideoIntervals[v, ImageMeasurements[Mean@#Image, "MeanIntensity"] < .47&, 5]

パーティションサイズがAutomaticではない場合，"Image"の値は画像のリストになる：

Wolfram Language code: inputs = {}; VideoIntervals[v, (AppendTo[inputs, #];False)&, 5];
Wolfram Language code: inputs[[1, "Image"]]

"Audio"の値は常に適切な長さの単一のAudioオブジェクトである：

Wolfram Language code: Duration@inputs[[1, "Audio"]]

パーティションの重なり合ない5つのフレームで基準を評価する：

Wolfram Language code: v = Video["ExampleData/bullfinch.mkv"];VideoIntervals[v, ImageMeasurements[Mean@#Image, "MeanIntensity"] < .47&, 5, 5]

時間量を使ってパーティションサイズとオフセットを指定する：

Wolfram Language code: v = Video["ExampleData/bullfinch.mkv"];VideoIntervals[v, ImageMeasurements[Mean@#Image, "MeanIntensity"] < .47&, Quantity[1, "Seconds"], Quantity[0.5, "Seconds"]]

複数の動画から間隔を計算する：

Wolfram Language code: videos = {Video["ExampleData/bullfinch.mkv"], Video["ExampleData/fish.mp4"]};VideoIntervals[videos, ImageMeasurements[#Image[[1]], "MeanIntensity"] > ImageMeasurements[#Image[[2]], "MeanIntensity"]&]

オプション  (2)

MaxItems  (1)

デフォルトで，MaxItems∞を使うと可能な関心区間について入力全体が評価される：

Wolfram Language code: v = Video["ExampleData/bullfinch.mkv"];
Wolfram Language code: Options[VideoIntervals]
Wolfram Language code: VideoIntervals[v, ImageMeasurements[#Image, "MeanIntensity"] < .47&]

n 個の完全な区間が検出されたところで計算を終える：

Wolfram Language code: VideoIntervals[v, ImageMeasurements[#Image, "MeanIntensity"] < .47&, MaxItems -> 2]

VideoPadding  (1)

ある動画トラックが他のトラックより短い場合は，時間を超えた部分に黒いフレームが使われる：

Wolfram Language code: v1 = FrameListVideo[ConstantImage @* Hue /@ Most[Subdivide[10]], FrameRate -> 2]; v2 = VideoCombine[{v1, AudioGenerator["Sin", 10]}]
Wolfram Language code: VideoIntervals[v2, ImageMeasurements[#Image, "MeanIntensity"] < .3&]

VideoPaddingを使って異なる色の充填を指定する：

Wolfram Language code: VideoIntervals[v2, ImageMeasurements[#Image, "MeanIntensity"] < .3&, VideoPadding -> White]

アプリケーション  (2)

動画で動きが最も大きい区間を求める：

Wolfram Language code: v = Video["ExampleData/bullfinch.mkv"];VideoIntervals[v, ImageMeasurements[ImageDifference@@#Image, "MeanIntensity"] > .025&, 2]

対応するフレームを抽出する：

Wolfram Language code: VideoExtractFrames[v, Interval@@%]//ImageCollage

固定フレームを含む区間を求める：

Wolfram Language code: v = Video["ExampleData/Caminandes.mp4"];
Wolfram Language code: int = VideoIntervals[v, Max[#Image] - Min[#Image] < .1&]

そのような区間を動画から削除する：

Wolfram Language code: VideoDelete[v, int]

もとの動画と結果の動画の継続時間を比較する：

Wolfram Language code: Duration /@ {v, %}
Wolfram Research (2020), VideoIntervals, Wolfram言語関数， https://reference.wolfram.com/language/ref/VideoIntervals.html.

テキスト

Wolfram Research (2020), VideoIntervals, Wolfram言語関数， https://reference.wolfram.com/language/ref/VideoIntervals.html.

CMS

Wolfram Language. 2020. "VideoIntervals." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/VideoIntervals.html.

APA

Wolfram Language. (2020). VideoIntervals. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/VideoIntervals.html

BibTeX

@misc{reference.wolfram_2026_videointervals, author="Wolfram Research", title="{VideoIntervals}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/VideoIntervals.html}", note=[Accessed: 04-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_videointervals, organization={Wolfram Research}, title={VideoIntervals}, year={2020}, url={https://reference.wolfram.com/language/ref/VideoIntervals.html}, note=[Accessed: 04-November-2026]}