WOLFRAM

Wolfram 语言与系统参考资料中心

AiryBi[z]

给出 Airy 函数 TemplateBox[{z}, AiryBi].

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
数值计算  
特殊值  
可视化  
Show More Show More
函数属性  
微分  
积分  
级数展开式  
积分变换  
函数恒等式和化简  
函数表示  
应用  
属性和关系  
可能存在的问题  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

AiryBi

AiryBi[z]

给出 Airy 函数 TemplateBox[{z}, AiryBi].

更多信息

  • 数学函数，适用于符号和数值运算.
  • Airy 函数 TemplateBox[{z}, AiryBi] 是微分方程 的解.
  • 随 ，TemplateBox[{z}, AiryBi] 呈指数增加.
  • AiryBi[z] 是定义域为整个 z 平面的解析函数，不存在分支线.
  • 对于一些特殊的自变量，AiryBi 自动运算出精确值.
  • AiryBi 可用于求解任意数值精度的值.
  • AiryBi 自动线性作用于列表.
  • AiryBi 可与 Interval 和 CenteredInterval 对象一起使用. »

范例

打开所有单元 关闭所有单元

基本范例  (5)

数值运算：

Wolfram Language code: AiryBi[1.8]

在实数的子集上绘图：

Wolfram Language code: Plot[AiryBi[x], {x, -10, 3}]

在复数的子集上绘图：

