WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

How to | グラフィックスをカスタマイズする方法

Wolfram言語では，グラフィックスをさまざまなオプションを使って2Dおよび3Dのグラフィックスをカスタマイズすることができる．

Plotによって作成されるデフォルトのグラフィックスは，さまざまなデフォルトのオプション値を使う：

Wolfram Language code: Plot[Sin[x], {x, 0, 2π}]

プロットにラベルを加える：

Wolfram Language code: Plot[Sin[x], {x, 0, 2π}, PlotLabel -> Sin[x]]

プロットラベルにスタイルを付ける：

Wolfram Language code: Plot[Sin[x], {x, 0, 2π}, PlotLabel -> Style[Sin[x], {Red, 18}]]
    

曲線にスタイルを付ける：

Wolfram Language code: Plot[Sin[x], {x, 0, 2π}, PlotStyle -> Directive[Thick, Dashed, Red]]

座標軸にスタイルを付ける：

Wolfram Language code: Plot[Sin[x], {x, 0, 2π}, AxesStyle -> Directive[Thick, Dashed, Red]]

ラベルにスタイルを付ける：

Wolfram Language code: Plot[Sin[x], {x, 0, 2π}, LabelStyle -> Directive[Thick, Dashed, Red]]
    

充填を施したプロットを作成する：

Wolfram Language code: Plot[Sin[x], {x, 0, 2π}, Filling -> Axis]

格子線を描く：

Wolfram Language code: Plot[Sin[x], {x, 0, 2π}, GridLines -> Automatic]

座標軸上に手入力の目盛を指定する：

Wolfram Language code: Plot[Sin[x], {x, 0, 2π}, Ticks -> {Range[0, 2π, π / 2], Range[-1, 1, 0.5]}]
    

プロットの上下に点を加える：

Wolfram Language code: Plot[Sin[x], {x, 0, 2π}, Prolog -> {Red, PointSize[0.02], Point[{{π / 2, 1}, {3π / 2, -1}}]}, Epilog -> {Green, PointSize[0.02], Point[{{0, 0}, {π, 0}, {2π, 0}}]}]

プロットにスタイル付けされたグラフィックスプリミティブをいくつか加える：

Wolfram Language code: Plot[Sin[x], {x, 0, 2π}, Epilog -> { {Red, Text["extrema", {4, 0.5}, {-1, -1}]}, {Blue, Arrowheads[{-0.04, 0.04}], Arrow[{{π / 2, 1}, {4, 0.5}, {3π / 2, -1}}]}}]
    

Plot3Dを使って作成したデフォルトのグラフィックスには，さまざまなデフォルトのオプション値が使われている：

Wolfram Language code: Plot3D[Sin[x] + Sin[y], {x, -6, 6}, {y, -6, 6}]

座標軸の交差点を制御する：

Wolfram Language code: Plot3D[Sin[x] + Sin[y], {x, -6, 6}, {y, -6, 6}, Boxed -> False, AxesOrigin -> {-6, -6, -2}]
    

メッシュを削除する：

Wolfram Language code: Plot3D[Sin[x] + Sin[y], {x, -6, 6}, {y, -6, 6}, Mesh -> False]

曲面上に描かれたメッシュの密度を制御する：

Wolfram Language code: Column[Table[Plot3D[Sin[x] + Sin[y], {x, -6, 6}, {y, -6, 6}, Mesh -> m], {m, {All, Full, 5}}]]
    

いくつかの曲面を一緒にプロットする：

Wolfram Language code: Plot3D[{-x ^ 4 - y ^ 4, x ^ 2 + y ^ 2, (x / 1.3) ^ 5 + (y / 1.3) ^ 5}, {x, -2, 2}, {y, -2, 2}]

曲面のプロットされた領域を制御する：

Wolfram Language code: Plot3D[{-x ^ 4 - y ^ 4, x ^ 2 + y ^ 2, (x / 1.3) ^ 5 + (y / 1.3) ^ 5}, {x, -2, 2}, {y, -2, 2}, RegionFunction -> Function[{x, y, z}, x ^ 4 + y ^ 4 ≤ 4]]

照明のシミュレーションを指定して曲面の色付けに使う：

Wolfram Language code: Plot3D[{-x ^ 4 - y ^ 4, x ^ 2 + y ^ 2, (x / 1.3) ^ 5 + (y / 1.3) ^ 5} , {x, -2, 2}, {y, -2, 2}, RegionFunction -> Function[{x, y, z}, x ^ 4 + y ^ 4 ≤ 4], Mesh -> None, Lighting -> {{"Point", Yellow, {0, -5, -5}}, {"Point", Blue, {0, 3, 3}}, {"Point", Red, {-3, -3, 0}}, {"Point", Green, {5, 5, 0}}}]

ボックス次元の率を制御して別のスタイルを加える：

Wolfram Language code: Plot3D[{-x ^ 4 - y ^ 4, x ^ 2 + y ^ 2, (x / 1.3) ^ 5 + (y / 1.3) ^ 5}, {x, -2, 2}, {y, -2, 2}, RegionFunction -> Function[{x, y, z}, x ^ 4 + y ^ 4 ≤ 4], BoxRatios -> {1, 1, 1}, Axes -> False, Background -> Black, Boxed -> False, Mesh -> None]
    

PlotおよびPlot3Dを使って生成するプロットをカスタマイズするのに使用できるすべてのオプションのリストを得る：

Wolfram Language code: Row[Column /@ {Options[Plot], Options[Plot3D]}]