WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

AirPressureData[]

現在地近くにおける気圧の最も新しい測定値を与える．

AirPressureData[datespec]

現在地近くにおける，指定された時間の気圧の値を与える．

AirPressureData[locationspec]

指定の場所の近くにおける気圧の最も新しい測定値を与える．

AirPressureData[locationspec,datespec]

指定の日付と場所における1つまたは複数の値を与える．

AirPressureData[{{location1,date1},{location2,date2},…}]

指定の日付における，指定の場所すべてでの値を与える．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
場所の指定  
測候所の特性  
日付指定  
場所のリスト  
形式指定  
連想指定  
オプション  
UnitSystem  
アプリケーション  
特性と関係  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

AirPressureData

AirPressureData[]

現在地近くにおける気圧の最も新しい測定値を与える．

AirPressureData[datespec]

現在地近くにおける，指定された時間の気圧の値を与える．

AirPressureData[locationspec]

指定の場所の近くにおける気圧の最も新しい測定値を与える．

AirPressureData[locationspec,datespec]

指定の日付と場所における1つまたは複数の値を与える．

AirPressureData[{{location1,date1},{location2,date2},…}]

指定の日付における，指定の場所すべてでの値を与える．

詳細とオプション

  • AirPressureDataは，世界中の標準的な測候所すべてにおける，現在と過去の平均海面気圧のデータを与える．平均海面気圧とは，海面位での大気圧，あるいは高度のある場所における海面位まで減少された測候所の気圧のことである．
  • AirPressureData[]では，$GeoLocationと$TimeZoneを利用して，現在の場所と時刻帯を見極める．$GeoLocationで指定された場所に最も近く信頼性の高い測候所で測定された最も新しい気圧の値を返す．
  • 場所は，"KNYC"等のICAOコード，"WMO12345"等のWMOコード，"C1234"等のアマチュア測候所のコード，別の標準化された測候所の識別子のいずれかで指定することができる．
  • 場所は，度数を単位とする緯度と経度のペア，GeoPosition指定，または地理的な座標でオブジェクトを表すと仮定した場合のEntityオブジェクトで指定することもできる．GeoDisk等のGeoGraphicsプリミティブ，またはCityDataで使われるタイプの都市指定も使える．AirPressureDataは，その場所に最も近く信頼性の高い測候所での測定値を与える．
  • locationspec は，個々の場所でも複数の場所のリストでもよい．
  • datespec は，日付のリストとして，DateString形式の文字列として，あるいはDateObjectとして指定できる．
  • AirPressureData[locationspec,datespec]はデフォルトで datespec が現地時刻で与えられるとし，すべての出力時刻にUTCを使う．
  • 特定の時間が与えられている場合，その時間の補間された結果が返される．1日あるいは長い期間についての datespec 指定は，気圧測定値の区間を返す．
  • datespec はDateRange指定との整合性のために，{start,end,step}として指定することができる．step は，All，"Day"，"Week"，"Month"，"Year"のいずれでもよい．Allは，記録された観測値すべてを与える．step は省略されると，値Allを持つとみなされる．
  • 位置と日付は，Association["Location"->locationspec,"Date"datespec]として一緒に指定することもできる．
  • AirPressureData[locationspec,datespec,func]は，場所が指定された場合の出力の形式を指定するのに使われる．
  • func の使用可能な設定値
  • All拡張された場所と時間における値をすべて返す
    Automatic拡張された場所と不定の時間について区間を返す
    Interval拡張された場所と時間について区間を返す
    Max拡張された場所と時間について最大値を返す
    Mean拡張された場所と時間について平均値を返す
    Min拡張された場所と時間について最小値を返す
    StandardDeviation拡張された場所と時間について標準偏差を返す
    "Stations"すべての値をそのソースである測候所とともに返す
  • 気圧は，ミリバールあるいは水銀柱インチでのQuantityとして返される．
  • オプションUnitSystemは出力単位を制御する．デフォルト値は$UnitSystemで設定される．次の設定も使うことができる．
  • "Imperial"帝国単位で結果を返す
    "Metric"メートル法で結果を返す
  • AirPressureData[locationspec,"property"]は，locationspec に対応する場所について，指定された測候所の特性を返す．
  • 測候所の特定に関連した特性
  • "Coordinates"GeoPositionとしての測候所の座標
    "Memberships"WMO，NCDC，CWOPのレポートネットワークの会員
    "NearestStation"最も近い測候所
    "StationDistance"指定の場所と指定の測候所の間の距離（単位：キロメートル）
    "StationName"測候所の名前
  • AirPressureDataは，世界中の気象観測所で観察された気圧データを取り出すことができる．

