WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

AppellF1[a,b1,b2,c,x,y]

二変数のアッペル(Appell)超幾何関数 である．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
数値評価  
特定の値  
可視化  
関数の特性  
微分  
級数展開  
アプリケーション  
特性と関係  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

AppellF1

AppellF1[a,b1,b2,c,x,y]

二変数のアッペル(Appell)超幾何関数 である．

詳細

  • AppellF1は，超幾何級数を一般化して多項式係数を持つHorn偏微分方程式系を解Appell関数族の一員である．
  • 記号操作・数値操作の両方に適した数学関数である．
  • は，領域max(TemplateBox[{x}, Abs],TemplateBox[{y}, Abs])<1の中で収束する超幾何級数 sum_(m=0)^inftysum_(n=0)^infty(TemplateBox[{a, {m, +, n}}, Pochhammer] TemplateBox[{{b, _, 1}, m}, Pochhammer] TemplateBox[{{b, _, 2}, n}, Pochhammer] )/(TemplateBox[{c, {m, +, n}}, Pochhammer]m! n!)x^m y^nを介して主定義を得る．
  • 引数の実数値についてのアッペルF1級数の収束領域は以下の通りである．
  • 一般に，は の形のHorn偏微分方程式系を満足する． »
  • は または のとき，に簡約される．
  • 特別な引数の場合，AppellF1は自動的に厳密値を計算する．
  • AppellF1は任意の数値精度で評価できる．
  • AppellF1[a,b1,b2,c,x,y]は，二変数複素空間でRe(x)=1およびRe(y)=1を満たす特異線を有し， および でからに伸びる半直線に沿って不連続な分枝切断線を有する．
  • FullSimplifyおよびFunctionExpandはAppellF1の変換規則を含んでいる．

例題

すべて開く すべて閉じる

例  (8)

数値的に評価する：

Wolfram Language code: AppellF1[2, 1, 1, 3, 0.7, 0.3]

記号的に評価する：

Wolfram Language code: AppellF1[1, 1, 1, 2, x, y]//Simplify

総和の定義：

Wolfram Language code: Sum[x^m y^n(Pochhammer[a, m + n]/Pochhammer[c, m + n])( Pochhammer[b1, m] Pochhammer[b2, n]/m! n! ), {m, 0, Infinity}, {n, 0, Infinity}]

実数の部分集合上でプロットする：

Wolfram Language code: Plot[AppellF1[1, 1, 1, 1, 4, x], {x, -2, 3}, PlotRange -> Automatic]

複素数の部分集合上でプロットする：

