WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

AiryBiPrime[z]

エアリー関数の導関数を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
数値評価  
特定の値  
可視化  
Show More Show More
関数の特性  
微分  
積分  
級数展開  
積分変換  
関数の恒等式と簡約  
関数表現  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

AiryBiPrime

AiryBiPrime[z]

エアリー関数の導関数を与える．

詳細

  • 記号操作・数値操作の両方に適した数学関数である．
  • 特別な引数の場合，AiryBiPrimeは，自動的に厳密値を計算する．
  • AiryBiPrimeは任意の数値精度で評価できる．
  • AiryBiPrimeは自動的にリストに縫い込まれる．
  • AiryBiPrimeはIntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる． »

例題

すべて開く すべて閉じる

例  (5)

数値的に評価する：

Wolfram Language code: AiryBiPrime[1.8]

実数の部分集合上でプロットする：

Wolfram Language code: Plot[AiryBiPrime[x], {x, -10, 2}]

複素数の部分集合上でプロットする：

Wolfram Language code: ComplexPlot3D[AiryBiPrime[z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

原点における級数開：

Wolfram Language code: Series[AiryBiPrime[x], {x, 0, 5}]

Infinityにおける級数展開：

Wolfram Language code: Series[AiryBiPrime[x], {x, ∞, 2}]//Normal

スコープ  (38)

数値評価  (5)

高精度で数値評価する：

Wolfram Language code: N[AiryBiPrime[5 / 2], 50]

出力精度は入力精度に従う：

Wolfram Language code: AiryBiPrime[2.50000000000000000000000]

複素引数について評価する：

Wolfram Language code: AiryBiPrime[2.5 + I]

AiryBiPrimeを高精度で効率的に評価する：

Wolfram Language code: AiryBiPrime[0.5`500]//Timing
Wolfram Language code: AiryBiPrime[0.5`5000];//Timing

IntervalオブジェクトとCenteredIntervalオブジェクトを使って最悪の場合に保証される区間を計算する：

Wolfram Language code: AiryBiPrime[Interval[{1.9, 2}]]
Wolfram Language code: AiryBiPrime[CenteredInterval[1, 0.1]]

Aroundを使って平均的な場合の統計区間を計算することもできる：

Wolfram Language code: AiryBiPrime[ Around[2, 0.01]]

配列の要素ごとの値を計算する：

Wolfram Language code: AiryBiPrime[{{-1.2, 0}, {0, 1.}}]

MatrixFunctionを使って行列のAiryBiPrime関数を計算することもできる：

Wolfram Language code: MatrixFunction[AiryBiPrime, {{-1.2, 0}, {0, 1.}}]

特定の値  (3)

簡単な厳密値は自動的に生成される：

Wolfram Language code: AiryBiPrime[0]

無限大における極限値：

Wolfram Language code: Limit[AiryBiPrime[x], x -> Infinity]

Solveを使ってAiryBiPrimeの零点を求める：

Wolfram Language code: xzero = N@Solve[AiryBiPrime[x] == 0 && -3 < x < -2, x][[1, 1, 2]]//Quiet
Wolfram Language code: Plot[AiryBiPrime[x], {x, -5, 2}, Epilog -> Style[Point[{xzero, AiryBiPrime[xzero]}], PointSize[Large], Red]]

可視化  (2)

AiryBiPrime関数をプロットする：

Wolfram Language code: Plot[AiryBiPrime[x], {x, -6, 2}]

TemplateBox[{z}, AiryBiPrime]の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[AiryBiPrime[z]], {z, -4 - 4I, 4 + 4I}, Contours -> 20]

TemplateBox[{z}, AiryBiPrime]の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[AiryBiPrime[z]], {z, -4 - 4I, 4 + 4I}, Contours -> 20]

関数の特性  (9)

AiryBiPrimeは，すべての実数と複素数の値について定義される：

Wolfram Language code: FunctionDomain[AiryBiPrime[x], x]
Wolfram Language code: FunctionDomain[AiryBiPrime[z], z, Complexes]

AiryBiPrime関数の値域：

Wolfram Language code: FunctionRange[AiryBiPrime[x], x, y]

AiryBiPrimeは x の解析関数である：

Wolfram Language code: FunctionAnalytic[AiryBiPrime[x], x]

AiryBiPrimeは非増加でも非減少でもない：

Wolfram Language code: FunctionMonotonicity[AiryBiPrime[x], x]

AiryBiPrimeは単射ではない：

Wolfram Language code: FunctionInjective[AiryBiPrime[x], x]
Wolfram Language code: Plot[{AiryBiPrime[x], .3}, {x, -10, 5}]

AiryBiPrimeは全射である：

Wolfram Language code: FunctionSurjective[AiryBiPrime[x], x]
Wolfram Language code: Plot[{AiryBiPrime[x], -1.5}, {x, -50, 5}]

AiryBiPrimeは非負でも非正でもない：

Wolfram Language code: FunctionSign[AiryBiPrime[x], x]

AiryBiPrimeは特異点も不連続点も持たない：

