WOLFRAM

Wolfram 语言与系统参考资料中心

AiryAi[z]

给出 Airy 函数 TemplateBox[{z}, AiryAi].

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
数值计算  
特殊值  
可视化  
Show More Show More
函数属性  
微分  
积分  
级数展开式  
积分转换  
函数恒等式和化简  
函数表示  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

AiryAi

AiryAi[z]

给出 Airy 函数 TemplateBox[{z}, AiryAi].

更多信息

  • 数学函数，适宜于符号和数值运算.
  • Airy 函数 TemplateBox[{z}, AiryAi] 是微分方程 的解.
  • 当 时，TemplateBox[{z}, AiryAi] 趋近于 0.
  • AiryAi[z] 是 z 的整函数，不存在分支切割.
  • 对于某些特殊参数，AiryAi 自动计算出精确值.
  • AiryAi 能够以任意数值精度进行计算.
  • AiryAi 自动逐项作用于列表的各个元素.
  • AiryAi 可与 Interval 和 CenteredInterval 对象一起使用. »

范例

打开所有单元 关闭所有单元

基本范例  (5)

数值运算：

Wolfram Language code: AiryAi[1.8]

在实数的子集上绘图：

Wolfram Language code: Plot[AiryAi[x], {x, -10, 10}]

在复数的子集上绘图：

