WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Animator[u]

0から1まで時間の経過に伴って持続的に増大する u の値とともに表示するオブジェクトを表す．

Animator[u,{umin,umax}]

u を uminから umaxまで変化させる．

Animator[u,{umin,umax,du}]

ステップ du で u を変化させる．

Animator[u,{umin,umax},ups]

u の値を1秒あたり ups 単位の割合で増大させる．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
アニメータのコンテンツ  
アニメータのコントロール  
オプション  
AnimationDirection  
AnimationRate  
AnimationRepetitions  
Show More Show More
AnimationRunning  
AnimationRunTime  
AnimationTimeIndex  
Appearance  
AppearanceElements  
Background  
BaselinePosition  
DefaultDuration  
DisplayAllSteps  
Enabled  
Exclusions  
ImageSize  
RefreshRate  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

Animator

Animator[u]

0から1まで時間の経過に伴って持続的に増大する u の値とともに表示するオブジェクトを表す．

Animator[u,{umin,umax}]

u を uminから umaxまで変化させる．

Animator[u,{umin,umax,du}]

ステップ du で u を変化させる．

Animator[u,{umin,umax},ups]

u の値を1秒あたり ups 単位の割合で増大させる．

詳細とオプション

  • デフォルトの継続時間は5秒である．
  • Animator[Dynamic[s],…]は s の値を時間につれて連続的に再設定する．
  • Animator[u,{umin,Infinity}]は，1秒ごとに u が1増加する割合で永遠に実行される．
  • Animator[u,{-Infinity,Infinity}]は，アニメーションが逆方向に進んでいる場合に u が永遠に減り続けるようにすることもできる．
  • 次のオプションを与えることができる．
  • AnimationDirection Forwardアニメーションの方向
    AnimationRate Automatic変数が変化する速度
    AnimationRepetitions Infinity停止するまでに何回実行するか
    AnimationRunning Trueアニメーションが実行中かどうか
    AnimationRunTime 0アニメーションが最後に開始されてからの経過時間．アニメーションが実行されていない場合は0
    AnimationTimeIndex Automaticアニメーションの時間指標．始まりは0，DefaultDurationの値は終り
    Appearance Automaticアニメータの全体的な外観
    AppearanceElements Automatic表示されたアニメータに含める要素
    BaselinePosition Automatic周囲のテキストのベースラインと何を揃えるか
    BaseStyle{}アニメータのベーススタイル指定
    DefaultDuration 5.デフォルトの継続時間（秒）
    DisplayAllSteps Falseすべての離散的ステップを強制的に表示するかどうか
    Enabled Automaticアニメータを有効にするか灰色（無効）にするか
    Exclusions {}避けるべき特定の値 u 個
    ImageMargins0表示されたアニメータの画像の周囲に置く余白
    ImageSize Automatic表示されたアニメータの全体的な画像サイズ
  • デフォルトのアニメータには"ProgressSlider"，"PlayPauseButton"，"FasterSlowerButtons"，"DirectionButton"の要素が含まれている．これらの要素は，AppearanceElementsの設定として与えられたリストで順不同で指定することができる．
  • "PlayButton"，"ResetPlayButton"，"PauseButton"，"ResetButton"等の要素も使うことができる．
  • Appearance -> "Labeled"は，アニメータの現行値を編集可能なラベルとして表示する．
  • Animator[]はAnimator[0]と等価である．

例題

すべて開く すべて閉じる

例  (3)

デフォルト範囲が0から1までで0.8に設定されたアニメータ：

Wolfram Language code: Animator[0.8]

動的に値が更新されるアニメータ：

Wolfram Language code: {Animator[Dynamic[x]], Dynamic[x]}

0から100までの整数値を持つアニメータ：

Wolfram Language code: {Animator[Dynamic[n], {0, 100, 1}], Dynamic[n]}

スコープ  (5)

アニメータのコンテンツ  (1)

異なる外見の要素を入れる：

Wolfram Language code: Table[Animator[0, AppearanceElements -> a, AnimationRunning -> False], {a, {"ProgressSlider", "StepLeftButton", "StepRightButton", "PlayPauseButton", "FasterSlowerButtons", "DirectionButton", "ResetButton", "PlayButton", "ResetPlayButton"}}]

アニメータのコントロール  (4)

初期値を指定する：

Wolfram Language code: Animator[0.5, AnimationRunning -> False]

