WOLFRAM

Wolfram 语言与系统参考资料中心

ARIMAProcess[{a1,…,ap},d,{b1,…,bq},v]

表示差分整合移动平均自回归过程 ，其中第 d 阶差分是弱平稳 ARMAProcess[{a1,…,ap},{b1,…,bq},v].

ARIMAProcess[{a1,…,ap},d,{b1,…,bq},Σ]

表示向量 ARIMA 过程 (y1(t),… ,yn(t))，其中第 (d,…,d) 阶差分是向量弱平稳 ARMAProcess.

ARIMAProcess[{a1,…,ap},{d1,…,dn},{b1,…,bq},Σ]

表示向量 ARIMA 过程 (y1(t),… ,yn(t))，其中第 (d1,…,dn) 阶差分是向量弱平稳 ARMAProcess.

ARIMAProcess[{a1,…,ap},d,{b1,…,bq},v,init]

表示初始数据为 init 的 ARIMA 过程.

ARIMAProcess[c,…]

表示常量为 c 的 ARIMA 过程.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
基本用法  
平稳性和可逆性  
估计方法  
过程切片性质  
表示法  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

ARIMAProcess

ARIMAProcess[{a1,…,ap},d,{b1,…,bq},v]

表示差分整合移动平均自回归过程 ，其中第 d 阶差分是弱平稳 ARMAProcess[{a1,…,ap},{b1,…,bq},v].

ARIMAProcess[{a1,…,ap},d,{b1,…,bq},Σ]

表示向量 ARIMA 过程 (y1(t),… ,yn(t))，其中第 (d,…,d) 阶差分是向量弱平稳 ARMAProcess.

ARIMAProcess[{a1,…,ap},{d1,…,dn},{b1,…,bq},Σ]

表示向量 ARIMA 过程 (y1(t),… ,yn(t))，其中第 (d1,…,dn) 阶差分是向量弱平稳 ARMAProcess.

ARIMAProcess[{a1,…,ap},d,{b1,…,bq},v,init]

表示初始数据为 init 的 ARIMA 过程.

ARIMAProcess[c,…]

表示常量为 c 的 ARIMA 过程.

更多信息

  • ARIMAProcess 是一个离散时间和连续状态随机过程.
  • 对于 d≥1，ARIMAProcess[…,d,…,v] 具有次数为 d 的多项式趋势.
  • ARIMA 过程由差分方程 给出， 其中 是状态输出， 是白噪声输入，而 是平移运算符，常数 c 在未指定的情况下取零.
  • 初始数据 init 可以用列表 {…,y[-2],y[-1]} 或时间标记为 {…,-2,-1} 的单一路径 TemporalData 对象的形式给出.
  • 标量 ARIMA 过程应该具有实系数 ai、bj 和 c，非负整数积分阶数 d 以及正方差 v.
  • 维向量 ARIMA 过程应该具有维度为 × 的实系数矩阵 ai 和 bj，长度为 的实向量 c，整数非负积分阶数 di 或者整数非负积分阶数 d，而协方差矩阵 Σ 应该是维度为 × 的对称正定矩阵.
  • 常数为零的 ARIMA 过程具有传递函数 ，其中 ，，其中 是 -维单位.
  • ARIMAProcess[p,d,q] 表示自回归和移动平均阶数为 p 和 q、积分阶数为 d 的 ARIMA 过程，用于 EstimatedProcess 及相关函数.
  • ARIMAProcess 可以与诸如 CovarianceFunction、RandomFunction 和 TimeSeriesForecast 等函数结合使用.

范例

打开所有单元 关闭所有单元

基本范例  (2)

模拟具有线性趋势的 ARIMA 过程：

Wolfram Language code: SeedRandom[234];sample = RandomFunction[ARIMAProcess[{-.1}, 1, {.2}, .1], {1, 10 ^ 2}]
Wolfram Language code: ListPlot[sample, Filling -> Axis]

模拟具有二次趋势的 ARIMA 过程：

