WOLFRAM

Wolfram 语言与系统参考资料中心

AirTemperatureData[]

给出当前位置附近气温的最新测量.

AirTemperatureData[datespec]

给出当前位置附近在给定时间的气温值.

AirTemperatureData[locationspec]

给出指定位置附近气温的最新测量.

AirTemperatureData[locationspec,datespec]

给出指定日期和位置的气温值.

AirTemperatureData[{{location1,date1},{location2,date2},…}]

给出全部指定位置在多个指定日期的气温值.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
位置指定  
气象站属性  
日期指定  
位置列表  
格式指定  
关联规范  
选项  
UnitSystem  
应用  
属性和关系  
巧妙范例  
参见
相关指南
相关链接
历史
按以下格式引用：

AirTemperatureData

AirTemperatureData[]

给出当前位置附近气温的最新测量.

AirTemperatureData[datespec]

给出当前位置附近在给定时间的气温值.

AirTemperatureData[locationspec]

给出指定位置附近气温的最新测量.

AirTemperatureData[locationspec,datespec]

给出指定日期和位置的气温值.

AirTemperatureData[{{location1,date1},{location2,date2},…}]

给出全部指定位置在多个指定日期的气温值.

更多信息和选项

  • AirTemperatureData 为全球所有标准气象站提供当前和历史气温数据.
  • AirTemperatureData[] 利用 $GeoLocation 和 $TimeZone 确定您所处位置和时区. 它返回与 $GeoLocation 指定位置最近的高可靠性气象站的最新气温测量.
  • 位置可以指定为 ICAO 代码（例如 "KNYC"）、WMO 代码（例如 "WMO12345"）、业余气象站代码（例如 "C1234"）或其他标准化气象站标识符.
  • 位置还可以通过纬度/经度对指定，假定度为单位，GeoPosition 指定、或 Entity 对象，假定它们表示具有地理坐标的对象. 它们也可以是 GeoGraphics 基元（例如 GeoDisk），或者用于 CityData 的类型城市指定. AirTemperatureData 给出距该位置最近的高可靠性气象站的测量结果.
  • locationspec 可以是单个位置或者是一个位置列表.
  • datespec 可以指定为日期列表、DateString 格式的字符串或者 DateObject.
  • AirTemperatureData[locationspec,datespec] 默认认为 datespec 以当地时间给出，并对所有输出时间使用世界标准时间（UTC）.
  • 如果给出具体时间，则返回时间的插值结果. 对于一天或更长的时间，datespec 指定返回温度测量的区间值.
  • datespec 可以指定为 {start,end,step}，以匹配 DateRange 指定. step 可以是 All、"Day"、"Week"、"Month" 或 "Year". All 给出所有记录的观察值. 如果省略，step 假定具有值 All.
  • 位置和日期也可以作为 Association["Location"->locationspec,"Date"datespec] 一起指定.
  • 当位置指定时，AirTemperatureData[locationspec,datespec,func] 用于指定输出结果.
  • func 的可能设置包括：
  • All返回扩展位置和时间的所有值
    Automatic返回扩展位置和不确定时间的区间
    Interval返回扩展位置和时间的区间
    Max返回扩展位置和时间的最大值
    Mean返回扩展位置和时间的平均值
    Min返回扩展位置和时间的最小值
    StandardDeviation返回扩展位置和时间的标准偏差
    "Stations"返回沿着来源气象站的所有值
  • 作为 Quantity 返回的温度单位是摄氏度或华氏度.
  • 选项 UnitSystem 控制输出单位. 默认值由 $UnitSystem 设定. 也可以使用下列设置：
  • "Imperial"返回英制单位的结果
    "Metric"返回公制单位的结果
  • AirTemperatureData[locationspec,"property"] 返回指定的气象站属性，其位置对应于 locationspec.
  • 有关识别气象站的属性包括：
  • "Coordinates"作为 GeoPosition 的气象站坐标
    "Memberships"WMO、NCDC 和 CWOP 报告网络成员
    "NearestStation"最近的气象站
    "StationDistance"指定位置和给定气象站之间的距离，单位为千米
    "StationName"气象站名称
  • AirTemperatureData 可以检索来自世界各地的气象观测站的气温数据.

