WOLFRAM

Wolfram 语言与系统参考资料中心

ArcCosDegrees[z]

给出复数 的反余弦，以度为单位.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
数值运算  
特定值  
可视化  
Show More Show More
函数的属性  
微分  
积分  
级数展开  
函数同一性和简化  
函数表示法  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
技术笔记
相关指南
历史
按以下格式引用：

ArcCosDegrees

ArcCosDegrees[z]

给出复数 的反余弦，以度为单位.

更多信息

  • ArcCosDegrees，以及其他反三角函数和三角函数在高中几何课程中学习，在许多科学学科中也有应用.
  • 所有结果均以度为单位.
  • 对于介于 和 之间的实数 ，结果总是在 到 之间.
  • ArcCosDegrees[z] 返回直角三角形邻边与斜边的比值为 的角度 ，以度为单位.
  • 对于某些特殊参数，ArcCosDegrees 会自动求出精确值.
  • ArcCosDegrees 可以按照任意数值精度进行计算.
  • ArcCosDegrees 自动逐项作用于列表的各个元素.
  • ArcCosDegrees[z] 在复平面 上有从 到 和 到 的分支切割不连续性.
  • ArcCosDegrees 可用于 Interval、CenteredInterval 和 Around 对象.
  • 数学函数，适用于符号和数字操作.

范例

打开所有单元 关闭所有单元

基本范例  (7)

结果以度为单位：

Wolfram Language code: ArcCosDegrees[0]

计算这个直角三角形的角 BAC：

手动计算：

Wolfram Language code: β = ArcCosDegrees[3 / 8]

该角度的数值：

Wolfram Language code: %//N

求解反三角方程：

Wolfram Language code: Solve[ArcCosDegrees[x] == 60, x]

求解反三角不等式：

Wolfram Language code: Reduce[ArcCosDegrees[x] > 60, x]

将 ArcCosDegrees 应用于以下列表：

Wolfram Language code: ArcCosDegrees[{0, 1 / 2, 1 / Sqrt[2], Sqrt[3] / 2, 1}]

在实数子集上绘图：

Wolfram Language code: Plot[ArcCosDegrees[x], {x, -1, 1}]

0 处的级数展开：

Wolfram Language code: Series[ArcCosDegrees[x], {x, 0, 10}]

范围  (38)

数值运算  (6)

进行数值运算：

Wolfram Language code: ArcCosDegrees[0.4]
Wolfram Language code: ArcCosDegrees[1.5]

高精度运算：

Wolfram Language code: N[ArcCosDegrees[1 / 3], 50]

输出的精度与输入的精度一致：

Wolfram Language code: ArcCosDegrees[0.33333333333333333333333333333333333333333]

复参数的运算：

Wolfram Language code: ArcCosDegrees[2.5 + I]

以高精度高效运算 ArcCosDegrees：

Wolfram Language code: ArcCosDegrees[0.4`500]//Timing
Wolfram Language code: ArcCosDegrees[0.4`100000];//Timing

使用 Interval 和 CenteredInterval 对象计算最坏情况下的保证区间（guaranteed intervals）：

Wolfram Language code: ArcCosDegrees[Interval[{1 / 3, 1 / 2}]]
Wolfram Language code: ArcCosDegrees[CenteredInterval[1 / 2, 1 / 100]]
Wolfram Language code: ArcCosDegrees[CenteredInterval[2 + 3I, (1 + I) / 100]]

或使用 Around 计算平均情况统计区间：

Wolfram Language code: ArcCosDegrees[Around[.9, 0.01]]

计算数组的元素值：

Wolfram Language code: ArcCosDegrees[{{1, 1 / Sqrt[2]}, {0, 1 / Sqrt[2]}}]

或者使用 MatrixFunction 计算矩阵 ArcCosDegrees 函数：

