WOLFRAM

Wolfram 语言与系统参考资料中心

AngerJ[ν,z]

给出 Anger 函数 TemplateBox[{nu, z}, AngerJ2].

AngerJ[ν,μ,z]

给出相关的 Anger 函数 TemplateBox[{nu, mu, z}, AngerJ].

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
数值计算  
特殊值  
可视化  
函数属性  
微分和积分  
级数展开  
属性和关系  
参见
相关指南
相关链接
历史
按以下格式引用：

AngerJ

AngerJ[ν,z]

给出 Anger 函数 TemplateBox[{nu, z}, AngerJ2].

AngerJ[ν,μ,z]

给出相关的 Anger 函数 TemplateBox[{nu, mu, z}, AngerJ].

更多信息

  • 数学函数，适宜于符号和数值运算.
  • TemplateBox[{nu, z}, AngerJ2] 函数满足微分方程 .
  • TemplateBox[{nu, z}, AngerJ2] 由 TemplateBox[{nu, z}, AngerJ2]=1/piint_0^picos(theta nu-z sin(theta))dtheta 定义.
  • AngerJ[ν,z] 是 z 的整函数，没有分支切割.
  • TemplateBox[{nu, mu, z}, AngerJ] is defined by TemplateBox[{nu, mu, z}, AngerJ]=1/piint_0^pi(2sin(theta))^mucos(theta nu-z sin(theta))dtheta.
  • 对某些特定参数，AngerJ 自动运算出精确值.
  • AngerJ 可求任意数值精度的值.
  • AngerJ 自动逐项作用于列表的各个元素.
  • AngerJ 可与 Interval 和 CenteredInterval 对象一起使用. »

范例

打开所有单元 关闭所有单元

基本范例  (4)

数值运算：

Wolfram Language code: AngerJ[1 / 2, 5.0]

在实数的子集上绘制 TemplateBox[{{1, /, 2}, x}, AngerJ2]：

Wolfram Language code: ReImPlot[AngerJ[1 / 2, x], {x, -25, 25}, PlotRange -> All]

在复数的子集上绘图：