範囲を指定する：

Wolfram Language code: Animator[0, {0, 5}, AnimationRunning -> False]

離散ジャンプを含む範囲を指定する：

Wolfram Language code: Animator[0, {0, 5, 1}, AnimationRunning -> False]

リフレッシュ速度で範囲を指定する：

Wolfram Language code: Animator[0, {0, 5}, 5, AnimationRunning -> False]

オプション  (25)

AnimationDirection  (1)

スライダーの方向を制御する：

Wolfram Language code: Table[Animator[0, AnimationDirection -> a, AnimationRunning -> False], {a, {Forward, Backward, ForwardBackward}}]

AnimationRate  (1)

スライダーの速度を制御する：

Wolfram Language code: Table[Animator[0, AnimationRate -> a, AnimationRunning -> False], {a, {Automatic, 0.5, 1, 1.5}}]

AnimationRepetitions  (1)

スライダーが繰り返す回数を制御する：

Wolfram Language code: Table[Animator[0, AnimationRepetitions -> a, AnimationRunning -> False], {a, 1, 3}]

AnimationRunning  (2)

デフォルトで，Animatorは動いているスライダーで開始する：

Wolfram Language code: Animator[0]

AnimationRunningを設定すると，スライダーは静止したままになる：

Wolfram Language code: Animator[0, AnimationRunning -> False]

AnimationRunTime  (1)

アニメーションがどのくらい長く実行されているかを追跡する：

Wolfram Language code: DynamicModule[{t}, {Animator[0, {0, 1}, AnimationRunTime -> Dynamic[t]], Dynamic[t]}]

AnimationTimeIndex  (1)

デフォルトのオプション設定では，AnimationTimeIndexは0から5までである：

Wolfram Language code: DynamicModule[{i}, {Animator[0, {0, 100}, AnimationTimeIndex -> Dynamic[i]], Dynamic[i]}]

Appearance  (3)

さまざまな大きさ：

Wolfram Language code: Table[Animator[0, Appearance -> a, AnimationRunning -> False], {a, {Tiny, Small, Medium, Large}}]

ラベルを加える：

Wolfram Language code: Animator[0, {0, 1}, Appearance -> "Labeled", AnimationRunning -> False]

定義済みのアニメータの外観：

Wolfram Language code: Table[Animator[Appearance -> a], {a, {"Indeterminate", "Necklace", "ArcUp", "ArcDown", "ArcUpFill", "Percolate", "Ellipsis"}}]

AppearanceElements  (4)

デフォルトで，Animatorはスライダーといくつかのボタンからなっている：

Wolfram Language code: Animator[0, AnimationRunning -> False]

AppearanceElementsを設定することで，どのコントロールを表示するかを指定する：

Wolfram Language code: Table[Animator[0, AppearanceElements -> a, AnimationRunning -> False], {a, {"ProgressSlider", "StepLeftButton", "StepRightButton", "PlayPauseButton", "FasterSlowerButtons", "DirectionButton", "ResetButton", "PlayButton", "ResetPlayButton"}}]

すべてのコントロールを同時に見る：

Wolfram Language code: Animator[0, AppearanceElements -> All, AnimationRunning -> False]

カスタマイズされたAnimatorを作る：

Wolfram Language code: Animator[0, AppearanceElements -> {"StepLeftButton", "StepRightButton", "ProgressSlider"}, AnimationRunning -> False]

Background  (2)

背景色を変える：

Wolfram Language code: Table[Animator[0, Background -> c, AnimationRunning -> False], {c, {Pink, Green, Gray, Yellow}}]

背景色を動的に変える：

Wolfram Language code: Animator[Dynamic[x], Background -> Dynamic[Hue[x]], AnimationRunning -> False]

BaselinePosition  (1)

周囲のテキストに揃える：

Wolfram Language code: Row[Table[Animator[0, AppearanceElements -> {"PlayPauseButton", "StepRightButton"}, BaselinePosition -> p], {p, {Top, Center, Bottom}}], "xxx"]

DefaultDuration  (2)

スライダーの持続時間を制御する：

Wolfram Language code: Table[Animator[0, DefaultDuration -> a, AnimationRunning -> False], {a, 1, 3}]

持続時間は1/速度に等しい：

Wolfram Language code: Table[Animator[0, AnimationRate -> 1 / a, AnimationRunning -> False], {a, 1, 3}]

