WOLFRAM

Wolfram 语言与系统参考资料中心

Append[expr,elem]

给出追加 elem 的 expr.

Append[elem]

表示 Append 的运算符形式，它可以应用于表达式.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
属性和关系  
可能存在的问题  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

Append

Append[expr,elem]

给出追加 elem 的 expr.

Append[elem]

表示 Append 的运算符形式，它可以应用于表达式.

更多信息

  • 当利用迭代法建立一个列表时，使用 Sow 和 Reap 通常比在每一步使用 Append[list,new] 更有效率.
  • Append 作用在 SparseArray 对象上，在必要时返回普通列表.
  • Append 可作用于 Association 对象. 单个新元素以 key->value 的形式指定. 当键相同时，新值将替换旧值. »
  • 追加至关联的多个元素可以 {key1->value1,key2->value2, …} 的形式指定.
  • Append[elem][expr] 等价于 Append[expr,elem]. »

范例

打开所有单元 关闭所有单元

基本范例  (3)

向列表追加一个元素：

Wolfram Language code: Append[{a, b, c, d}, x]

往矩阵中追加一行：

Wolfram Language code: Append[(⁠| | | | - | - | | a | b | | c | d |⁠), {1, 2}]//MatrixForm

追加到 Association：

Wolfram Language code: Append[<|1 -> a, 2 -> b|>, 3 -> d]

范围  (4)

调用追加算符：

Wolfram Language code: op = Append[{1, 2}];

将列表追加到一个展平列表中，得到一个嵌套列表：

Wolfram Language code: op[{a, b, c, d}]

向列表的列表追加元素，生成一个矩阵：

Wolfram Language code: op[{{a, b}, {c, d}, {e, f}}]

以矩阵形式显示：

Wolfram Language code: %//MatrixForm

创建一个 3×3 的稀疏数组：

Wolfram Language code: sa = SparseArray[{{3, 3} -> 1}]

向其追加一行，生成另一个稀疏数组：

Wolfram Language code: Append[sa, {a, 0, b}]

如果无法维持数组结构，稀疏数组将恢复为普通数组：

Wolfram Language code: Append[sa, a]

向有通用标头的表达式追加内容：

Wolfram Language code: Append[f[a, b, c], x + y]

将多个规则追加至 Association：

Wolfram Language code: Append[<|1 -> a, 2 -> b|>, {3 -> d, 4 -> e}]

与向规则列表前面添加元素的行为进行比较：

Wolfram Language code: Append[{1 -> a, 2 -> b}, {3 -> d, 4 -> e}]

应用  (4)

把一行追加到一个矩阵：

Wolfram Language code: Append[{{a, b}, {c, d}}, {x, y}]//MatrixForm

追加到矩阵的各行：

Wolfram Language code: Map[Append[#, x]&, {{a, b}, {c, d}}]//MatrixForm

把向量追加到一个矩阵：

Wolfram Language code: MapThread[Append, {{{a, b}, {c, d}}, {x, y}}]//MatrixForm

连续追加到一个列表：

Wolfram Language code: NestList[Append[#, x]&, {a}, 5]

属性和关系  (4)

Append[list,x] 等价于 Join[list,{x}]：

Wolfram Language code: Append[{a, b, c}, 1] === Join[{a, b, c}, {1}]

即便 x 是一个列表，这也是成立的：

Wolfram Language code: Append[{a, b, c}, {1}] === Join[{a, b, c}, {{1}}]

对于普通表达式 e，Append[e,x] 等价于 Join[e,Head[e][x]]：

Wolfram Language code: With[{e = f[a, b, c]}, Append[e, 3] === Join[e, Head[e][3]]]

Append[x][e] 等价于 Append[e,x]：

Wolfram Language code: Append[x][{a, b, c}] === Append[{a, b, c}, x]

当向关联追加元素时，如果键已存在，其值将被追加的值覆盖：

Wolfram Language code: Append[<|1 -> a, 2 -> b|>, 2 -> c]

可能存在的问题  (2)

当第一个和第二个参数的标头相同时，一切正常：

Wolfram Language code: Append[{a, b, c}, {x, y}]

可以在 Append 之后使用 Flatten，实现将多个元素分别添加到前面：

Wolfram Language code: Flatten[%]

也可以使用 Join，但参数的顺序是颠倒的：

Wolfram Language code: Join[{a, b, c}, {x, y}]

在并行处理共享列表时，Append 不具备原子性（或线程安全的）：

Wolfram Language code: sl = {};SetSharedVariable[sl]
Wolfram Language code: ParallelDo[sl = Append[sl, i ^ 2], {i, 1, 8}]
Wolfram Language code: sl

这种情况下使用 AppendTo：

Wolfram Language code: sl = {};SetSharedVariable[sl]
Wolfram Language code: ParallelDo[AppendTo[sl, i ^ 2], {i, 1, 8}]
Wolfram Language code: sl
Wolfram Research (1988)，Append，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Append.html （更新于 2014 年）.

文本

Wolfram Research (1988)，Append，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Append.html （更新于 2014 年）.

CMS

Wolfram 语言. 1988. "Append." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2014. https://reference.wolfram.com/language/ref/Append.html.

APA

Wolfram 语言. (1988). Append. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Append.html 年

BibTeX

@misc{reference.wolfram_2026_append, author="Wolfram Research", title="{Append}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/Append.html}", note=[Accessed: 13-July-2026]}

BibLaTeX

@online{reference.wolfram_2026_append, organization={Wolfram Research}, title={Append}, year={2014}, url={https://reference.wolfram.com/language/ref/Append.html}, note=[Accessed: 13-July-2026]}