WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

AirTemperatureData[]

現在地近くにおける気温の最も新しい測定値を与える．

AirTemperatureData[datespec]

現在地近くにおける，指定された時間の気温の値を与える．

AirTemperatureData[locationspec]

指定の場所の近くにおける気温の最も新しい測定値を与える．

AirTemperatureData[locationspec,datespec]

指定の日付と場所における1つまたは複数の値を与える．

AirTemperatureData[{{location1,date1},{location2,date2},…}]

指定の日付における，指定の場所すべてでの値を与える．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
場所の指定  
測候所の特性  
日付指定  
場所のリスト  
形式指定  
連想指定  
オプション  
UnitSystem  
アプリケーション  
特性と関係  
おもしろい例題  
関連項目
関連するガイド
関連リンク
履歴
引用書式

AirTemperatureData

AirTemperatureData[]

現在地近くにおける気温の最も新しい測定値を与える．

AirTemperatureData[datespec]

現在地近くにおける，指定された時間の気温の値を与える．

AirTemperatureData[locationspec]

指定の場所の近くにおける気温の最も新しい測定値を与える．

AirTemperatureData[locationspec,datespec]

指定の日付と場所における1つまたは複数の値を与える．

AirTemperatureData[{{location1,date1},{location2,date2},…}]

指定の日付における，指定の場所すべてでの値を与える．

詳細とオプション

  • AirTemperatureDataは，世界中の標準的な測候所すべてにおける，現在と過去の気温のデータを与える．
  • AirTemperatureData[]は，$GeoLocationと$TimeZoneを利用して，現在の場所と時刻帯を見極める．$GeoLocationで指定された場所に最も近く信頼性の高い測候所で測定された最も新しい気温の値を返す．
  • 場所は，"KNYC"等のICAOコード，"WMO12345"等のWMOコード，"C1234"等のアマチュア測候所のコード，別の標準化された測候所の識別子のいずれかで指定することができる．
  • 場所は，度数を単位とする緯度と経度のペア，GeoPosition指定，または地理的な座標でオブジェクトを表すと仮定した場合のEntityオブジェクトで指定することができる．GeoDisk等のGeoGraphicsプリミティブ，またはCityDataで使われるタイプの都市指定も使える．AirTemperatureDataは，その場所に最も近く信頼性の高い測候所での測定値を与える．
  • locationspec は，個々の場所でも複数の場所のリストでもよい．
  • datespec は，日付のリストとして，DateString形式の文字列として，あるいはDateObjectとして指定できる．
  • AirTemperatureData[locationspec,datespec]はデフォルトで datespec が現地時刻で与えられるとし，すべての出力時刻にUTCを使う．
  • 特定の時間が与えられている場合，その時間の補間された結果が返される．1日あるいは長い期間についての datespec 指定は，気温測定値の区間を返す．
  • datespec はDateRange指定との整合性のために，{start,end,step}として指定することができる．step は，All，"Day"，"Week"，"Month"，"Year"のいずれでもよい．Allは，記録された観測値すべてを与える．省略されるた場合，step は値Allを持つとみなされる．
  • 位置と日付も，Association["Location"->locationspec,"Date"datespec]として一緒に指定することができる．
  • AirTemperatureData[locationspec,datespec,func]は，場所が指定された場合の出力の形式を指定するのに使われる．
  • func の使用可能な設定
  • All拡張された場所と時間における値をすべて返す
    Automatic拡張された場所と不定の時間について区間を返す
    Interval拡張された場所と時間について区間を返す
    Max拡張された場所と時間について最大値を返す
    Mean拡張された場所と時間について平均値を返す
    Min拡張された場所と時間について最小値を返す
    StandardDeviation拡張された場所と時間について標準偏差を返す
    "Stations"すべての値をそのソースである測候所とともに返す
  • 気温は，摂氏あるいは華氏のQuantityとして返される．
  • オプションUnitSystemは出力単位を制御する．デフォルト値は$UnitSystemで設定される．次の設定も使うことができる．
  • "Imperial"帝国単位で結果を返す
    "Metric"メートル法で結果を返す
  • AirTemperatureData[locationspec,"property"]は，locationspec に対応する場所について，指定された測候所の特性を返す．
  • 測候所の特定に関連した特性
  • "Coordinates"GeoPosition としての測候所の座標
    "Memberships"WMO，NCDC，CWOPのレポートネットワークの会員
    "NearestStation"最も近い測候所
    "StationDistance"指定の場所と指定の測候所の間の距離（単位：キロメートル）
    "StationName"測候所の名前
  • AirTemperatureDataは，世界中の気象観測所で観察された気温データを取り出すことができる．

