WOLFRAM

Wolfram 语言与系统参考资料中心

AiryAiPrime[z]

给出 Airy 函数的导数 .

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
数值计算  
特殊值  
可视化  
Show More Show More
函数属性  
微分  
积分  
级数展开式  
积分变换  
函数恒等式和化简  
函数表示  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

AiryAiPrime

AiryAiPrime[z]

给出 Airy 函数的导数 .

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (5)

数值运算：

Wolfram Language code: AiryAiPrime[0.5]

在实数的子集上绘图：

Wolfram Language code: Plot[AiryAiPrime[x], {x, -10, 10}]

在复数的子集上绘图：

Wolfram Language code: ComplexPlot3D[AiryAiPrime[z], {z, -8 - I, 5 + I}, PlotLegends -> Automatic]

在原点的级数展开：

Wolfram Language code: Series[AiryAiPrime[x], {x, 0, 4}]

在 Infinity 的级数展开：

Wolfram Language code: Series[AiryAiPrime[x], {x, ∞, 2}]

范围  (40)

数值计算  (5)

高精度数值计算：

Wolfram Language code: N[AiryAiPrime[5 / 2], 50]

输出精度与输入精度一致：

Wolfram Language code: AiryAiPrime[2.50000000000000000000000]

对复变量求值：

Wolfram Language code: AiryAiPrime[2.5 + I]

在高精度条件下高效计算 AiryAiPrime：

Wolfram Language code: AiryAiPrime[0.5`500]//Timing
Wolfram Language code: AiryAiPrime[0.5`2000];//Timing

用 Interval 和 CenteredInterval 对象计算最坏情况下的区间：

Wolfram Language code: AiryAiPrime[Interval[{1.9, 2}]]
Wolfram Language code: AiryAiPrime[CenteredInterval[2, 0.1]]

或用 Around 计算一般情况下的统计区间：

Wolfram Language code: AiryBiPrime[ Around[2, 0.01]]

计算数组中每个元素的值：

Wolfram Language code: AiryBiPrime[{{-1.2, 0}, {0, 1.}}]

或用 MatrixFunction 计算矩阵形式的 AiryBiPrime 函数：

Wolfram Language code: MatrixFunction[AiryBiPrime, {{-1.2, 0}, {0, 1.}}]

特殊值  (3)

自动生成简单精确值：

Wolfram Language code: AiryAiPrime[0]

无穷处的极限值：

Wolfram Language code: Limit[AiryAiPrime[x], x -> Infinity]

用 Solve 求 AiryAiPrime 的零点：

Wolfram Language code: xzero = N@Solve[AiryAiPrime[x] == 0 && -4 < x < -2, x][[1, 1, 2]]//Quiet
Wolfram Language code: Plot[AiryAiPrime[x], {x, -5, 3}, Epilog -> Style[Point[{xzero, AiryAiPrime[xzero]}], PointSize[Large], Red]]

可视化  (3)

绘制 AiryAiPrime 函数：

Wolfram Language code: Plot[AiryAiPrime[x], {x, -7, 3}]

绘制 TemplateBox[{z}, AiryAiPrime] 的实部：

Wolfram Language code: ComplexContourPlot[Re[AiryAiPrime[z]], {z, -4 - 4I, 4 + 4I}, Contours -> 20]

绘制 TemplateBox[{z}, AiryAiPrime] 的虚部：

Wolfram Language code: ComplexContourPlot[Im[AiryAiPrime[z]], {z, -4 - 4I, 4 + 4I}, Contours -> 20]

复平面上标绘 AiryAiPrime 的绝对值：

Wolfram Language code: Plot3D[Abs[AiryAiPrime[x + I y]], {x, -8, 5}, {y, -1, 1}, ClippingStyle -> None]

函数属性  (9)

AiryAiPrime 是针对所有实数和复数定义的：

Wolfram Language code: FunctionDomain[AiryAiPrime[x], x]
Wolfram Language code: FunctionDomain[AiryAiPrime[z], z, Complexes]

AiryAiPrime 函数的范围：

Wolfram Language code: FunctionRange[AiryAiPrime[x], x, y]

AiryAiPrime 是 x 的解析函数：

Wolfram Language code: FunctionAnalytic[AiryAiPrime[x], x]

AiryAiPrime 既不是非递增，也不是非递减：

Wolfram Language code: FunctionMonotonicity[AiryAiPrime[x], x]

AiryAiPrime 不是单射函数：

Wolfram Language code: FunctionInjective[AiryAiPrime[x], x]
Wolfram Language code: Plot[{AiryAiPrime[x], .3}, {x, -10, 5}]

AiryAiPrime 是满射函数：

Wolfram Language code: FunctionSurjective[AiryAiPrime[x], x]
Wolfram Language code: Plot[{AiryAiPrime[x], -1.5}, {x, -50, 5}]

AiryAiPrime 既不是非负，也不是非正：

Wolfram Language code: FunctionSign[AiryAiPrime[x], x]

AiryAiPrime 没有奇点或断点：

