WOLFRAM

Wolfram 语言与系统参考资料中心

Accuracy[x]

给出数 x 小数点右侧的有效位数.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
推广和延伸  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

Accuracy

Accuracy[x]

给出数 x 小数点右侧的有效位数.

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (3)

机器精度数：

Wolfram Language code: Accuracy[1.2]

任意精度数：

Wolfram Language code: Accuracy[1.2``20]

精确数：

Wolfram Language code: Accuracy[3]

范围  (4)

Accuracy 显示为小数点右侧已知的有效位数：

Wolfram Language code: Accuracy[123456789.987654321]

已知准确度为20的零：

Wolfram Language code: z = 0``20
Wolfram Language code: Accuracy[z]

z+1 的精确度与 z 的准确度相同：

Wolfram Language code: 1 + z
Wolfram Language code: Precision[%]

一个机器零的准确度：

Wolfram Language code: Accuracy[0.]

0. 的不确定性等于最小的正的规范化机器数的不确定性：

Wolfram Language code: Accuracy[$MinMachineNumber]

指定准确度作为 N 的目标：

Wolfram Language code: N[1 + 1 / GoldenRatio - GoldenRatio, {∞, 30}]
Wolfram Language code: Accuracy[%]

推广和延伸  (1)

一个符号表达式的准确度是其数值准确度的极小值:

Wolfram Language code: Accuracy[f[1``25, 2``30]]
Wolfram Language code: Accuracy[1``25 + 3``30 x ^ 2]

应用  (2)

检查一个结果的质量：

Wolfram Language code: Sin[1234`32] + 12.`34
Wolfram Language code: Accuracy[%]

跟踪一个重复计算的准确度损失：

Wolfram Language code: logistic = NestList[4 # (1 - #)&, N[1 / Pi, 30], 20]
Wolfram Language code: ListPlot[Map[Accuracy, logistic]]

属性和关系  (4)

对于规范化的机器精度数，Accuracy[x] 与 $MachinePrecision-Log[10,Abs[x]] 相同：

Wolfram Language code: x = RandomReal[{-1, 1}] 10 ^ RandomInteger[{-300, 300}]
Wolfram Language code: Accuracy[x]
Wolfram Language code: $MachinePrecision - Log[10, Abs[x]]

没有机器数的准确度能高于 $MinMachineNumber：

Wolfram Language code: Accuracy[$MinMachineNumber]

复数的实部和虚部可以有不同的精确度：

Wolfram Language code: 3.64``10 + I

算术运算通常会将其一起运算：

Wolfram Language code: % ^ 4

但要注意的是，实部和虚部的精度可能仍然不同：

Wolfram Language code: Accuracy /@ ReIm[%]

整个数字的精确度总是小于或等于这两个精确度中的任何一个：

Wolfram Language code: Accuracy[%%]

对于机器数，大小变小时准确度增加，$MinMachineNumber 的准确度最大：

Wolfram Language code: Plot[Accuracy[$MinMachineNumber / 2^n], {n, -100, 100}, PlotTheme -> "FrameGrid", FrameLabel -> {n, Accuracy}, PlotLegends -> {HoldForm@($MinMachineNumber/2^n)}]//Quiet

对于近似数，Precision[x]==RealExponent[x]+Accuracy[x]：

Wolfram Language code: numberTypes = {123456789.987654321, 0``40, 2`21, N[Pi, 18.9], -7, N[Exp[10 + I]]};
Wolfram Language code: TableForm[Table[{x, Precision[x], RealExponent[x], Accuracy[x], Precision[x] == RealExponent[x] + Accuracy[x]}, {x, numberTypes}], TableHeadings -> {{}, {"x", "Precision", "RealExponent", "Accuracy", "equality"}}, TableSpacing -> {1, 1}]

可能存在的问题  (1)

非规范机器数不满足关系式 Precision[x]==RealExponent[x]+Accuracy[x]：

Wolfram Language code: x = $MinMachineNumber / 2
Wolfram Language code: Precision[x] == RealExponent[x] + Accuracy[x]

相反，所有非规范数具有与 $MinMachineNumber 相同的不确定性：

Wolfram Language code: Accuracy[x] == Accuracy[$MinMachineNumber]

巧妙范例  (1)

Accuracy 和 Precision 在逻辑图迭代中：

Wolfram Language code: i = NestList[4 # (1 - #)&, N[1 / Pi, 30], 56];
Wolfram Language code: a = Accuracy /@ i; p = Precision /@ i;
Wolfram Language code: ListPlot[{a, p}, Filling -> {1 -> Axis}, PlotStyle -> {Blue, Red}]
Wolfram Research (1988)，Accuracy，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Accuracy.html （更新于 2018 年）.

文本

Wolfram Research (1988)，Accuracy，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Accuracy.html （更新于 2018 年）.

CMS

Wolfram 语言. 1988. "Accuracy." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2018. https://reference.wolfram.com/language/ref/Accuracy.html.

APA

Wolfram 语言. (1988). Accuracy. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Accuracy.html 年

BibTeX

@misc{reference.wolfram_2026_accuracy, author="Wolfram Research", title="{Accuracy}", year="2018", howpublished="\url{https://reference.wolfram.com/language/ref/Accuracy.html}", note=[Accessed: 14-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_accuracy, organization={Wolfram Research}, title={Accuracy}, year={2018}, url={https://reference.wolfram.com/language/ref/Accuracy.html}, note=[Accessed: 14-October-2026]}