WOLFRAM

Wolfram 语言与系统参考资料中心

AirPressureData[]

给出当前位置附近气压的最新测量.

AirPressureData[datespec]

给出当前位置附近在给定时间的气压值.

AirPressureData[locationspec]

给出指定位置附近气压的最新测量.

AirPressureData[locationspec,datespec]

给出指定日期和位置的气压值.

AirPressureData[{{location1,date1},{location2,date2},…}]

给出全部指定位置在多个指定日期的气压值.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
位置指定  
气象站属性  
日期指定  
位置列表  
格式指定  
关联规范  
选项  
UnitSystem  
应用  
属性和关系  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

AirPressureData

AirPressureData[]

给出当前位置附近气压的最新测量.

AirPressureData[datespec]

给出当前位置附近在给定时间的气压值.

AirPressureData[locationspec]

给出指定位置附近气压的最新测量.

AirPressureData[locationspec,datespec]

给出指定日期和位置的气压值.

AirPressureData[{{location1,date1},{location2,date2},…}]

给出全部指定位置在多个指定日期的气压值.

更多信息和选项

  • AirPressureData 为全球标准气象站提供当前和历史平均海平面气压数据. 平均海平面气压是海平面大气压，或对位于一定海拔的地区，降低到海平面的气象站气压.
  • AirPressureData[] 利用 $GeoLocation 和 $TimeZone 确定您所处位置和时区. 它返回与 $GeoLocation 指定位置最近的高可靠性气象站的最新气压测量.
  • 位置可以指定为 ICAO 代码（例如 "KNYC"）、WMO 代码（例如 "WMO12345"）、业余气象站代码（例如 "C1234"）或其他标准化气象站标识符.
  • 位置还可以通过纬度/经度对指定，假定度为单位，GeoPosition 指定、或 Entity 对象，假定它们表示具有地理坐标的对象. 它们也可以是 GeoGraphics 基元（例如 GeoDisk），或者用于 CityData 的类型城市指定. AirPressureData 给出距该位置最近的高可靠性气象站的测量.
  • locationspec 可以是单个位置或者是一个位置列表.
  • datespec 可以指定为日期列表、DateString 格式的字符串或者 DateObject.
  • AirPressureData[locationspec,datespec] 默认认为 datespec 以当地时间给出，并对所有输出时间使用世界标准时间（UTC).
  • 如果给出具体时间，则返回时间的插值结果. 对于一天或更长的时间，datespec 指定返回气压测量的区间值.
  • datespec 可以指定为 {start,end,step}，以匹配 DateRange 指定. step 可以是 All、"Day"、"Week"、"Month" 或 "Year". All 给出所有记录的观察值. 如果省略，step 假定具有值 All.
  • 位置和日期也可以作为 Association["Location"->locationspec,"Date"datespec] 一起指定.
  • 当位置指定时，AirPressureData[locationspec,datespec,func] 用于指定输出结果.
  • func 的可能设置包括：
  • All返回扩展位置和时间的所有值
    Automatic返回扩展位置和不确定时间的区间
    Interval返回扩展位置和时间的区间
    Max返回扩展位置和时间的最大值
    Mean返回扩展位置和时间的平均值
    Min返回扩展位置和时间的最小值
    StandardDeviation返回扩展位置和时间的标准偏差
    "Stations"返回沿着来源气象站的所有值
  • 作为 Quantity 返回的压强单位是毫巴或英寸汞柱.
  • 选项 UnitSystem 控制输出单位. 默认值由 $UnitSystem 设定. 也可以使用下列设置：
  • "Imperial"返回英制单位的结果
    "Metric"返回公制单位的结果
  • AirPressureData[locationspec,"property"] 返回指定的气象站属性，其位置对应于 locationspec.
  • 有关识别气象站的属性包括：
  • "Coordinates"作为 GeoPosition 的气象站坐标
    "Memberships"WMO、NCDC 和 CWOP 报告网络成员
    "NearestStation"最近的气象站
    "StationDistance"指定位置和给定气象站之间的距离，单位为千米
    "StationName"气象站名称
  • AirPressureData 可以检索来自世界各地的气象观测站的气压数据.

范例

打开所有单元 关闭所有单元

基本范例  (1)

求您当前所在位置附近的最新气压测量：

Wolfram Language code: AirPressureData[]