例題

すべて開く すべて閉じる

例  (1)

現在地の近くにおける最も新しい気圧の測定値を求める：

Wolfram Language code: AirPressureData[]

気圧は，ミリバールあるいは水銀柱インチで返される：

Wolfram Language code: AirPressureData[UnitSystem -> "Imperial"]

特定の測候所において記録された気圧を求める：

Wolfram Language code: AirPressureData["KMCI"]

特定の日付と測候所において，補間された気圧を得る：

Wolfram Language code: AirPressureData["KSAC", DateObject[{2012, 1, 2, 13, 0, 0.}, "Instant", "Gregorian", -5.]]

スコープ  (19)

場所の指定  (6)

"KBOS"の近似座標において，信頼性の高い測候所で測定した現在の気圧：

Wolfram Language code: AirPressureData["KBOS"]

場所の座標を与えることができる：

Wolfram Language code: AirPressureData[{40.67, -73.94}]
Wolfram Language code: AirPressureData[GeoPosition[{40.67, -73.94}]]

Entityオブジェクトも使える：

Wolfram Language code: AirPressureData[Entity["Dam", "HooverDam"]]

自由形式入力()を使って，適切なEntityを得る：

Wolfram Language code: AirPressureData[["Hoover Dam"]]

ロンドン西に対して180度の弧を描く地域の気圧の測定値の範囲を求める：

Wolfram Language code: AirPressureData[GeoDisk[EntityValue[["london"], "Coordinates"], Quantity[100, "Miles"], {180, 360}]]

地理的な地域において記録された気圧を求める：

Wolfram Language code: AirPressureData[Polygon[["Spain"]]]

座標または都市名から測候所を求めるには，"StationName"の特性を使う：

Wolfram Language code: AirPressureData[{42.3, -71.0}, "StationName"]

測候所の特性  (3)

使用される測候所の名前と座標を求める：

Wolfram Language code: AirPressureData["StationName"]
Wolfram Language code: AirPressureData["Coordinates"]

指定の場所から使用された測候所までのおよその距離を求める：

Wolfram Language code: AirPressureData[{40.67, -73.94}, "StationDistance"]

測候所の記録を行う高度を求める：

Wolfram Language code: AirPressureData["KCMI", "Elevation"]

日付指定  (3)

日付は，DateObjectを使って入力できる：

Wolfram Language code: AirPressureData["KSAC", DateObject[{2012, 1, 2, 13, 0, 0}]]

日付は，DateList形式でも指定できる：

Wolfram Language code: AirPressureData["KSAC", {2012, 1, 2, 13, 0, 0}]

{start,end}の形式の日付範囲は，その範囲内のすべてのデータを返す：

Wolfram Language code: AirPressureData["KMCI", {DateObject[{2012, 1, 1}], DateObject[{2012, 1, 2}]}]
Wolfram Language code: DateListPlot[%]

1時間より長い期間についての日付指定は，その期間に記録された気圧のIntervalを返す：

Wolfram Language code: AirPressureData["KSAC", DateObject[{2012, 1, 1}]]

場所のリスト  (3)

場所のリストを与えることができる：

Wolfram Language code: AirPressureData[{"KSAC", Entity["Building", "EmpireStateBuilding"], {40.11, -88.24}}]

特定時間における複数の場所での気圧を計算する：

Wolfram Language code: AirPressureData[{"KSAC", Entity["Building", "EmpireStateBuilding"], {40.11, -88.24}}, DateObject[{2012, 6, 17, 17, 0, 0}]]

複数の場所と日付について計算された気圧を求める：

Wolfram Language code: AirPressureData[{{"KCMI", DateObject[{2008, 8, 4, 12}]}, {"KSAC", DateObject[{2008, 8, 4, 12}]}, {"KISP", DateObject[{2012, 6, 6, 13}]}}]

形式指定  (2)

拡張された場所について気圧を求める：

Wolfram Language code: AirPressureData[GeoDisk[{40, -80}, Quantity[50, "Miles"]], DateObject[{2011, 6, 14, 12, 30}]]

最大気圧と最低気圧を得る：

Wolfram Language code: AirPressureData[GeoDisk[{40, -80}, Quantity[50, "Miles"]], DateObject[{2011, 6, 14, 12, 30}], Max]
Wolfram Language code: AirPressureData[GeoDisk[{40, -80}, Quantity[50, "Miles"]], DateObject[{2011, 6, 14, 12, 30}], Min]

設定Meanを使って平均気圧を求める：

Wolfram Language code: AirPressureData[GeoDisk[{40, -80}, Quantity[50, "Miles"]], DateObject[{2011, 6, 14, 12, 30}], Mean]

