WOLFRAM

Wolfram 语言与系统参考资料中心

"StringVector" （数据结构）

"StringVector"

表示字符串向量.

更多信息

  • "StringVector" 是字符串列表或向量的高效不可变表示.
  • CreateDataStructure["StringVector",{s1,…}]根据字符串列表创建新的 "StringVector"
    Typed[x,"StringVector"]指定 x 的类型为 "StringVector"
  • 对于类型为 "StringVector" 的数据结构，可进行以下运算：
  • ds["Part",i]给出 ds 的第 i 个元素用时：O(1)
    ds["Pick",bvec]选择与 "BitVector" bvec 的置位位元相对应的 ds 的元素用时：O(n)
    ds["Join",ds1]合并向量 ds 和 ds1用时：O(n)
    ds["StringByteCount"]给出 ds 中每个字符串元素的 StringByteCount用时：O(n)
    ds["StringLength"]给出 ds 中每个字符串元素的 StringLength用时：O(n)
    ds["StringCount",patt]给出 ds 中每个元素含有字符串表达式 patt 的 StringCount用时：O(n)
    ds["StringMatchQ",patt]返回一个 "BitVector"，其中，与 StringMatchQ[si,patt] 为True 的 ds 的元素 si 对应的位元 i 被置位用时：O(n)
    ds["StringFreeQ",patt]返回一个 "BitVector"，其中，与 StringFreeQ[si,patt] 为True 的 ds 的元素 si 对应的位元 i 被置位用时：O(n)
    ds["StringContainsQ",patt]返回一个 "BitVector"，其中，与 StringContainsQ[si,patt] 为 True 的 ds 的元素 si 对应的位元 i 被置位用时：O(n)
    ds["StringStartsQ",patt]返回一个 "BitVector"，其中，与 StringStartsQ[si,patt] 为 True 的 ds 的元素 si 对应的位元 i 被置位用时：O(n)
    ds["StringEndsQ",patt]返回一个 "BitVector"，其中，与 StringEndsQ[si,patt] 为 True 的 ds 的元素 si 对应的位元 i 被置位用时：O(n)
    ds["Visualization"]返回 ds 的可视化用时：O(n)
  • 还支持以下函数：
  • dsi===dsj如果 dsi 等于 dsj 则为 True
    FullForm[ds]ds 的完全形式
    Information[ds]关于 ds 的信息
    InputForm[ds]ds 的输入形式
    Normal[ds]将 ds 转换成普通表达式

范例

打开所有单元 关闭所有单元

基本范例  (4)

可用 CreateDataStructure 创建新的 "StringVector"：

Wolfram Language code: ds = CreateDataStructure["StringVector", {"For", "each", "ϵ > 0", "there", "exists", "δ", "such", "that", "…"}]

以字符串的形式获取第三个元素：

Wolfram Language code: ds["Part", 3]

以 "StringVector" 的形式通过逆序获取最后三个元素：

Wolfram Language code: ds["Part", -1 ;; -3 ;; -1]

将结果更改为字符串列表：

Wolfram Language code: Normal[%]

获取每个元素的字符串长度：

Wolfram Language code: ds["StringLength"]

获取每个元素的字符串字节数：

Wolfram Language code: ds["StringByteCount"]

计算每个元素中英语元音的数量：

Wolfram Language code: ds["StringCount", RegularExpression["[aeiou]"]]

判断哪些元素含有字母 "a"：

Wolfram Language code: ds["StringContainsQ", "a"]

给出这些元素：

Wolfram Language code: ds1 = ds["Pick", %]
Wolfram Language code: ds1//Normal

选择不含字母 "e" 的元素：

Wolfram Language code: ds2 = ds["Pick", ds["StringFreeQ", "e"]]
Wolfram Language code: Normal[%]

"StringVector" 通常会比字符串列表使用更少的内存：

Wolfram Language code: words = BlockRandom[RandomWord[10000], RandomSeeding -> 314]; ds = CreateDataStructure["StringVector", words]
Wolfram Language code: {ByteCount[words], ByteCount[ds]}

用 "StringVector" 查找文字字符串比查找字符串列表要快得多：

Wolfram Language code: BlockRandom[ words = RandomWord[100]; wordlist = RandomChoice[words, 12345], RandomSeeding -> 314 ]; ds = CreateDataStructure["StringVector", wordlist]; literal = ds[[-1]]
Wolfram Language code: RepeatedTiming[btest = ds["StringMatchQ", literal]]
Wolfram Language code: RepeatedTiming[test = StringMatchQ[wordlist, literal];]

用 "StringVector" 选择元素比选择字符串列表要快得多：

Wolfram Language code: BlockRandom[ words = RandomWord[100]; wordlist = RandomChoice[words, 12345], RandomSeeding -> 314 ]; ds = CreateDataStructure["StringVector", wordlist];

选择以 "r" 开头、以 "e" 结尾的 "StringVector" 元素：

Wolfram Language code: RepeatedTiming[dselected = ds["Pick", ds["StringContainsQ", "r*e"]]]

将 Select 与字符串列表一起使用：

Wolfram Language code: RepeatedTiming[selected = Select[wordlist, StringContainsQ[#, "r*e"]&];]

结果相同：

Wolfram Language code: Normal[dselected] === selected

范围  (1)

信息  (1)

可用 CreateDataStructure 创建新的 "StringVector"：

Wolfram Language code: ds = CreateDataStructure["StringVector", {"This", "is", "a", "string", "vector"}]

关于数据结构 ds 的信息：

Wolfram Language code: Information[ds]