返回气压的单位可以是毫巴或英寸汞柱：

Wolfram Language code: AirPressureData[UnitSystem -> "Imperial"]

发现特定气象站的记录气压：

Wolfram Language code: AirPressureData["KMCI"]

获得某一特定日期和气象站的插值气压：

Wolfram Language code: AirPressureData["KSAC", DateObject[{2012, 1, 2, 13, 0, 0.}, "Instant", "Gregorian", -5.]]

范围  (19)

位置指定  (6)

在 "KBOS" 近似坐标来自高可靠性气象站的当前气压：

Wolfram Language code: AirPressureData["KBOS"]

可以为位置提供坐标：

Wolfram Language code: AirPressureData[{40.67, -73.94}]
Wolfram Language code: AirPressureData[GeoPosition[{40.67, -73.94}]]

可使用 Entity 对象：

Wolfram Language code: AirPressureData[Entity["Dam", "HooverDam"]]

使用自由格式输入（）获得适当的 Entity：

Wolfram Language code: AirPressureData[["Hoover Dam"]]

求伦敦西部180度圆弧内的气压测量范围：

Wolfram Language code: AirPressureData[GeoDisk[EntityValue[["london"], "Coordinates"], Quantity[100, "Miles"], {180, 360}]]

求整个地理区域的记录气压：

Wolfram Language code: AirPressureData[Polygon[["Spain"]]]

如要从坐标或城市名称返回气象站，使用 "StationName" 属性：

Wolfram Language code: AirPressureData[{42.3, -71.0}, "StationName"]

气象站属性  (3)

求气象站所用的名称和坐标：

Wolfram Language code: AirPressureData["StationName"]
Wolfram Language code: AirPressureData["Coordinates"]

从指定位置中使用的气象站的近似距离：

Wolfram Language code: AirPressureData[{40.67, -73.94}, "StationDistance"]

了解一气象站的记录海拔高度：

Wolfram Language code: AirPressureData["KCMI", "Elevation"]

日期指定  (3)

日期可以是使用 DateObject 输入：

Wolfram Language code: AirPressureData["KSAC", DateObject[{2012, 1, 2, 13, 0, 0}]]

日期也可以用 DateList 格式指定：

Wolfram Language code: AirPressureData["KSAC", {2012, 1, 2, 13, 0, 0}]

格式为 {start,end} 的日期范围将返回该范围内的所有数据：

Wolfram Language code: AirPressureData["KMCI", {DateObject[{2012, 1, 1}], DateObject[{2012, 1, 2}]}]
Wolfram Language code: DateListPlot[%]

时间段超过一小时的日期指定将返回该时间段上记录压强的 Interval：

Wolfram Language code: AirPressureData["KSAC", DateObject[{2012, 1, 1}]]

位置列表  (3)

可以提供一个位置列表：

Wolfram Language code: AirPressureData[{"KSAC", Entity["Building", "EmpireStateBuilding"], {40.11, -88.24}}]

计算多个位置在指定时间的气压：

Wolfram Language code: AirPressureData[{"KSAC", Entity["Building", "EmpireStateBuilding"], {40.11, -88.24}}, DateObject[{2012, 6, 17, 17, 0, 0}]]

求多个位置和日期的计算气压：

Wolfram Language code: AirPressureData[{{"KCMI", DateObject[{2008, 8, 4, 12}]}, {"KSAC", DateObject[{2008, 8, 4, 12}]}, {"KISP", DateObject[{2012, 6, 6, 13}]}}]

格式指定  (2)

求扩展位置的气压：

Wolfram Language code: AirPressureData[GeoDisk[{40, -80}, Quantity[50, "Miles"]], DateObject[{2011, 6, 14, 12, 30}]]

获取最大或最小压强：

Wolfram Language code: AirPressureData[GeoDisk[{40, -80}, Quantity[50, "Miles"]], DateObject[{2011, 6, 14, 12, 30}], Max]
Wolfram Language code: AirPressureData[GeoDisk[{40, -80}, Quantity[50, "Miles"]], DateObject[{2011, 6, 14, 12, 30}], Min]

使用设置 Mean 获得平均压强：

Wolfram Language code: AirPressureData[GeoDisk[{40, -80}, Quantity[50, "Miles"]], DateObject[{2011, 6, 14, 12, 30}], Mean]

返回所有显示值的气象站：