Wolfram Language code: ComplexPlot3D[AiryAi[z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

在原点的级数展开：

Wolfram Language code: Series[AiryAi[x], {x, 0, 4}]

在 Infinity 的级数展开：

Wolfram Language code: Series[AiryAi[x], {x, ∞, 2}]//Normal

范围  (42)

数值计算  (5)

高精度数值计算：

Wolfram Language code: N[AiryAi[2], 50]

输出与输入的精度保持一致：

Wolfram Language code: AiryAi[2.00000000000000000000000]

对复变量求值：

Wolfram Language code: AiryAi[2.5 + I]

在高精度条件下高效计算 AiryAi：

Wolfram Language code: AiryAi[0.5`500]//Timing
Wolfram Language code: AiryAi[0.5`5000];//Timing

用 Interval 和 CenteredInterval 对象计算最坏情况下的区间：

Wolfram Language code: AiryAi[Interval[{1.9, 2}]]
Wolfram Language code: AiryAi[CenteredInterval[2, 0.1]]

或用 Around 计算一般情况下的统计区间：

Wolfram Language code: AiryAi[ Around[2, 0.01]]

计算数组中每个元素的值：

Wolfram Language code: AiryAi[{{-1.2, 0}, {0, 1.}}]

或用 MatrixFunction 计算矩阵形式的 AiryAi 函数：

Wolfram Language code: MatrixFunction[AiryAi, {{-1.2, 0}, {0, 1.}}]

特殊值  (4)

自动生成简单精确值：

Wolfram Language code: AiryAi[0]

无穷处的极限值：

Wolfram Language code: {Limit[AiryAi[x], x -> Infinity], Limit[AiryAi[x], x -> -Infinity]}

前三个零点：

Wolfram Language code: {AiryAiZero[1], AiryAiZero[2], AiryAiZero[3]}//N

用 Solve 求 AiryAi 的零点：

Wolfram Language code: xzero = Solve[AiryAi[x] == 0 && -4 < x < -2, x][[1, 1, 2]]
Wolfram Language code: Plot[AiryAi[x], {x, -5, 3}, Epilog -> Style[Point[{xzero, AiryAi[xzero]}], PointSize[Large], Red]]

可视化  (2)

绘制 AiryAi 函数：

Wolfram Language code: Plot[AiryAi[x], {x, -7, 3}]

绘制 TemplateBox[{z}, AiryAi] 的实部：

Wolfram Language code: ComplexContourPlot[Re[AiryAi[z]], {z, -4 - 4I, 4 + 4I}, Contours -> 20]

绘制 TemplateBox[{z}, AiryAi] 的虚部：

Wolfram Language code: ComplexContourPlot[Im[AiryAi[z]], {z, -4 - 4I, 4 + 4I}, Contours -> 20]

函数属性  (9)

AiryAi 是针对所有实数和复数定义的：

Wolfram Language code: FunctionDomain[AiryAi[x], x]
Wolfram Language code: FunctionDomain[AiryAi[z], z, Complexes]

AiryAi 函数的近似范围：

Wolfram Language code: FunctionRange[AiryAi[x], x, y]//N

AiryAi 是 x 的解析函数：

Wolfram Language code: FunctionAnalytic[AiryAi[x], x]

AiryAi 既不是非递增，也不是非递减：

Wolfram Language code: FunctionMonotonicity[AiryAi[x], x]

AiryAi 不是单射函数：

Wolfram Language code: FunctionInjective[AiryAi[x], x]
Wolfram Language code: Plot[{AiryAi[x], .3}, {x, -10, 5}]

AiryAi 不是满射函数：

Wolfram Language code: FunctionSurjective[AiryAi[x], x]
Wolfram Language code: Plot[{AiryAi[x], 1}, {x, -20, 20}]

AiryAi 既不是非负，也不是非正：

Wolfram Language code: FunctionSign[AiryAi[x], x]

AiryAi 没有奇点或断点：

Wolfram Language code: FunctionSingularities[AiryAi[x], x]
Wolfram Language code: FunctionDiscontinuities[AiryAi[x], x]

AiryAi 既不凸，也不凹：

Wolfram Language code: FunctionConvexity[AiryAi[x], x]

微分  (3)

一阶导数：

Wolfram Language code: D[AiryAi[x], x]

高阶导数：

Wolfram Language code: Table[D[AiryAi[x], {x, n}], {n, 1, 4}]
Wolfram Language code: Plot[Evaluate[%], {x, -1, 1}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

阶导数的公式：

Wolfram Language code: D[AiryAi[x], {x, n}]

积分  (3)

AiryAi 函数的不定积分：

Wolfram Language code: Integrate[AiryAi[x], x]//FullSimplify

验证反导数：

Wolfram Language code: FullSimplify[D[%, x]]

AiryAi 函数的定积分：

Wolfram Language code: Integrate[AiryAi[x], {x, -Infinity, 0}]

更多积分：

Wolfram Language code: ∫ z^αAiryAi[z]^2ⅆz//TraditionalForm
Wolfram Language code: ∫z^2 AiryAi[z] AiryBi[z]ⅆz//FullSimplify//TraditionalForm

级数展开式  (5)

AiryAi 的泰勒展开式：

Wolfram Language code: Series[AiryAi[x], {x, 0, 7}]

绘制 AiryAi 在 处的前三个近似式：

Wolfram Language code: terms = Normal@Table[Series[AiryAi[x], {x, 0, m}], {m, 1, 5, 2}]; Plot[{AiryAi[x], terms}, {x, -2, 2}]

AiryAi 级数展开式的通项:

Wolfram Language code: SeriesCoefficient[AiryAi[x], {x, 0, n}]

求在无穷处的级数展开式：

Wolfram Language code: Series[AiryAi[x], {x, Infinity, 3}]

求任意符号方向 上无穷处的级数展开式：

Wolfram Language code: Series[AiryAi[x], {x, DirectedInfinity[z], 1}, Assumptions -> x > 0]

AiryAi 可被应用于幂级数：

Wolfram Language code: AiryAi[x + (x^2/2) + (x^3/9) + O[x]^4]

积分转换  (3)

用 FourierTransform 计算傅立叶变换：

Wolfram Language code: FourierTransform[AiryAi[t], t, ω]

MellinTransform:

Wolfram Language code: MellinTransform[AiryAi[x], x, s]

HankelTransform:

Wolfram Language code: HankelTransform[AiryAi[r], r, s ]

函数恒等式和化简  (3)

把表达式化简为 AiryAi：

Wolfram Language code: (Hypergeometric0F1[(2/3), (z^3/9)]/3^2 / 3 Gamma[(2/3)]) - (z Hypergeometric0F1[(4/3), (z^3/9)]/3^1 / 3 Gamma[(1/3)])//FullSimplify

用 FunctionExpand 简化 AiryAi 的参数：

Wolfram Language code: FunctionExpand[AiryAi[z E^(2 π I/3)]]//Simplify
Wolfram Language code: FunctionExpand[AiryAi[(z^3)^1 / 3]]

函数恒等式：

Wolfram Language code: AiryAi[z] + E^(2 π I/3) AiryAi[z E^(2 π I/3)] + E^-(2 π I/3) AiryAi[z E^-(2 π I/3)]//FullSimplify

函数表示  (5)

实参数的积分表示：

Wolfram Language code: (1/π)Integrate[Cos[t ^ 3 / 3 + x t], {t, 0, Infinity}, Assumptions -> x∈Reals]

与贝塞尔函数的关系：

Wolfram Language code: AiryAi[z] == (1/3) ((z^3 / 2)^1 / 3 BesselI[-(1/3), (2 z^3 / 2/3)] - z (z^3 / 2)^-(1/3) BesselI[(1/3), (2 z^3 / 2/3)])//FullSimplify

可用 DifferentialRoot 表示 AiryAi：

Wolfram Language code: DifferentialRootReduce[AiryAi[x], x]

可用 MeijerG 表示 AiryAi：

Wolfram Language code: MeijerGReduce[AiryAi[x], x]
Wolfram Language code: Activate[%]//FullSimplify

TraditionalForm 格式输出：

Wolfram Language code: AiryAi[z]//TraditionalForm

应用  (4)

求解一个线性电位（例如均匀电场）的薛定谔方程：

Wolfram Language code: DSolve[-ψ''[x] + x ψ[x] == ε ψ[x], ψ[x], x]

在一个复平面中标绘绝对值：

Wolfram Language code: Plot3D[Abs[AiryAi[x + I y]], {x, -5, 5}, {y, -1, 1}]

AiryAi 平方的嵌套积分：

Wolfram Language code: NestList[Integrate[#, z]&, AiryAi[z] ^ 2, 4]//Simplify//TraditionalForm

计算封闭形式的 Map–Airy 分布 [MathWorld] 的概率密度，用 AiryAi 和 AiryAiPrime 函数表示：

Wolfram Language code: pdf = PDF[StableDistribution[1, 3 / 2, -1, 0, 18^-1 / 3], x]//Simplify
Wolfram Language code: Plot[pdf, {x, -5, 5}, PlotRange -> All, Filling -> Axis]

求众数的位置：

Wolfram Language code: FindMaximum[pdf, x]

属性和关系  (8)

利用 FullSimplify 简化包含 Airy 函数的表达式：

Wolfram Language code: Det[Outer[D[#1, {x, #2}]&, {AiryAi[x], AiryBi[x]}, {0, 1}]]
Wolfram Language code: FullSimplify[%]

与 Wronskian 的输出进行比较：

Wolfram Language code: Wronskian[{AiryAi[x], AiryBi[x]}, x]

FunctionExpand 力求简化 AiryAi 的自变量：

Wolfram Language code: FunctionExpand[AiryAi[z E^(2 π I/3)]]//Simplify

求解 Airy 微分方程：

Wolfram Language code: DSolve[w''[z] == z w[z], w[z], z]
Wolfram Language code: DSolve[w'''[z] - 4z w'[z] - 2w[z] == 0, w[z], z]

求出一个数值根：

Wolfram Language code: FindRoot[AiryAi[z] == 0, {z, -2}]

与嵌入函数 AiryAiZero 进行比较：

Wolfram Language code: AiryAiZero[1]//N

积分：

Wolfram Language code: ∫ AiryAi[z]ⅆz//FunctionExpand//TraditionalForm

检验反导数：

Wolfram Language code: FullSimplify[D[%, z]]

积分变换：

Wolfram Language code: FourierTransform[AiryAi[t], t, s]

AiryAi 可表示成为一个 DifferentialRoot：

Wolfram Language code: DifferentialRootReduce[AiryAi[x], x]

AiryAi 可以用 MeijerG 来表示：

Wolfram Language code: MeijerGReduce[AiryAi[x], x]
Wolfram Language code: Activate[%]//FullSimplify

可能存在的问题  (5)

机器精度输入不足以获得正确答案：

Wolfram Language code: AiryAi[-10. ^ 12]

采用任意精度计算：

Wolfram Language code: N[AiryAi[-10 ^ 12 ], 10]

$MaxExtraPrecision 可能需要用较大的数值设置：

Wolfram Language code: N[AiryAi[-10 ^ 100], 20]
Wolfram Language code: Block[{$MaxExtraPrecision = 200}, N[AiryAi[-10 ^ 100], 20]]

机器数输入可以给出高精度结果：

Wolfram Language code: AiryAi[150.I]
Wolfram Language code: MachineNumberQ[%]

化简有时只限于部分复平面：

Wolfram Language code: FullSimplify[(Sqrt[(z/3)] BesselK[(1/3), (2 z^3 / 2/3)]/π) , z > 0]
Wolfram Language code: {(Sqrt[(z/3)] BesselK[(1/3), (2 z^3 / 2/3)]/π), AiryAi[z]} /. z -> -2.

以传统形式输入时需要圆括号：

Wolfram Language code: Ai x
Wolfram Language code: Ai(x)

巧妙范例  (1)

播放由 AiryAi 函数的线性组合制成的颤音：

Wolfram Language code: Play[Clip[AiryAi[300 (t - 1)] + AiryAi[298 (t - 1)], {-1, 1}], {t, 0, 1}, PlayRange -> {-0.5, 0.5}]
Wolfram Research (1988)，AiryAi，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AiryAi.html （更新于 2022 年）.

文本

Wolfram Research (1988)，AiryAi，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AiryAi.html （更新于 2022 年）.

CMS

Wolfram 语言. 1988. "AiryAi." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2022. https://reference.wolfram.com/language/ref/AiryAi.html.

APA

Wolfram 语言. (1988). AiryAi. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/AiryAi.html 年

BibTeX

@misc{reference.wolfram_2026_airyai, author="Wolfram Research", title="{AiryAi}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/AiryAi.html}", note=[Accessed: 15-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_airyai, organization={Wolfram Research}, title={AiryAi}, year={2022}, url={https://reference.wolfram.com/language/ref/AiryAi.html}, note=[Accessed: 15-August-2026]}