WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

AiryAi[z]

エアリー(Airy)関数 TemplateBox[{z}, AiryAi]を計算する．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
数値評価  
特定の値  
可視化  
Show More Show More
関数の特性  
微分  
積分  
級数展開  
積分変換  
関数の恒等式と簡約  
関数表現  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

AiryAi

AiryAi[z]

エアリー(Airy)関数 TemplateBox[{z}, AiryAi]を計算する．

詳細

  • 記号と数値のどちらの操作にも適した数学関数である．
  • TemplateBox[{z}, AiryAi]は，微分方程式 の解である．
  • TemplateBox[{z}, AiryAi]は，のときゼロに収束する．
  • AiryAi[z]は不連続な分枝切断線を持たない z に関する整関数である．
  • 特別な引数の場合，AiryAiは自動的に厳密値を計算する．
  • AiryAiは任意の数値精度で評価することができる．
  • AiryAiは自動的にリストに並列的な関数の適用を行う．
  • AiryAiはIntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる． »

例題

すべて開く すべて閉じる

例  (5)

数値的に評価する：

Wolfram Language code: AiryAi[1.8]

実数の部分集合上でプロットする：

Wolfram Language code: Plot[AiryAi[x], {x, -10, 10}]

複素数の部分集合上でプロットする：

Wolfram Language code: ComplexPlot3D[AiryAi[z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

原点における級数展開：

Wolfram Language code: Series[AiryAi[x], {x, 0, 4}]

Infinityにおける級数展開：

Wolfram Language code: Series[AiryAi[x], {x, ∞, 2}]//Normal

スコープ  (42)

数値評価  (5)

高精度で評価する：

Wolfram Language code: N[AiryAi[2], 50]

出力の精度は入力の精度に従う：

Wolfram Language code: AiryAi[2.00000000000000000000000]

複素引数について評価する：

Wolfram Language code: AiryAi[2.5 + I]

高精度で効率的にAiryAiを評価する：

Wolfram Language code: AiryAi[0.5`500]//Timing
Wolfram Language code: AiryAi[0.5`5000];//Timing

IntervalオブジェクトとCenteredIntervalオブジェクトを使って最悪の場合に保証される区間を計算する：

Wolfram Language code: AiryAi[Interval[{1.9, 2}]]
Wolfram Language code: AiryAi[CenteredInterval[2, 0.1]]

Aroundを使って平均的な場合の統計区間を計算することもできる：

Wolfram Language code: AiryAi[ Around[2, 0.01]]

配列の要素ごとの値を計算する：

Wolfram Language code: AiryAi[{{-1.2, 0}, {0, 1.}}]

MatrixFunctionを使って行列のAiryAi関数を計算することもできる：

Wolfram Language code: MatrixFunction[AiryAi, {{-1.2, 0}, {0, 1.}}]

特定の値  (4)

簡単な厳密値は自動的に生成される：

Wolfram Language code: AiryAi[0]

無限大における極限値：

Wolfram Language code: {Limit[AiryAi[x], x -> Infinity], Limit[AiryAi[x], x -> -Infinity]}

最初の3つの零点：

Wolfram Language code: {AiryAiZero[1], AiryAiZero[2], AiryAiZero[3]}//N

Solveを使ってAiryAiの零点を求める：

Wolfram Language code: xzero = Solve[AiryAi[x] == 0 && -4 < x < -2, x][[1, 1, 2]]
Wolfram Language code: Plot[AiryAi[x], {x, -5, 3}, Epilog -> Style[Point[{xzero, AiryAi[xzero]}], PointSize[Large], Red]]

可視化  (2)

AiryAi関数をプロットする：

Wolfram Language code: Plot[AiryAi[x], {x, -7, 3}]

TemplateBox[{z}, AiryAi]の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[AiryAi[z]], {z, -4 - 4I, 4 + 4I}, Contours -> 20]

TemplateBox[{z}, AiryAi]の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[AiryAi[z]], {z, -4 - 4I, 4 + 4I}, Contours -> 20]

関数の特性  (9)

AiryAiは，すべての実数値と虚数値について定義される：

Wolfram Language code: FunctionDomain[AiryAi[x], x]
Wolfram Language code: FunctionDomain[AiryAi[z], z, Complexes]

AiryAiの関数範囲を近似する：

Wolfram Language code: FunctionRange[AiryAi[x], x, y]//N

AiryAiは x の解析関数である：

Wolfram Language code: FunctionAnalytic[AiryAi[x], x]

AiryAiは非増加でも非減少でもない：

Wolfram Language code: FunctionMonotonicity[AiryAi[x], x]

AiryAiは単射ではない：

Wolfram Language code: FunctionInjective[AiryAi[x], x]
Wolfram Language code: Plot[{AiryAi[x], .3}, {x, -10, 5}]

AiryAiは全射ではない：

Wolfram Language code: FunctionSurjective[AiryAi[x], x]
Wolfram Language code: Plot[{AiryAi[x], 1}, {x, -20, 20}]