Wolfram Language code: FunctionSingularities[AiryBiPrime[x], x]
Wolfram Language code: FunctionDiscontinuities[AiryBiPrime[x], x]

AiryBiPrimeは凸でも凹でもない：

Wolfram Language code: FunctionConvexity[AiryBiPrime[x], x]

微分  (3)

一次導関数：

Wolfram Language code: D[AiryBiPrime[x], x]

高次導関数：

Wolfram Language code: Table[D[AiryBiPrime[x], {x, n}], {n, 1, 4}]
Wolfram Language code: Plot[Evaluate[%], {x, -1, 1}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

次導関数の式：

Wolfram Language code: D[AiryBiPrime[x], {x, n}]

積分  (3)

AiryBiPrimeの不定積分はAiryBiを返す：

Wolfram Language code: Integrate[AiryBiPrime[x], x]

AiryBiPrimeの定積分：

Wolfram Language code: Integrate[AiryBiPrime[x], {x, -Infinity, 0}]

その他の積分例：

Wolfram Language code: Integrate[AiryBi[a x]AiryBiPrime[a x], x]
Wolfram Language code: Integrate[x ^ a AiryBiPrime[x] ^ 2, x]//TraditionalForm

級数展開  (4)

AiryBiPrimeのテイラー(Taylor)展開：

Wolfram Language code: Series[AiryBiPrime[x], {x, 0, 7}]

の周りのAiryBiPrimeについての最初の3つの近似をプロットする：

Wolfram Language code: terms = Normal@{Series[AiryBiPrime[x], {x, 0, 2}], Series[AiryBiPrime[x], {x, 0, 3}], Series[AiryBiPrime[x], {x, 0, 5}]}; Plot[{AiryBiPrime[x], terms}, {x, -2, 2}]

AiryBiPrimeの級数展開における一般項：

Wolfram Language code: SeriesCoefficient[AiryBiPrime[x], {x, 0, n}]

無限大における級数展開を求める：

Wolfram Language code: Series[AiryBiPrime[x], {x, Infinity, 3}]

負の無限大における動作は非常に異なる：

Wolfram Language code: Series[AiryBiPrime[x], {x, -Infinity, 1}]

AiryBiPrimeはベキ級数に適用できる：

Wolfram Language code: AiryBiPrime[Log[1 + x] + O[x] ^ 4]

積分変換  (2)

FourierCosTransformを使ってフーリエ(Fourier)余弦変換を計算する：

Wolfram Language code: FourierCosTransform[AiryBiPrime[-t], t, s]//TraditionalForm

HankelTransform：

Wolfram Language code: HankelTransform[AiryBiPrime[r], r, s ]

関数の恒等式と簡約  (3)

関数の恒等式：

Wolfram Language code: AiryBiPrime[z] + E^(2 I π/3) AiryBiPrime[E^-(2 I π/3) z] + E^-(2 I π/3) AiryBiPrime[E^(2 I π/3) z]//FullSimplify

式を簡約してAiryBiPrimeにする：

Wolfram Language code: (z^2 Hypergeometric0F1[(5/3), (z^3/9)]/2 3^1 / 6 Gamma[(2/3)]) + (3^1 / 6 Hypergeometric0F1[(1/3), (z^3/9)]/ Gamma[(1/3)])//FullSimplify

FunctionExpandはAiryBiPrimeの引数を簡約しようとする：

Wolfram Language code: FunctionExpand [AiryBiPrime[z Exp[2Pi I / 3]]] // Simplify
Wolfram Language code: FunctionExpand[AiryBiPrime[(z^3)^1 / 3]]

関数表現  (4)

ベッセル(Bessel)関数との関係：

Wolfram Language code: (1/Sqrt[3])(z^2(z^3 / 2)^-(2/3) BesselI[(2/3), (2 z^3 / 2/3)] + (z^3 / 2)^2 / 3 BesselI[-(2/3), (2 z^3 / 2/3)])//FullSimplify

AiryBiPrimeはDifferentialRootとして表現できる：

Wolfram Language code: DifferentialRootReduce[AiryBiPrime[x], x]

MeijerGReduceを使ってMeijerGについて表現する：

Wolfram Language code: MeijerGReduce[AiryBiPrime[x], x]
Wolfram Language code: Activate[%]//FullSimplify

TraditionalFormによる表示：

Wolfram Language code: AiryBiPrime[z]//TraditionalForm

アプリケーション  (3)

微分方程式をAiryBiPrimeについて解く：

Wolfram Language code: DSolve[-9 z ^ 2 w[z] + 9 z ^ 5 w[z] - 15 w'[z] + 20 z ^ 3 w'[z] + 15 z w''[z] - 10 z ^ 4 w''[z] - 6 z ^ 2 w'''[z] + z ^ 3 w''''[z] == 0, w, z]

任意の関数 についての修正線形Korteweg–deVries方程式の解：

Wolfram Language code: u[x_, t_] := (3 t) ^ (-2 / 3) Integrate[AiryBiPrime[(x - y) (3 t) ^ (-1 / 3)] f[y], {y, -Infinity, Infinity}]

解を検証する：

Wolfram Language code: D[u[x, t], t, x] + D[u[x, t], x, x, x, x] //. α_.Integrate[a_, i_] + β_.Integrate[b_, i_] :> Integrate[α a + β b, i]

AiryAiPrimeとAiryBiPrimeで表された線形円錐ポテンシャルの中の時間非依存シュレディンガー(Schrödinger)方程式の解：

Wolfram Language code: DSolve[{-ψ''[z] + Piecewise[{{z, z > 0}, {-z, z < 0}}] ψ[z] == ε ψ[z], ψ[0] == 1, ψ'[0] == 0}, ψ[z], z]

正規化可能な状態はAiryAiPrimeの零点を介して決定される：

Wolfram Language code: b[n_] := x /. FindRoot[AiryAiPrime[x], {x, -(3Pi / 8(Max[0, 4n - 1])) ^ (2 / 3), -(3Pi / 8(4n + 3)) ^ (2 / 3)}]
Wolfram Language code: ψ[n_, x_] := 1 / Sqrt[-b[n]] / AiryAi[b[n]]AiryAi[Sqrt[x ^ 2] + b[n]]

正規化可能な状態をプロットする：

Wolfram Language code: Plot[Evaluate[Prepend[Table[-b[n] + ψ[n, x], {n, 0, 12}], Abs[x]]], {x, -16, 16}, Frame -> True, Axes -> False]

特性と関係  (5)

FullSimplifyを用いてエアリー関数を，ここではエアリー方程式のWronskian中で，簡約する：

Wolfram Language code: Det[Outer[D[#1, {x, #2}]&, {AiryAi[x], AiryBi[x]}, {0, 1}]]
Wolfram Language code: FullSimplify[%]

Wronskianの出力と比較する：

Wolfram Language code: Wronskian[{AiryAi[x], AiryBi[x]}, x]

微分方程式からエアリー関数を生成する：

Wolfram Language code: DSolve[z w''[z] - w'[z] - z ^ 2w[z] == 0, w, z]

積分変換：

Wolfram Language code: FourierCosTransform[AiryBiPrime[-t], t, s]//TraditionalForm

総和からAiryBiPrimeを求める：

Wolfram Language code: (3^1 / 6 /Gamma[(1/3)])Underoverscript[∑, k = 0, ∞](1/Pochhammer[(1/3), k] k!)((z^3/9))^k + (z^2 /2 3^1 / 6 Gamma[(2/3)])Underoverscript[∑, k = 0, ∞](1/Pochhammer[(5/3), k] k!)((z^3/9))^k//FullSimplify

AiryBiPrimeはいくつかの数学関数の特殊形に現れる：

Wolfram Language code: {(z^2 Hypergeometric0F1[(5/3), (z^3/9)]/2 3^1 / 6 Gamma[(2/3)]) + (3^1 / 6 Hypergeometric0F1[(1/3), (z^3/9)]/ Gamma[(1/3)]), MeijerG[{{}, {-(1/6), (1/3)}}, {{0, (2/3)}, {-(1/6), (1/3)}}, 3^-2 / 3 z, (1/3)]}//FunctionExpand

考えられる問題  (3)

正しい答を得るのには機械精度の入力では不十分である：

Wolfram Language code: AiryBiPrime[-10. ^ 12 ]

代りに任意精度の評価を使う：

Wolfram Language code: N[AiryBiPrime[-10 ^ 12 ], 10]

$MaxExtraPrecisionの設定値を大きくする必要があるかもしれない：

Wolfram Language code: N[AiryBiPrime[-10 ^ 100], 20]
Wolfram Language code: Block[{$MaxExtraPrecision = 200}, N[AiryBiPrime[-10 ^ 100], 20]]

機械精度入力が高精度の結果を返すことがある：

Wolfram Language code: AiryBiPrime[10. ^ 3]
Wolfram Language code: MachineNumberQ[%]

おもしろい例題  (1)

AiryBiPrimeの二乗のネストした積分：

Wolfram Language code: NestList[Integrate[#, z]&, AiryBiPrime[z] ^ 2, 4]//Simplify//TraditionalForm
Wolfram Research (1991), AiryBiPrime, Wolfram言語関数， https://reference.wolfram.com/language/ref/AiryBiPrime.html （2022年に更新）.

テキスト

Wolfram Research (1991), AiryBiPrime, Wolfram言語関数， https://reference.wolfram.com/language/ref/AiryBiPrime.html （2022年に更新）.

CMS

Wolfram Language. 1991. "AiryBiPrime." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2022. https://reference.wolfram.com/language/ref/AiryBiPrime.html.

APA

Wolfram Language. (1991). AiryBiPrime. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/AiryBiPrime.html

BibTeX

@misc{reference.wolfram_2026_airybiprime, author="Wolfram Research", title="{AiryBiPrime}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/AiryBiPrime.html}", note=[Accessed: 13-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_airybiprime, organization={Wolfram Research}, title={AiryBiPrime}, year={2022}, url={https://reference.wolfram.com/language/ref/AiryBiPrime.html}, note=[Accessed: 13-September-2026]}