Wolfram Language code: AirPressureData[Polygon[{{-99.24, 39.11}, {-99.24, 41.11}, {-101.24, 41.11}, {-101.24, 39.11}}], DateObject[{2011, 6, 14, 12, 30}], "Stations"]

关联规范  (2)

日期和位置可以使用 Association 一起指定：

Wolfram Language code: AirPressureData[Association["Location" -> "KSAC", "Date" -> DateObject[{2012, 1, 1}]]]

Association 规范适用于格式参数：

Wolfram Language code: AirPressureData[Association["Location" -> "KSAC", "Date" -> DateObject[{2012, 1, 1}]], Mean]

选项  (2)

UnitSystem  (2)

默认情况下，结果使用由 $UnitSystem 给出的格式：

Wolfram Language code: $UnitSystem

将 UnitSystem 设置为 "Imperial"，指定英寸汞柱：

Wolfram Language code: AirPressureData[UnitSystem -> "Imperial"]

或者将 UnitSystem 设置为 "Metric"，指定毫巴：

Wolfram Language code: AirPressureData[UnitSystem -> "Metric"]

UnitConvert 也可以用来调整单位：

Wolfram Language code: UnitConvert[AirPressureData[], "Newtons" / "Centimeters" ^ 2]

应用  (2)

基于温度和压强，计算新泽西达较大城市的空气密度：

Wolfram Language code: Grid[{#, ThermodynamicData["Air", "Density", {"Temperature" -> AirTemperatureData[#], "Pressure" -> AirPressureData[#]}]}& /@ CityData[{Large, "NewJersey", "UnitedStates"}], Frame -> All]

计算一个位置附近的绝对气压：

Wolfram Language code: AirPressureData[Entity["City", {"Denver", "Colorado", "UnitedStates"}]]
Wolfram Language code: molarmassofdryair = Quantity[0.0289644, "Kilograms" / "Moles"]; stationpressure[loc_] := AirPressureData[loc] * Exp[-AirPressureData[loc, "Elevation"] * Quantity["StandardAccelerationOfGravity"] * molarmassofdryair / (UnitConvert[AirTemperatureData[loc], "Kelvins"] * Quantity["GasConstant"])]
Wolfram Language code: stationpressure[Entity["City", {"Denver", "Colorado", "UnitedStates"}]]

属性和关系  (2)

默认情况下，位置由 $GeoLocation 指定：

Wolfram Language code: AirPressureData[]
Wolfram Language code: AirPressureData[$GeoLocation]

通过 GeoEntities 查找一个地区的所有气象站：

Wolfram Language code: stations = GeoEntities[["rhode island"], "WeatherStation"]

求在所有气象站的压强：

Wolfram Language code: AirPressureData /@ stations

巧妙范例  (2)

检查强风暴时压强读数的下降：

Wolfram Language code: DateListPlot[AirPressureData["KISP", {DateObject[{2012, 10, 28}], DateObject[{2012, 10, 30}]}], FrameLabel -> Automatic]

将一个位置的记录气压分布拟合为正态分布：

Wolfram Language code: ps = Cases[QuantityMagnitude[AirPressureData[Entity["Building", "EmpireStateBuilding"], {DateObject[{2000, 1, 1}], DateObject[{2010, 1, 1}], All}]["Values"]], _ ? NumberQ]; hg = Histogram[ps, Automatic, "PDF"];
Wolfram Language code: values = FindDistributionParameters[ps, NormalDistribution[μ, σ]]
Wolfram Language code: Show[{hg, Plot[Evaluate[PDF[NormalDistribution[μ, σ], x] /. values], {x, 980, 1050}]}]
Wolfram Research (2014)，AirPressureData，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AirPressureData.html.

文本

Wolfram Research (2014)，AirPressureData，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AirPressureData.html.

CMS

Wolfram 语言. 2014. "AirPressureData." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/AirPressureData.html.

APA

Wolfram 语言. (2014). AirPressureData. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/AirPressureData.html 年

BibTeX

@misc{reference.wolfram_2026_airpressuredata, author="Wolfram Research", title="{AirPressureData}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/AirPressureData.html}", note=[Accessed: 10-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_airpressuredata, organization={Wolfram Research}, title={AirPressureData}, year={2014}, url={https://reference.wolfram.com/language/ref/AirPressureData.html}, note=[Accessed: 10-August-2026]}