WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

AbsoluteCorrelation[v,w]

ベクトル v とベクトル w の間の絶対相関を与える．

AbsoluteCorrelation[a,b]

行列 a と行列 b の絶対相互相関行列を与える．

AbsoluteCorrelation[a]

行列 a の絶対相関行列を与える．

AbsoluteCorrelation[dist]

多変量記号分布 dist の絶対相関行列を与える．

AbsoluteCorrelation[dist,i,j]

多変量記号分布 dist の(i,j)番目の絶対相関を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
データ  
分布と過程  
アプリケーション  
特性と関係  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

AbsoluteCorrelation

AbsoluteCorrelation[v,w]

ベクトル v とベクトル w の間の絶対相関を与える．

AbsoluteCorrelation[a,b]

行列 a と行列 b の絶対相互相関行列を与える．

AbsoluteCorrelation[a]

行列 a の絶対相関行列を与える．

AbsoluteCorrelation[dist]

多変量記号分布 dist の絶対相関行列を与える．

AbsoluteCorrelation[dist,i,j]

多変量記号分布 dist の(i,j)番目の絶対相関を与える．

詳細

例題

すべて開く すべて閉じる

例  (3)

2つのベクトル間の絶対相関：

Wolfram Language code: AbsoluteCorrelation[{a, b}, {x, y}]

行列の絶対相関行列：

Wolfram Language code: AbsoluteCorrelation[{{a, b}, {c, d}}]//MatrixForm

2つの行列の絶対相関行列：

Wolfram Language code: AbsoluteCorrelation[{{a, b}, {c, d}}, {{x}, {y}}]//MatrixForm

スコープ  (10)

データ  (6)

厳密な入力は厳密な出力を与える：

Wolfram Language code: AbsoluteCorrelation[{5, 3 / 4, 1}, {2, 1 / 2, 1}]
Wolfram Language code: AbsoluteCorrelation[{1, π, 2}, {2, 2, 1}]//Simplify

近似入力は近似出力を与える：

Wolfram Language code: AbsoluteCorrelation[{1.5, 3, 5, 10}, {2, 1.25, 15, 8}]
Wolfram Language code: AbsoluteCorrelation[N[{1, 2, 5, 6}, 20], N[{2, 3, 6, 8}, 20]]

複素ベクトル間の絶対相関：

Wolfram Language code: AbsoluteCorrelation[{2 + I, 3 - 2I, 5 + 4I}, {I, 1 + 2I, 10 - 5I}]

大規模配列に使うことができる：

Wolfram Language code: AbsoluteCorrelation[RandomReal[1, 10 ^ 7], RandomReal[1, 10 ^ 7]]

構造化配列を使うことができる（ガイドを参照のこと）：

Wolfram Language code: AbsoluteCorrelation[SparseArray[{{2, 2} -> 1, {5, 3} -> 2}]]//MatrixForm
Wolfram Language code: AbsoluteCorrelation[IdentityMatrix[3]]//MatrixForm
Wolfram Language code: AbsoluteCorrelation[ToeplitzMatrix[4]]//MatrixForm
Wolfram Language code: AbsoluteCorrelation[QuantityArray[RandomReal[1, {20, 2}], "Meters"]]//MatrixForm

数量を含むデータに使うことができる：

Wolfram Language code: {v, w} = Quantity[{{2.5, 3, 5, 10}, {2, 1.25, 15, 8}}, "Meters"];
Wolfram Language code: AbsoluteCorrelation[v, w]

分布と過程  (4)

多変量連続分布についての絶対相関：

Wolfram Language code: AbsoluteCorrelation[BinormalDistribution[ρ]]//MatrixForm
Wolfram Language code: AbsoluteCorrelation[BinormalDistribution[ρ], 2, 1]

多変量離散分布についての絶対相関：

Wolfram Language code: AbsoluteCorrelation[MultivariatePoissonDistribution[μ, {2, 3}]]//MatrixForm
Wolfram Language code: AbsoluteCorrelation[MultivariatePoissonDistribution[μ, {2, 3}], 2, 1]

派生分布についての絶対相関：

Wolfram Language code: AbsoluteCorrelation[ProductDistribution[ExponentialDistribution[1], NormalDistribution[3, 5]]]//MatrixForm
Wolfram Language code: 𝒟 = CopulaDistribution[{"Frank", 2}, {UniformDistribution[{0, 1}], UniformDistribution[{0, 1}]}];
Wolfram Language code: AbsoluteCorrelation[𝒟]//MatrixForm

データ分布について：

Wolfram Language code: 𝒟 = HistogramDistribution[RandomVariate[BinormalDistribution[.75], 10 ^ 4]];
Wolfram Language code: AbsoluteCorrelation[𝒟]//MatrixForm
Wolfram Language code: AbsoluteCorrelation[BinormalDistribution[.75]]//MatrixForm

時点 s および t におけるランダム過程についての絶対相関行列：

Wolfram Language code: Correlation[WienerProcess[][{s, t}]]//MatrixForm

アプリケーション  (3)

2つの金融時系列の絶対相関を計算する：

Wolfram Language code: AbsoluteCorrelation[FinancialData["^GSPC", "Open", {2009, 1, 1}, "Value"], FinancialData["^GSPC", "Close", {2009, 1, 1}, "Value"]]

AbsoluteCorrelationを使って線形関係を測ることができる：

Wolfram Language code: data = BlockRandom[SeedRandom[1];Table[RandomVariate[BinormalDistribution[i], 3000], {i, {-.99, -.75, -.25, -.5, 0., .25, .5, .75, .99}}]];
Wolfram Language code: Grid[Partition[Table[ListPlot[i, PlotStyle -> Directive[PointSize[Tiny]], FrameTicks -> None, Frame -> True, Axes -> None, PlotLabel -> Row[{"ρ : ", AbsoluteCorrelation[i][[1, 2]]}]], {i, data}], 3]]

