WOLFRAM

Wolfram 语言与系统参考资料中心

Animator[u]

表示一个显示对象，u 的值随时间变化从 0 到 1 连续增加.

Animator[u,{umin,umax}]

使 u 从 umin 变化到 umax.

Animator[u,{umin,umax,du}]

使 u 以步长 du 变化.

Animator[u,{umin,umax},ups]

使 u 的值以每秒 ups 单位的速率增加.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
动画内容  
动画控制  
选项  
AnimationDirection  
AnimationRate  
AnimationRepetitions  
Show More Show More
AnimationRunning  
AnimationRunTime  
AnimationTimeIndex  
Appearance  
AppearanceElements  
Background  
BaselinePosition  
DefaultDuration  
DisplayAllSteps  
Enabled  
Exclusions  
ImageSize  
RefreshRate  
应用  
属性和关系  
可能存在的问题  
参见
技术笔记
相关指南
历史
按以下格式引用：

Animator

Animator[u]

表示一个显示对象，u 的值随时间变化从 0 到 1 连续增加.

Animator[u,{umin,umax}]

使 u 从 umin 变化到 umax.

Animator[u,{umin,umax,du}]

使 u 以步长 du 变化.

Animator[u,{umin,umax},ups]

使 u 的值以每秒 ups 单位的速率增加.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (3)

一个在缺省范围 0 到 1 之间设定为 0.8 的动画器：

Wolfram Language code: Animator[0.8]

一个动态更新其值的动画器：

Wolfram Language code: {Animator[Dynamic[x]], Dynamic[x]}

一个在 0 到 100 之间取正整数值的动画器：

Wolfram Language code: {Animator[Dynamic[n], {0, 100, 1}], Dynamic[n]}

范围  (5)

动画内容  (1)

包括各种外观元素：

Wolfram Language code: Table[Animator[0, AppearanceElements -> a, AnimationRunning -> False], {a, {"ProgressSlider", "StepLeftButton", "StepRightButton", "PlayPauseButton", "FasterSlowerButtons", "DirectionButton", "ResetButton", "PlayButton", "ResetPlayButton"}}]

动画控制  (4)

指定一个初始值：

Wolfram Language code: Animator[0.5, AnimationRunning -> False]

指定一个范围：

Wolfram Language code: Animator[0, {0, 5}, AnimationRunning -> False]

指定一个带有不连续跳跃的范围：

Wolfram Language code: Animator[0, {0, 5, 1}, AnimationRunning -> False]

指定一个带有刷新速率的范围：

Wolfram Language code: Animator[0, {0, 5}, 5, AnimationRunning -> False]

选项  (25)

AnimationDirection  (1)

控制滑块的方向：

Wolfram Language code: Table[Animator[0, AnimationDirection -> a, AnimationRunning -> False], {a, {Forward, Backward, ForwardBackward}}]

AnimationRate  (1)

控制滑块的速率：

Wolfram Language code: Table[Animator[0, AnimationRate -> a, AnimationRunning -> False], {a, {Automatic, 0.5, 1, 1.5}}]

AnimationRepetitions  (1)

控制滑块重复的次数：

Wolfram Language code: Table[Animator[0, AnimationRepetitions -> a, AnimationRunning -> False], {a, 1, 3}]

AnimationRunning  (2)

Animator 在缺省状态下利用一个移动滑块启动：

Wolfram Language code: Animator[0]

通过设置 AnimationRunning，滑块保持静止：

Wolfram Language code: Animator[0, AnimationRunning -> False]

AnimationRunTime  (1)

跟踪动画已运行多久：

Wolfram Language code: DynamicModule[{t}, {Animator[0, {0, 1}, AnimationRunTime -> Dynamic[t]], Dynamic[t]}]

AnimationTimeIndex  (1)

在默认选项设置下，AnimationTimeIndex 从0运行至5：

Wolfram Language code: DynamicModule[{i}, {Animator[0, {0, 100}, AnimationTimeIndex -> Dynamic[i]], Dynamic[i]}]

Appearance  (3)

各种尺寸：

Wolfram Language code: Table[Animator[0, Appearance -> a, AnimationRunning -> False], {a, {Tiny, Small, Medium, Large}}]

添加标签：

Wolfram Language code: Animator[0, {0, 1}, Appearance -> "Labeled", AnimationRunning -> False]

预定义的动画外观：

Wolfram Language code: Table[Animator[Appearance -> a], {a, {"Indeterminate", "Necklace", "ArcUp", "ArcDown", "ArcUpFill", "Percolate", "Ellipsis"}}]

AppearanceElements  (4)

Animator 在缺省状态下由一个滑块和一组按钮组成：

Wolfram Language code: Animator[0, AnimationRunning -> False]

通过设置 AppearanceElements 指定显示哪些控件：

Wolfram Language code: Table[Animator[0, AppearanceElements -> a, AnimationRunning -> False], {a, {"ProgressSlider", "StepLeftButton", "StepRightButton", "PlayPauseButton", "FasterSlowerButtons", "DirectionButton", "ResetButton", "PlayButton", "ResetPlayButton"}}]

同时看到所有控件：

Wolfram Language code: Animator[0, AppearanceElements -> All, AnimationRunning -> False]

创建自定义的 Animator：

