WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ArcCos[z]

複素数 の逆余弦を与える．

詳細
Details and Options Details and Options
予備知識
例題  
例  
スコープ  
数値評価  
特定の値  
可視化  
Show More Show More
関数の特性  
微分  
積分  
級数展開  
関数の恒等式と簡約  
関数表現  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

ArcCos

ArcCos[z]

複素数 の逆余弦を与える．

詳細

  • 記号操作・数値操作の両方に適した数学関数である．
  • 答はラジアンで求まる．
  • が実数で，〜の範囲にあるとき，答は必ずから の範囲にある．
  • 特別な引数の場合，ArcCosは自動的に厳密値を計算する．
  • ArcCosは任意の数値精度で評価できる．
  • ArcCosは自動的にリストに並列的な関数の適用を行う．
  • ArcCos[z]は，複素 平面上，〜と〜の範囲で不連続な分枝切断線を持つ．
  • ArcCosはIntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる． »

予備知識

  • ArcCosは逆余弦関数である．ArcCos[x]は，実数 について， となるような のラジアン角度を表す．
  • ArcCosは自動的にリストに縫い込まれる．特別な引数の場合，ArcCosは自動的に厳密値を計算する．厳密な数式が引数として与えられると，ArcCosは任意の数値精度に評価できることがある．ArcCosを含む記号式の操作に便利なその他の演算には，FunctionExpand，TrigToExp，TrigExpand，Simplify，FullSimplifyがある．
  • ArcCosは，複素引数 について，によって定義される．ArcCos[z]は複素 平面上で不連続な分枝切断線を持つ．
  • 関連する数学関数には，Cos，ArcSin，ArcCoshがある．

例題

すべて開く すべて閉じる

例  (6)

結果はラジアンである：

Wolfram Language code: ArcCos[0]

Degreeで割って結果を度で得る：

Wolfram Language code: ArcCos[0] / Degree//FullSimplify

実数の部分集合上でプロットする：

Wolfram Language code: Plot[ArcCos[x], {x, -1, 1}]

複素数の部分集合上でプロットする：

Wolfram Language code: ComplexPlot3D[ArcCos[z], {z, -4 - 2I, 4 + 2I}, PlotLegends -> Automatic]

0における級数展開：

Wolfram Language code: Series[ArcCos[x], {x, 0, 10}]

Infinityにおける漸近展開：

Wolfram Language code: Series[ArcCos[x], {x, ∞, 5}]

特異点における漸近展開：

Wolfram Language code: Series[ArcCos[x], {x, 1, 3}, Assumptions -> x > 1]//Simplify

スコープ  (41)

数値評価  (6)

数値的に評価する：

Wolfram Language code: ArcCos[0.4]
Wolfram Language code: ArcCos[1.5]

高精度で評価する：

Wolfram Language code: N[ArcCos[1 / 3], 50]

出力の精度は入力の精度に従う：

Wolfram Language code: ArcCos[0.33333333333333333333333333333333333333333]

複素引数について評価する：

Wolfram Language code: ArcCos[2.5 + I]

ArcCosを高精度で効率的に評価する：

Wolfram Language code: ArcCos[0.4`500]//Timing
Wolfram Language code: ArcCos[0.4`100000];//Timing

IntervalオブジェクトとCenteredIntervalオブジェクトを使って最悪の場合に保証される区間を計算する：

Wolfram Language code: ArcCos[Interval[{1 / 3, 1 / 2}]]
Wolfram Language code: ArcCos[CenteredInterval[1 / 2, 1 / 100]]
Wolfram Language code: ArcCos[CenteredInterval[2 + 3I, (1 + I) / 100]]

Aroundを使って平均的な場合の統計区間を計算することもできる：

Wolfram Language code: ArcCos[Around[.9, 0.1]]

配列の要素ごとの値を計算する：

Wolfram Language code: ArcCos[{{1, 1 / Sqrt[2]}, {0, 1 / Sqrt[2]}}]

MatrixFunctionを使って行列のArcCos関数を計算することもできる：