范例

打开所有单元 关闭所有单元

基本范例  (1)

求您当前所在位置附近的最新气温测量：

Wolfram Language code: AirTemperatureData[]

返回的温度单位可以是摄氏度或华氏度：

Wolfram Language code: AirTemperatureData[UnitSystem -> "Imperial"]

发现特定气象站的气温：

Wolfram Language code: AirTemperatureData["KMCI"]

获得某一特定日期和位置的插值气温：

Wolfram Language code: AirTemperatureData["KSAC", DateObject[{2012, 1, 2, 13, 0, 0}]]

范围  (19)

位置指定  (6)

在 "KBOS" 近似坐标来自高可靠性气象站的当前记录温度：

Wolfram Language code: AirTemperatureData["KBOS"]

可以为一个位置提供坐标：

Wolfram Language code: AirTemperatureData[{40.67, -73.94}]
Wolfram Language code: AirTemperatureData[GeoPosition[{40.67, -73.94}]]

可以使用 Entity 对象：

Wolfram Language code: AirTemperatureData[Entity["Dam", "HooverDam"]]

使用自由格式输入（）获得适当的 Entity：

Wolfram Language code: AirTemperatureData[["Hoover dam"]]

求巴黎东部180度圆弧内的记录气温范围：

Wolfram Language code: AirTemperatureData[GeoDisk[EntityValue[["Paris"], "Coordinates"], Quantity[100, "Miles"], {0, 180}]]

求一个地理区域的近期气温测量的范围：

Wolfram Language code: AirTemperatureData[Polygon[["italy"]]]

根据坐标或城市名称返回气象站，使用 "StationName" 属性：

Wolfram Language code: AirTemperatureData[{42.3, -71.0}, "StationName"]

气象站属性  (3)

求气象站所用的名称和坐标：

Wolfram Language code: AirTemperatureData["StationName"]
Wolfram Language code: AirTemperatureData["Coordinates"]

从指定位置求使用的气象站的相对距离：

Wolfram Language code: AirTemperatureData[{40.67, -73.94}, "StationDistance"]

了解一气象站的海拔高度：

Wolfram Language code: AirTemperatureData["KCMI", "Elevation"]

日期指定  (3)

日期可以是使用 DateObject 输入：

Wolfram Language code: AirTemperatureData["KSAC", DateObject[{2012, 1, 1, 12, 30, 0}]]

日期也可以用 DateList 格式指定：

Wolfram Language code: AirTemperatureData["KSAC", {2012, 1, 1, 12, 30, 0}]

格式为 {start,end} 的日期范围将返回该范围内的所有数据：

Wolfram Language code: AirTemperatureData["KMCI", {DateObject[{2012, 1, 1}], DateObject[{2012, 1, 2}]}]
Wolfram Language code: DateListPlot[%]

时间段超过一小时的日期指定将返回该时间段上温度的 Interval：

Wolfram Language code: AirTemperatureData["KSAC", DateObject[{2012, 1, 1}]]

位置列表  (3)

可以提供一个位置列表：

Wolfram Language code: AirTemperatureData[{"KSAC", Entity["Building", "EmpireStateBuilding"], {40.11, -88.24}}]

计算多个位置在指定时间的插值气温：

Wolfram Language code: AirTemperatureData[{"KSAC", Entity["Building", "EmpireStateBuilding"], {40.11, -88.24}}, DateObject[{2012, 6, 17, 17, 0, 0.}]]

计算多个位置和日期的气温：

Wolfram Language code: AirTemperatureData[{{"KCMI", DateObject[{2008, 8, 4, 12}]}, {"KSAC", DateObject[{2008, 8, 4, 2}]}, {"KISP", DateObject[{2012, 6, 6, 13}]}}]

格式指定  (2)

求扩展位置的气温：

Wolfram Language code: AirTemperatureData[GeoDisk[{40, -90}, Quantity[25, "Miles"]], DateObject[{2008, 8, 4, 12}]]