Wolfram Language code: ComplexPlot3D[AiryBi[z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

在原点的级数展开：

Wolfram Language code: Series[AiryBi[x], {x, 0, 4}]

在 Infinity 的级数展开：

Wolfram Language code: Series[AiryBi[x], {x, ∞, 2}]//Normal

范围  (40)

数值计算  (5)

高精度数值计算：

Wolfram Language code: N[AiryBi[2], 50]

输出精度与输入精度一致：

Wolfram Language code: AiryBi[2.00000000000000000000000]

对复变量求值：

Wolfram Language code: AiryBi[2.5 + I]

在高精度条件下高效计算 AiryBi：

Wolfram Language code: AiryBi[0.5`500]//Timing
Wolfram Language code: AiryBi[0.5`5000];//Timing

用 Interval 和 CenteredInterval 对象计算最坏情况下的区间：

Wolfram Language code: AiryBi[Interval[{1.9, 2}]]
Wolfram Language code: AiryBi[CenteredInterval[2, 0.1]]

或用 Around 计算一般情况下的统计区间：

Wolfram Language code: AiryBi[ Around[2, 0.01]]

计算数组中每个元素的值：

Wolfram Language code: AiryBi[{{-1.2, 0}, {0, 1.}}]

或用 MatrixFunction 计算矩阵形式的 AiryBi 函数：

Wolfram Language code: MatrixFunction[AiryBi, {{-1.2, 0}, {0, 1.}}]

特殊值  (4)

自动生成简单精确值：

Wolfram Language code: AiryBi[0]

无穷处的极限值：

Wolfram Language code: {Limit[AiryBi[x], x -> Infinity], Limit[AiryBi[x], x -> -Infinity]}

前三个零点：

Wolfram Language code: {AiryBiZero[1], AiryBiZero[2], AiryBiZero[3]}//N

用 Solve 求 AiryBi 的零点：

Wolfram Language code: xzero = Solve[AiryBi[x] == 0 && -4 < x < -2, x][[1, 1, 2]]
Wolfram Language code: Plot[AiryBi[x], {x, -4, 1}, Epilog -> Style[Point[{xzero, AiryBi[xzero]}], PointSize[Large], Red]]

可视化  (2)

绘制 AiryBi 函数：

Wolfram Language code: Plot[AiryBi[x], {x, -8, 3}]

绘制 TemplateBox[{z}, AiryBi] 的实部：

Wolfram Language code: ComplexContourPlot[Re[AiryBi[z]], {z, -4 - 4I, 4 + 4I}, Contours -> 20]

绘制 TemplateBox[{z}, AiryBi] 的虚部：

Wolfram Language code: ComplexContourPlot[Im[AiryBi[z]], {z, -4 - 4I, 4 + 4I}, Contours -> 20]

函数属性  (9)

AiryBi 是针对所有实数和复数定义的：

Wolfram Language code: FunctionDomain[AiryBi[x], x]
Wolfram Language code: FunctionDomain[AiryBi[z], z, Complexes]

AiryBi 函数的近似范围：

Wolfram Language code: FunctionRange[AiryBi[x], x, y]//N

AiryBi 是 x 的解析函数：

Wolfram Language code: FunctionAnalytic[AiryBi[x], x]

AiryBi 既不是非递增，也不是非递减：

Wolfram Language code: FunctionMonotonicity[AiryBi[x], x]

AiryBi 不是单射函数：

Wolfram Language code: FunctionInjective[AiryBi[x], x]
Wolfram Language code: Plot[{AiryBi[x], .3}, {x, -10, 5}]

AiryBi 不是满射函数：

Wolfram Language code: FunctionSurjective[AiryBi[x], x]
Wolfram Language code: Plot[{AiryBi[x], -2}, {x, -10, 5}]

AiryBi 既不是非负，也不是非正：

Wolfram Language code: FunctionSign[AiryBi[x], x]

AiryBi 没有奇点或断点：

Wolfram Language code: FunctionSingularities[AiryBi[x], x]
Wolfram Language code: FunctionDiscontinuities[AiryBi[x], x]

AiryBi 既不凸，也不凹：

Wolfram Language code: FunctionConvexity[AiryBi[x], x]

微分  (3)

一阶导数：

Wolfram Language code: D[AiryBi[x], x]

高阶导数：

Wolfram Language code: Table[D[AiryBi[x], {x, n}], {n, 1, 4}]
Wolfram Language code: Plot[Evaluate[%], {x, -1, 1}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

阶导数的公式：

Wolfram Language code: D[AiryBi[x], {x, n}]

积分  (3)

AiryBi 函数的不定积分：

Wolfram Language code: Integrate[AiryBi[x], x]//FullSimplify

AiryBi 函数的定积分：

Wolfram Language code: Integrate[AiryBi[x], {x, -Infinity, 0}]

更多积分：

Wolfram Language code: ∫ z^αAiryBi[z]^2ⅆz//TraditionalForm
Wolfram Language code: ∫z^2 AiryAi[z] AiryBi[z]ⅆz//FullSimplify//TraditionalForm

级数展开式  (5)

AiryBi 的泰勒展开式：

Wolfram Language code: Series[AiryBi[x], {x, 0, 7}]

绘制 AiryBi 在 处的前三个近似式：

Wolfram Language code: terms = Normal@Table[Series[AiryBi[x], {x, 0, m}], {m, 1, 5, 2}]; Plot[{AiryBi[x], terms}, {x, -2, 2}]

AiryBi 级数展开式的通项:

Wolfram Language code: SeriesCoefficient[AiryBi[x], {x, 0, n}]

求在无穷处的级数展开式：

Wolfram Language code: Series[AiryBi[x], {x, Infinity, 5}]
Wolfram Language code: Series[AiryBi[x], {x, -Infinity, 2}]

求任意符号方向 上无穷远处的级数展开式：

Wolfram Language code: Series[AiryBi[x], {x, DirectedInfinity[z], 1}]//Normal

AiryBi 能被应用于幂级数：

Wolfram Language code: AiryBi[x + (x^2/2) + (x^3/9) + O[x]^4]

积分变换  (2)

用 FourierCosTransform 计算傅立叶变换：

Wolfram Language code: FourierCosTransform[AiryBi[-t], t, ω]//TraditionalForm

HankelTransform:

Wolfram Language code: HankelTransform[AiryBi[r], r, s ]

函数恒等式和化简  (3)

把表达式化简为 AiryBi：

Wolfram Language code: (Hypergeometric0F1[(2/3), (z^3/9)]/3^1 / 6 Gamma[(2/3)]) + (3^1 / 6 z Hypergeometric0F1[(4/3), (z^3/9)]/Gamma[(1/3)])//FullSimplify

FunctionExpand 试图简化 AiryBi 的参数：

Wolfram Language code: FunctionExpand[AiryBi[z E^(2 π I/3)] ]// Simplify
Wolfram Language code: FunctionExpand[AiryBi[(z^3)^1 / 3]]

函数恒等式：

Wolfram Language code: AiryBi[z] + E^(2 π I/3) AiryBi[z E^(2 π I/3)] + E^-(2 π I/3) AiryBi[z E^-(2 π I/3)]//FullSimplify

函数表示  (4)

与贝塞尔函数的关系：

Wolfram Language code: AiryBi[z] == (1/Sqrt[3])((z^3 / 2)^1 / 3 BesselI[-(1/3), (2 z^3 / 2/3)] + z (z^3 / 2)^-(1/3) BesselI[(1/3), (2 z^3 / 2/3)])//FullSimplify

可用 DifferentialRoot 来表示 AiryBi：

Wolfram Language code: DifferentialRootReduce[AiryBi[x], x]

也可用 MeijerG 来表示 AiryBi：

Wolfram Language code: MeijerGReduce[AiryBi[x], x]
Wolfram Language code: Activate[%]//FullSimplify

TraditionalForm 格式输出：

Wolfram Language code: AiryBi[z]//TraditionalForm

应用  (2)

在线性位势中求解薛定谔方程（如均衡电场）：

Wolfram Language code: DSolve[-ψ''[x] + x ψ[x] == ε ψ[x], ψ[x], x]

检验组合 Airy 函数的萨默菲尔德辐射条件：

Wolfram Language code: Series[AiryBi[z] - I AiryAi[z], {z, -∞, 2}]

只有一个外向平面波：

Wolfram Language code: Simplify[Normal[%]//TrigToExp]

属性和关系  (5)

这里，在 Airy 方程的朗斯基行列式中，用 FullSimplify 简化 Airy 函数：

Wolfram Language code: Det[Outer[D[#1, {x, #2}]&, {AiryAi[x], AiryBi[x]}, {0, 1}]]
Wolfram Language code: FullSimplify[%]

与 Wronskian 的输出相比：

Wolfram Language code: Wronskian[{AiryAi[x], AiryBi[x]}, x]

FunctionExpand 简化 AiryBi 的自变量：

Wolfram Language code: FunctionExpand[AiryBi[z E^(2 π I/3)] ]// Simplify

由微分方程生成 Airy 函数：

Wolfram Language code: DSolve[w''[z] == z w[z], w[z], z]
Wolfram Language code: DSolve[w'''[z] - 4z w'[z] - 2w[z] == 0, w[z], z]

获得一个数值根：

Wolfram Language code: FindRoot[AiryBi[z] == 0, {z, -2}]

与内置函数 AiryBiZero 相比：

Wolfram Language code: AiryBiZero[1]//N

积分：

Wolfram Language code: ∫ z^αAiryBi[z]^2ⅆz//TraditionalForm
Wolfram Language code: ∫z^2 AiryAi[z] AiryBi[z]ⅆz//FullSimplify//TraditionalForm

可能存在的问题  (5)

输入的机器精度不足以得到正确解：

Wolfram Language code: AiryBi[-10. ^ 12 ]

代之以任意精度计算：

Wolfram Language code: N[AiryBi[-10 ^ 12 ], 10]

需要对 $MaxExtraPrecision 进行较大的设置：

Wolfram Language code: N[AiryBi[-10 ^ 100], 20]
Wolfram Language code: Block[{$MaxExtraPrecision = 200}, N[AiryBi[-10 ^ 100], 20]]

机器数输入能给出高精度解：

Wolfram Language code: AiryBi[10. ^ 3]
Wolfram Language code: MachineNumberQ[%]

有时候只有部分复平面能够简化：

Wolfram Language code: FullSimplify[Sqrt[-(z/3)] (BesselJ[-(1/3), (2/3) (-z)^3 / 2] - BesselJ[(1/3), (2/3) (-z)^3 / 2]), z < 0]
Wolfram Language code: {Sqrt[-(z/3)] (BesselJ[-(1/3), (2/3) (-z)^3 / 2] - BesselJ[(1/3), (2/3) (-z)^3 / 2]), AiryBi[z]} /. z -> 2.

传统形式需要用圆括号进行正确分析：

Wolfram Language code: Bi x
Wolfram Language code: Bi(x)
Wolfram Research (1991)，AiryBi，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AiryBi.html （更新于 2022 年）.

文本

Wolfram Research (1991)，AiryBi，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AiryBi.html （更新于 2022 年）.

CMS

Wolfram 语言. 1991. "AiryBi." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2022. https://reference.wolfram.com/language/ref/AiryBi.html.

APA

Wolfram 语言. (1991). AiryBi. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/AiryBi.html 年

BibTeX

@misc{reference.wolfram_2026_airybi, author="Wolfram Research", title="{AiryBi}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/AiryBi.html}", note=[Accessed: 06-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_airybi, organization={Wolfram Research}, title={AiryBi}, year={2022}, url={https://reference.wolfram.com/language/ref/AiryBi.html}, note=[Accessed: 06-September-2026]}