WOLFRAM

Wolfram 语言与系统参考资料中心

AppellF1[a,b1,b2,c,x,y]

是双变量 Appell 超几何函数 .

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
数值计算  
特殊值  
可视化  
函数属性  
微分  
级数展开  
应用  
属性和关系  
巧妙范例  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

AppellF1

AppellF1[a,b1,b2,c,x,y]

是双变量 Appell 超几何函数 .

更多信息

  • AppellF1 属于Appell函数家族，它概括了超几何数列，解决了具有多项式系数的 Horn 偏微分方程组.
  • 数学函数，适宜于符号和数值计算.
  • 有一个通过超几何数列 sum_(m=0)^inftysum_(n=0)^infty(TemplateBox[{a, {m, +, n}}, Pochhammer] TemplateBox[{{b, _, 1}, m}, Pochhammer] TemplateBox[{{b, _, 2}, n}, Pochhammer] )/(TemplateBox[{c, {m, +, n}}, Pochhammer]m! n!)x^m y^n 的主要定义，其在区域 max(TemplateBox[{x}, Abs],TemplateBox[{y}, Abs])<1 内是收敛的.
  • Appell F1 数列对其参数的实值的收敛区域如下：
  • 一般来说， 满足以下 Horn 偏微分方程组 »: .
  • 当 或 时， 简化成为 .
  • 对某些特殊自变量，AppellF1 自动计算出精确值.
  • AppellF1 能够计算到任意数值精度.
  • AppellF1[a,b1,b2,c,x,y] 在双变量复合 空间中的 Re(x)=1 和 Re(y)=1 处有奇异线，并且沿 和 的从 到 的射线上有分支切割.
  • FullSimplify 和 FunctionExpand 包含用于 AppellF1 的变换法则.

范例

打开所有单元 关闭所有单元

基本范例  (8)

数值计算：

Wolfram Language code: AppellF1[2, 1, 1, 3, 0.7, 0.3]

符号计算：

Wolfram Language code: AppellF1[1, 1, 1, 2, x, y]//Simplify

定义和：

Wolfram Language code: Sum[x^m y^n(Pochhammer[a, m + n]/Pochhammer[c, m + n])( Pochhammer[b1, m] Pochhammer[b2, n]/m! n! ), {m, 0, Infinity}, {n, 0, Infinity}]

在实数的子集上绘图：

Wolfram Language code: Plot[AppellF1[1, 1, 1, 1, 4, x], {x, -2, 3}, PlotRange -> Automatic]

在复数的子集上绘图：