Wolfram Language code: FunctionSingularities[AiryAiPrime[x], x]
Wolfram Language code: FunctionDiscontinuities[AiryAiPrime[x], x]

AiryAiPrime 既不凸，也不凹：

Wolfram Language code: FunctionConvexity[AiryAiPrime[x], x]

微分  (3)

一阶导数：

Wolfram Language code: D[AiryAiPrime[x], x]

高阶导数：

Wolfram Language code: Table[D[AiryAiPrime[x], {x, n}], {n, 1, 4}]
Wolfram Language code: Plot[Evaluate[%], {x, -1, 1}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

阶导数的公式：

Wolfram Language code: D[AiryAiPrime[x], {x, n}]

积分  (3)

AiryAiPrime 的积分返回 AiryAi：

Wolfram Language code: Integrate[AiryAiPrime[x], x]

AiryAiPrime 的定积分：

Wolfram Language code: Integrate[AiryAiPrime[x], {x, 0, Infinity}]

更多积分：

Wolfram Language code: Integrate[x ^ a AiryAiPrime[x] ^ 2, x]
Wolfram Language code: Integrate[AiryAi[a x]AiryAiPrime[a x], x]

级数展开式  (4)

AiryAiPrime 的泰勒展开式：

Wolfram Language code: Series[AiryAiPrime[x], {x, 0, 7}]

绘制 AiryAiPrime 在 处的前三个近似式：

Wolfram Language code: terms = Normal@{Series[AiryAiPrime[x], {x, 0, 2}], Series[AiryAiPrime[x], {x, 0, 3}], Series[AiryAiPrime[x], {x, 0, 5}]}; Plot[{AiryAiPrime[x], terms}, {x, -2, 2}]

AiryAiPrime 级数展开式的通项:

Wolfram Language code: SeriesCoefficient[AiryAiPrime[x], {x, 0, n}]

求无穷处的级数展开式：

Wolfram Language code: Series[AiryAiPrime[x], {x, Infinity, 3}]

在负无穷处的级数展开式非常不同：

Wolfram Language code: Series[AiryAiPrime[x], {x, -Infinity, 1}]

AiryAiPrime 可应用于幂级数：

Wolfram Language code: AiryAiPrime[Log[1 + x] + O[x] ^ 4]

积分变换  (3)

用 FourierTransform 计算傅立叶变换：

Wolfram Language code: FourierTransform[AiryAiPrime[t], t, ω]

MellinTransform:

Wolfram Language code: MellinTransform[AiryAiPrime[x], x, s]

HankelTransform:

Wolfram Language code: HankelTransform[AiryAiPrime[r], r, s ]

函数恒等式和化简  (3)

函数恒等式：

Wolfram Language code: AiryAiPrime[z] + E^(2 I π/3) AiryAiPrime[E^-(2 I π/3) z] + E^-(2 I π/3) AiryAiPrime[E^(2 I π/3) z]//FullSimplify

把表达式化简为 AiryAiPrime：

Wolfram Language code: (z^2 Hypergeometric0F1[(5/3), (z^3/9)]/2 3^2 / 3 Gamma[(2/3)]) - ( Hypergeometric0F1[(1/3), (z^3/9)]/3^1 / 3 Gamma[(1/3)])//FullSimplify

FunctionExpand 试图简化 AiryAiPrime 的参数：

Wolfram Language code: FunctionExpand [AiryAiPrime[z Exp[2Pi I / 3]]]//Simplify
Wolfram Language code: FunctionExpand[AiryAiPrime[(z^3)^1 / 3]]

函数表示  (4)

与贝塞尔函数的关系：

Wolfram Language code: AiryAiPrime[z] == (1/3) (z^2 (z^3 / 2)^-(2/3) BesselI[(2/3), (2 z^3 / 2/3)] - (z^3 / 2)^2 / 3 BesselI[-(2/3), (2 z^3 / 2/3)])//FullSimplify

AiryAiPrime 可用 DifferentialRoot 来表示：

Wolfram Language code: DifferentialRootReduce[AiryAiPrime[x], x]

AiryAiPrime 也可用 MeijerG 来表示：

Wolfram Language code: MeijerGReduce[AiryAiPrime[x], x]
Wolfram Language code: Activate[%]//FullSimplify

TraditionalForm 格式输出：

Wolfram Language code: AiryAiPrime[z]//TraditionalForm

应用  (4)

以 AiryAiPrime 的形式解微分方程：

Wolfram Language code: DSolve[-9 z ^ 2 w[z] + 9 z ^ 5 w[z] - 15 w'[z] + 20 z ^ 3 w'[z] + 15 z w''[z] - 10 z ^ 4 w''[z] - 6 z ^ 2 w'''[z] + z ^ 3 w''''[z] == 0, w[z], z]

线性锥形位势中的定常薛定谔方程解：

Wolfram Language code: DSolve[{-ψ''[z] + Piecewise[{{z, z > 0}, {-z, z < 0}}] ψ[z] == ε ψ[z], ψ[0] == 1, ψ'[0] == 0}, ψ[z], z]

由 AiryAiPrime 零点确定可规范化状态：

Wolfram Language code: b[n_] := x /. FindRoot[AiryAiPrime[x], {x, -(3Pi / 8(Max[0, 4n - 1])) ^ (2 / 3), -(3Pi / 8(4n + 3)) ^ (2 / 3)}]
Wolfram Language code: ψ[n_, x_] := 1 / Sqrt[-b[n]] / AiryAi[b[n]]AiryAi[Sqrt[x ^ 2] + b[n]]

绘制可规范化状态：

Wolfram Language code: Plot[Evaluate[Prepend[Table[-b[n] + ψ[n, x], {n, 0, 12}], Abs[x]]], {x, -16, 16}, Frame -> True, Axes -> False]

与高斯酉系综（GUE）有关的积分核：

Wolfram Language code: ContourPlot[(AiryAi[x] AiryAiPrime[y] - AiryAiPrime[x] AiryAi[y]) / (x - y), {x, -5, 2}, {y, -5.5, 2}, Exclusions -> None]

卷积积分对任意函数 求解修正线性 Korteweg–deVries方程：

Wolfram Language code: u[x_, t_] := (3 t) ^ (-2 / 3) Integrate[AiryAiPrime[(x - y) (3 t) ^ (-1 / 3)] f[y], {y, -Infinity, Infinity}]

验证解：

Wolfram Language code: D[u[x, t], t, x] + D[u[x, t], x, x, x, x] //. α_. Integrate[a_, i_] + β_. Integrate[b_, i_] :> Integrate[α a + β b, i]

属性和关系  (5)

利用 FullSimplify 化简 Airy 函数，这里在 Airy 方程的 Wronskian 中：

Wolfram Language code: Det[Outer[D[#1, {x, #2}]&, {AiryAi[x], AiryBi[x]}, {0, 1}]]
Wolfram Language code: FullSimplify[%]

与 Wronskian 的输出进行比较：

Wolfram Language code: Wronskian[{AiryAi[x], AiryBi[x]}, x]

FunctionExpand 力求化简 AiryAiPrime 的自变量：

Wolfram Language code: FunctionExpand [AiryAiPrime[z Exp[2Pi I / 3]]]//Simplify

由 DSolve 的解生成 Airy 函数：

Wolfram Language code: DSolve[z w''[z] - w'[z] - z ^ 2w[z] == 0, w[z], z]

由各项和得到 AiryAiPrime：

Wolfram Language code: -(1 /3^1 / 3 Gamma[(1/3)])Underoverscript[∑, k = 0, ∞](1/Pochhammer[(1/3), k] k!)((z^3/9))^k + (z^2 /2 3^2 / 3 Gamma[(2/3)])Underoverscript[∑, k = 0, ∞](1/Pochhammer[(5/3), k] k!)((z^3/9))^k//FullSimplify

AiryAiPrime 出现在一些数学函数特例中：

Wolfram Language code: { (z^2 Hypergeometric0F1[(5/3), (z^3/9)]/2 3^2 / 3 Gamma[(2/3)]) - ( Hypergeometric0F1[(1/3), (z^3/9)]/3^1 / 3 Gamma[(1/3)]), MeijerG[{{}, {}}, {{0, (2/3)}, {}}, 3^-2 / 3 z, (1/3)]}//FullSimplify

可能存在的问题  (3)

输入的机器精度不足以得到正确解：

Wolfram Language code: AiryAiPrime[-10. ^ 12 ]

代之以任意精度计算：

Wolfram Language code: N[AiryAiPrime[-10 ^ 12 ], 10]

需要对 $MaxExtraPrecision 设置较大的值：

Wolfram Language code: N[AiryAiPrime[-10 ^ 100], 20]
Wolfram Language code: Block[{$MaxExtraPrecision = 200}, N[AiryAiPrime[-10 ^ 100], 20]]

机器数输入能给出高精度结果：

Wolfram Language code: AiryAiPrime[150.I]
Wolfram Language code: MachineNumberQ[%]

巧妙范例  (1)

AiryAiPrime 平方的嵌套积分：

Wolfram Language code: NestList[Integrate[#, z]&, AiryAiPrime[z] ^ 2, 4]//Simplify//TraditionalForm
Wolfram Research (1991)，AiryAiPrime，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AiryAiPrime.html （更新于 2022 年）.

文本

Wolfram Research (1991)，AiryAiPrime，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AiryAiPrime.html （更新于 2022 年）.

CMS

Wolfram 语言. 1991. "AiryAiPrime." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2022. https://reference.wolfram.com/language/ref/AiryAiPrime.html.

APA

Wolfram 语言. (1991). AiryAiPrime. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/AiryAiPrime.html 年

BibTeX

@misc{reference.wolfram_2026_airyaiprime, author="Wolfram Research", title="{AiryAiPrime}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/AiryAiPrime.html}", note=[Accessed: 17-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_airyaiprime, organization={Wolfram Research}, title={AiryAiPrime}, year={2022}, url={https://reference.wolfram.com/language/ref/AiryAiPrime.html}, note=[Accessed: 17-August-2026]}