表示された値すべてについて測候所を返す：

Wolfram Language code: AirPressureData[Polygon[{{-99.24, 39.11}, {-99.24, 41.11}, {-101.24, 41.11}, {-101.24, 39.11}}], DateObject[{2011, 6, 14, 12, 30}], "Stations"]

連想指定  (2)

日付と位置は，Associationを使って一緒に指定することができる：

Wolfram Language code: AirPressureData[Association["Location" -> "KSAC", "Date" -> DateObject[{2012, 1, 1}]]]

Association指定は，形式引数と一緒に使うことができる：

Wolfram Language code: AirPressureData[Association["Location" -> "KSAC", "Date" -> DateObject[{2012, 1, 1}]], Mean]

オプション  (2)

UnitSystem  (2)

デフォルトで，結果には$UnitSystemによって与えられる形式が使われる：

Wolfram Language code: $UnitSystem

UnitSystemを"Imperial"に設定して，水銀柱インチを指定する：

Wolfram Language code: AirPressureData[UnitSystem -> "Imperial"]

UnitSystemを"Metric" に設定してミリバールを指定することもできる：

Wolfram Language code: AirPressureData[UnitSystem -> "Metric"]

単位の調整にUnitConvertを使うこともできる：

Wolfram Language code: UnitConvert[AirPressureData[], "Newtons" / "Centimeters" ^ 2]

アプリケーション  (2)

ニュージャージー州の大都市の気温と気圧に基づいて，空気密度を計算する：

Wolfram Language code: Grid[{#, ThermodynamicData["Air", "Density", {"Temperature" -> AirTemperatureData[#], "Pressure" -> AirPressureData[#]}]}& /@ CityData[{Large, "NewJersey", "UnitedStates"}], Frame -> All]

ある場所の近くの絶対気圧を計算する：

Wolfram Language code: AirPressureData[Entity["City", {"Denver", "Colorado", "UnitedStates"}]]
Wolfram Language code: molarmassofdryair = Quantity[0.0289644, "Kilograms" / "Moles"]; stationpressure[loc_] := AirPressureData[loc] * Exp[-AirPressureData[loc, "Elevation"] * Quantity["StandardAccelerationOfGravity"] * molarmassofdryair / (UnitConvert[AirTemperatureData[loc], "Kelvins"] * Quantity["GasConstant"])]
Wolfram Language code: stationpressure[Entity["City", {"Denver", "Colorado", "UnitedStates"}]]

特性と関係  (2)

デフォルトで，場所は$GeoLocationで指定される：

Wolfram Language code: AirPressureData[]
Wolfram Language code: AirPressureData[$GeoLocation]

GeoEntitiesで領域内の測候所を求める：

Wolfram Language code: stations = GeoEntities[["rhode island"], "WeatherStation"]

すべての測候所における気圧を求める：

Wolfram Language code: AirPressureData /@ stations

おもしろい例題  (2)

大嵐で気圧が下がる様子を観察する：

Wolfram Language code: DateListPlot[AirPressureData["KISP", {DateObject[{2012, 10, 28}], DateObject[{2012, 10, 30}]}], FrameLabel -> Automatic]

ある場所において記録された気圧の分布を正規分布にフィットする：

Wolfram Language code: ps = Cases[QuantityMagnitude[AirPressureData[Entity["Building", "EmpireStateBuilding"], {DateObject[{2000, 1, 1}], DateObject[{2010, 1, 1}], All}]["Values"]], _ ? NumberQ]; hg = Histogram[ps, Automatic, "PDF"];
Wolfram Language code: values = FindDistributionParameters[ps, NormalDistribution[μ, σ]]
Wolfram Language code: Show[{hg, Plot[Evaluate[PDF[NormalDistribution[μ, σ], x] /. values], {x, 980, 1050}]}]
Wolfram Research (2014), AirPressureData, Wolfram言語関数， https://reference.wolfram.com/language/ref/AirPressureData.html.

テキスト

Wolfram Research (2014), AirPressureData, Wolfram言語関数， https://reference.wolfram.com/language/ref/AirPressureData.html.

CMS

Wolfram Language. 2014. "AirPressureData." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/AirPressureData.html.

APA

Wolfram Language. (2014). AirPressureData. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/AirPressureData.html

BibTeX

@misc{reference.wolfram_2026_airpressuredata, author="Wolfram Research", title="{AirPressureData}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/AirPressureData.html}", note=[Accessed: 13-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_airpressuredata, organization={Wolfram Research}, title={AirPressureData}, year={2014}, url={https://reference.wolfram.com/language/ref/AirPressureData.html}, note=[Accessed: 13-August-2026]}