Wolfram Language code: MatrixFunction[ArcCosDegrees[#]&, {{1, 1 / Sqrt[2]}, {0, 1 / Sqrt[2]}}]

特定值  (5)

固定点处的 ArcCosDegrees 值：

Wolfram Language code: Table[ArcCosDegrees[(n /2)], {n, -2, 2}]

会自动生成简单的精确值：

Wolfram Language code: ArcCosDegrees[(1/Sqrt[2])]

无穷大时的值：

Wolfram Language code: ArcCosDegrees[Infinity]
Wolfram Language code: ArcCosDegrees[ComplexInfinity]

ArcCosDegrees 的零点：

Wolfram Language code: ArcCosDegrees[1]

求满足方程 的 值：

Wolfram Language code: f[x_] := ArcCosDegrees[x] - 60;
Wolfram Language code: sol = Solve[f[x] == 0, x]

代入数值：

Wolfram Language code: xzero = x /. First[sol]

将结果可视化：

Wolfram Language code: Plot[f[x], {x, -1, 1}, Rule[...]]

可视化  (4)

绘制 ArcCosDegrees 函数：

Wolfram Language code: Plot[ArcCosDegrees[x], {x, -1, 1}]

在复数子集上绘图：

Wolfram Language code: ComplexPlot3D[ArcCosDegrees[z], {z, -4 - 2I, 4 + 2I}, Rule[...]]

绘制 ArcCosDegrees 的实部：

Wolfram Language code: ComplexContourPlot[Re[ArcCosDegrees[z]], {z, -3 - 3I, 3 + 3I}, ...]

绘制 ArcCosDegrees 的虚部：

Wolfram Language code: ComplexContourPlot[Im[ArcCosDegrees[z]], {z, -3 - 3I, 3 + 3I}, ...]

使用 ArcCosDegrees 绘制极坐标图：

Wolfram Language code: Table[PolarPlot[ArcCosDegrees[k ϕ], {ϕ, -π, π}, ...], {k, 1, 4}]

函数的属性  (10)

ArcCosDegrees 定义域为区间 中的所有实数值：

Wolfram Language code: FunctionDomain[ArcCosDegrees[x], x]

复数域是整个平面：

Wolfram Language code: FunctionDomain[ArcCosDegrees[z], z, Complexes]

ArcCosDegrees 值域为区间 内的所有实数值：

Wolfram Language code: FunctionRange[ArcCosDegrees[x], x, y]

复参数的值域：

Wolfram Language code: FunctionRange[ArcCosDegrees[x], x, y, Complexes]

ArcCosDegrees 不是解析函数：

Wolfram Language code: FunctionAnalytic[ArcCosDegrees[x], x]

也不是亚纯函数：

Wolfram Language code: FunctionMeromorphic[ArcCosDegrees[x], x]

ArcCosDegrees 既不是非递减也不是非递增：

Wolfram Language code: FunctionMonotonicity[ArcCosDegrees[x], x]

它在实域上是单调的：

Wolfram Language code: FunctionMonotonicity[{ArcCosDegrees[x], -1 ≤ x ≤ 1}, x]

ArcCosDegrees 是单射函数：

Wolfram Language code: FunctionInjective[ArcCosDegrees[x], x]
Wolfram Language code: Plot[{ArcCosDegrees[x], 90}, {x, -1, 1}]

ArcCosDegrees 不是满射函数：

Wolfram Language code: FunctionSurjective[ArcCosDegrees[x], x]
Wolfram Language code: Plot[{ArcCosDegrees[x], 250}, {x, -1, 1}]

ArcCosDegrees 在其实域上为非负：

Wolfram Language code: FunctionSign[{ArcCosDegrees[x], -1 ≤ x ≤ 1}, x]

ArcCosDegrees 在 (-∞,-1] 和 [1,∞) 都有奇点和不连续性：

Wolfram Language code: FunctionSingularities[ArcCosDegrees[x], x]
Wolfram Language code: FunctionDiscontinuities[ArcCosDegrees[x], x]

ArcCosDegrees 既不是凸函数也不是凹函数：

Wolfram Language code: FunctionConvexity[ArcCosDegrees[x], x]

ArcCosDegrees x 在 [-1,0] 区间内为凸函数：

Wolfram Language code: FunctionConvexity[{ArcCosDegrees[x], -1 <= x <= 0}, x]
Wolfram Language code: Plot[ArcCosDegrees[x], {x, -1, 0}]

TraditionalForm 格式:

Wolfram Language code: ArcCosDegrees[α]//TraditionalForm

微分  (3)

一阶导数：

Wolfram Language code: D[ArcCosDegrees[x], x]

更高阶导数：

Wolfram Language code: Table[D[ArcCosDegrees[x], {x, n}], {n, 1, 4}]
Wolfram Language code: Plot[Evaluate[%], {x, -1, 1}, Rule[...]]

阶导数公式：:

Wolfram Language code: D[ArcCosDegrees[x], {x, n}]

积分  (2)

ArcCosDegrees 的不定积分：

Wolfram Language code: Integrate[ArcCosDegrees[x], x]

ArcCosDegrees 在整个实域上的定积分：

Wolfram Language code: Integrate[ArcCosDegrees[x], {x, -1, 1}]

级数展开  (5)

利用 Series 求泰勒展开式：

Wolfram Language code: Series[ArcCosDegrees[x], {x, 0, 7}]

在 周围绘制 ArcCosDegrees 的前三个近似值：

Wolfram Language code: terms = Normal@Table[Series[ArcCosDegrees[x], {x, 0, m}], {m, 1, 5, 2}]; Plot[{ArcCosDegrees[x], terms}, {x, -1, 1}, PlotRange -> {{-1, 1}, All}]

Infinity 处的渐近展开：

Wolfram Language code: Series[ArcCosDegrees[x], {x, ∞, 5}]

奇点处的渐近展开：

Wolfram Language code: Series[ArcCosDegrees[x], {x, -1, 5}, Assumptions -> x > 1]//Simplify

求分支点和分支切割处的数列展开式：

Wolfram Language code: Series[ArcCosDegrees[x], {x, 1, 1}]
Wolfram Language code: Series[ArcCosDegrees[x], {x, -2, 1}]

ArcCosDegrees 可用于幂级数：

Wolfram Language code: ArcCosDegrees[x + (x^2/2) + (x^3/3) + O[x]^4]

函数同一性和简化  (2)

简化有关 ArcCosDegrees 的表达式：

Wolfram Language code: FullSimplify[ArcCosDegrees[Sqrt[1 - x^2]], 0 ≤ x ≤ 1]

使用 TrigToExp 通过对数和平方根进行表达：

Wolfram Language code: TrigToExp@ArcCosDegrees[z]

函数表示法  (1)

使用 ArcSecDegrees 进行表示：

Wolfram Language code: ArcSecDegrees[1 / x]//FullSimplify

应用  (8)

求解反三角方程：

Wolfram Language code: Solve[ArcCosDegrees[z]^2 + 3 ArcCosDegrees[z] == 2, z]

求解带参数的反三角方程：

Wolfram Language code: Reduce[ArcCosDegrees[Cos[z]] == w, z]

获取 ArcCosDegrees 的零点：

Wolfram Language code: Solve[ArcCosDegrees[α x + β] == 0, x]

使用 Reduce 解决关于 ArcCosDegrees 的不等式：

Wolfram Language code: Reduce[ArcCosDegrees[x] > 60, x]

通过数字求出超越方程的根：

Wolfram Language code: FindRoot[ArcCosDegrees[z] - 1 / 3 ArcCosDegrees[z + 1 / 3] == 50, {z, 1 / 2, 2}]//Chop

绘制函数图，检查解是否正确：

Wolfram Language code: Plot[ArcCosDegrees[z] - 1 / 3 ArcCosDegrees[z + 1 / 3] - 50, {z, 0, 1}]

绘制 ArcCosDegrees 的实部和虚部：

Wolfram Language code: ReImPlot[ArcCosDegrees[x], {x, -3, 3}]

绘制 ArcCosDegrees 的黎曼曲面：

Wolfram Language code: ParametricPlot3D[Evaluate[{Re[CosDegrees[u + I v]], Im[CosDegrees[u + I v]], u}], {u, 0, 720}, {v, -450, 450}]

求两个向量之间的夹角：

Wolfram Language code: ArcCosDegrees[Normalize[{1, 1}].Normalize[{-1, 1}]]
Wolfram Language code: Graphics[{Arrow[{{0, 0}, {1, 1}}], Arrow[{{0, 0}, {-1, 1}}]}, PlotRange -> All]

属性和关系  (5)

与反函数合成：

Wolfram Language code: {CosDegrees[ArcCosDegrees[z]], ArcCosDegrees[CosDegrees[z]]}

使用 PowerExpand 可忽略 ArcCosDegrees 的多值性：

Wolfram Language code: PowerExpand[%]

或者，根据其他假设进行评估：

Wolfram Language code: Refine[ArcCosDegrees[CosDegrees[z]], 0 < z < 90]

这显示了 ArcCosDegrees 函数的分支切割：

Wolfram Language code: Plot3D[Im[ArcCosDegrees[x - I y]], {x, -2, 2}, {y, -2, 2}]

ArcCosDegrees 以度数为单位给出角度，而 ArcCos 以弧度为单位给出角度：

Wolfram Language code: ArcCosDegrees[1 / 2]
Wolfram Language code: ArcCos[1 / 2]

FunctionExpand 应用于 ArcCosDegrees 会生成以弧度为单位的三角函数表达式：

Wolfram Language code: FunctionExpand[ArcCosDegrees[x]]
Wolfram Language code: FunctionExpand[ArcCosDegrees[x ^ 2]ArcCosDegrees[120 - x / 2]]

ExpToTrig 应用于 TrigToExp 将生成以弧度为单位的三角函数：

Wolfram Language code: ArcCosDegrees[z]//TrigToExp
Wolfram Language code: ExpToTrig[%]

可能存在的问题  (3)

一般情况下 ：

Wolfram Language code: ArcCosDegrees[CosDegrees[30.]]
Wolfram Language code: CosDegrees[ArcCosDegrees[30.]]

在分支切割时，机器精度输入可能会给出数值错误的答案：

Wolfram Language code: ArcCosDegrees[-2 + I((180 + 1) ^ 2 - 180 ^ 2 - 2180 - 1 - Exp[-180 ^ 4])]//N
Wolfram Language code: ArcCosDegrees[-2 + I((180 + 1) ^ 2 - 180 ^ 2 - 2180 - 1 - Exp[-180 ^ 4])]//N[#, 20]&

输出的精度可能远远低于输入的精度：

Wolfram Language code: ArcCosDegrees[0.99999999999999999999999999999999999991]

巧妙范例  (3)

求解 ArcCosDegrees 相关的三角方程：

Wolfram Language code: Reduce[ArcCosDegrees[z] + ArcCosDegrees[z - 1 / 2] == 90, z]//Quiet

该角度的数值，单位为度：

Wolfram Language code: %//N

绘制指定的 ArcCosDegrees：

Wolfram Language code: Plot3D[Im[ArcCosDegrees[(x + I y) ^ 3]], {x, -2, 2}, {y, -2, 2}, ...]

绘制整数点的 ArcCosDegrees：

Wolfram Language code: ArrayPlot[Table[FractionalPart[Abs[ArcCosDegrees[x y]]], {x, -40, 40}, {y, -40, 40}]]
Wolfram Research (2024)，ArcCosDegrees，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ArcCosDegrees.html.

文本

Wolfram Research (2024)，ArcCosDegrees，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ArcCosDegrees.html.

CMS

Wolfram 语言. 2024. "ArcCosDegrees." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/ArcCosDegrees.html.

APA

Wolfram 语言. (2024). ArcCosDegrees. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ArcCosDegrees.html 年

BibTeX

@misc{reference.wolfram_2026_arccosdegrees, author="Wolfram Research", title="{ArcCosDegrees}", year="2024", howpublished="\url{https://reference.wolfram.com/language/ref/ArcCosDegrees.html}", note=[Accessed: 11-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_arccosdegrees, organization={Wolfram Research}, title={ArcCosDegrees}, year={2024}, url={https://reference.wolfram.com/language/ref/ArcCosDegrees.html}, note=[Accessed: 11-September-2026]}