Wolfram Language code: ComplexPlot3D[AppellF1[1, 1, 1, 1, 4, z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

原点における級数展開：

Wolfram Language code: Series[AppellF1[1, 1, 1, 1, 4, x], {x, 0, 3}]

Infinityにおける級数展開：

Wolfram Language code: Series[AppellF1[1, 1, 1, 1, 4, x], {x, ∞, 5}]//Normal//FullSimplify

特異点における級数展開：

Wolfram Language code: Series[AppellF1[1, 1, 1, 1, 4, x], {x, 1, 2}]

スコープ  (28)

数値評価  (6)

数値的に評価する：

Wolfram Language code: AppellF1[3, 2, 1, 2, 7, 5.2]
Wolfram Language code: AppellF1[2, -1, 2, 5, 0.4, 1.3]

高精度で評価する：

Wolfram Language code: N[AppellF1[3, 2, 5, 2, 3, 5], 10]

出力精度は入力精度に従う：

Wolfram Language code: AppellF1[1, 1, 3 / 5, 3, 2 / 3, 0.400000000024000000000000]

複素数入力：

Wolfram Language code: AppellF1[I, 1, 1 + I, 3.2, 0.5, 0.2 + 0.5 I]

AppellF1を高精度で効率的に評価する：

Wolfram Language code: AppellF1[3, 2, 1, 2, 7, 7 / 4`100]//Timing
Wolfram Language code: AppellF1[3, 2, 1, 2, 7, 7 / 4`100];//Timing

Aroundを使って平均的な場合の統計区間を計算する：

Wolfram Language code: AppellF1[ 1 / 2, 1, 5 / 2, 3, 1, Around[2.1, 0.01]]

配列の要素ごとの値を計算する：

Wolfram Language code: AppellF1[1 / 2, 1, 1 / 2, 1 / 2, {{1 / 2, 2}, {2, 1 / 2}}, {{1 / 2, 2}, {2, 1 / 2}}]

MatrixFunctionを使って行列のAppellF1関数を計算することもできる：

Wolfram Language code: MatrixFunction[AppellF1[1 / 2, 1, 1 / 2, 1, #, #]&, {{1 / 2, 2}, {2, 1 / 2}}]//FullSimplify

特定の値  (4)

固定点における値：

Wolfram Language code: AppellF1[1 / 2, 1, 1 / 2, 1, 2, 2]
Wolfram Language code: AppellF1[1 / 2, 1, 5 / 2, 3, 2, 2]

記号的に評価する：

Wolfram Language code: AppellF1[a, Subscript[b, 1], Subscript[b, 2], c, x, 0]
Wolfram Language code: AppellF1[a, b, b, c, x, -x]

ゼロにおける値：

Wolfram Language code: AppellF1[a, Subscript[b, 1], Subscript[b, 2], c, 0, 0]

AppellF1を単純なパラメータについて評価するとより単純な関数になる：

Wolfram Language code: AppellF1[1, 1 / 2, 1, 1, x, y]//FullSimplify
Wolfram Language code: AppellF1[1, 1, 1, 2, x, y]//FullSimplify
Wolfram Language code: AppellF1[1 / 2, 1 / 2, 1, 3 / 2, x, y]//FullSimplify

可視化  (4)

AppellF1関数をさまざまなパラメータについてプロットする：

Wolfram Language code: Plot[{AppellF1[1, 1 / 2, 1, 1, x, 2], AppellF1[1, 1 / 2, 3, 1, x, 3], AppellF1[1, 1 / 2, 1, 1, x, 4]}, {x, -2, 2}]

AppellF1を第2パラメータ の関数としてプロットする：

Wolfram Language code: Plot[{AppellF1[1, 1, 2, 1, 2, y], AppellF1[1, 1, 4, 1, 3, y], AppellF1[1, 1, 1, 1, 4, y]}, {y, -2, 4}]

の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[AppellF1[1, 1, 4, 1, 0, z]], {z, -5 - 5I, 5 + 5I}]

の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[AppellF1[1, 1, 4, 1, 0, z]], {z, -5 - 5I, 5 + 5I}]

F_1(2,1,4,3,0,z)の実部を三次元でプロットする：

Wolfram Language code: Plot3D[Re[AppellF1[2, 1, 4, 3, 0, x + I y]], {x, -4, 4}, {y, -4, 4}]

F_1(2,1,4,3,0,z)の虚部を三次元でプロットする：

Wolfram Language code: Plot3D[Im[AppellF1[2, 1, 4, 3, 0, x + I y]], {x, -4, 4}, {y, -4, 4}]

関数の特性  (9)

AppellF1の実領域：

Wolfram Language code: FunctionDomain[AppellF1[1, 1, 1, 2, x, y], x]

AppellF1の複素領域：

Wolfram Language code: FunctionDomain[AppellF1[1, 1, 1, 2, x, y], x, Complexes]
Wolfram Language code: FunctionDomain[AppellF1[1, 1, 2, 2, x, y], x, Complexes]

AppellF1は解析関数ではない：

Wolfram Language code: FunctionAnalytic[AppellF1[1, 1, 1, 2, 4, x], x]

特異点と不連続点の両方を持つ：

Wolfram Language code: FunctionSingularities[AppellF1[1, 1, 1, 2, 4, x], x]
Wolfram Language code: FunctionDiscontinuities[AppellF1[1, 1, 1, 1, 4, x], x]

TemplateBox[{1, 1, 1, 1, 4, x}, AppellF1]は非減少でも非増加でもない：

Wolfram Language code: FunctionMonotonicity[AppellF1[1, 1, 1, 1, 4, x], x]

TemplateBox[{1, 1, 1, 1, 4, x}, AppellF1]は単射である：

Wolfram Language code: FunctionInjective[AppellF1[1, 1, 1, 1, 4, x], x]
Wolfram Language code: Plot[{AppellF1[1, 1, 1, 1, 4, x], -2}, {x, 0, 3}]

TemplateBox[{1, 1, 1, 1, 4, x}, AppellF1]は全射ではない：

Wolfram Language code: FunctionSurjective[AppellF1[1, 1, 1, 1, 4, x], x]
Wolfram Language code: Plot[{AppellF1[1, 1, 1, 1, 4, x], 0}, {x, -5, 5}]

TemplateBox[{1, 1, 1, 1, 4, x}, AppellF1]は非負でも非正でもない：

Wolfram Language code: FunctionSign[AppellF1[1, 1, 1, 1, 4, x], x]

TemplateBox[{1, 1, 1, 1, 4, x}, AppellF1]は凸でも凹でもない：

Wolfram Language code: FunctionConvexity[AppellF1[1, 1, 1, 1, 4, x], x]

TraditionalFormによる表示：

Wolfram Language code: AppellF1[a, Subscript[b, 1], Subscript[b, 2], c, x, y]//TraditionalForm

微分  (3)

y についての一次導関数：

Wolfram Language code: D[AppellF1[a, Subscript[b, 1], Subscript[b, 2], c, x, y], y]

y についての高次導関数：

Wolfram Language code: Table[D[AppellF1[a, Subscript[b, 1], Subscript[b, 2], c, x, y], {y, k}], {k, 1, 3}]//FullSimplify

a=b1=b2=2， c=10，x=1/2のとき，y についての高次導関数をプロットする：

Wolfram Language code: Plot[Evaluate[% /. {a -> 2, Subscript[b, 1] -> 2, Subscript[b, 2] -> 2, c -> 10, x -> 1 / 2}], {y, -1, 1}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

y についての 次導関数の式：

Wolfram Language code: D[AppellF1[a, Subscript[b, 1], Subscript[b, 2], c, x, y], {y, k}]// FullSimplify

級数展開  (2)

Seriesを使ってテイラー(Taylor)展開を求める：

Wolfram Language code: Series[AppellF1[a, Subscript[b, 1], Subscript[b, 2], c, x, y], {x, 0, 2}]//Normal//FullSimplify

の周りの最初の3つの近似をプロットする：

Wolfram Language code: terms = Normal@Table[Series[AppellF1[2, 1, 1, 3, x, .3], {x, 0, m}], {m, 1, 5, 2}]; Plot[{AppellF1[2, 1, 1, 3, x, .3], terms//Evaluate}, {x, 0, 10}, PlotRange -> {-30, 30}]

生成点におけるテイラー展開：

Wolfram Language code: Series[AppellF1[a, Subscript[b, 1], Subscript[b, 2], c, x, y], {x, x0, 2}]//Normal// FullSimplify

アプリケーション  (1)

アッペル関数 は，多項式係数を持つ以下の偏微分方程式系を解く：

Wolfram Language code: pde = {x(1 - x) f^(2, 0)[x, y] + y (1 - x) f^(1, 1)[x, y] + (c - (a + Subscript[b, 1] + 1)x) f^(1, 0)[x, y] - Subscript[b, 1] y f^(0, 1)[x, y] - a Subscript[b, 1] f[x, y] == 0, y (1 - y) f^(0, 2)[x, y] + x (1 - y) f^(1, 1)[x, y] + (c - (a + Subscript[b, 2] + 1)y) f^(0, 1)[x, y] - Subscript[b, 2] x f^(1, 0)[x, y] - a Subscript[b, 2] f[x, y] == 0};

が解であることを確かめる：

Wolfram Language code: (pde /. {a -> 1 / 4, Subscript[b, 1] -> 1 / 4, Subscript[b, 2] -> 1 / 4, c -> 1}) /. f -> Function[{x, y}, AppellF1[1 / 4, 1 / 4, 1 / 4, 1, x, y]];
Wolfram Language code: % /. Thread[{x, y} -> RandomReal[{-1, 1}, {2}, WorkingPrecision -> 50]]

特性と関係  (2)

AppellF1によって積分を評価する：

Wolfram Language code: Integrate[Sqrt[x](x + 1)^n (x + 2)^k , x]
Wolfram Language code: Integrate[Sin[x]^1 / 2 Cos[x]^1 / 2 (2 - Sin[x]^2)^1 / 2, x]

FullSimplifyを使ってAppellF1を含む式を簡約する：

Wolfram Language code: FullSimplify[x^5 AppellF1[(3/2), 1, 2, (5/2), x^3, x^5] + x^3 AppellF1[(3/2), 2, 1, (5/2), x^3, x^5] - (3 / 2/1 - x^3 - x^5 + x^8)]

おもしろい例題  (1)

初等関数および特殊関数の多くはAppellF1の特殊ケースである：

Wolfram Language code: funclist = Inactivate[...];
Wolfram Language code: Grid[...]//TraditionalForm
Wolfram Research (1999), AppellF1, Wolfram言語関数， https://reference.wolfram.com/language/ref/AppellF1.html （2023年に更新）.

テキスト

Wolfram Research (1999), AppellF1, Wolfram言語関数， https://reference.wolfram.com/language/ref/AppellF1.html （2023年に更新）.

CMS

Wolfram Language. 1999. "AppellF1." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2023. https://reference.wolfram.com/language/ref/AppellF1.html.

APA

Wolfram Language. (1999). AppellF1. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/AppellF1.html

BibTeX

@misc{reference.wolfram_2026_appellf1, author="Wolfram Research", title="{AppellF1}", year="2023", howpublished="\url{https://reference.wolfram.com/language/ref/AppellF1.html}", note=[Accessed: 07-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_appellf1, organization={Wolfram Research}, title={AppellF1}, year={2023}, url={https://reference.wolfram.com/language/ref/AppellF1.html}, note=[Accessed: 07-August-2026]}