Wolfram Language code: MatrixFunction[ArcCos[#]&, {{1, 1 / Sqrt[2]}, {0, 1 / Sqrt[2]}}]

特定の値  (4)

固定点におけるArcCosの値：

Wolfram Language code: Table[ArcCos[(n /2)], {n, -2, 2}]

無限大における値：

Wolfram Language code: ArcCos[Infinity]
Wolfram Language code: ArcCos[ComplexInfinity]

ArcCosの零点：

Wolfram Language code: ArcCos[1]

方程式を満足する の値を求める：

Wolfram Language code: f[x_] := ArcCos[x] - (π/3);
Wolfram Language code: sol = Solve[f[x] == 0, x]

値を代入する：

Wolfram Language code: xzero = x /. First[sol]

結果を可視化する：

Wolfram Language code: Plot[f[x], {x, -1, 1}, Epilog -> Style[Point[{xzero, f[xzero]}], PointSize[Large], Red]]

可視化  (3)

ArcCos関数をプロットする：

Wolfram Language code: Plot[ArcCos[x], {x, -1, 1}]

の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[ArcCos[z]], {z, -3 - 3I, 3 + 3I}, IconizedObject[«PlotOptions»]]

の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[ArcCos[z]], {z, -3 - 3I, 3 + 3I}, IconizedObject[«PlotOptions»]]

による極プロット：

Wolfram Language code: Table[PolarPlot[ArcCos[k ϕ], {ϕ, -π, π}, Sequence[Frame -> True, Exclusions -> None, PlotLabel -> "k=" <> ToString[k], PlotRange -> All]], {k, 1, 4}]

関数の特性  (10)

ArcCosは，区間からのすべての実数値について定義される：

Wolfram Language code: FunctionDomain[ArcCos[x], x]

複素領域は平面全体である：

Wolfram Language code: FunctionDomain[ArcCos[z], z, Complexes]

ArcCosは区間からのすべての実数値に達する：

Wolfram Language code: FunctionRange[ArcCos[x], x, y]

複素領域からの引数についての関数領域：

Wolfram Language code: FunctionRange[ArcCos[z], z, y, Complexes]

ArcCosは解析関数ではない：

Wolfram Language code: FunctionAnalytic[ArcCos[x], x]

有理型でもない：

Wolfram Language code: FunctionMeromorphic[ArcCos[x], x]

ArcCosは，非減少でも非増加でもない：

Wolfram Language code: FunctionMonotonicity[ArcCos[x], x]

実数領域上で単調である：

Wolfram Language code: FunctionMonotonicity[{ArcCos[x], -1 ≤ x ≤ 1}, x]

ArcCosは単射である：

Wolfram Language code: FunctionInjective[ArcCos[x], x]
Wolfram Language code: Plot[{ArcCos[x], 1 / 2}, {x, -2π, 2π}]

ArcCosは全射ではない：

Wolfram Language code: FunctionSurjective[ArcCos[x], x]
Wolfram Language code: Plot[{ArcCos[x], 3.5}, {x, -2π, 2π}]

ArcCosは実数領域上で非負である：

Wolfram Language code: FunctionSign[{ArcCos[x], -1 ≤ x ≤ 1}, x]

ArcCosは，(-∞,-1]と[1,∞)に特異点と不連続点の両方を持つ：

Wolfram Language code: FunctionSingularities[ArcCos[x], x]
Wolfram Language code: FunctionDiscontinuities[ArcCos[x], x]

ArcCosは凸でも凹でもない：

Wolfram Language code: FunctionConvexity[ArcCos[x], x]

TraditionalFormによる表示：

Wolfram Language code: ArcCos[x]//TraditionalForm

微分  (3)

一次導関数：

Wolfram Language code: D[ArcCos[x], x]

高次導関数：

