ARIMAProcess
ARIMAProcess[{a1,…,ap},d,{b1,…,bq},v]
次差分が弱定常ARMAProcess[{a1,…,ap},{b1,…,bq},v]である，ARIMA（自己回帰和分移動平均）過程 
を表す．
ARIMAProcess
ARIMAProcess[{a1,…,ap},d,{b1,…,bq},v]
次差分が弱定常ARMAProcess[{a1,…,ap},{b1,…,bq},v]である，ARIMA（自己回帰和分移動平均）過程 
を表す．
ARIMAProcess[{a1,…,ap},d,{b1,…,bq},Σ]
(d,…,d)次差分が弱定常ベクトルARMAProcessである，ベクトルARIMA過程 (y1(t),… ,yn(t))を表す．
ARIMAProcess[{a1,…,ap},{d1,…,dn},{b1,…,bq},Σ]
(d,…,d)次差分が弱定常ベクトルARMAProcessである，ベクトルARIMA過程 (y1(t),… ,yn(t))を表す．
ARIMAProcess[{a1,…,ap},d,{b1,…,bq},v,init]
初期データ init のARIMA過程を表す．
ARIMAProcess[c,…]
定数 c のARIMA過程を表す．
詳細
- ARIMAProcessは離散時間・連続状態のランダム過程である．
- ARIMAProcess[…,d,…,v]には，次数 d（ただし d≥1）の多項式トレンドがある．
- ARIMA過程は差分方程式
で説明される．
は状態出力，
はホワイトノイズ入力，
はシフト演算子であり，定数 c は指定がなければゼロであるとみなされる． - 初期データ init は，リスト{…,y[-2],y[-1]}として，あるいはタイムスタンプが{…,-2,-1}であると考えられる単一路TemporalDataオブジェクトとして与えることができる．
- スカラーARIMA過程には，実数係数 ai，bj，c，非負整数の和分次数 d，正の分散 v がなければならない．
次元ベクトルARIMA過程には，次元が 
×
の実数係数行列 ai および bj，長さ 
の実ベクトル c，非負整数の和分次数 di または非負整数の和分次数 d がなければならず，共分散行列 Σ は次元 
×
の正定値対称行列でなければならない．- 定数がゼロであるARIMA過程は伝達関数
を持つ．ただし，
かつ
であり，
は 
次元単位である． - ARIMAProcess[p,d,q]は，自己回帰および移動平均の次数がそれぞれ p および q であり，和分次数が d である，EstimatedProcessおよび関連関数に使われるARIMA過程を表す．
- ARIMAProcessは，CovarianceFunction，RandomFunction，TimeSeriesForecast等の関数で使うことができる．
例題
すべて開く すべて閉じる例 (2)
SeedRandom[234];sample = RandomFunction[ARIMAProcess[{-.1}, 1, {.2}, .1], {1, 10 ^ 2}]ListPlot[sample, Filling -> Axis]二次曲線のトレンドがあるARIMA過程のシミュレーションを行う：
SeedRandom[19];sample = RandomFunction[ARIMAProcess[.2, {-.6}, 2, {.8}, .1], {1, 50}]ListPlot[sample, Filling -> Axis]スコープ (25)
基本的な用法 (9)
data = RandomFunction[ARIMAProcess[1, {.5}, 1, {.7}, 1], {30}, 4]ListLinePlot[data, Filling -> Axis]RandomFunction[ARIMAProcess[1 / 4, {2 / 10, 1 / 10}, 2, {2 / 7}, 1 / 10], {1, 4}, WorkingPrecision -> 20]["Paths"]sproc[x_] := ARIMAProcess[0, {.6}, 1, {.3}, 1, {x}];pts = {-4, 0, 4, 8};samples = Table[SeedRandom[4];RandomFunction[sproc[x], {100}], {x, pts}];ListLinePlot[samples, DataRange -> {0, 12}, PlotLegends -> (StringJoin["x = ", ToString[#]]& /@ pts)]tproc[x_] := ARIMAProcess[0.2, {1.1}, 1, {.3}, 1, {x}];tsamples = Table[SeedRandom[4];RandomFunction[tproc[x], {30}], {x, pts}];ListLinePlot[tsamples, DataRange -> {0, 12}, PlotLegends -> (StringJoin["x = ", ToString[#]]& /@ pts)]α = {{.2, .1}, {-.3, .2}};
β = {{.2, .5}, {-.2, .9}};
Σ = {{1, 0}, {0, .3}};
sample = RandomFunction[ARIMAProcess[{α}, {1, 1}, {β}, Σ], {1, 10 ^ 3}];s = TimeSeries[sample, ResamplingMethod -> Automatic];
f = s["PathFunction"];
g[t_ ? NumericQ] := f[t]ParametricPlot[g[t], {t, 1, 100}, ColorFunction -> Function[{x, y, t}, (ColorData["BlueGreenYellow"][t])], PlotStyle -> Thick, AspectRatio -> 1, AxesLabel -> {x, y}]gg[t_ ? NumericQ] := Join[{t}, f[t]]ParametricPlot3D[gg[t], {t, 1, 100}, ColorFunction -> Function[{t, x, y}, (ColorData["BlueGreenYellow"][t])], PlotStyle -> Thick, BoxRatios -> 1, AxesLabel -> {t, x, y}]α = {{.2, .1, .1}, {-.3, .2, .1}, {-.3, .2, -.1}};
β = {{.2, .5, .1}, {-.2, .9, .5}, {.3, .1, -.4}};
Σ = {{1, 0, 0}, {0, .3, 0}, {0, 0, .1}};
SeedRandom[4];sample = RandomFunction[ARIMAProcess[{α}, 1, {β}, Σ], {1, 10 ^ 2}];s = TimeSeries[sample, ResamplingMethod -> Automatic];
f = s["PathFunction"];
g[t_ ? NumericQ] := f[t]ParametricPlot3D[g[t], {t, 1, 100}, ColorFunction -> Function[{x, y, z, t}, (ColorData["BlueGreenYellow"][t])], PlotStyle -> Thick, BoxRatios -> 1, AxesLabel -> {x, y, z}]SeedRandom[314];sample = RandomFunction[ARIMAProcess[.3, {.2}, 1, {.3}, .1], {1, 1000}];eproc = EstimatedProcess[sample, ARIMAProcess[1, d, 1]]TimeSeriesModelを使って自動的に次数を求める：
tsm = TimeSeriesModelFit[sample]tsm["Process"]proc = ARIMAProcess[{1, 2}, {{{.2, .1}, {.5, .3}}}, {1, 0}, {{{.9, .2}, {-.5, -.2}}}, {{1, .3}, {.3, .5}}];
data = RandomFunction[proc, {10 ^ 2}];eproc = EstimatedProcess[data, ARIMAProcess[1, {1, 0}, 1]]proc = ARIMAProcess[.4, {.3}, 2, {-.5}, 1];
sample = RandomFunction[proc, {1, 10 ^ 2}];
forecast = TimeSeriesForecast[proc, sample, {15}]forecast["Path"]ListLinePlot[{sample, forecast}, InterpolationOrder -> 0, Filling -> Axis]proc = ARIMAProcess[{{{.3, .1}, {.9, .1}}}, {1, 2}, {{{.4, -.2}, {.1, .7}}, {{.2, -.4}, {.5, -.3}}}, {{1, .2}, {.2, .6}}];
data = RandomFunction[proc, {0, 15}];forecast = TimeSeriesForecast[proc, data, {10}]Row@Table[ListLinePlot[#["PathComponent", j]& /@ {data, forecast}, PlotLabel -> Subscript[x, j], PlotLegends -> {"data", "forecast"}], {j, 1, 2}]定常性と可逆性 (2)
WeakStationarity[ARIMAProcess[c, {Subscript[a, 1], Subscript[a, 2]}, d, {Subscript[b, 1], Subscript[b, 2]}, σ^2]]TimeSeriesInvertibility[ARIMAProcess[c, {Subscript[a, 1], Subscript[a, 2]}, d, {Subscript[b, 1], Subscript[b, 2]}, σ^2]]推定法 (5)
ARIMAProcessの推定に使用できるメソッド：
methods = {Automatic, "MethodOfMoments", "MaximumConditionalLikelihood", "MaximumLikelihood", "SpectralEstimator"};SeedRandom[3];
data = RandomFunction[ARIMAProcess[.3, {.4}, 1, {.3}, 1], {100}];Grid[res = Table[{m, EstimatedProcess[data, ARIMAProcess[1, 1], ProcessEstimator -> m]}, {m, methods}], Frame -> All, Spacings -> {1, 2}, Alignment -> {Left, Center}]solvers = {Automatic, "FindRoot", "NSolve"};SeedRandom[3];
data = RandomFunction[ARIMAProcess[{.4}, 1, {.3}, 1], {100}];Grid[res = Table[{m, EstimatedProcess[data, ARIMAProcess[1, 1], ProcessEstimator -> {"MethodOfMoments", Method -> m}]}, {m, solvers}], Frame -> All, Spacings -> {1, 2}, Alignment -> {Left, Center}]EstimatedProcess[data, ARIMAProcess[c, {.4, b}, d, {m}, v], ProcessEstimator -> "MethodOfMoments"]EstimatedProcess[data, ARIMAProcess[c, {a * b, b}, d, {a}, v], ProcessEstimator -> "MethodOfMoments"]solvers = {Automatic, "FindMaximum", "NMaximize"};SeedRandom[3];
data = RandomFunction[ARIMAProcess[2, {.4}, 1, {.3}, 1], {100}];Grid[Table[{m, EstimatedProcess[data, ARIMAProcess[1, 1], ProcessEstimator -> {"MaximumConditionalLikelihood", Method -> m}]}, {m, solvers}], Frame -> All, Spacings -> {1, 2}, Alignment -> {Left, Center}]EstimatedProcess[data, ARIMAProcess[c, {.1, b}, d, {m}, v], ProcessEstimator -> "MaximumConditionalLikelihood"]EstimatedProcess[data, ARIMAProcess[c, {b, b}, d, {m}, v], ProcessEstimator -> "MaximumConditionalLikelihood"]solvers = {Automatic, "FindMaximum", "NMaximize"};SeedRandom[3];
data = RandomFunction[ARIMAProcess[2, {.4, .2}, 1, {.3}, 1], {100}];Grid[Table[{m, EstimatedProcess[data, ARIMAProcess[2, 1], ProcessEstimator -> {"MaximumLikelihood", Method -> m}]}, {m, solvers}], Frame -> All, Spacings -> {1, 2}, Alignment -> {Left, Center}]EstimatedProcess[data, ARIMAProcess[c, {.1, b}, d, {m}, v], ProcessEstimator -> "MaximumLikelihood"]EstimatedProcess[data, ARIMAProcess[c, {b, b}, d, {m}, v], ProcessEstimator -> "MaximumLikelihood"]スペクトル推定器では，PowerSpectralDensityの計算に使う窓を指定することができる：
SeedRandom[3];
data = RandomFunction[ARIMAProcess[2, {.4, .2}, 1, {.3}, 1], {100}];Grid[Table[{m, EstimatedProcess[data, ARIMAProcess[2, 1], ProcessEstimator -> {"SpectralEstimator", "Window" -> m}]}, {m, {10, BartlettWindow, {3, HannWindow}}}], Frame -> All, Spacings -> {1, 2}, Alignment -> {Left, Center}]solvers = {Automatic, "FindMinimum", "NMinimize"};Grid[Table[{m, EstimatedProcess[data, ARIMAProcess[2, 1], ProcessEstimator -> {"SpectralEstimator", Method -> m}]}, {m, solvers}], Frame -> All, Spacings -> {1, 2}, Alignment -> {Left, Center}]EstimatedProcess[data, ARIMAProcess[c, {.1, b}, d, {m}, v], ProcessEstimator -> "SpectralEstimator"]EstimatedProcess[data, ARIMAProcess[c, {b, b}, d, {m}, v], ProcessEstimator -> "SpectralEstimator"]過程スライス特性 (5)
1つの時間スライス分布(SliceDistribution)：
SliceDistribution[ARIMAProcess[c, {a}, d, {b}, σ ^ 2], t]//MeanSliceDistribution[ARIMAProcess[1.2, {.2}, 1, {.3}, 1, {}], {1, 3}]//CovarianceSliceDistribution[ARIMAProcess[1, {.2}, 1, {.3}, 1], {1, 2, 3}]//Meanα = {{Subscript[a, 1], 0}, {0, Subscript[a, 2]}};
β = {{Subscript[b, 1], 0}, {0, Subscript[b, 2]}};
Σ = {{Subscript[σ, 1]^2, ρ Subscript[σ, 1]Subscript[σ, 2]}, {ρ Subscript[σ, 1]Subscript[σ, 2], Subscript[σ, 2]^2}};
ARIMAProcess[{α}, {1, 2}, {β}, Σ][t]//Meanpdf[t_] = PDF[ARIMAProcess[{1 / 4}, 1, {1 / 3}, 1, {5}][t], x]//Simplifytimes = {1, 2, 3, 4};Plot[Evaluate@Table[pdf[t], {t, times}], {x, -10, 12}, Filling -> Axis, PlotLegends -> (StringJoin["t = ", ToString[#]]& /@ times)]Expectation[x[t] ^ 2, xARIMAProcess[c, {a}, 1, {b}, σ^2], Assumptions -> t > 0]//SimplifyProbability[x[t] < 6, xARIMAProcess[c, {a}, 1, {b}, σ^2], Assumptions -> t > 0]//SimplifySkewness[ARMAProcess[c, {a}, {b}, σ^2][t]]Kurtosis[ARMAProcess[c, {a}, {b}, σ^2][t]]Table[Moment[ARMAProcess[c, {a}, {b}, σ^2][t], r], {r, 0, 4}]//TogetherCharacteristicFunction[ARMAProcess[c, {a}, {b}, σ^2][t], w]MomentGeneratingFunction[ARMAProcess[c, {a}, {b}, σ^2][t], w]CentralMomentおよびその母関数：
Table[CentralMoment[ARMAProcess[c, {a}, {b}, σ^2][t], r], {r, 0, 4}]CentralMomentGeneratingFunction[ARMAProcess[c, {a}, {b}, σ^2][t], w]FactorialMomentは，記号次数では閉形式を持たない：
Table[FactorialMoment[ARMAProcess[c, {a}, {b}, σ^2][t], r]//Simplify, {r, 0, 3}]FactorialMomentGeneratingFunction[ARMAProcess[c, {a}, {b}, σ^2][t], w]Cumulantおよびその母関数：
Table[Cumulant[ARMAProcess[c, {a}, {b}, σ^2][t], r], {r, 0, 4}]CumulantGeneratingFunction[ARMAProcess[c, {a}, {b}, σ^2][t], w]表現 (4)
MAProcess[ARIMAProcess[.4, {.2, .3}, 4, {.1}, 1, {}], 5]proc = ARIMAProcess[{.2, .3}, 1, {.5}, 1, {}];
aproc = ARProcess[proc, 5]SeedRandom[13];sample = RandomFunction[proc, {100}];
SeedRandom[13];asample = RandomFunction[aproc, {100}];
ListLinePlot[{sample, asample}, PlotLegends -> {"ARIMA", "AR"}]proc = ARIMAProcess[{{{.2, .5}, {-.3, .5}}}, {1, 2}, {{{.2, .3}, {0, .4}}}, {{.6, .2}, {.2, .4}}];
aproc = ARProcess[proc, 3]proc = ARIMAProcess[{a}, 2, {b}, 1];
newproc = ARMAProcess[proc]WeakStationarity[newproc]//SimplifyTransferFunctionModel[ARIMAProcess[{Subscript[a, 1], Subscript[a, 2]}, 2, {Subscript[b, 1], Subscript[b, 2]}, σ^2], z]α = {{.2, .3}, {0, .1}};
β = {{-.3, 0}, {.5, -.4}};
δ = {1, 0};
Σ = {{1, 0}, {0, 1}};
TransferFunctionModel[ARIMAProcess[{α}, δ, {β}, Σ], z]StateSpaceModel[ARIMAProcess[{Subscript[a, 1], Subscript[a, 2]}, 2, {Subscript[b, 1], Subscript[b, 2]}, σ^2]]α = {{.2, .3}, {0, .1}};
β = {{-.3, .9}, {.5, -.4}};
δ = {1, 2};
Σ = {{1, 0}, {0, 1}};
StateSpaceModel[ARIMAProcess[{α}, δ, {β}, Σ]]アプリケーション (3)
ExampleData[{"Statistics", "AirlinePassengerMiles"}, "LongDescription"]revenue = ExampleData[{"Statistics", "AirlinePassengerMiles"}, "TimeSeries"]ListLinePlot[revenue, InterpolationOrder -> 0, Filling -> Axis]データには線形のトレンドがある．これはUnitRootTestで確かめることができる：
UnitRootTest[revenue, Automatic, "TestConclusion"]eproc = EstimatedProcess[revenue, ARIMAProcess[2, 1, 2]]forecast = TimeSeriesForecast[eproc, revenue, {10}]ListLinePlot[{revenue, forecast}, InterpolationOrder -> 0, Filling -> Axis]1951年から1980年までの基線と比較した，地球の年間平均気温：
gmt = TemporalData[Automatic, {{{-0.32, -0.32, -0.23, -0.29, -0.3, -0.34, -0.33, -0.29, -0.36, -0.29,
-0.18, -0.41, -0.29, -0.34, -0.35, -0.36, -0.28, -0.2, -0.16, -0.3, -0.19, -0.18, -0.28, -0.33,
-0.37, -0.28, -0.22, -0.42, -0.36, -0.37, -0.3 ... 1, 0.06, 0.28, 0.33,
0.33, 0.21, 0.36, 0.14, 0.14, 0.14, 0.4, 0.31, 0.31, 0.42, 0.34, 0.36, 0.36, 0.49, 0.56, 0.49,
0.49, 0.62, 0.59, 0.44, 0.44, 0.57, 0.51}}, {{1880, 2011, 1}}, 1, {"Discrete", 1},
{"Discrete", 1}, 1, {}}, False, 9.];ListPlot[gmt, Joined -> True, AxesOrigin -> {1880, -.5}]UnitRootTestで和分次数を求める：
Table[UnitRootTest[Differences[gmt, k]], {k, 0, 3}]eproc = EstimatedProcess[gmt, ARIMAProcess[1, 1, 1]]forecast = TimeSeriesForecast[eproc, gmt, {20}]ListPlot[{gmt, forecast}, Joined -> True, AxesOrigin -> {1880, -.5}]data = FinancialData["SBUX", "Close", {{2013, 1, 1}, {2013, 12, 1}, "Week"}];RegularlySampledQ[data]定期的にサンプリングされた時系列を得るためにサンプルを取り直す：
stocks = TimeSeriesResample[data]RegularlySampledQ[stocks]DateListPlot[stocks, Filling -> Axis]eproc = EstimatedProcess[stocks, ARIMAProcess[3, 1, 0], ProcessEstimator -> "MaximumConditionalLikelihood"]forecast = TimeSeriesForecast[eproc, stocks, {26}];DateListPlot[{stocks, forecast}, Filling -> Axis]特性と関係 (4)
ARIMAProcessはARMAProcessを一般化したものである：
TransferFunctionModel[ARIMAProcess[{Subscript[a, 1], Subscript[a, 2]}, 0, {Subscript[b, 1], Subscript[b, 2]}, σ^2], z]TransferFunctionModel[ARMAProcess[{Subscript[a, 1], Subscript[a, 2]}, {Subscript[b, 1], Subscript[b, 2]}, σ^2], z]% - %%ARIMAProcessはARProcessを一般化したものである：
TransferFunctionModel[ARIMAProcess[{Subscript[a, 1], Subscript[a, 2]}, 0, {}, σ^2], z]TransferFunctionModel[ARProcess[{Subscript[a, 1], Subscript[a, 2]}, σ^2], z]% - %%ARIMAProcessはMAProcessを一般化したものである：
TransferFunctionModel[ARIMAProcess[{}, 0, {Subscript[b, 1], Subscript[b, 2]}, σ^2], z]TransferFunctionModel[MAProcess[{Subscript[b, 1], Subscript[b, 2]}, σ^2], z]% - %%ARIMA過程は，離散ステップのWienerProcessに従う：
wiener = WienerProcess[];
arima = ARIMAProcess[{}, 1, {}, 1, {}];Mean /@ {wiener[t], arima[t]}PDF[#, x]& /@ {wiener[t + 1], arima[t]}//Simplify[#, t > 0]&MatrixForm[Covariance[#]]& /@ {wiener[{s + 1, t + 1}], arima[{s, t}]}//Simplify[#, 0 < s < t]&考えられる問題 (5)
複数の時間スライス特性は，記号タイムスタンプについては評価されないことがある：
Correlation[ARIMAProcess[{1 / 2}, 1, {1 / 4}, 1][{Subscript[t, 1], Subscript[t, 2], Subscript[t, 3]}]]Correlation[ARIMAProcess[{1 / 2}, 1, {1 / 4}, 1][{1, 4, 8}]]CovarianceFunction[ARIMAProcess[{2, .3}, 1, {.3, .2}, σ^2], h]
FindInstanceを使って弱定常過程を求める：
FindInstance[a > 0 && WeakStationarity[ARIMAProcess[{a, .2}, d, {.3, .2}, σ^2]], {a, d}]CovarianceFunction[ARIMAProcess[{.4, .2}, 0, {.3, .2}, σ^2], h]厳密ではない母数のスライス分布特性は，記号時間については条件が不良であることがある：
var[t_] = Variance[ARIMAProcess[{.4}, 10, {-.5}, 1, {}][t]];var[2]Variance[ARIMAProcess[{.4}, 10, {-.5}, 1, {}][2]]v[t_] = Variance[ARIMAProcess[{4 / 10}, 10, {-1 / 2}, 1, {}][t]];v[2]N[%]ToInvertibleTimeSeriesは，常に存在するとは限らない：
ToInvertibleTimeSeries[ARIMAProcess[{.2}, 1, {.3, 1}, .2]]
単位円上にはTransferFunctionModelの零点が存在する：
TransferFunctionZeros[TransferFunctionModel[ARIMAProcess[{.2}, 1, {.3, 1}, .2]]]Abs[%]SeedRandom[4];
data = RandomFunction[ARIMAProcess[2, {.4}, 1, {.3}, 1], {100}];EstimatedProcess[data, ARIMAProcess[c, {.4, b}, 1, {1}, v], ProcessEstimator -> {"MethodOfMoments", Method -> "NSolve"}]
EstimatedProcess[data, ARIMAProcess[c, {.4, a}, 1, {b}, v], ProcessEstimator -> {"MethodOfMoments", Method -> "FindRoot"}]おもしろい例題 (2)
三次元ARIMAProcessのシミュレーションを行う：
A = {{.2, .1, .1}, {0, -.2, .3}, {.2, -.1, .3}};
B = {{.4, .2, 0}, {-.2, .8, -.3}, {0, .2, 0}};
S = {{.8, .1, -.2}, {.1, .5, .1}, {-.2, .1, .3}};
proc = ARIMAProcess[{A}, 1, {B}, S];
data = RandomFunction[proc, {100}, k = 8]["ValueList"];Graphics3D@Table[{ColorData["SolarColors"][RandomReal[]], Tube@Line@data[[i]]}, {i, k}]SeedRandom[154];data = RandomFunction[ARIMAProcess[.4, {.3}, 1, {.6}, 1], {50}, 300];sd = data["SliceData", 50];cf = ColorData["Rainbow"];
sliced = BarChart[Last[#], Axes -> False, BarOrigin -> Left, AspectRatio -> 4, ChartStyle -> (cf /@ Rescale[MovingAverage[First[#], 2], {Min[sd], Max[sd]}, {0, 1}]), ImageSize -> 65]&[HistogramList[sd, {Range[Min[sd], Max[sd], (Max[sd] - Min[sd]) / 20]}]];50におけるスライス分布の経路とヒストグラム分布をプロットする：
ListLinePlot[data, ImageSize -> 400, PlotRange -> All,
AspectRatio -> 3 / 4, Epilog -> Inset[sliced, {51, 0}, {0, 4}], PlotStyle -> (Directive[Thin, cf[#]]& /@ Rescale[sd]), PlotRangePadding -> {{0, 15}, {5, 20}}]
Wolfram Research (2012), ARIMAProcess, Wolfram言語関数， https://reference.wolfram.com/language/ref/ARIMAProcess.html （2014年に更新）.
テキスト
Wolfram Research (2012), ARIMAProcess, Wolfram言語関数， https://reference.wolfram.com/language/ref/ARIMAProcess.html （2014年に更新）.
CMS
Wolfram Language. 2012. "ARIMAProcess." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2014. https://reference.wolfram.com/language/ref/ARIMAProcess.html.
APA
Wolfram Language. (2012). ARIMAProcess. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ARIMAProcess.html