例題

すべて開く すべて閉じる

例  (1)

現在地の近くにおける最も新しい気温の測定値を求める：

Wolfram Language code: AirTemperatureData[]

気温は，摂氏あるいは華氏で返される：

Wolfram Language code: AirTemperatureData[UnitSystem -> "Imperial"]

特定の測候所において記録された気温を求める：

Wolfram Language code: AirTemperatureData["KMCI"]

特定の日付と測候所において，補間された気温を得る：

Wolfram Language code: AirTemperatureData["KSAC", DateObject[{2012, 1, 2, 13, 0, 0}]]

スコープ  (19)

場所の指定  (6)

"KBOS"の近似座標において，信頼性の高い測候所で測定した現在の気温：

Wolfram Language code: AirTemperatureData["KBOS"]

場所の座標を与えることができる：

Wolfram Language code: AirTemperatureData[{40.67, -73.94}]
Wolfram Language code: AirTemperatureData[GeoPosition[{40.67, -73.94}]]

Entityオブジェクトも使える：

Wolfram Language code: AirTemperatureData[Entity["Dam", "HooverDam"]]

自由形式入力()を使って，適切なEntityを得る：

Wolfram Language code: AirTemperatureData[["Hoover dam"]]

パリの東に対して180度の弧を描く地域で記録された気温の範囲を求める：

Wolfram Language code: AirTemperatureData[GeoDisk[EntityValue[["Paris"], "Coordinates"], Quantity[100, "Miles"], {0, 180}]]

地理的な地域における，最近の気温の範囲を求める：

Wolfram Language code: AirTemperatureData[Polygon[["italy"]]]

座標または都市名から測候所を求めるには，"StationName"の特性を使う：

Wolfram Language code: AirTemperatureData[{42.3, -71.0}, "StationName"]

測候所の特性  (3)

使用される測候所の名前と座標を求める：

Wolfram Language code: AirTemperatureData["StationName"]
Wolfram Language code: AirTemperatureData["Coordinates"]

指定の場所から使用された測候所までの相対距離を求める：

Wolfram Language code: AirTemperatureData[{40.67, -73.94}, "StationDistance"]

測候所の高度を求める：

Wolfram Language code: AirTemperatureData["KCMI", "Elevation"]

日付指定  (3)

日付は，DateObjectを使って入力できる：

Wolfram Language code: AirTemperatureData["KSAC", DateObject[{2012, 1, 1, 12, 30, 0}]]

日付は，DateList形式でも指定できる：

Wolfram Language code: AirTemperatureData["KSAC", {2012, 1, 1, 12, 30, 0}]

{start,end}の形式の日付範囲は，その範囲内で記録されたすべてのデータを返す：

Wolfram Language code: AirTemperatureData["KMCI", {DateObject[{2012, 1, 1}], DateObject[{2012, 1, 2}]}]
Wolfram Language code: DateListPlot[%]

1時間より長い期間についての日付指定は，その期間の気温のIntervalを返す：

Wolfram Language code: AirTemperatureData["KSAC", DateObject[{2012, 1, 1}]]

場所のリスト  (3)

場所のリストを与えることができる：

Wolfram Language code: AirTemperatureData[{"KSAC", Entity["Building", "EmpireStateBuilding"], {40.11, -88.24}}]

特定時間における複数の場所での気温を計算する：

Wolfram Language code: AirTemperatureData[{"KSAC", Entity["Building", "EmpireStateBuilding"], {40.11, -88.24}}, DateObject[{2012, 6, 17, 17, 0, 0.}]]

複数の場所と日付について計算された気温を求める：

Wolfram Language code: AirTemperatureData[{{"KCMI", DateObject[{2008, 8, 4, 12}]}, {"KSAC", DateObject[{2008, 8, 4, 2}]}, {"KISP", DateObject[{2012, 6, 6, 13}]}}]

形式指定  (2)

拡張された場所について気温を求める：

