WOLFRAM

Wolfram 语言与系统参考资料中心

AiryBiPrime[z]

给出 Airy 函数的导数 .

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
数值计算  
特殊值  
可视化  
Show More Show More
函数属性  
微分  
积分  
级数展开式  
积分变换  
函数恒等式和化简  
函数表示  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

AiryBiPrime

AiryBiPrime[z]

给出 Airy 函数的导数 .

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (5)

数值运算：

Wolfram Language code: AiryBiPrime[1.8]

在实数的子集上绘图：

Wolfram Language code: Plot[AiryBiPrime[x], {x, -10, 2}]

在复数的子集上绘图：

Wolfram Language code: ComplexPlot3D[AiryBiPrime[z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

在原点的级数展开：

Wolfram Language code: Series[AiryBiPrime[x], {x, 0, 5}]

在 Infinity 的级数展开：

Wolfram Language code: Series[AiryBiPrime[x], {x, ∞, 2}]//Normal

范围  (38)

数值计算  (5)

高精度数值计算：

Wolfram Language code: N[AiryBiPrime[5 / 2], 50]

输出精度与输入精度一致：

Wolfram Language code: AiryBiPrime[2.50000000000000000000000]

对复变量求值：

Wolfram Language code: AiryBiPrime[2.5 + I]

在高精度条件下高效计算 AiryBiPrime:

Wolfram Language code: AiryBiPrime[0.5`500]//Timing
Wolfram Language code: AiryBiPrime[0.5`5000];//Timing

用 Interval 和 CenteredInterval 对象计算最坏情况下的区间：

Wolfram Language code: AiryBiPrime[Interval[{1.9, 2}]]
Wolfram Language code: AiryBiPrime[CenteredInterval[1, 0.1]]

或用 Around 计算一般情况下的统计区间：

Wolfram Language code: AiryBiPrime[ Around[2, 0.01]]

计算数组中每个元素的值：

Wolfram Language code: AiryBiPrime[{{-1.2, 0}, {0, 1.}}]

或用 MatrixFunction 计算矩阵形式的 AiryBiPrime 函数：

Wolfram Language code: MatrixFunction[AiryBiPrime, {{-1.2, 0}, {0, 1.}}]

特殊值  (3)

自动生成简单精确值：

Wolfram Language code: AiryBiPrime[0]

无穷处的极限值：

Wolfram Language code: Limit[AiryBiPrime[x], x -> Infinity]

用 Solve 求 AiryBiPrime 的零点：

Wolfram Language code: xzero = N@Solve[AiryBiPrime[x] == 0 && -3 < x < -2, x][[1, 1, 2]]//Quiet
Wolfram Language code: Plot[AiryBiPrime[x], {x, -5, 2}, Epilog -> Style[Point[{xzero, AiryBiPrime[xzero]}], PointSize[Large], Red]]

可视化  (2)

绘制 AiryBiPrime 函数：

Wolfram Language code: Plot[AiryBiPrime[x], {x, -6, 2}]

绘制 TemplateBox[{z}, AiryBiPrime] 的实部：

Wolfram Language code: ComplexContourPlot[Re[AiryBiPrime[z]], {z, -4 - 4I, 4 + 4I}, Contours -> 20]

绘制 TemplateBox[{z}, AiryBiPrime] 的虚部：

Wolfram Language code: ComplexContourPlot[Im[AiryBiPrime[z]], {z, -4 - 4I, 4 + 4I}, Contours -> 20]

函数属性  (9)

AiryBiPrime 是针对所有实数和复数定义的：

Wolfram Language code: FunctionDomain[AiryBiPrime[x], x]
Wolfram Language code: FunctionDomain[AiryBiPrime[z], z, Complexes]

AiryBiPrime 函数的范围：

Wolfram Language code: FunctionRange[AiryBiPrime[x], x, y]

AiryBiPrime 是 x 的解析函数：

Wolfram Language code: FunctionAnalytic[AiryBiPrime[x], x]

AiryBiPrime 既不是非递增，也不是非递减：

Wolfram Language code: FunctionMonotonicity[AiryBiPrime[x], x]

AiryBiPrime 不是单射函数：

Wolfram Language code: FunctionInjective[AiryBiPrime[x], x]
Wolfram Language code: Plot[{AiryBiPrime[x], .3}, {x, -10, 5}]

AiryBiPrime 是满射函数：

Wolfram Language code: FunctionSurjective[AiryBiPrime[x], x]
Wolfram Language code: Plot[{AiryBiPrime[x], -1.5}, {x, -50, 5}]

AiryBiPrime 既不是非负，也不是非正：

Wolfram Language code: FunctionSign[AiryBiPrime[x], x]

AiryBiPrime 没有奇点或断点：

Wolfram Language code: FunctionSingularities[AiryBiPrime[x], x]
Wolfram Language code: FunctionDiscontinuities[AiryBiPrime[x], x]

AiryBiPrime 既不凸，也不凹：

Wolfram Language code: FunctionConvexity[AiryBiPrime[x], x]

微分  (3)

一阶导数：

Wolfram Language code: D[AiryBiPrime[x], x]

高阶导数：

Wolfram Language code: Table[D[AiryBiPrime[x], {x, n}], {n, 1, 4}]
Wolfram Language code: Plot[Evaluate[%], {x, -1, 1}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

阶导数的公式：

Wolfram Language code: D[AiryBiPrime[x], {x, n}]

积分  (3)

AiryBiPrime 的不定积分返回 AiryBi：

Wolfram Language code: Integrate[AiryBiPrime[x], x]

AiryBiPrime 的定积分：

Wolfram Language code: Integrate[AiryBiPrime[x], {x, -Infinity, 0}]

更多积分：

Wolfram Language code: Integrate[AiryBi[a x]AiryBiPrime[a x], x]
Wolfram Language code: Integrate[x ^ a AiryBiPrime[x] ^ 2, x]//TraditionalForm

级数展开式  (4)

AiryBiPrime 的泰勒展开式：

Wolfram Language code: Series[AiryBiPrime[x], {x, 0, 7}]

绘制 AiryBiPrime 在 处的前三个近似式：

Wolfram Language code: terms = Normal@{Series[AiryBiPrime[x], {x, 0, 2}], Series[AiryBiPrime[x], {x, 0, 3}], Series[AiryBiPrime[x], {x, 0, 5}]}; Plot[{AiryBiPrime[x], terms}, {x, -2, 2}]

AiryBiPrime 级数展开式的通项:

Wolfram Language code: SeriesCoefficient[AiryBiPrime[x], {x, 0, n}]

求无穷处的级数展开式：

Wolfram Language code: Series[AiryBiPrime[x], {x, Infinity, 3}]

在负无穷处的级数展开式非常不同：

Wolfram Language code: Series[AiryBiPrime[x], {x, -Infinity, 1}]

AiryBiPrime 可应用于幂级数：

Wolfram Language code: AiryBiPrime[Log[1 + x] + O[x] ^ 4]

积分变换  (2)

用 FourierCosTransform 计算傅立叶变换：

Wolfram Language code: FourierCosTransform[AiryBiPrime[-t], t, s]//TraditionalForm

HankelTransform:

Wolfram Language code: HankelTransform[AiryBiPrime[r], r, s ]

函数恒等式和化简  (3)

函数恒等式：

Wolfram Language code: AiryBiPrime[z] + E^(2 I π/3) AiryBiPrime[E^-(2 I π/3) z] + E^-(2 I π/3) AiryBiPrime[E^(2 I π/3) z]//FullSimplify

把表达式化简为 AiryBiPrime：

Wolfram Language code: (z^2 Hypergeometric0F1[(5/3), (z^3/9)]/2 3^1 / 6 Gamma[(2/3)]) + (3^1 / 6 Hypergeometric0F1[(1/3), (z^3/9)]/ Gamma[(1/3)])//FullSimplify

FunctionExpand 力图对 AiryBiPrime 的自变量进行化简：

Wolfram Language code: FunctionExpand [AiryBiPrime[z Exp[2Pi I / 3]]] // Simplify
Wolfram Language code: FunctionExpand[AiryBiPrime[(z^3)^1 / 3]]

函数表示  (4)

与贝塞尔函数的关系：

Wolfram Language code: (1/Sqrt[3])(z^2(z^3 / 2)^-(2/3) BesselI[(2/3), (2 z^3 / 2/3)] + (z^3 / 2)^2 / 3 BesselI[-(2/3), (2 z^3 / 2/3)])//FullSimplify

可用 DifferentialRoot 来表示 AiryBiPrime：

Wolfram Language code: DifferentialRootReduce[AiryBiPrime[x], x]

通过 MeijerGReduce 用 MeijerG 来表示：

Wolfram Language code: MeijerGReduce[AiryBiPrime[x], x]
Wolfram Language code: Activate[%]//FullSimplify

TraditionalForm 格式输出：

Wolfram Language code: AiryBiPrime[z]//TraditionalForm

应用  (3)

以 AiryBiPrime 的形式求解微分方程：

Wolfram Language code: DSolve[-9 z ^ 2 w[z] + 9 z ^ 5 w[z] - 15 w'[z] + 20 z ^ 3 w'[z] + 15 z w''[z] - 10 z ^ 4 w''[z] - 6 z ^ 2 w'''[z] + z ^ 3 w''''[z] == 0, w, z]

修正线性 Korteweg–deVries方程对任意函数 的解：

Wolfram Language code: u[x_, t_] := (3 t) ^ (-2 / 3) Integrate[AiryBiPrime[(x - y) (3 t) ^ (-1 / 3)] f[y], {y, -Infinity, Infinity}]

验证解：

Wolfram Language code: D[u[x, t], t, x] + D[u[x, t], x, x, x, x] //. α_.Integrate[a_, i_] + β_.Integrate[b_, i_] :> Integrate[α a + β b, i]

线性锥势中与时间无关的薛定谔方程的解，用 AiryAiPrime 和 AiryBiPrime 表示：

Wolfram Language code: DSolve[{-ψ''[z] + Piecewise[{{z, z > 0}, {-z, z < 0}}] ψ[z] == ε ψ[z], ψ[0] == 1, ψ'[0] == 0}, ψ[z], z]

通过 AiryAiPrime 的零点确定正规化状态：

Wolfram Language code: b[n_] := x /. FindRoot[AiryAiPrime[x], {x, -(3Pi / 8(Max[0, 4n - 1])) ^ (2 / 3), -(3Pi / 8(4n + 3)) ^ (2 / 3)}]
Wolfram Language code: ψ[n_, x_] := 1 / Sqrt[-b[n]] / AiryAi[b[n]]AiryAi[Sqrt[x ^ 2] + b[n]]

绘制正规化的状态：

Wolfram Language code: Plot[Evaluate[Prepend[Table[-b[n] + ψ[n, x], {n, 0, 12}], Abs[x]]], {x, -16, 16}, Frame -> True, Axes -> False]

属性和关系  (5)

利用 FullSimplify 化简 Airy 函数，此处在 Airy 方程的 Wronskian 中：

Wolfram Language code: Det[Outer[D[#1, {x, #2}]&, {AiryAi[x], AiryBi[x]}, {0, 1}]]
Wolfram Language code: FullSimplify[%]

与 Wronskian 的输出比较：

Wolfram Language code: Wronskian[{AiryAi[x], AiryBi[x]}, x]

从微分方程生成 Airy 函数：

Wolfram Language code: DSolve[z w''[z] - w'[z] - z ^ 2w[z] == 0, w, z]

积分变换：

Wolfram Language code: FourierCosTransform[AiryBiPrime[-t], t, s]//TraditionalForm

由各项和得到 AiryBiPrime：

Wolfram Language code: (3^1 / 6 /Gamma[(1/3)])Underoverscript[∑, k = 0, ∞](1/Pochhammer[(1/3), k] k!)((z^3/9))^k + (z^2 /2 3^1 / 6 Gamma[(2/3)])Underoverscript[∑, k = 0, ∞](1/Pochhammer[(5/3), k] k!)((z^3/9))^k//FullSimplify

AiryBiPrime 出现在一些数学函数特例中：

Wolfram Language code: {(z^2 Hypergeometric0F1[(5/3), (z^3/9)]/2 3^1 / 6 Gamma[(2/3)]) + (3^1 / 6 Hypergeometric0F1[(1/3), (z^3/9)]/ Gamma[(1/3)]), MeijerG[{{}, {-(1/6), (1/3)}}, {{0, (2/3)}, {-(1/6), (1/3)}}, 3^-2 / 3 z, (1/3)]}//FunctionExpand

可能存在的问题  (3)

输入的机器精度不足以得到正确答案：

Wolfram Language code: AiryBiPrime[-10. ^ 12 ]

代之以任意精度计算：

Wolfram Language code: N[AiryBiPrime[-10 ^ 12 ], 10]

需要对 $MaxExtraPrecision 设置较大的值：

Wolfram Language code: N[AiryBiPrime[-10 ^ 100], 20]
Wolfram Language code: Block[{$MaxExtraPrecision = 200}, N[AiryBiPrime[-10 ^ 100], 20]]

机器数输入能给出高精度结果：

Wolfram Language code: AiryBiPrime[10. ^ 3]
Wolfram Language code: MachineNumberQ[%]

巧妙范例  (1)

AiryBiPrime 平方的嵌套积分：

Wolfram Language code: NestList[Integrate[#, z]&, AiryBiPrime[z] ^ 2, 4]//Simplify//TraditionalForm
Wolfram Research (1991)，AiryBiPrime，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AiryBiPrime.html （更新于 2022 年）.

文本

Wolfram Research (1991)，AiryBiPrime，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AiryBiPrime.html （更新于 2022 年）.

CMS

Wolfram 语言. 1991. "AiryBiPrime." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2022. https://reference.wolfram.com/language/ref/AiryBiPrime.html.

APA

Wolfram 语言. (1991). AiryBiPrime. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/AiryBiPrime.html 年

BibTeX

@misc{reference.wolfram_2026_airybiprime, author="Wolfram Research", title="{AiryBiPrime}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/AiryBiPrime.html}", note=[Accessed: 12-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_airybiprime, organization={Wolfram Research}, title={AiryBiPrime}, year={2022}, url={https://reference.wolfram.com/language/ref/AiryBiPrime.html}, note=[Accessed: 12-August-2026]}