获取最高或最低记录温度：

Wolfram Language code: AirTemperatureData[GeoDisk[{40, -90}, Quantity[25, "Miles"]], DateObject[{2008, 8, 4, 12}], Max]
Wolfram Language code: AirTemperatureData[GeoDisk[{40, -90}, Quantity[25, "Miles"]], DateObject[{2008, 8, 4, 12}], Min]

使用设置 Mean 获得平均温度：

Wolfram Language code: AirTemperatureData[GeoDisk[{40, -90}, Quantity[25, "Miles"]], DateObject[{2008, 8, 4, 12}], Mean]

返回所有显示值的气象站：

Wolfram Language code: AirTemperatureData[GeoDisk[{39.11, -99.24}, Quantity[100, "Kilometers"]], DateObject[{2011, 6, 14, 12, 30, 0.}], "Stations"]

关联规范  (2)

日期和位置可以使用 Association 一起指定：

Wolfram Language code: AirTemperatureData[Association["Location" -> GeoPosition[{45, -90}], "Date" -> DateObject[{2000, 1, 1}]]]

Association 规范适用于格式参数：

Wolfram Language code: AirTemperatureData[Association["Location" -> GeoPosition[{45, -90}], "Date" -> DateObject[{2000, 1, 1}]], Mean]

选项  (2)

UnitSystem  (2)

默认情况下，结果使用由 $UnitSystem 给出的格式：

Wolfram Language code: $UnitSystem

设置 UnitSystem 为 "Imperial"，以指定华氏度：

Wolfram Language code: AirTemperatureData[UnitSystem -> "Imperial"]

或者设置 UnitSystem 为 "Metric" ，以指定摄氏度：

Wolfram Language code: AirTemperatureData[UnitSystem -> "Metric"]

UnitConvert 也可以用来调整单位：

Wolfram Language code: UnitConvert[N@AirTemperatureData[], "Kelvins"]

应用  (4)

南美洲首府城市的近期温度测量：