Wolfram Language code: Table[D[ArcCos[x], {x, n}], {n, 1, 4}]
Wolfram Language code: Plot[Evaluate[%], {x, -1, 1}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

次導関数の式：

Wolfram Language code: D[ArcCos[x], {x, n}]

積分  (3)

ArcCosの不定積分：

Wolfram Language code: Integrate[ArcCos[x], x]

実領域全体でのArcCosの定積分：

Wolfram Language code: Integrate[ArcCos[x], {x, -1, 1}]

その他の積分例：

Wolfram Language code: Integrate[ArcCos[x] ArcSin[x], x]
Wolfram Language code: Integrate[ArcCos[z]^a, z]

級数展開  (4)

Seriesを使ってテイラー(Taylor)展開を求める：

Wolfram Language code: Series[ArcCos[x], {x, 0, 7}]

の周りのArcCosについて最初の3つの近似をプロットする：

Wolfram Language code: terms = Normal@Table[Series[ArcCos[x], {x, 0, m}], {m, 1, 5, 2}]; Plot[{ArcCos[x], terms}, {x, -1, 1}, PlotRange -> {{-1, 1}, All}]

ArcCosの級数展開における一般項：

Wolfram Language code: SeriesCoefficient[ArcCos[x], {x, 0, n}]

分岐点と分枝切断線における級数展開を求める：

Wolfram Language code: Series[ArcCos[x], {x, 1, 1}]
Wolfram Language code: Series[ArcCos[x], {x, -2, 1}]

ArcCosはベキ級数に適用できる：

Wolfram Language code: ArcCos[x + (x^2/2) + (x^3/3) + O[x]^4]

関数の恒等式と簡約  (3)

ArcCosを含む式を簡約する：

Wolfram Language code: FullSimplify[ArcCos[Sqrt[1 - x^2]], 0 ≤ x ≤ 1]

TrigToExpを使って，対数と平方根によって表現する：

Wolfram Language code: TrigToExp@ArcCos[z]
Wolfram Language code: ExpToTrig[%]//FullSimplify

実変数 および を仮定して展開する：

Wolfram Language code: ComplexExpand[ArcCos[x + I y]]

関数表現  (5)

ArcSecを使って表現する：

Wolfram Language code: ArcSec[1 / x]//FullSimplify

ヤコビ関数の逆関数を介した表現：

Wolfram Language code: InverseJacobiCN[z, 0]
Wolfram Language code: InverseJacobiDC[(1/z), 0]//FullSimplify

Hypergeometric2F1を使って表現する：

Wolfram Language code: z Hypergeometric2F1[1 / 2, 1 / 2, 3 / 2, z ^ 2]

MeijerGによる表現：

Wolfram Language code: (π/2) - x / 2 / Sqrt[π]MeijerG[{{(1/2), (1/2)}, {}}, {{0}, {-(1/2)}}, -x^2]//FullSimplify

ArcCosはDifferentialRootとして表すことができる：

Wolfram Language code: DifferentialRootReduce[ArcCos[x], x]

アプリケーション  (5)

ArcCosの実部と虚部をプロットする：

Wolfram Language code: Plot[{Re[ArcCos[x]], Im[ArcCos[x]]}, {x, -2, 2}, PlotStyle -> Thick]

ArcCosのリーマン(Riemann)面をプロットする：

Wolfram Language code: ParametricPlot3D[Evaluate[{Re[Cos[u + I v]], Im[Cos[u + I v]], u}], {u, 0, 4π}, {v, -2, 2}]

2つのベクトル間の角度を求める：

Wolfram Language code: ArcCos[Normalize[{1, 1}].Normalize[{-1, 1}]]
Wolfram Language code: Graphics[{Arrow[{{0, 0}, {1, 1}}], Arrow[{{0, 0}, {-1, 1}}]}, PlotRange -> All]

微分方程式を解く：

Wolfram Language code: DSolve[(b + a x) y[x] + (-1 + 2 x) Derivative[1][y][x] + 2 (-1 + x) x Derivative[2][y][x] == 0, y[x], x]

葉序パターンの3Dバージョン：

Wolfram Language code: Graphics3D[Sphere[Table[FromSphericalCoordinates[N@{1, ArcCos[1 - i / 1000], Mod[i GoldenAngle, 2Pi, -Pi]}], {i, 1, 1000}], .04]]

特性と関係  (9)

逆関数で構成する：

Wolfram Language code: {Cos[ArcCos[z]], ArcCos[Cos[z]]}

PowerExpandを使ってArcCosの多価性を無視する：

Wolfram Language code: PowerExpand[%]

別な方法として，追加的な仮定の下で評価する：

Wolfram Language code: Refine[ArcCos[Cos[z]], 0 < z < Pi / 2]

TrigToExpを使いArcCosを対数と平方根を通して表現する：

Wolfram Language code: ArcCos[z]//TrigToExp

以下はArcCos関数の分枝切断線を示す：

Wolfram Language code: Plot3D[Im[ArcCos[x - I y]], {x, -2, 2}, {y, -2, 2}]

ArcCosは角度をラジアンで与えるのに対し，ArcCosDegreesは同じ角度を度で与える：

Wolfram Language code: ArcCos[1 / 2]
Wolfram Language code: ArcCosDegrees[1 / 2]

実変数を仮定して展開する：

Wolfram Language code: ComplexExpand[ArcCos[x + I y]]

逆三角方程式を解く：

Wolfram Language code: Reduce[ArcCos[z]^3 + 3 ArcCos[z] == 2, z]
Wolfram Language code: Reduce[ArcCos[Cos[z]] == w, z]

ゼロについて解く：

Wolfram Language code: Reduce[ArcCos[α x + β] == 0, x]

ラプラス(Laplace)変換：

Wolfram Language code: LaplaceTransform[ArcCos[t], t, s]

ArcCosは自動的にさまざまな数学関数の特殊ケースとして返される：

Wolfram Language code: InverseJacobiCD[z, 0]

考えられる問題  (4)

一般的に である：

Wolfram Language code: ArcCos[Cos[30.]]
Wolfram Language code: Cos[ArcCos[30.]]

分枝切断線においては，機械精度の入力が数値的に間違った答を返すことがある：

Wolfram Language code: ArcCos[-2 + I((Pi + 1) ^ 2 - Pi ^ 2 - 2Pi - 1 - Exp[-Pi ^ 4])]//N
Wolfram Language code: ArcCos[-2 + I((Pi + 1) ^ 2 - Pi ^ 2 - 2Pi - 1 - Exp[-Pi ^ 4])]//N[#, 20]&

出力精度は入力精度よりもはるかに低いことがある：

Wolfram Language code: ArcCos[0.99999999999999999999999999999999999991]

慣用形では，引数の周りに丸カッコが必要である：

Wolfram Language code: cos^-1x
Wolfram Language code: cos^-1(x)

おもしろい例題  (2)

ネストした積分：

Wolfram Language code: NestList[Integrate[#, x]&, ArcCos[x], 4]

以下はArcCosベキ乗関数の分枝切断線を示す：

Wolfram Language code: Plot3D[Im[ArcCos[(x + I y) ^ 3]], {x, -2, 2}, {y, -2, 2}, ...]
Wolfram Research (1988), ArcCos, Wolfram言語関数， https://reference.wolfram.com/language/ref/ArcCos.html （2021年に更新）.

テキスト

Wolfram Research (1988), ArcCos, Wolfram言語関数， https://reference.wolfram.com/language/ref/ArcCos.html （2021年に更新）.

CMS

Wolfram Language. 1988. "ArcCos." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2021. https://reference.wolfram.com/language/ref/ArcCos.html.

APA

Wolfram Language. (1988). ArcCos. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ArcCos.html

BibTeX

@misc{reference.wolfram_2026_arccos, author="Wolfram Research", title="{ArcCos}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/ArcCos.html}", note=[Accessed: 13-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_arccos, organization={Wolfram Research}, title={ArcCos}, year={2021}, url={https://reference.wolfram.com/language/ref/ArcCos.html}, note=[Accessed: 13-August-2026]}