Wolfram Language code: AirTemperatureData[GeoDisk[{40, -90}, Quantity[25, "Miles"]], DateObject[{2008, 8, 4, 12}]]

記録された気温の中で最高のものと最低のものを得る：

Wolfram Language code: AirTemperatureData[GeoDisk[{40, -90}, Quantity[25, "Miles"]], DateObject[{2008, 8, 4, 12}], Max]
Wolfram Language code: AirTemperatureData[GeoDisk[{40, -90}, Quantity[25, "Miles"]], DateObject[{2008, 8, 4, 12}], Min]

設定Meanを使って平均気温を求める：

Wolfram Language code: AirTemperatureData[GeoDisk[{40, -90}, Quantity[25, "Miles"]], DateObject[{2008, 8, 4, 12}], Mean]

表示された値すべてについて測候所を返す：

Wolfram Language code: AirTemperatureData[GeoDisk[{39.11, -99.24}, Quantity[100, "Kilometers"]], DateObject[{2011, 6, 14, 12, 30, 0.}], "Stations"]

連想指定  (2)

日付と位置は，Associationを使って一緒に指定することができる：

Wolfram Language code: AirTemperatureData[Association["Location" -> GeoPosition[{45, -90}], "Date" -> DateObject[{2000, 1, 1}]]]

Association指定は，形式引数と一緒に使うことができる：

Wolfram Language code: AirTemperatureData[Association["Location" -> GeoPosition[{45, -90}], "Date" -> DateObject[{2000, 1, 1}]], Mean]

オプション  (2)

UnitSystem  (2)

デフォルトで，結果には$UnitSystemで与えられる形式が使われる：

Wolfram Language code: $UnitSystem

UnitSystemを"Imperial"に設定して，華氏を指定する：

Wolfram Language code: AirTemperatureData[UnitSystem -> "Imperial"]

UnitSystemを"Metric"に設定して摂氏を指定することもできる：

Wolfram Language code: AirTemperatureData[UnitSystem -> "Metric"]

単位の調整にUnitConvertを使うこともできる：

Wolfram Language code: UnitConvert[N@AirTemperatureData[], "Kelvins"]

アプリケーション  (4)

南アメリカの首都における最近の気温の測定値：