AbsoluteCorrelationは単調関係しか検出することができない：

Wolfram Language code: uni = RandomReal[{-3, 3}, 3000];
Wolfram Language code: f[x_] := {{x, -Sqrt[Abs[x]] + RandomReal[.5]}, {x, .25x^2 + RandomReal[.5]}, {x, -Sinc[x] + RandomReal[.5]}, {Cos[x], Sin[x] + RandomReal[.5]}}
Wolfram Language code: data = f /@ uni;
Wolfram Language code: Table[ListPlot[data[[All, i]], Frame -> True, Axes -> None, PlotLabel -> Row[{"ρ : ", AbsoluteCorrelation[data[[All, i]]][[1, 2]]}], PlotStyle -> Directive[PointSize[Tiny]], FrameTicks -> None], {i, 4}]

HoeffdingDを使ってさまざまな依存構造を検出することができる：

Wolfram Language code: Table[HoeffdingD[data[[All, i]]][[1, 2]], {i, 4}]

特性と関係  (8)

絶対相関行列は，対称かつ半正定値の行列である：

Wolfram Language code: corr = AbsoluteCorrelation[RandomVariate[BinormalDistribution[1 / 3], 10 ^ 3]];
Wolfram Language code: SymmetricMatrixQ[corr]
Wolfram Language code: PositiveSemidefiniteMatrixQ[corr]

CovarianceおよびAbsoluteCorrelationは，ゼロ平均の分布について等しい：

Wolfram Language code: 𝒟 = BinormalDistribution[ρ];
Wolfram Language code: Mean[𝒟]
Wolfram Language code: Covariance[𝒟]
Wolfram Language code: AbsoluteCorrelation[𝒟]

CorrelationおよびAbsoluteCorrelationは，ゼロ平均および単位周辺分散について一致する：

Wolfram Language code: 𝒟 = BinormalDistribution[ρ];
Wolfram Language code: Mean[𝒟]
Wolfram Language code: Variance[𝒟]
Wolfram Language code: Correlation[𝒟]
Wolfram Language code: AbsoluteCorrelation[𝒟]

AbsoluteCorrelationFunctionは，絶対相関行列の非対角項である：

Wolfram Language code: 𝒫 = WienerProcess[μ, σ];
Wolfram Language code: AbsoluteCorrelation[𝒫[{s, t}], 1, 2]
Wolfram Language code: AbsoluteCorrelationFunction[𝒫, s, t]
Wolfram Language code: Simplify[%% - %, 0 < s < t]

リストについてのAbsoluteCorrelationFunctionは，絶対相関を使って計算することができる：

Wolfram Language code: data = Range[10]; n = Length[data];

データについての絶対相関関数を計算する：

Wolfram Language code: AbsoluteCorrelationFunction[data, {n - 1}]n / Range[n, 1, -1]

絶対相関を使う：

Wolfram Language code: Table[AbsoluteCorrelation[Drop[data, i], Drop[RotateRight[data, i], i]], {i, 0, n - 1}]
Wolfram Language code: % - %%

絶対相関はランダム行列の対角上のみで大きくなる傾向がある：

Wolfram Language code: ArrayPlot[AbsoluteCorrelation[RandomReal[{-1, 1}, {50, 50}]]]

リストのそれ自身との絶対相関は二次モーメントである：

Wolfram Language code: Moment[{a, b, c}, 2]
Wolfram Language code: AbsoluteCorrelation[{a, b, c}, {a, b, c}]//Simplify[#, {a, b, c}∈Reals]&
Wolfram Language code: %% - %//Simplify

ランダムデータについて：

Wolfram Language code: data = RandomReal[1, 10 ^ 6]; Moment[data, 2] / AbsoluteCorrelation[data, data]

絶対相関行列の対角は二次モーメントである：

Wolfram Language code: data = RandomReal[5, {20, 5}]; n = Length[data];
Wolfram Language code: Diagonal[AbsoluteCorrelation[data]]
Wolfram Language code: Moment[data, 2]
Wolfram Language code: % - %%

おもしろい例題  (1)

最小公倍数の配列の絶対相関を計算する：

Wolfram Language code: MatrixPlot[AbsoluteCorrelation[Array[LCM, {50, 50}]]]
Wolfram Research (2012), AbsoluteCorrelation, Wolfram言語関数， https://reference.wolfram.com/language/ref/AbsoluteCorrelation.html （2023年に更新）.

テキスト

Wolfram Research (2012), AbsoluteCorrelation, Wolfram言語関数， https://reference.wolfram.com/language/ref/AbsoluteCorrelation.html （2023年に更新）.

CMS

Wolfram Language. 2012. "AbsoluteCorrelation." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2023. https://reference.wolfram.com/language/ref/AbsoluteCorrelation.html.

APA

Wolfram Language. (2012). AbsoluteCorrelation. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/AbsoluteCorrelation.html

BibTeX

@misc{reference.wolfram_2026_absolutecorrelation, author="Wolfram Research", title="{AbsoluteCorrelation}", year="2023", howpublished="\url{https://reference.wolfram.com/language/ref/AbsoluteCorrelation.html}", note=[Accessed: 11-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_absolutecorrelation, organization={Wolfram Research}, title={AbsoluteCorrelation}, year={2023}, url={https://reference.wolfram.com/language/ref/AbsoluteCorrelation.html}, note=[Accessed: 11-August-2026]}