Wolfram Language code: ComplexPlot3D[AppellF1[1, 1, 1, 1, 4, z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

在原点的级数展开：

Wolfram Language code: Series[AppellF1[1, 1, 1, 1, 4, x], {x, 0, 3}]

在 Infinity 的级数展开：

Wolfram Language code: Series[AppellF1[1, 1, 1, 1, 4, x], {x, ∞, 5}]//Normal//FullSimplify

在奇点处的级数展开：

Wolfram Language code: Series[AppellF1[1, 1, 1, 1, 4, x], {x, 1, 2}]

范围  (28)

数值计算  (6)

数值化计算：

Wolfram Language code: AppellF1[3, 2, 1, 2, 7, 5.2]
Wolfram Language code: AppellF1[2, -1, 2, 5, 0.4, 1.3]

高精度计算：

Wolfram Language code: N[AppellF1[3, 2, 5, 2, 3, 5], 10]

输出的精度与输入的精度一致：

Wolfram Language code: AppellF1[1, 1, 3 / 5, 3, 2 / 3, 0.400000000024000000000000]

复数输入：

Wolfram Language code: AppellF1[I, 1, 1 + I, 3.2, 0.5, 0.2 + 0.5 I]

用高精度高效计算 AppellF1：

Wolfram Language code: AppellF1[3, 2, 1, 2, 7, 7 / 4`100]//Timing
Wolfram Language code: AppellF1[3, 2, 1, 2, 7, 7 / 4`100];//Timing

或用 Around 计算一般情况下的统计区间：

Wolfram Language code: AppellF1[ 1 / 2, 1, 5 / 2, 3, 1, Around[2.1, 0.01]]

计算数组中每个元素的值：

Wolfram Language code: AppellF1[1 / 2, 1, 1 / 2, 1 / 2, {{1 / 2, 2}, {2, 1 / 2}}, {{1 / 2, 2}, {2, 1 / 2}}]

或用 MatrixFunction 计算矩阵形式的 AppellF1 函数：

Wolfram Language code: MatrixFunction[AppellF1[1 / 2, 1, 1 / 2, 1, #, #]&, {{1 / 2, 2}, {2, 1 / 2}}]//FullSimplify

特殊值  (4)

在固定点的值：

Wolfram Language code: AppellF1[1 / 2, 1, 1 / 2, 1, 2, 2]
Wolfram Language code: AppellF1[1 / 2, 1, 5 / 2, 3, 2, 2]

符号式计算：

Wolfram Language code: AppellF1[a, Subscript[b, 1], Subscript[b, 2], c, x, 0]
Wolfram Language code: AppellF1[a, b, b, c, x, -x]

零处的值：

Wolfram Language code: AppellF1[a, Subscript[b, 1], Subscript[b, 2], c, 0, 0]

对于简单参数，AppellF1 计算为更简单的函数：

Wolfram Language code: AppellF1[1, 1 / 2, 1, 1, x, y]//FullSimplify
Wolfram Language code: AppellF1[1, 1, 1, 2, x, y]//FullSimplify
Wolfram Language code: AppellF1[1 / 2, 1 / 2, 1, 3 / 2, x, y]//FullSimplify

可视化  (4)

绘制各种参数值的 AppellF1 函数：

Wolfram Language code: Plot[{AppellF1[1, 1 / 2, 1, 1, x, 2], AppellF1[1, 1 / 2, 3, 1, x, 3], AppellF1[1, 1 / 2, 1, 1, x, 4]}, {x, -2, 2}]

将 AppellF1 绘制为第二个参数 的函数：

Wolfram Language code: Plot[{AppellF1[1, 1, 2, 1, 2, y], AppellF1[1, 1, 4, 1, 3, y], AppellF1[1, 1, 1, 1, 4, y]}, {y, -2, 4}]

绘制 实部：

Wolfram Language code: ComplexContourPlot[Re[AppellF1[1, 1, 4, 1, 0, z]], {z, -5 - 5I, 5 + 5I}]

绘制 虚部：

Wolfram Language code: ComplexContourPlot[Im[AppellF1[1, 1, 4, 1, 0, z]], {z, -5 - 5I, 5 + 5I}]

在三维空间中绘制 F_1(2,1,4,3,0,z) 的实部：

Wolfram Language code: Plot3D[Re[AppellF1[2, 1, 4, 3, 0, x + I y]], {x, -4, 4}, {y, -4, 4}]

在三维空间中绘制 F_1(2,1,4,3,0,z) 的虚部：

Wolfram Language code: Plot3D[Im[AppellF1[2, 1, 4, 3, 0, x + I y]], {x, -4, 4}, {y, -4, 4}]

函数属性  (9)

AppellF1 的实定义域：

Wolfram Language code: FunctionDomain[AppellF1[1, 1, 1, 2, x, y], x]

AppellF1 的复定义域：

Wolfram Language code: FunctionDomain[AppellF1[1, 1, 1, 2, x, y], x, Complexes]
Wolfram Language code: FunctionDomain[AppellF1[1, 1, 2, 2, x, y], x, Complexes]

AppellF1 并非解析函数：

Wolfram Language code: FunctionAnalytic[AppellF1[1, 1, 1, 2, 4, x], x]

该函数有奇点和断点：

Wolfram Language code: FunctionSingularities[AppellF1[1, 1, 1, 2, 4, x], x]
Wolfram Language code: FunctionDiscontinuities[AppellF1[1, 1, 1, 1, 4, x], x]

TemplateBox[{1, 1, 1, 1, 4, x}, AppellF1] 不是非递减或非递增：

Wolfram Language code: FunctionMonotonicity[AppellF1[1, 1, 1, 1, 4, x], x]

TemplateBox[{1, 1, 1, 1, 4, x}, AppellF1] 为单射函数：

Wolfram Language code: FunctionInjective[AppellF1[1, 1, 1, 1, 4, x], x]
Wolfram Language code: Plot[{AppellF1[1, 1, 1, 1, 4, x], -2}, {x, 0, 3}]

TemplateBox[{1, 1, 1, 1, 4, x}, AppellF1] 不是满射函数：

Wolfram Language code: FunctionSurjective[AppellF1[1, 1, 1, 1, 4, x], x]
Wolfram Language code: Plot[{AppellF1[1, 1, 1, 1, 4, x], 0}, {x, -5, 5}]

TemplateBox[{1, 1, 1, 1, 4, x}, AppellF1] 不是非负或非正函数：

Wolfram Language code: FunctionSign[AppellF1[1, 1, 1, 1, 4, x], x]

TemplateBox[{1, 1, 1, 1, 4, x}, AppellF1] 不是凹函数或凸函数：

Wolfram Language code: FunctionConvexity[AppellF1[1, 1, 1, 1, 4, x], x]

TraditionalForm 格式化：

Wolfram Language code: AppellF1[a, Subscript[b, 1], Subscript[b, 2], c, x, y]//TraditionalForm

微分  (3)

关于 y 的一阶导：

Wolfram Language code: D[AppellF1[a, Subscript[b, 1], Subscript[b, 2], c, x, y], y]

关于 y 的高阶导：

Wolfram Language code: Table[D[AppellF1[a, Subscript[b, 1], Subscript[b, 2], c, x, y], {y, k}], {k, 1, 3}]//FullSimplify

绘制关于 y 當 a=b1=b2=2, c=10 和 x=1/2 的高阶导：

Wolfram Language code: Plot[Evaluate[% /. {a -> 2, Subscript[b, 1] -> 2, Subscript[b, 2] -> 2, c -> 10, x -> 1 / 2}], {y, -1, 1}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

关于 y 的 ^(th) 阶导数公式：

Wolfram Language code: D[AppellF1[a, Subscript[b, 1], Subscript[b, 2], c, x, y], {y, k}]// FullSimplify

级数展开  (2)

使用 Series 求泰勒展开：

Wolfram Language code: Series[AppellF1[a, Subscript[b, 1], Subscript[b, 2], c, x, y], {x, 0, 2}]//Normal//FullSimplify

绘制 附近的前三个近似：

Wolfram Language code: terms = Normal@Table[Series[AppellF1[2, 1, 1, 3, x, .3], {x, 0, m}], {m, 1, 5, 2}]; Plot[{AppellF1[2, 1, 1, 3, x, .3], terms//Evaluate}, {x, 0, 10}, PlotRange -> {-30, 30}]

普通点的泰勒展开：

Wolfram Language code: Series[AppellF1[a, Subscript[b, 1], Subscript[b, 2], c, x, y], {x, x0, 2}]//Normal// FullSimplify

应用  (1)

Appell 函数 求解以下具有多项式系数的偏微分方程组：

Wolfram Language code: pde = {x(1 - x) f^(2, 0)[x, y] + y (1 - x) f^(1, 1)[x, y] + (c - (a + Subscript[b, 1] + 1)x) f^(1, 0)[x, y] - Subscript[b, 1] y f^(0, 1)[x, y] - a Subscript[b, 1] f[x, y] == 0, y (1 - y) f^(0, 2)[x, y] + x (1 - y) f^(1, 1)[x, y] + (c - (a + Subscript[b, 2] + 1)y) f^(0, 1)[x, y] - Subscript[b, 2] x f^(1, 0)[x, y] - a Subscript[b, 2] f[x, y] == 0};

检验 是一个解：

Wolfram Language code: (pde /. {a -> 1 / 4, Subscript[b, 1] -> 1 / 4, Subscript[b, 2] -> 1 / 4, c -> 1}) /. f -> Function[{x, y}, AppellF1[1 / 4, 1 / 4, 1 / 4, 1, x, y]];
Wolfram Language code: % /. Thread[{x, y} -> RandomReal[{-1, 1}, {2}, WorkingPrecision -> 50]]

属性和关系  (2)

利用 AppellF1 计算积分：

Wolfram Language code: Integrate[Sqrt[x](x + 1)^n (x + 2)^k , x]
Wolfram Language code: Integrate[Sin[x]^1 / 2 Cos[x]^1 / 2 (2 - Sin[x]^2)^1 / 2, x]

利用 FullSimplify 简化某些包含 AppellF1 的表达式：

Wolfram Language code: FullSimplify[x^5 AppellF1[(3/2), 1, 2, (5/2), x^3, x^5] + x^3 AppellF1[(3/2), 2, 1, (5/2), x^3, x^5] - (3 / 2/1 - x^3 - x^5 + x^8)]

巧妙范例  (1)

许多基本和特殊函数都是 AppellF1 的特例：

Wolfram Language code: funclist = Inactivate[...];
Wolfram Language code: Grid[...]//TraditionalForm
Wolfram Research (1999)，AppellF1，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AppellF1.html （更新于 2023 年）.

文本

Wolfram Research (1999)，AppellF1，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AppellF1.html （更新于 2023 年）.

CMS

Wolfram 语言. 1999. "AppellF1." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2023. https://reference.wolfram.com/language/ref/AppellF1.html.

APA

Wolfram 语言. (1999). AppellF1. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/AppellF1.html 年

BibTeX

@misc{reference.wolfram_2026_appellf1, author="Wolfram Research", title="{AppellF1}", year="2023", howpublished="\url{https://reference.wolfram.com/language/ref/AppellF1.html}", note=[Accessed: 07-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_appellf1, organization={Wolfram Research}, title={AppellF1}, year={2023}, url={https://reference.wolfram.com/language/ref/AppellF1.html}, note=[Accessed: 07-August-2026]}