Wolfram Language code: Animator[0, AppearanceElements -> {"StepLeftButton", "StepRightButton", "ProgressSlider"}, AnimationRunning -> False]

Background  (2)

改变背景颜色：

Wolfram Language code: Table[Animator[0, Background -> c, AnimationRunning -> False], {c, {Pink, Green, Gray, Yellow}}]

动态改变背景颜色：

Wolfram Language code: Animator[Dynamic[x], Background -> Dynamic[Hue[x]], AnimationRunning -> False]

BaselinePosition  (1)

与周围的文本对齐：

Wolfram Language code: Row[Table[Animator[0, AppearanceElements -> {"PlayPauseButton", "StepRightButton"}, BaselinePosition -> p], {p, {Top, Center, Bottom}}], "xxx"]

DefaultDuration  (2)

控制滑块持续的时间：

Wolfram Language code: Table[Animator[0, DefaultDuration -> a, AnimationRunning -> False], {a, 1, 3}]

持续时间等于 1/速率：

Wolfram Language code: Table[Animator[0, AnimationRate -> 1 / a, AnimationRunning -> False], {a, 1, 3}]

DisplayAllSteps  (1)

利用 DisplayAllSteps 强制显示每一个中间步长：

Wolfram Language code: Table[Animator[0, {0, 5000, 5}, DisplayAllSteps -> t, AnimationRunning -> False], {t, {True, False}}]

Enabled  (2)

缺省时，Animator 可用：

Wolfram Language code: Animator[0, AnimationRunning -> False]

通过设置 Enabled->False，使动画器不被可用，但在其当前状态下可见：

Wolfram Language code: Animator[0, Enabled -> False, AnimationRunning -> False]

Exclusions  (1)

排除该范围内的值：

Wolfram Language code: {Animator[Dynamic[x], {0, 1, 0.2}, Exclusions -> {0.4, 0.8}, AnimationRunning -> False], Dynamic[x]}

ImageSize  (1)

利用预定尺寸：

Wolfram Language code: Column@Table[Animator[0, ImageSize -> s, Background -> Pink, AnimationRunning -> False], {s, {Tiny, Small, Medium, Large}}]

RefreshRate  (1)

控制滑块的刷新率：

Wolfram Language code: Table[Animator[0, RefreshRate -> r, AnimationRunning -> False], {r, 1, 4}]

应用  (2)

制作一个绘图过程的动画：

Wolfram Language code: DynamicModule[{n}, {Animator[Dynamic[n], AnimationRunning -> False], Dynamic[Plot[Sin[n x], {x, 0, 6}, PlotRange -> 1]]}]
Wolfram Language code: DynamicModule[{t}, {Animator[Dynamic[t], AnimationDirection -> ForwardBackward, AnimationRunning -> False], Dynamic[Plot[{Cos[x], Sin[x], t Cos[x] + (1 - t)Sin[x]}, {x, 0, 6}, PlotRange -> 1]]}]

制作任意过程的动画：

Wolfram Language code: DynamicModule[{n}, {Animator[Dynamic[n], {1, 20, 2}, AnimationRunning -> False], Dynamic[Expand[(x + y) ^ n]]}]
Wolfram Language code: DynamicModule[{n}, {Animator[Dynamic[n], {1000, 10000, 1}, AnimationRunning -> False], Dynamic[Prime[n]]}]

属性和关系  (1)

Animate 和 ListAnimate 使用 Animator 控件：

Wolfram Language code: DynamicModule[{x = 0}, {Animator[Dynamic[x], AnimationRunning -> False], Graphics[Line[Dynamic@{{0, 0}, {x, x}}], Axes -> True, PlotRange -> {{0, 1}, {0, 1}}]}]
Wolfram Language code: Animate[Graphics[Line[{{0, 0}, {x, x}}], Axes -> True, PlotRange -> {{0, 1}, {0, 1}}], {x, 0, 1}, AnimationRunning -> False]
Wolfram Language code: ListAnimate[Table[Graphics[Line[{{0, 0}, {x, x}}], Axes -> True, PlotRange -> {{0, 1}, {0, 1}}], {x, 0, 1, 0.01}], AnimationRunning -> False]

可能存在的问题  (1)

Animator 控件由实时时钟驱动，暂停仅影响显示，而不会影响状态：

Wolfram Language code: Animate[Animator[Dynamic[t], AnimationRunning -> Which[0 ≤ r < 1, True, 1 ≤ r < 2, False, 2 ≤ r ≤ 3, True]], {r, 0, 3}]
Wolfram Research (2007)，Animator，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Animator.html （更新于 2014 年）.

文本

Wolfram Research (2007)，Animator，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Animator.html （更新于 2014 年）.

CMS

Wolfram 语言. 2007. "Animator." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2014. https://reference.wolfram.com/language/ref/Animator.html.

APA

Wolfram 语言. (2007). Animator. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Animator.html 年

BibTeX

@misc{reference.wolfram_2026_animator, author="Wolfram Research", title="{Animator}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/Animator.html}", note=[Accessed: 19-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_animator, organization={Wolfram Research}, title={Animator}, year={2014}, url={https://reference.wolfram.com/language/ref/Animator.html}, note=[Accessed: 19-August-2026]}