DisplayAllSteps  (1)

DisplayAllStepsを使ってすべての中間ステップを行うように強制する：

Wolfram Language code: Table[Animator[0, {0, 5000, 5}, DisplayAllSteps -> t, AnimationRunning -> False], {t, {True, False}}]

Enabled  (2)

デフォルトで，Animatorは有効になっている：

Wolfram Language code: Animator[0, AnimationRunning -> False]

Enabled->Falseを設定すると，アニメータは無効となり現行値が可視で残る：

Wolfram Language code: Animator[0, Enabled -> False, AnimationRunning -> False]

Exclusions  (1)

範囲から値を除く：

Wolfram Language code: {Animator[Dynamic[x], {0, 1, 0.2}, Exclusions -> {0.4, 0.8}, AnimationRunning -> False], Dynamic[x]}

ImageSize  (1)

定義済みの大きさを使う：

Wolfram Language code: Column@Table[Animator[0, ImageSize -> s, Background -> Pink, AnimationRunning -> False], {s, {Tiny, Small, Medium, Large}}]

RefreshRate  (1)

スライダーのリフレッシュ速度を制御する：

Wolfram Language code: Table[Animator[0, RefreshRate -> r, AnimationRunning -> False], {r, 1, 4}]

アプリケーション  (2)

プロットのプロセスをアニメーションにする：

Wolfram Language code: DynamicModule[{n}, {Animator[Dynamic[n], AnimationRunning -> False], Dynamic[Plot[Sin[n x], {x, 0, 6}, PlotRange -> 1]]}]
Wolfram Language code: DynamicModule[{t}, {Animator[Dynamic[t], AnimationDirection -> ForwardBackward, AnimationRunning -> False], Dynamic[Plot[{Cos[x], Sin[x], t Cos[x] + (1 - t)Sin[x]}, {x, 0, 6}, PlotRange -> 1]]}]

任意のプロセスをアニメーションにする：

Wolfram Language code: DynamicModule[{n}, {Animator[Dynamic[n], {1, 20, 2}, AnimationRunning -> False], Dynamic[Expand[(x + y) ^ n]]}]
Wolfram Language code: DynamicModule[{n}, {Animator[Dynamic[n], {1000, 10000, 1}, AnimationRunning -> False], Dynamic[Prime[n]]}]

特性と関係  (1)

AnimateとListAnimateはAnimatorのコントロールを使う：

Wolfram Language code: DynamicModule[{x = 0}, {Animator[Dynamic[x], AnimationRunning -> False], Graphics[Line[Dynamic@{{0, 0}, {x, x}}], Axes -> True, PlotRange -> {{0, 1}, {0, 1}}]}]
Wolfram Language code: Animate[Graphics[Line[{{0, 0}, {x, x}}], Axes -> True, PlotRange -> {{0, 1}, {0, 1}}], {x, 0, 1}, AnimationRunning -> False]
Wolfram Language code: ListAnimate[Table[Graphics[Line[{{0, 0}, {x, x}}], Axes -> True, PlotRange -> {{0, 1}, {0, 1}}], {x, 0, 1, 0.01}], AnimationRunning -> False]

考えられる問題  (1)

Animatorのコントロールはリアルタイムの時計で動かされており，一時停止しても表示に影響するだけで状態には影響しない：

Wolfram Language code: Animate[Animator[Dynamic[t], AnimationRunning -> Which[0 ≤ r < 1, True, 1 ≤ r < 2, False, 2 ≤ r ≤ 3, True]], {r, 0, 3}]
Wolfram Research (2007), Animator, Wolfram言語関数， https://reference.wolfram.com/language/ref/Animator.html （2014年に更新）.

テキスト

Wolfram Research (2007), Animator, Wolfram言語関数， https://reference.wolfram.com/language/ref/Animator.html （2014年に更新）.

CMS

Wolfram Language. 2007. "Animator." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2014. https://reference.wolfram.com/language/ref/Animator.html.

APA

Wolfram Language. (2007). Animator. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Animator.html

BibTeX

@misc{reference.wolfram_2026_animator, author="Wolfram Research", title="{Animator}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/Animator.html}", note=[Accessed: 19-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_animator, organization={Wolfram Research}, title={Animator}, year={2014}, url={https://reference.wolfram.com/language/ref/Animator.html}, note=[Accessed: 19-August-2026]}