WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

"CArray" （コンパイルタイプ）

"CArray"::[type]

指定された型の要素を含む，C言語と互換の配列型を表す．

詳細

  • "CArray"はTypedおよび型を指定する関連した構造で使うことができる．
  • 型"CArray"を持つオブジェクトは自動的にはメモリ管理されないので，手動で解放しなければならない．
  • "CArray"::[t]はC言語のt*に等しい．
  • "CArray"はC言語と互換の外部ライブラリとインタラクトする際に使うことができる．
  • 内部的には型"CArray"を持つオブジェクトはポインタで表される．

コンストラクタ

特性

  • 型"CArray"::[type]の carr のInformation[carr,"ElementType"]は type を与える．
  • FromRawPointer[carr,offset]はC配列 carr に指標を付ける．指標は0から始まる．

変換

    配列

  • 配列型は管理されたC配列にCastすることができる．サポートされる配列型には"ListVector"，"NumericArray"，"PackedArray"がある．

    • "RawPointer"および"OpaqueRawPointer"

  • CastはC配列を未加工のポインタにビットキャストしたり未加工のポインタからビットキャストするために使うことができる．

ランタイムエラー

  • 指標付けは安全ではない操作であり，C配列の終りを超えた指標付けはクラッシュを起こす場合がある．

例題

すべて開く すべて閉じる

例  (3)

メモリ管理されたC配列を作成し，その要素の中の一つにアクセスする：

Wolfram Language code: cf = FunctionCompile[Function[{}, Module[{carr}, carr = CreateTypeInstance["Managed"::["CArray"::["MachineInteger"]], {3, 1, 4}]; FromRawPointer[carr, 2] ]]]
Wolfram Language code: cf[]

引数としてC配列を取る，外部ライブラリからの関数を表す：

Wolfram Language code: dec = LibraryFunctionDeclaration["sumArray", "compilerDemoBase", {"CArray"::["CLong"], "CLong"} -> "CInt"];

C配列を作成しその関数を呼び出すプログラムをコンパイルする：

Wolfram Language code: cf = FunctionCompile[dec, Function[Typed[arg, "ListVector"::["CLong"]], Module[{carr}, carr = CreateTypeInstance["Managed"::["CArray"::["CLong"]], arg]; LibraryFunction["sumArray"][carr, Length[arg]] ] ]]
Wolfram Language code: cf[Range[100]]

C配列を作成しそれを解放するプログラムをコンパイルする：

Wolfram Language code: cf = FunctionCompile[ Function[Typed[arg, "MachineInteger"], Module[{carr}, carr = CreateTypeInstance[ "CArray"::["Real64"], arg]; DeleteObject[carr] ] ]]
Wolfram Language code: cf[10]

考えられる問題  (1)

"Managed"オブジェクトの外部で生成されたC配列は自動的にメモリ管理されないので，手動で解放しなければならない．管理されないC配列を作成する関数をコンパイルする：

Wolfram Language code: cf1 = FunctionCompile[Function[{}, With[{carr = CreateTypeInstance["CArray"::["Integer8"], 100]}, Null ]]]

この関数はメモリをリークする：

Wolfram Language code: With[{before = MemoryInUse[]}, Do[cf1[], 10];MemoryInUse[] - before]

DeleteObjectを使って手動でC配列を解放する：

Wolfram Language code: cf2 = FunctionCompile[Function[{}, With[{carr = CreateTypeInstance["CArray"::["Integer8"], 100]}, DeleteObject[carr] ]]]

結果の関数はメモリをリークしない：

Wolfram Language code: With[{before = MemoryInUse[]}, Do[cf2[], 10];MemoryInUse[] - before]