AiryAiは非負でも非正でもない：

Wolfram Language code: FunctionSign[AiryAi[x], x]

AiryAiは特異点も不連続点も持たない：

Wolfram Language code: FunctionSingularities[AiryAi[x], x]
Wolfram Language code: FunctionDiscontinuities[AiryAi[x], x]

AiryAiは凸でも凹でもない：

Wolfram Language code: FunctionConvexity[AiryAi[x], x]

微分  (3)

一次導関数：

Wolfram Language code: D[AiryAi[x], x]

高次導関数：

Wolfram Language code: Table[D[AiryAi[x], {x, n}], {n, 1, 4}]
Wolfram Language code: Plot[Evaluate[%], {x, -1, 1}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

次導関数の式：

Wolfram Language code: D[AiryAi[x], {x, n}]

積分  (3)

AiryAiの不定積分：

Wolfram Language code: Integrate[AiryAi[x], x]//FullSimplify

不定積分を証明する：

Wolfram Language code: FullSimplify[D[%, x]]

AiryAiの定積分：

Wolfram Language code: Integrate[AiryAi[x], {x, -Infinity, 0}]

その他の積分例：

Wolfram Language code: ∫ z^αAiryAi[z]^2ⅆz//TraditionalForm
Wolfram Language code: ∫z^2 AiryAi[z] AiryBi[z]ⅆz//FullSimplify//TraditionalForm

級数展開  (5)

AiryAiのテイラー(Taylor)展開：

Wolfram Language code: Series[AiryAi[x], {x, 0, 7}]

の周りのAiryAiの最初の3つの近似をプロットする：

Wolfram Language code: terms = Normal@Table[Series[AiryAi[x], {x, 0, m}], {m, 1, 5, 2}]; Plot[{AiryAi[x], terms}, {x, -2, 2}]

AiryAiの級数展開における一般項：

Wolfram Language code: SeriesCoefficient[AiryAi[x], {x, 0, n}]

無限大で級数展開を求める：

Wolfram Language code: Series[AiryAi[x], {x, Infinity, 3}]

任意の記号方向 についての無限大における級数展開を求める：

Wolfram Language code: Series[AiryAi[x], {x, DirectedInfinity[z], 1}, Assumptions -> x > 0]

AiryAiはベキ級数に適用できる：

Wolfram Language code: AiryAi[x + (x^2/2) + (x^3/9) + O[x]^4]

積分変換  (3)

FourierTransformを使ってフーリエ(Fourier)変換を計算する：

Wolfram Language code: FourierTransform[AiryAi[t], t, ω]

MellinTransform：

Wolfram Language code: MellinTransform[AiryAi[x], x, s]

HankelTransform：

Wolfram Language code: HankelTransform[AiryAi[r], r, s ]

関数の恒等式と簡約  (3)

式を簡約してAiryAiにする：

Wolfram Language code: (Hypergeometric0F1[(2/3), (z^3/9)]/3^2 / 3 Gamma[(2/3)]) - (z Hypergeometric0F1[(4/3), (z^3/9)]/3^1 / 3 Gamma[(1/3)])//FullSimplify

FunctionExpandはAiryAiの引数を簡約しようとする：

Wolfram Language code: FunctionExpand[AiryAi[z E^(2 π I/3)]]//Simplify
Wolfram Language code: FunctionExpand[AiryAi[(z^3)^1 / 3]]

関数の恒等式：

Wolfram Language code: AiryAi[z] + E^(2 π I/3) AiryAi[z E^(2 π I/3)] + E^-(2 π I/3) AiryAi[z E^-(2 π I/3)]//FullSimplify

関数表現  (5)

実引数の積分表現：

Wolfram Language code: (1/π)Integrate[Cos[t ^ 3 / 3 + x t], {t, 0, Infinity}, Assumptions -> x∈Reals]

ベッセル(Bessel)関数表現：

Wolfram Language code: AiryAi[z] == (1/3) ((z^3 / 2)^1 / 3 BesselI[-(1/3), (2 z^3 / 2/3)] - z (z^3 / 2)^-(1/3) BesselI[(1/3), (2 z^3 / 2/3)])//FullSimplify

AiryAiはDifferentialRootとして表現することができる：

Wolfram Language code: DifferentialRootReduce[AiryAi[x], x]

AiryAiはMeijerGについて表現することができる：

Wolfram Language code: MeijerGReduce[AiryAi[x], x]
Wolfram Language code: Activate[%]//FullSimplify

TraditionalFormによる表示：

Wolfram Language code: AiryAi[z]//TraditionalForm

アプリケーション  (4)

例えば均一電場のような線形ポテンシャルにおけるシュレーディンガー(Schrödinger)方程式を解く：

Wolfram Language code: DSolve[-ψ''[x] + x ψ[x] == ε ψ[x], ψ[x], x]

複素平面における絶対値をプロットする：

Wolfram Language code: Plot3D[Abs[AiryAi[x + I y]], {x, -5, 5}, {y, -1, 1}]

AiryAiの平方のネストした積分：

Wolfram Language code: NestList[Integrate[#, z]&, AiryAi[z] ^ 2, 4]//Simplify//TraditionalForm

Map–Airy分布[MathWorld]の確率密度を，AiryAi関数およびAiryAiPrime関数で表される閉じた形で計算する：

Wolfram Language code: pdf = PDF[StableDistribution[1, 3 / 2, -1, 0, 18^-1 / 3], x]//Simplify
Wolfram Language code: Plot[pdf, {x, -5, 5}, PlotRange -> All, Filling -> Axis]

最頻値（モード）の位置を求める：

Wolfram Language code: FindMaximum[pdf, x]

特性と関係  (8)

FullSimplifyを使って，エアリー方程式を含む式を簡約する：

Wolfram Language code: Det[Outer[D[#1, {x, #2}]&, {AiryAi[x], AiryBi[x]}, {0, 1}]]
Wolfram Language code: FullSimplify[%]

Wronskianの出力と比較する：

Wolfram Language code: Wronskian[{AiryAi[x], AiryBi[x]}, x]

FunctionExpandはAiryAiの引数を簡約しようとする：

Wolfram Language code: FunctionExpand[AiryAi[z E^(2 π I/3)]]//Simplify

エアリー微分方程式を解く：

Wolfram Language code: DSolve[w''[z] == z w[z], w[z], z]
Wolfram Language code: DSolve[w'''[z] - 4z w'[z] - 2w[z] == 0, w[z], z]

数値根を求める：

Wolfram Language code: FindRoot[AiryAi[z] == 0, {z, -2}]

組込み関数AiryAiZeroと比較する：

Wolfram Language code: AiryAiZero[1]//N

積分：

Wolfram Language code: ∫ AiryAi[z]ⅆz//FunctionExpand//TraditionalForm

反導関数を証明する：

Wolfram Language code: FullSimplify[D[%, z]]

積分変換：

Wolfram Language code: FourierTransform[AiryAi[t], t, s]

AiryAiはDifferentialRootとして表すことができる：

Wolfram Language code: DifferentialRootReduce[AiryAi[x], x]

AiryAiはMeijerGによって表すことができる：

Wolfram Language code: MeijerGReduce[AiryAi[x], x]
Wolfram Language code: Activate[%]//FullSimplify

考えられる問題  (5)

機械精度は正確な解を求めるのには不十分である：

Wolfram Language code: AiryAi[-10. ^ 12]

代りに任意精度の評価を使う：

Wolfram Language code: N[AiryAi[-10 ^ 12 ], 10]

$MaxExtraPrecisionの設定値を大きくする必要があるかもしれない：

Wolfram Language code: N[AiryAi[-10 ^ 100], 20]
Wolfram Language code: Block[{$MaxExtraPrecision = 200}, N[AiryAi[-10 ^ 100], 20]]

機械数による入力を使うと高精度の結果が得られる：

Wolfram Language code: AiryAi[150.I]
Wolfram Language code: MachineNumberQ[%]

簡約は複素平面の一部にしか当て嵌らないこともある：

Wolfram Language code: FullSimplify[(Sqrt[(z/3)] BesselK[(1/3), (2 z^3 / 2/3)]/π) , z > 0]
Wolfram Language code: {(Sqrt[(z/3)] BesselK[(1/3), (2 z^3 / 2/3)]/π), AiryAi[z]} /. z -> -2.

慣用形では丸カッコが必要になる：

Wolfram Language code: Ai x
Wolfram Language code: Ai(x)

おもしろい例題  (1)

AiryAi関数の線形結合から生成された，ビブラートのかかった音を生成する：

Wolfram Language code: Play[Clip[AiryAi[300 (t - 1)] + AiryAi[298 (t - 1)], {-1, 1}], {t, 0, 1}, PlayRange -> {-0.5, 0.5}]
Wolfram Research (1988), AiryAi, Wolfram言語関数， https://reference.wolfram.com/language/ref/AiryAi.html （2022年に更新）.

テキスト

Wolfram Research (1988), AiryAi, Wolfram言語関数， https://reference.wolfram.com/language/ref/AiryAi.html （2022年に更新）.

CMS

Wolfram Language. 1988. "AiryAi." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2022. https://reference.wolfram.com/language/ref/AiryAi.html.

APA

Wolfram Language. (1988). AiryAi. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/AiryAi.html

BibTeX

@misc{reference.wolfram_2026_airyai, author="Wolfram Research", title="{AiryAi}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/AiryAi.html}", note=[Accessed: 14-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_airyai, organization={Wolfram Research}, title={AiryAi}, year={2022}, url={https://reference.wolfram.com/language/ref/AiryAi.html}, note=[Accessed: 14-August-2026]}