Wolfram Language code: ComplexPlot3D[AngerJ[2, z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

在原点的级数展开：

Wolfram Language code: Series[AngerJ[1 / 2, x], {x, 0, 4}]//FullSimplify

范围  (39)

数值计算  (6)

数值化计算：

Wolfram Language code: AngerJ[1, 2.0]
Wolfram Language code: AngerJ[1, -3.0]

高精度计算：

Wolfram Language code: N[AngerJ[2, 3], 50]

输出的精度与输入的精度一致：

Wolfram Language code: AngerJ[1 / 3, 1.000000000240000000000000000000]

复数输入：

Wolfram Language code: N[AngerJ[2, 3 + I]]

高精度的高效计算：

Wolfram Language code: AngerJ[2, 3.`100]//Timing
Wolfram Language code: AngerJ[2, 4.`10000];//Timing

使用 Interval 和 CenteredInterval 对象计算最坏情况下的保证间隔：

Wolfram Language code: AngerJ[1, Interval[{0.5, 0.6}]]
Wolfram Language code: AngerJ[1.2, CenteredInterval[2, 1 / 10]]

或用 Around 计算一般情况下的统计区间：

Wolfram Language code: AngerJ[2, Around[2, 0.01]]

计算数组中每个元素的值：

Wolfram Language code: AngerJ[ 2, {{5 / 6, 0}, {1 / 2, -1 / 3}}]

或用 MatrixFunction 计算矩阵形式的 AngerJ 函数：

Wolfram Language code: MatrixFunction[AngerJ[2, #]&, {{5 / 6, 0}, {1 / 2, -1 / 3}}]

特殊值  (7)

无穷处的极限值：

Wolfram Language code: Limit[AngerJ[ν, x], x -> Infinity]

零处的值：

Wolfram Language code: AngerJ[1, 0]
Wolfram Language code: AngerJ[0, 0]

符号 ν 和 x 的 AngerJ:

Wolfram Language code: AngerJ[ν, x ]//FunctionExpand

求 AngerJ 的第一个正极大值：

Wolfram Language code: xmax = x /. FindRoot[D[AngerJ[1, x ], x] == 0, {x, 2}]
Wolfram Language code: Plot[AngerJ[1, x], {x, 0, 8}, Epilog -> Style[Point[{xmax, AngerJ[1, xmax]}], PointSize[Large], Red]]

AngerJ 对整数阶数简化为 BesselJ：

Wolfram Language code: AngerJ[3, x]//FunctionExpand

自动产生简化的精确值：

Wolfram Language code: AngerJ[ν, 0]

计算半整数阶的 AngerJ：

Wolfram Language code: Table[AngerJ[ν, x], {ν, {-1 / 3, 1 / 2}}]//FunctionExpand

可视化  (3)

绘制整数 () 和半整数 () 阶的 AngerJ 函数：

Wolfram Language code: ReImPlot[{AngerJ[0, x], AngerJ[1, x], AngerJ[-1 / 2, x]}, {x, -10, 10}]

绘制 TemplateBox[{0, z}, AngerJ2] 的实部：

Wolfram Language code: ComplexContourPlot[Re[AngerJ[0, z]], {z, -4 - 4I, 8 + 4I}, IconizedObject[«PlotOptions»]]

绘制 TemplateBox[{0, z}, AngerJ2] 的虚部：

Wolfram Language code: ComplexContourPlot[Im[AngerJ[0, z]], {z, -4 - 4I, 8 + 4I}, IconizedObject[«PlotOptions»]]

绘制 TemplateBox[{{-, {1, /, 4}}, z}, AngerJ2] 的实部：

Wolfram Language code: ComplexContourPlot[Re[AngerJ[-1 / 4, z]], {z, -4 - 4I, 8 + 4I}, IconizedObject[«PlotOptions»]]

绘制 TemplateBox[{{-, {1, /, 4}}, z}, AngerJ2] 的虚部：

Wolfram Language code: ComplexContourPlot[Im[AngerJ[-1 / 4, z]], {z, -4 - 4I, 8 + 4I}, IconizedObject[«PlotOptions»]]

函数属性  (15)

TemplateBox[{0, x}, AngerJ2] 的实域：

Wolfram Language code: FunctionDomain[AngerJ[0, x], x]

TemplateBox[{0, z}, AngerJ2] 的复数域：

Wolfram Language code: FunctionDomain[AngerJ[0, z], z, Complexes]

TemplateBox[{{-, {1, /, 2}}, x}, AngerJ2] 为所有实数定义：

Wolfram Language code: FunctionDomain[AngerJ[-1 / 2, x], x]

复数域是整个平面：

Wolfram Language code: FunctionDomain[AngerJ[-1 / 2, z], z, Complexes]

TemplateBox[{0, x}, AngerJ2] 的近似函数范围：

Wolfram Language code: FunctionRange[AngerJ[0, x], x, y]//N//Quiet

TemplateBox[{1, x}, AngerJ2] 的近似函数范围：

Wolfram Language code: FunctionRange[AngerJ[1, x], x, y]//N//Quiet

TemplateBox[{0, x}, AngerJ2] 是偶函数：

Wolfram Language code: AngerJ[0, -x] == AngerJ[0, x]

TemplateBox[{1, x}, AngerJ2] 是奇函数：

Wolfram Language code: AngerJ[1, -x] == -AngerJ[1, x]

使用 FullSimplify 简化 Anger 函数：

Wolfram Language code: FullSimplify[x AngerJ[2, x] + x AngerJ[0, x]]

AngerJ 按元素线性作用于列表：

Wolfram Language code: AngerJ[1 / 2, {0.1, 0.2, 0.3}]

TemplateBox[{2, x}, AngerJ2] 是 的解析函数：

Wolfram Language code: FunctionAnalytic[AngerJ[2, x], x]

AngerJ 既不是非递增，也不是非递减：

Wolfram Language code: FunctionMonotonicity[AngerJ[2, x], x]

TemplateBox[{2, x}, AngerJ2] 不是单射函数：

Wolfram Language code: FunctionInjective[AngerJ[2, x], x]
Wolfram Language code: Plot[{AngerJ[2, x], .2}, {x, -10, 10}]

TemplateBox[{2, x}, AngerJ2] 不是满射函数：

Wolfram Language code: FunctionSurjective[AngerJ[2, x], x]
Wolfram Language code: Plot[{AngerJ[2, x], 1}, {x, -10, 10}]

AngerJ 既不是非负，也不是非正：

Wolfram Language code: FunctionSign[AngerJ[2, x], x]
Wolfram Language code: FunctionSign[AngerJ[1, x], x]

AngerJ 没有奇点或断点：

Wolfram Language code: FunctionSingularities[AngerJ[2, x], x]
Wolfram Language code: FunctionDiscontinuities[AngerJ[2, x], x]

AngerJ 既不凸，也不凹：

Wolfram Language code: FunctionConvexity[AngerJ[2, x], x]

TraditionalForm 格式：

Wolfram Language code: AngerJ[ν, x]//TraditionalForm
Wolfram Language code: AngerJ[ν, μ, x]//TraditionalForm

微分和积分  (5)

关于 的一阶导：

Wolfram Language code: D[AngerJ[ν, x], x]
Wolfram Language code: D[AngerJ[ν, μ, x], x]

关于 的高阶导：

Wolfram Language code: Table[D[AngerJ[ν, x], {x, k}], {k, 1, 3}]//FullSimplify

绘制关于 when 的高阶导：

Wolfram Language code: Plot[Evaluate[% /. {ν -> 1 / 4}], {x, -10, 10}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

当 时，关于 的 ^(th) 阶导数公式：

Wolfram Language code: D[AngerJ[3, x], {x, k}]// FullSimplify

AngerJ 的不定积分：

Wolfram Language code: Integrate[AngerJ[ν, x], x]//FullSimplify
Wolfram Language code: Integrate[AngerJ[ν, μ, x], x]//FullSimplify

更多积分：

Wolfram Language code: ∫ x AngerJ[ν, x]ⅆx//TraditionalForm
Wolfram Language code: ∫ x^αAngerJ[ν, μ, x^2]ⅆx//TraditionalForm

级数展开  (3)

使用 Series 求泰勒展开：

Wolfram Language code: Series[AngerJ[ν, x], {x, 0, 3}]

绘制 附近的前三个近似：

Wolfram Language code: terms = Normal@Table[Series[Hypergeometric0F1Regularized[1 / 3, x], {x, 0, m}], {m, 1, 5, 2}]; Plot[{Hypergeometric0F1Regularized[1 / 3, x], terms}, {x, -10, 10}, PlotRange -> {-10, 10}]

使用 SeriesCoefficient 进行级数展开的一般项：

Wolfram Language code: SeriesCoefficient[AngerJ[ν, x], {x, 1, n}]

在 generic point 上的泰勒展开：

Wolfram Language code: Series[AngerJ[ν, x], {x, x0, 2}]// FullSimplify

属性和关系  (2)

用 FunctionExpand 将 AngerJ 展开成超几何函数：

Wolfram Language code: FunctionExpand[AngerJ[ν, x]]

安格尔和韦伯函数之间的关系：

Wolfram Language code: FunctionExpand[Sin[Pi ν]AngerJ[ν, x] == Cos[Pi ν]WeberE[ν, x] - WeberE[-ν, x]]//Simplify
Wolfram Language code: FunctionExpand[Sin[Pi ν]WeberE[ν, x] == -Cos[Pi ν]AngerJ[ν, x] + AngerJ[-ν, x]]//Simplify
Wolfram Research (2008)，AngerJ，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AngerJ.html.

文本

Wolfram Research (2008)，AngerJ，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AngerJ.html.

CMS

Wolfram 语言. 2008. "AngerJ." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/AngerJ.html.

APA

Wolfram 语言. (2008). AngerJ. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/AngerJ.html 年

BibTeX

@misc{reference.wolfram_2026_angerj, author="Wolfram Research", title="{AngerJ}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/AngerJ.html}", note=[Accessed: 10-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_angerj, organization={Wolfram Research}, title={AngerJ}, year={2008}, url={https://reference.wolfram.com/language/ref/AngerJ.html}, note=[Accessed: 10-August-2026]}