Wolfram Language code: SeedRandom[19];sample = RandomFunction[ARIMAProcess[.2, {-.6}, 2, {.8}, .1], {1, 50}]
Wolfram Language code: ListPlot[sample, Filling -> Axis]

范围  (25)

基本用法  (9)

模拟一组路径：

Wolfram Language code: data = RandomFunction[ARIMAProcess[1, {.5}, 1, {.7}, 1], {30}, 4]
Wolfram Language code: ListLinePlot[data, Filling -> Axis]

给定精度，进行模拟：

Wolfram Language code: RandomFunction[ARIMAProcess[1 / 4, {2 / 10, 1 / 10}, 2, {2 / 7}, 1 / 10], {1, 4}, WorkingPrecision -> 20]["Paths"]

给定初始值，进行模拟：

Wolfram Language code: sproc[x_] := ARIMAProcess[0, {.6}, 1, {.3}, 1, {x}];
Wolfram Language code: pts = {-4, 0, 4, 8};
Wolfram Language code: samples = Table[SeedRandom[4];RandomFunction[sproc[x], {100}], {x, pts}];
Wolfram Language code: ListLinePlot[samples, DataRange -> {0, 12}, PlotLegends -> (StringJoin["x = ", ToString[#]]& /@ pts)]

在非零常数的情况下：

Wolfram Language code: tproc[x_] := ARIMAProcess[0.2, {1.1}, 1, {.3}, 1, {x}];
Wolfram Language code: tsamples = Table[SeedRandom[4];RandomFunction[tproc[x], {30}], {x, pts}];
Wolfram Language code: ListLinePlot[tsamples, DataRange -> {0, 12}, PlotLegends -> (StringJoin["x = ", ToString[#]]& /@ pts)]

模拟二维过程：

Wolfram Language code: α = {{.2, .1}, {-.3, .2}}; β = {{.2, .5}, {-.2, .9}}; Σ = {{1, 0}, {0, .3}}; sample = RandomFunction[ARIMAProcess[{α}, {1, 1}, {β}, Σ], {1, 10 ^ 3}];

从数据创建一个二维样本路径函数：

Wolfram Language code: s = TimeSeries[sample, ResamplingMethod -> Automatic]; f = s["PathFunction"]; g[t_ ? NumericQ] := f[t]

路径的颜色是时间的函数：

Wolfram Language code: ParametricPlot[g[t], {t, 1, 100}, ColorFunction -> Function[{x, y, t}, (ColorData["BlueGreenYellow"][t])], PlotStyle -> Thick, AspectRatio -> 1, AxesLabel -> {x, y}]

创建关于时间的三维样本路径函数：

Wolfram Language code: gg[t_ ? NumericQ] := Join[{t}, f[t]]

路径的颜色是时间的函数：

Wolfram Language code: ParametricPlot3D[gg[t], {t, 1, 100}, ColorFunction -> Function[{t, x, y}, (ColorData["BlueGreenYellow"][t])], PlotStyle -> Thick, BoxRatios -> 1, AxesLabel -> {t, x, y}]

模拟三维过程：

Wolfram Language code: α = {{.2, .1, .1}, {-.3, .2, .1}, {-.3, .2, -.1}}; β = {{.2, .5, .1}, {-.2, .9, .5}, {.3, .1, -.4}}; Σ = {{1, 0, 0}, {0, .3, 0}, {0, 0, .1}}; SeedRandom[4];sample = RandomFunction[ARIMAProcess[{α}, 1, {β}, Σ], {1, 10 ^ 2}];

从数据创建样本路径函数：

Wolfram Language code: s = TimeSeries[sample, ResamplingMethod -> Automatic]; f = s["PathFunction"]; g[t_ ? NumericQ] := f[t]

路径的颜色是时间的函数：

Wolfram Language code: ParametricPlot3D[g[t], {t, 1, 100}, ColorFunction -> Function[{x, y, z, t}, (ColorData["BlueGreenYellow"][t])], PlotStyle -> Thick, BoxRatios -> 1, AxesLabel -> {x, y, z}]

估计过程参数：

Wolfram Language code: SeedRandom[314];sample = RandomFunction[ARIMAProcess[.3, {.2}, 1, {.3}, .1], {1, 1000}];

求模型参数：

Wolfram Language code: eproc = EstimatedProcess[sample, ARIMAProcess[1, d, 1]]

使用 TimeSeriesModel 自动求阶数：

Wolfram Language code: tsm = TimeSeriesModelFit[sample]
Wolfram Language code: tsm["Process"]

估计向量过程：

Wolfram Language code: proc = ARIMAProcess[{1, 2}, {{{.2, .1}, {.5, .3}}}, {1, 0}, {{{.9, .2}, {-.5, -.2}}}, {{1, .3}, {.3, .5}}]; data = RandomFunction[proc, {10 ^ 2}];
Wolfram Language code: eproc = EstimatedProcess[data, ARIMAProcess[1, {1, 0}, 1]]

预测将来值：

Wolfram Language code: proc = ARIMAProcess[.4, {.3}, 2, {-.5}, 1]; sample = RandomFunction[proc, {1, 10 ^ 2}]; forecast = TimeSeriesForecast[proc, sample, {15}]

显示预测的路径：

Wolfram Language code: forecast["Path"]

绘制数据和预测值：

Wolfram Language code: ListLinePlot[{sample, forecast}, InterpolationOrder -> 0, Filling -> Axis]

求向量值时间序列过程的预测：

Wolfram Language code: proc = ARIMAProcess[{{{.3, .1}, {.9, .1}}}, {1, 2}, {{{.4, -.2}, {.1, .7}}, {{.2, -.4}, {.5, -.3}}}, {{1, .2}, {.2, .6}}]; data = RandomFunction[proc, {0, 15}];

对接下来的10步进行预测：

Wolfram Language code: forecast = TimeSeriesForecast[proc, data, {10}]

绘制每个分量的数据和预测值：

Wolfram Language code: Row@Table[ListLinePlot[#["PathComponent", j]& /@ {data, forecast}, PlotLabel -> Subscript[x, j], PlotLegends -> {"data", "forecast"}], {j, 1, 2}]

平稳性和可逆性  (2)

求过程是弱平稳的条件：

Wolfram Language code: WeakStationarity[ARIMAProcess[c, {Subscript[a, 1], Subscript[a, 2]}, d, {Subscript[b, 1], Subscript[b, 2]}, σ^2]]

求可逆性条件：

Wolfram Language code: TimeSeriesInvertibility[ARIMAProcess[c, {Subscript[a, 1], Subscript[a, 2]}, d, {Subscript[b, 1], Subscript[b, 2]}, σ^2]]

估计方法  (5)

估计 ARIMAProcess 的可用方法：

Wolfram Language code: methods = {Automatic, "MethodOfMoments", "MaximumConditionalLikelihood", "MaximumLikelihood", "SpectralEstimator"};
Wolfram Language code: SeedRandom[3]; data = RandomFunction[ARIMAProcess[.3, {.4}, 1, {.3}, 1], {100}];
Wolfram Language code: Grid[res = Table[{m, EstimatedProcess[data, ARIMAProcess[1, 1], ProcessEstimator -> m]}, {m, methods}], Frame -> All, Spacings -> {1, 2}, Alignment -> {Left, Center}]

矩量法允许下列求解器：

Wolfram Language code: solvers = {Automatic, "FindRoot", "NSolve"};
Wolfram Language code: SeedRandom[3]; data = RandomFunction[ARIMAProcess[{.4}, 1, {.3}, 1], {100}];
Wolfram Language code: Grid[res = Table[{m, EstimatedProcess[data, ARIMAProcess[1, 1], ProcessEstimator -> {"MethodOfMoments", Method -> m}]}, {m, solvers}], Frame -> All, Spacings -> {1, 2}, Alignment -> {Left, Center}]

这种方法允许固定参数：

Wolfram Language code: EstimatedProcess[data, ARIMAProcess[c, {.4, b}, d, {m}, v], ProcessEstimator -> "MethodOfMoments"]

也允许参数之间的一些关系：

Wolfram Language code: EstimatedProcess[data, ARIMAProcess[c, {a * b, b}, d, {a}, v], ProcessEstimator -> "MethodOfMoments"]

最大条件似然法允许以下求解器：

Wolfram Language code: solvers = {Automatic, "FindMaximum", "NMaximize"};
Wolfram Language code: SeedRandom[3]; data = RandomFunction[ARIMAProcess[2, {.4}, 1, {.3}, 1], {100}];
Wolfram Language code: Grid[Table[{m, EstimatedProcess[data, ARIMAProcess[1, 1], ProcessEstimator -> {"MaximumConditionalLikelihood", Method -> m}]}, {m, solvers}], Frame -> All, Spacings -> {1, 2}, Alignment -> {Left, Center}]

这种方法允许固定参数：

Wolfram Language code: EstimatedProcess[data, ARIMAProcess[c, {.1, b}, d, {m}, v], ProcessEstimator -> "MaximumConditionalLikelihood"]

也允许参数之间的一些关系：

Wolfram Language code: EstimatedProcess[data, ARIMAProcess[c, {b, b}, d, {m}, v], ProcessEstimator -> "MaximumConditionalLikelihood"]

最大似然法允许以下求解器：

Wolfram Language code: solvers = {Automatic, "FindMaximum", "NMaximize"};
Wolfram Language code: SeedRandom[3]; data = RandomFunction[ARIMAProcess[2, {.4, .2}, 1, {.3}, 1], {100}];
Wolfram Language code: Grid[Table[{m, EstimatedProcess[data, ARIMAProcess[2, 1], ProcessEstimator -> {"MaximumLikelihood", Method -> m}]}, {m, solvers}], Frame -> All, Spacings -> {1, 2}, Alignment -> {Left, Center}]

这种方法允许固定参数：

Wolfram Language code: EstimatedProcess[data, ARIMAProcess[c, {.1, b}, d, {m}, v], ProcessEstimator -> "MaximumLikelihood"]

也允许参数之间的一些关系：

Wolfram Language code: EstimatedProcess[data, ARIMAProcess[c, {b, b}, d, {m}, v], ProcessEstimator -> "MaximumLikelihood"]

谱估计量允许用于 PowerSpectralDensity 计算的窗：

Wolfram Language code: SeedRandom[3]; data = RandomFunction[ARIMAProcess[2, {.4, .2}, 1, {.3}, 1], {100}];
Wolfram Language code: Grid[Table[{m, EstimatedProcess[data, ARIMAProcess[2, 1], ProcessEstimator -> {"SpectralEstimator", "Window" -> m}]}, {m, {10, BartlettWindow, {3, HannWindow}}}], Frame -> All, Spacings -> {1, 2}, Alignment -> {Left, Center}]

谱估计量允许以下求解器：

Wolfram Language code: solvers = {Automatic, "FindMinimum", "NMinimize"};
Wolfram Language code: Grid[Table[{m, EstimatedProcess[data, ARIMAProcess[2, 1], ProcessEstimator -> {"SpectralEstimator", Method -> m}]}, {m, solvers}], Frame -> All, Spacings -> {1, 2}, Alignment -> {Left, Center}]

这种方法允许固定参数：

Wolfram Language code: EstimatedProcess[data, ARIMAProcess[c, {.1, b}, d, {m}, v], ProcessEstimator -> "SpectralEstimator"]

也允许参数之间的一些关系：

Wolfram Language code: EstimatedProcess[data, ARIMAProcess[c, {b, b}, d, {m}, v], ProcessEstimator -> "SpectralEstimator"]

过程切片性质  (5)

单一时间 SliceDistribution：

Wolfram Language code: SliceDistribution[ARIMAProcess[c, {a}, d, {b}, σ ^ 2], t]//Mean

多个时间切片分布：

Wolfram Language code: SliceDistribution[ARIMAProcess[1.2, {.2}, 1, {.3}, 1, {}], {1, 3}]//Covariance
Wolfram Language code: SliceDistribution[ARIMAProcess[1, {.2}, 1, {.3}, 1], {1, 2, 3}]//Mean

向量值时间序列的切片分布：

Wolfram Language code: α = {{Subscript[a, 1], 0}, {0, Subscript[a, 2]}}; β = {{Subscript[b, 1], 0}, {0, Subscript[b, 2]}}; Σ = {{Subscript[σ, 1]^2, ρ Subscript[σ, 1]Subscript[σ, 2]}, {ρ Subscript[σ, 1]Subscript[σ, 2], Subscript[σ, 2]^2}}; ARIMAProcess[{α}, {1, 2}, {β}, Σ][t]//Mean

一阶概率密度函数：

Wolfram Language code: pdf[t_] = PDF[ARIMAProcess[{1 / 4}, 1, {1 / 3}, 1, {5}][t], x]//Simplify
Wolfram Language code: times = {1, 2, 3, 4};
Wolfram Language code: Plot[Evaluate@Table[pdf[t], {t, times}], {x, -10, 12}, Filling -> Axis, PlotLegends -> (StringJoin["t = ", ToString[#]]& /@ times)]

计算一个表达式的期望：

Wolfram Language code: Expectation[x[t] ^ 2, xARIMAProcess[c, {a}, 1, {b}, σ^2], Assumptions -> t > 0]//Simplify

计算一个表达式的概率：

Wolfram Language code: Probability[x[t] < 6, xARIMAProcess[c, {a}, 1, {b}, σ^2], Assumptions -> t > 0]//Simplify

偏度和峰度是不变的：

Wolfram Language code: Skewness[ARMAProcess[c, {a}, {b}, σ^2][t]]
Wolfram Language code: Kurtosis[ARMAProcess[c, {a}, {b}, σ^2][t]]

r 阶矩：

Wolfram Language code: Table[Moment[ARMAProcess[c, {a}, {b}, σ^2][t], r], {r, 0, 4}]//Together

母函数：

Wolfram Language code: CharacteristicFunction[ARMAProcess[c, {a}, {b}, σ^2][t], w]
Wolfram Language code: MomentGeneratingFunction[ARMAProcess[c, {a}, {b}, σ^2][t], w]

CentralMoment 及其母函数：

Wolfram Language code: Table[CentralMoment[ARMAProcess[c, {a}, {b}, σ^2][t], r], {r, 0, 4}]
Wolfram Language code: CentralMomentGeneratingFunction[ARMAProcess[c, {a}, {b}, σ^2][t], w]

对于符号式阶数，FactorialMoment 无解析形式：

Wolfram Language code: Table[FactorialMoment[ARMAProcess[c, {a}, {b}, σ^2][t], r]//Simplify, {r, 0, 3}]
Wolfram Language code: FactorialMomentGeneratingFunction[ARMAProcess[c, {a}, {b}, σ^2][t], w]

Cumulant 及其母函数：

Wolfram Language code: Table[Cumulant[ARMAProcess[c, {a}, {b}, σ^2][t], r], {r, 0, 4}]
Wolfram Language code: CumulantGeneratingFunction[ARMAProcess[c, {a}, {b}, σ^2][t], w]

表示法  (4)

使用 MA 过程近似：

Wolfram Language code: MAProcess[ARIMAProcess[.4, {.2, .3}, 4, {.1}, 1, {}], 5]

使用 AR 过程近似：

Wolfram Language code: proc = ARIMAProcess[{.2, .3}, 1, {.5}, 1, {}]; aproc = ARProcess[proc, 5]

与样本路径比较：

Wolfram Language code: SeedRandom[13];sample = RandomFunction[proc, {100}]; SeedRandom[13];asample = RandomFunction[aproc, {100}]; ListLinePlot[{sample, asample}, PlotLegends -> {"ARIMA", "AR"}]

近似向量过程：

Wolfram Language code: proc = ARIMAProcess[{{{.2, .5}, {-.3, .5}}}, {1, 2}, {{{.2, .3}, {0, .4}}}, {{.6, .2}, {.2, .4}}]; aproc = ARProcess[proc, 3]

用等价的 ARMA 过程表示：

Wolfram Language code: proc = ARIMAProcess[{a}, 2, {b}, 1]; newproc = ARMAProcess[proc]

它通常不是弱平稳的：

Wolfram Language code: WeakStationarity[newproc]//Simplify

TransferFunctionModel 表示法：

Wolfram Language code: TransferFunctionModel[ARIMAProcess[{Subscript[a, 1], Subscript[a, 2]}, 2, {Subscript[b, 1], Subscript[b, 2]}, σ^2], z]

对于向量值过程：

Wolfram Language code: α = {{.2, .3}, {0, .1}}; β = {{-.3, 0}, {.5, -.4}}; δ = {1, 0}; Σ = {{1, 0}, {0, 1}}; TransferFunctionModel[ARIMAProcess[{α}, δ, {β}, Σ], z]

StateSpaceModel 表示法：

Wolfram Language code: StateSpaceModel[ARIMAProcess[{Subscript[a, 1], Subscript[a, 2]}, 2, {Subscript[b, 1], Subscript[b, 2]}, σ^2]]

对于向量值过程：

Wolfram Language code: α = {{.2, .3}, {0, .1}}; β = {{-.3, .9}, {.5, -.4}}; δ = {1, 2}; Σ = {{1, 0}, {0, 1}}; StateSpaceModel[ARIMAProcess[{α}, δ, {β}, Σ]]

应用  (3)

预测商用航空公司的年收入：

Wolfram Language code: ExampleData[{"Statistics", "AirlinePassengerMiles"}, "LongDescription"]
Wolfram Language code: revenue = ExampleData[{"Statistics", "AirlinePassengerMiles"}, "TimeSeries"]
Wolfram Language code: ListLinePlot[revenue, InterpolationOrder -> 0, Filling -> Axis]

数据具有线性趋势，可用 UnitRootTest 来确认：

Wolfram Language code: UnitRootTest[revenue, Automatic, "TestConclusion"]

将 ARIMA 模型拟合到时间序列：

Wolfram Language code: eproc = EstimatedProcess[revenue, ARIMAProcess[2, 1, 2]]

对未来10年进行预测：

Wolfram Language code: forecast = TimeSeriesForecast[eproc, revenue, {10}]
Wolfram Language code: ListLinePlot[{revenue, forecast}, InterpolationOrder -> 0, Filling -> Axis]

全球年平均气温，与1951-1980年基准相比：

Wolfram Language code: gmt = TemporalData[Automatic, {{{-0.32, -0.32, -0.23, -0.29, -0.3, -0.34, -0.33, -0.29, -0.36, -0.29, -0.18, -0.41, -0.29, -0.34, -0.35, -0.36, -0.28, -0.2, -0.16, -0.3, -0.19, -0.18, -0.28, -0.33, -0.37, -0.28, -0.22, -0.42, -0.36, -0.37, -0.3 ... 1, 0.06, 0.28, 0.33, 0.33, 0.21, 0.36, 0.14, 0.14, 0.14, 0.4, 0.31, 0.31, 0.42, 0.34, 0.36, 0.36, 0.49, 0.56, 0.49, 0.49, 0.62, 0.59, 0.44, 0.44, 0.57, 0.51}}, {{1880, 2011, 1}}, 1, {"Discrete", 1}, {"Discrete", 1}, 1, {}}, False, 9.];
Wolfram Language code: ListPlot[gmt, Joined -> True, AxesOrigin -> {1880, -.5}]

用 UnitRootTest 求积分阶数：

Wolfram Language code: Table[UnitRootTest[Differences[gmt, k]], {k, 0, 3}]

估计积分阶数等于1的 ARIMA 过程：

Wolfram Language code: eproc = EstimatedProcess[gmt, ARIMAProcess[1, 1, 1]]

对未来20年进行预测：

Wolfram Language code: forecast = TimeSeriesForecast[eproc, gmt, {20}]
Wolfram Language code: ListPlot[{gmt, forecast}, Joined -> True, AxesOrigin -> {1880, -.5}]

预测股票价格：

Wolfram Language code: data = FinancialData["SBUX", "Close", {{2013, 1, 1}, {2013, 12, 1}, "Week"}];

检查是否定期采样：

Wolfram Language code: RegularlySampledQ[data]

重新采样以获得定期采样的时间序列：

Wolfram Language code: stocks = TimeSeriesResample[data]
Wolfram Language code: RegularlySampledQ[stocks]

绘制价格：

Wolfram Language code: DateListPlot[stocks, Filling -> Axis]

拟合 ARIMA 过程：

Wolfram Language code: eproc = EstimatedProcess[stocks, ARIMAProcess[3, 1, 0], ProcessEstimator -> "MaximumConditionalLikelihood"]

对下半年进行预测：

Wolfram Language code: forecast = TimeSeriesForecast[eproc, stocks, {26}];
Wolfram Language code: DateListPlot[{stocks, forecast}, Filling -> Axis]

属性和关系  (4)

ARIMAProcess 是 ARMAProcess 的推广：

Wolfram Language code: TransferFunctionModel[ARIMAProcess[{Subscript[a, 1], Subscript[a, 2]}, 0, {Subscript[b, 1], Subscript[b, 2]}, σ^2], z]
Wolfram Language code: TransferFunctionModel[ARMAProcess[{Subscript[a, 1], Subscript[a, 2]}, {Subscript[b, 1], Subscript[b, 2]}, σ^2], z]
Wolfram Language code: % - %%

ARIMAProcess 是 ARProcess 的推广：

Wolfram Language code: TransferFunctionModel[ARIMAProcess[{Subscript[a, 1], Subscript[a, 2]}, 0, {}, σ^2], z]
Wolfram Language code: TransferFunctionModel[ARProcess[{Subscript[a, 1], Subscript[a, 2]}, σ^2], z]
Wolfram Language code: % - %%

ARIMAProcess 是 MAProcess 的推广：

Wolfram Language code: TransferFunctionModel[ARIMAProcess[{}, 0, {Subscript[b, 1], Subscript[b, 2]}, σ^2], z]
Wolfram Language code: TransferFunctionModel[MAProcess[{Subscript[b, 1], Subscript[b, 2]}, σ^2], z]
Wolfram Language code: % - %%

ARIMA 过程在离散步长服从 WienerProcess：

Wolfram Language code: wiener = WienerProcess[]; arima = ARIMAProcess[{}, 1, {}, 1, {}];

单一时间切片性质：

Wolfram Language code: Mean /@ {wiener[t], arima[t]}
Wolfram Language code: PDF[#, x]& /@ {wiener[t + 1], arima[t]}//Simplify[#, t > 0]&

混合矩：

Wolfram Language code: MatrixForm[Covariance[#]]& /@ {wiener[{s + 1, t + 1}], arima[{s, t}]}//Simplify[#, 0 < s < t]&

可能存在的问题  (5)

对于符号式时间标记，多时间切片属性可能不能计算：

Wolfram Language code: Correlation[ARIMAProcess[{1 / 2}, 1, {1 / 4}, 1][{Subscript[t, 1], Subscript[t, 2], Subscript[t, 3]}]]
Wolfram Language code: Correlation[ARIMAProcess[{1 / 2}, 1, {1 / 4}, 1][{1, 4, 8}]]

有些属性仅适用于弱平稳过程的定义：

Wolfram Language code: CovarianceFunction[ARIMAProcess[{2, .3}, 1, {.3, .2}, σ^2], h]

使用 FindInstance 求弱平稳过程：

Wolfram Language code: FindInstance[a > 0 && WeakStationarity[ARIMAProcess[{a, .2}, d, {.3, .2}, σ^2]], {a, d}]
Wolfram Language code: CovarianceFunction[ARIMAProcess[{.4, .2}, 0, {.3, .2}, σ^2], h]

具有不精确参数的切片分布属性对于符号式时间是病态的：

Wolfram Language code: var[t_] = Variance[ARIMAProcess[{.4}, 10, {-.5}, 1, {}][t]];

负数结果是不正确的：

Wolfram Language code: var[2]

使用数值时间：

Wolfram Language code: Variance[ARIMAProcess[{.4}, 10, {-.5}, 1, {}][2]]

或使用参数的精确值：

Wolfram Language code: v[t_] = Variance[ARIMAProcess[{4 / 10}, 10, {-1 / 2}, 1, {}][t]];
Wolfram Language code: v[2]
Wolfram Language code: N[%]

ToInvertibleTimeSeries 并不总是存在：

Wolfram Language code: ToInvertibleTimeSeries[ARIMAProcess[{.2}, 1, {.3, 1}, .2]]

在单位圆上有 TransferFunctionModel 的零点：

Wolfram Language code: TransferFunctionZeros[TransferFunctionModel[ARIMAProcess[{.2}, 1, {.3, 1}, .2]]]
Wolfram Language code: Abs[%]

矩量法可能无法找到估计的解：

Wolfram Language code: SeedRandom[4]; data = RandomFunction[ARIMAProcess[2, {.4}, 1, {.3}, 1], {100}];
Wolfram Language code: EstimatedProcess[data, ARIMAProcess[c, {.4, b}, 1, {1}, v], ProcessEstimator -> {"MethodOfMoments", Method -> "NSolve"}]

用 "FindRoot" 法来代替：

Wolfram Language code: EstimatedProcess[data, ARIMAProcess[c, {.4, a}, 1, {b}, v], ProcessEstimator -> {"MethodOfMoments", Method -> "FindRoot"}]

巧妙范例  (2)

模拟三维 ARIMAProcess：

Wolfram Language code: A = {{.2, .1, .1}, {0, -.2, .3}, {.2, -.1, .3}}; B = {{.4, .2, 0}, {-.2, .8, -.3}, {0, .2, 0}}; S = {{.8, .1, -.2}, {.1, .5, .1}, {-.2, .1, .3}}; proc = ARIMAProcess[{A}, 1, {B}, S]; data = RandomFunction[proc, {100}, k = 8]["ValueList"];
Wolfram Language code: Graphics3D@Table[{ColorData["SolarColors"][RandomReal[]], Tube@Line@data[[i]]}, {i, k}]

模拟 ARIMA 过程的路径：

Wolfram Language code: SeedRandom[154];data = RandomFunction[ARIMAProcess[.4, {.3}, 1, {.6}, 1], {50}, 300];

在 50 处取切片，并可视化其分布：

Wolfram Language code: sd = data["SliceData", 50];
Wolfram Language code: cf = ColorData["Rainbow"]; sliced = BarChart[Last[#], Axes -> False, BarOrigin -> Left, AspectRatio -> 4, ChartStyle -> (cf /@ Rescale[MovingAverage[First[#], 2], {Min[sd], Max[sd]}, {0, 1}]), ImageSize -> 65]&[HistogramList[sd, {Range[Min[sd], Max[sd], (Max[sd] - Min[sd]) / 20]}]];

绘制在50处切片分布的路径和直方图分布：

Wolfram Language code: ListLinePlot[data, ImageSize -> 400, PlotRange -> All, AspectRatio -> 3 / 4, Epilog -> Inset[sliced, {51, 0}, {0, 4}], PlotStyle -> (Directive[Thin, cf[#]]& /@ Rescale[sd]), PlotRangePadding -> {{0, 15}, {5, 20}}]
Wolfram Research (2012)，ARIMAProcess，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ARIMAProcess.html （更新于 2014 年）.

文本

Wolfram Research (2012)，ARIMAProcess，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ARIMAProcess.html （更新于 2014 年）.

CMS

Wolfram 语言. 2012. "ARIMAProcess." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2014. https://reference.wolfram.com/language/ref/ARIMAProcess.html.

APA

Wolfram 语言. (2012). ARIMAProcess. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ARIMAProcess.html 年

BibTeX

@misc{reference.wolfram_2026_arimaprocess, author="Wolfram Research", title="{ARIMAProcess}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/ARIMAProcess.html}", note=[Accessed: 10-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_arimaprocess, organization={Wolfram Research}, title={ARIMAProcess}, year={2014}, url={https://reference.wolfram.com/language/ref/ARIMAProcess.html}, note=[Accessed: 10-August-2026]}