Wolfram Language code: Grid[SortBy[{#, AirTemperatureData[#]}& /@ (CountryData[#, "CapitalCity"]& /@ CountryData["SouthAmerica"]), Last], Frame -> All]

求美国阿拉斯加的安克雷奇100英里范围内最冷的当前温度测量：

Wolfram Language code: coordinates = CityData[Entity["City", {"Anchorage", "Alaska", "UnitedStates"}], "Coordinates"]; stations = DeleteDuplicates[AirTemperatureData[GeoDisk[coordinates, Quantity[100, "Miles"]], "StationName"]];
Wolfram Language code: First@SortBy[Quiet[DeleteCases[{#, AirTemperatureData[#]}& /@ stations, {_, Missing[_] | _AirTemperatureData}]], Last]

求沿西经90度的气象站：

Wolfram Language code: data = DeleteDuplicates[Table[WeatherData[{i, -90}], {i, 30, 48, 0.1}]]; data = {WeatherData[#, "Coordinates"], Quiet[AirTemperatureData[#, DateObject[{2012, 8, 4, 12}]]]}& /@ data;
Wolfram Language code: WeatherData["KNEW", "Coordinates"]

观察中午的插值温度，作为纬度的函数：

Wolfram Language code: ListPlot[{#[[1, 1]], #[[2]]}& /@ data, PlotRange -> All]

求威尼斯某一天的温度测量分布：

Wolfram Language code: data = Flatten[Table[AirTemperatureData[{45.43, 12.33}, {{i, 6, 20}, {i, 6, 20}}, UnitSystem -> "Metric"]["ValueList"], {i, 1993, 2012}]];
Wolfram Language code: Histogram[data, {1}]

属性和关系  (4)

默认情况下，位置由 $GeoLocation 指定：

Wolfram Language code: AirTemperatureData[]
Wolfram Language code: AirTemperatureData[$GeoLocation]

IconData 适用于 AirTemperatureData 的输出：

Wolfram Language code: IconData["AirTemperature", AirTemperatureData[]]

使用 GeoGraphics 和 IconData 显示德国一组城市的当地温度：

Wolfram Language code: cities = {["Berlin"], ["Hamburg"], ["Munich"], ["Cologne"], ["Frankfurt"], ["Stuttgart"], ["Dortmund"], ["Bremen"], ["Dresden"], ["Hanover"], ["Nuremberg"]};
Wolfram Language code: data = {CityData[#, "Coordinates"], CityData[#, "Name"], AirTemperatureData[#]}& /@ cities;
Wolfram Language code: GeoGraphics[{GeoStyling["ReliefMap"], EdgeForm[Thin], Opacity[0.5], Polygon[Entity["Country", "Germany"]], PointSize[Large], Opacity[1], {Black, Text[#[[2]], GeoPosition[#[[1]]], {-1.5, 0}], Red, Point[GeoPosition[#[[1]]]], Inset[IconData["AirTemperature", #[[3]]], GeoPosition[#[[1]]], Bottom, 1]}& /@ data}, RasterSize -> 200]

用 GeoEntities 求一个区域上的所有气象站：

Wolfram Language code: stations = GeoEntities[["Delaware"], "WeatherStation"]

求在所有气象站的温度：

Wolfram Language code: AirTemperatureData /@ stations

巧妙范例  (3)

根据在科罗拉多州主要城市的近期气压和温度计算声速：

Wolfram Language code: Grid[SortBy[{#, ThermodynamicData["Air", "SoundSpeed", {"Temperature" -> AirTemperatureData[#], "Pressure" -> AirPressureData[#]}]}& /@ CityData[{Large, "Colorado", "UnitedStates"}], Last], Frame -> All]

检查阿尔卑斯山内气象站的温度和海拔的相关性：

Wolfram Language code: stations = WeatherData[{{"Davos", "Graubunden", "Switzerland"}, 100}];
Wolfram Language code: ListPlot[Tooltip[{AirTemperatureData[#], AirTemperatureData[#, "Elevation"]}, #]& /@ stations, Frame -> True, Axes -> False, FrameLabel -> {Quantity[None, "Celsius"], Quantity[None, "Meters"]}]

求一年的过程中温度的变化：

Wolfram Language code: data = Table[{DatePlus[DateObject[{2012, 1, 1}], i], AirTemperatureData["KCMI", First@DatePlus[DateObject[{2012, 1, 1}], i], Interval]}, {i, 0, 364}];
Wolfram Language code: data = {DateList[First[#]], First[Differences@@#[[2, 1]]]}& /@ data;

求逐月的平均温度变化：

Wolfram Language code: averages = {#[[1, 1, ;; 2]], Mean[#[[All, 2]]]}& /@ GatherBy[data, #[[1, 2]]&];
Wolfram Language code: BarChart[averages[[All, 2]], ChartLabels -> averages[[All, 1, 2]]]

得到最大温度变化发生在冬季而不是夏季，如平均值：

Wolfram Language code: pos = Position[data, Max[data[[All, 2]]]]; data[[pos[[1, 1]]]]

在此基础上，看看这一年逐日气温变化的方差如何改变：

Wolfram Language code: variance = {#[[1, 1, ;; 2]], Variance[#[[All, 2]]]}& /@ GatherBy[data, #[[1, 2]]&];
Wolfram Language code: BarChart[variance[[All, 2]], ChartLabels -> variance[[All, 1, 2]]]
Wolfram Research (2014)，AirTemperatureData，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AirTemperatureData.html.

文本

Wolfram Research (2014)，AirTemperatureData，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AirTemperatureData.html.

CMS

Wolfram 语言. 2014. "AirTemperatureData." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/AirTemperatureData.html.

APA

Wolfram 语言. (2014). AirTemperatureData. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/AirTemperatureData.html 年

BibTeX

@misc{reference.wolfram_2026_airtemperaturedata, author="Wolfram Research", title="{AirTemperatureData}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/AirTemperatureData.html}", note=[Accessed: 11-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_airtemperaturedata, organization={Wolfram Research}, title={AirTemperatureData}, year={2014}, url={https://reference.wolfram.com/language/ref/AirTemperatureData.html}, note=[Accessed: 11-September-2026]}