Wolfram Language code: Grid[SortBy[{#, AirTemperatureData[#]}& /@ (CountryData[#, "CapitalCity"]& /@ CountryData["SouthAmerica"]), Last], Frame -> All]

アラスカ州アンカレッジから100マイル以内の地域で，現在の最低気温を求める：

Wolfram Language code: coordinates = CityData[Entity["City", {"Anchorage", "Alaska", "UnitedStates"}], "Coordinates"]; stations = DeleteDuplicates[AirTemperatureData[GeoDisk[coordinates, Quantity[100, "Miles"]], "StationName"]];
Wolfram Language code: First@SortBy[Quiet[DeleteCases[{#, AirTemperatureData[#]}& /@ stations, {_, Missing[_] | _AirTemperatureData}]], Last]

西経90度に沿った測候所を求める：

Wolfram Language code: data = DeleteDuplicates[Table[WeatherData[{i, -90}], {i, 30, 48, 0.1}]]; data = {WeatherData[#, "Coordinates"], Quiet[AirTemperatureData[#, DateObject[{2012, 8, 4, 12}]]]}& /@ data;
Wolfram Language code: WeatherData["KNEW", "Coordinates"]

正午において補間された気温を，緯度の関数として観察する：

Wolfram Language code: ListPlot[{#[[1, 1]], #[[2]]}& /@ data, PlotRange -> All]

ある日のベニスにおける気温の測定値の分布を求める：

Wolfram Language code: data = Flatten[Table[AirTemperatureData[{45.43, 12.33}, {{i, 6, 20}, {i, 6, 20}}, UnitSystem -> "Metric"]["ValueList"], {i, 1993, 2012}]];
Wolfram Language code: Histogram[data, {1}]

特性と関係  (4)

デフォルトで，場所は$GeoLocationで指定される：

Wolfram Language code: AirTemperatureData[]
Wolfram Language code: AirTemperatureData[$GeoLocation]

IconDataはAirTemperatureDataの出力に用いることができる：

Wolfram Language code: IconData["AirTemperature", AirTemperatureData[]]

GeoGraphicsとIconDataを使って，ドイツ内の都市における気温を表示する：

Wolfram Language code: cities = {["Berlin"], ["Hamburg"], ["Munich"], ["Cologne"], ["Frankfurt"], ["Stuttgart"], ["Dortmund"], ["Bremen"], ["Dresden"], ["Hanover"], ["Nuremberg"]};
Wolfram Language code: data = {CityData[#, "Coordinates"], CityData[#, "Name"], AirTemperatureData[#]}& /@ cities;
Wolfram Language code: GeoGraphics[{GeoStyling["ReliefMap"], EdgeForm[Thin], Opacity[0.5], Polygon[Entity["Country", "Germany"]], PointSize[Large], Opacity[1], {Black, Text[#[[2]], GeoPosition[#[[1]]], {-1.5, 0}], Red, Point[GeoPosition[#[[1]]]], Inset[IconData["AirTemperature", #[[3]]], GeoPosition[#[[1]]], Bottom, 1]}& /@ data}, RasterSize -> 200]

領域内のすべての測候所をGeoEntitiesで求める：

Wolfram Language code: stations = GeoEntities[["Delaware"], "WeatherStation"]

すべての測候所における気温を求める：

Wolfram Language code: AirTemperatureData /@ stations

おもしろい例題  (3)

コロラド州の主要都市における最近の気圧と気温の測定値に基づいて，音速を計算する：

Wolfram Language code: Grid[SortBy[{#, ThermodynamicData["Air", "SoundSpeed", {"Temperature" -> AirTemperatureData[#], "Pressure" -> AirPressureData[#]}]}& /@ CityData[{Large, "Colorado", "UnitedStates"}], Last], Frame -> All]

アルプス山脈の測候所における，気温と高度の相関関係を調べる：

Wolfram Language code: stations = WeatherData[{{"Davos", "Graubunden", "Switzerland"}, 100}];
Wolfram Language code: ListPlot[Tooltip[{AirTemperatureData[#], AirTemperatureData[#, "Elevation"]}, #]& /@ stations, Frame -> True, Axes -> False, FrameLabel -> {Quantity[None, "Celsius"], Quantity[None, "Meters"]}]

1年を通して気温の変化を調べる：

Wolfram Language code: data = Table[{DatePlus[DateObject[{2012, 1, 1}], i], AirTemperatureData["KCMI", First@DatePlus[DateObject[{2012, 1, 1}], i], Interval]}, {i, 0, 364}];
Wolfram Language code: data = {DateList[First[#]], First[Differences@@#[[2, 1]]]}& /@ data;

月ごとの平均気温の変化を求める：

Wolfram Language code: averages = {#[[1, 1, ;; 2]], Mean[#[[All, 2]]]}& /@ GatherBy[data, #[[1, 2]]&];
Wolfram Language code: BarChart[averages[[All, 2]], ChartLabels -> averages[[All, 1, 2]]]

平均のように，最高の気温の変化は，夏よりも冬に起ることを調べる：

Wolfram Language code: pos = Position[data, Max[data[[All, 2]]]]; data[[pos[[1, 1]]]]

このことに基づいて，1年を通して日々の気温の変化における分散がどのように変化するかを調べる：

Wolfram Language code: variance = {#[[1, 1, ;; 2]], Variance[#[[All, 2]]]}& /@ GatherBy[data, #[[1, 2]]&];
Wolfram Language code: BarChart[variance[[All, 2]], ChartLabels -> variance[[All, 1, 2]]]
Wolfram Research (2014), AirTemperatureData, Wolfram言語関数， https://reference.wolfram.com/language/ref/AirTemperatureData.html.

テキスト

Wolfram Research (2014), AirTemperatureData, Wolfram言語関数， https://reference.wolfram.com/language/ref/AirTemperatureData.html.

CMS

Wolfram Language. 2014. "AirTemperatureData." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/AirTemperatureData.html.

APA

Wolfram Language. (2014). AirTemperatureData. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/AirTemperatureData.html

BibTeX

@misc{reference.wolfram_2026_airtemperaturedata, author="Wolfram Research", title="{AirTemperatureData}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/AirTemperatureData.html}", note=[Accessed: 16-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_airtemperaturedata, organization={Wolfram Research}, title={AirTemperatureData}, year={2014}, url={https://reference.wolfram.com/language/ref/AirTemperatureData.html}, note=[Accessed: 16-August-2026]}