WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ArcCsc[z]

複素数 の逆余割を与える．

詳細
Details and Options Details and Options
予備知識
例題  
例  
スコープ  
数値評価  
特定の値  
可視化  
Show More Show More
関数の特性  
微分  
積分  
級数展開  
関数の恒等式と簡約  
関数表現  
アプリケーション  
特性と関係  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

ArcCsc

ArcCsc[z]

複素数 の逆余割を与える．

詳細

  • 記号操作・数値操作の両方に適した数学関数である．
  • 答はラジアンで求まる．
  • z が実数で〜の区間の外にあるとき，答は必ず0を除いた〜の範囲にある．
  • 特別な引数の場合，ArcCscは自動的に厳密値を計算する．
  • ArcCscは任意の数値精度で評価できる．
  • ArcCscは自動的にリストに関数の並列的な適用を行う．
  • ArcCsc[z]は，複素 平面上，〜の範囲で不連続な分枝切断線を持つ．
  • ArcCscはIntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる． »

予備知識

  • ArcCscは逆余割関数である．実数 について，ArcCsc[x]は， となるような，ただしのラジアン角を表す．
  • ArcCscは自動的にリストに縫い込まれる．特別な引数の場合，ArcCscは自動的に厳密値を計算する．厳密な数式が引数として与えられると，ArcCscは任意の数値精度に評価できることがある．ArcCscを含む記号式の操作に便利なその他の演算には，FunctionExpand，TrigToExp，TrigExpand，Simplify，FullSimplifyがある．
  • ArcCscは，複素引数 について，によって定義される．ArcCsc[z]は複素 平面上で不連続な分枝切断線を持つ．
  • 関連する数学関数には，Csc，ArcSec，ArcCschがある．

例題

すべて開く すべて閉じる

例  (5)

結果はラジアンで与えられる：

Wolfram Language code: ArcCsc[1]

Degreeで割って結果を度で得る：

Wolfram Language code: ArcCsc[1] / Degree//FullSimplify

実数の部分集合上でプロットする：

Wolfram Language code: Plot[ArcCsc[x], {x, -5, 5}]

複素数の部分集合上でプロットする：

Wolfram Language code: ComplexPlot3D[ArcCsc[z], {z, -4 - 2I, 4 + 2I}, PlotLegends -> Automatic]

Infinityにおける漸近展開：

Wolfram Language code: Series[ArcCsc[x], {x, ∞, 5}]

特異点における漸近展開：

Wolfram Language code: Series[ArcCsc[x], {x, 1, 3}, Assumptions -> x > 1]//FullSimplify

スコープ  (41)

数値評価  (6)

数値的に評価する：

Wolfram Language code: ArcCsc[5.0]

高精度で評価する：

Wolfram Language code: N[ArcCsc[5], 50]

出力精度は入力精度に従う：

Wolfram Language code: ArcCsc[5.00000000000000000000000000000000000000000]

複素引数について評価する：

Wolfram Language code: ArcCsc[0.5 + 2.3I]

ArcCscを高精度で効率的に評価する：

Wolfram Language code: ArcCsc[5`500]//Timing
Wolfram Language code: ArcCsc[5`100000];//Timing

IntervalオブジェクトとCenteredIntervalオブジェクトを使って最悪の場合に保証される区間を計算する：

Wolfram Language code: ArcCsc[Interval[{1, 5}]]
Wolfram Language code: ArcCsc[CenteredInterval[-3, 1 / 100]]
Wolfram Language code: ArcCsc[CenteredInterval[2 + 3I, (1 + I) / 100]]

Aroundを使って平均的な場合の統計区間を計算することもできる：

Wolfram Language code: ArcCsc[Around[(2/Sqrt[3]), 0.1]]

配列の要素ごとの値を計算する：

Wolfram Language code: ArcCsc[{{Sqrt[2], -Sqrt[2]}, {0, -Sqrt[2]}}]

MatrixFunctionを使って行列のArcCsc関数を計算することもできる：

Wolfram Language code: MatrixFunction[ArcCsc[#]&, {{Sqrt[2], -Sqrt[2]}, {0, -Sqrt[2]}}]

特定の値  (4)

固定点におけるArcCscの値：

Wolfram Language code: {ArcCsc[-Sqrt[2]], ArcCsc[-(2/Sqrt[3])], ArcCsc[(2/Sqrt[3])], ArcCsc[Sqrt[2]]}

無限大における値：

Wolfram Language code: ArcCsc[Infinity]
Wolfram Language code: ArcCsc[ComplexInfinity]

ArcCscの特異点：

Wolfram Language code: ArcCsc[{1, -1, 0}]

ArcCscはこれらの点では微分不可能である：

Wolfram Language code: ArcCsc'[{1, -1, 0}]//Quiet

方程式 を満足する の値を求める：

Wolfram Language code: f[x_] := ArcCsc[x] - (π/3);
Wolfram Language code: sol = Solve[f[x] == 0, x]

値を代入する：

Wolfram Language code: xzero = x /. First[sol]

結果を可視化する：

Wolfram Language code: Plot[f[x], {x, 1, 2}, Epilog -> Style[Point[{xzero, f[xzero]}], PointSize[Large], Red]]

可視化  (3)

ArcCsc関数をプロットする：

Wolfram Language code: Plot[ArcCsc[x], {x, -2, 2}]

の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[ArcCsc[z]], {z, -2π - 2π I, 2π + 2π I}, IconizedObject[«PlotOptions»]]

の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[ArcCsc[z]], {z, -2π - 2π I, 2π + 2π I}, IconizedObject[«PlotOptions»]]

の極プロット：

Wolfram Language code: Table[PolarPlot[ArcCsc[k ϕ], {ϕ, -4π, 4π}, Sequence[Frame -> True, PlotLabel -> "k=" <> ToString[k], FrameTicks -> {{{-1, 0, 1}, None}, {{-1, 0, 1}, None}}, PlotRange -> {{-1, 1}, {-1, 1}}]], {k, 1, 4}]

関数の特性  (11)

ArcCscはからのものを除くすべての実数値について定義される：

Wolfram Language code: FunctionDomain[ArcCsc[x], x]

複素領域：

Wolfram Language code: FunctionDomain[ArcCsc[z], z, Complexes]

ArcCscは，0を除く区間からのすべての実数値に達する：

Wolfram Language code: FunctionRange[ArcCsc[x], x, y]

複素領域からの引数についての関数の範囲：

Wolfram Language code: FunctionRange[ArcCsc[z], z, y, Complexes]

ArcCscは奇関数である：

Wolfram Language code: ArcCsc[-x]

ArcCscは解析関数ではない：

Wolfram Language code: FunctionAnalytic[ArcCsc[x], x]

有理型でもない：

Wolfram Language code: FunctionMeromorphic[ArcCsc[x], x]

ArcCscは特定の領域で単調である：

Wolfram Language code: FunctionMonotonicity[ArcCsc[x], x]
Wolfram Language code: FunctionMonotonicity[{ArcCsc[x], x ≤ -1 }, x]
Wolfram Language code: FunctionMonotonicity[{ArcCsc[x], x ≥ 1}, x]
Wolfram Language code: Plot[ArcCsc[x], {x, -3, 3}]

ArcCscは単射である：

Wolfram Language code: FunctionInjective[ArcCsc[x], x]
Wolfram Language code: Plot[{ArcCsc[x], 1 / 2}, {x, -5, 5}]

ArcCscは全射ではない：

Wolfram Language code: FunctionSurjective[ArcCsc[x], x]
Wolfram Language code: Plot[{ArcCsc[x], 2}, {x, -5, 5}]

ArcCscは非負でも非正でもない：

Wolfram Language code: FunctionSign[ArcCsc[x], x]

[-1,1]で x について特異点と不連続点の両方を持つ：

Wolfram Language code: FunctionSingularities[ArcCsc[x], x]
Wolfram Language code: FunctionDiscontinuities[ArcCsc[x], x]

ArcCscは凸でも凹でもない：

Wolfram Language code: FunctionConvexity[ArcCsc[x], x]

TraditionalFormによる表示：

Wolfram Language code: ArcCsc[x]//TraditionalForm

微分  (3)

一次導関数：

Wolfram Language code: D[ArcCsc[x], x]

高次導関数：

Wolfram Language code: Table[D[ArcCsc[x], {x, n}], {n, 1, 4}]//FullSimplify
Wolfram Language code: Plot[Evaluate[%], {x, -3, 3}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

次導関数の式：

Wolfram Language code: D[ArcCsc[x], {x, n}]

積分  (3)

ArcCscの不定積分：

Wolfram Language code: Integrate[ArcCsc[x], x]

区間上でのArcCscの定積分：

Wolfram Language code: Integrate[ArcCsc[x], {x, 1, 2}]

その他の積分例：

Wolfram Language code: Integrate[x ArcCsc[x], x]
Wolfram Language code: Integrate[z ^ k ArcCsc[z], z]

級数展開  (3)

Seriesを使ってテイラー(Taylor)展開を求める：

Wolfram Language code: Series[ArcCsc[x], {x, 2, 4}]

の周囲のArcCscの最初の3つの近似をプロットする：

Wolfram Language code: terms = Normal@Table[Series[ArcCsc[x], {x, 2, m}], {m, 1, 3}]; Plot[{ArcCsc[x], terms}, {x, 1, 3}, PlotRange -> {{1, 3}, {0, 3}}]

分岐点および分枝切断線における級数展開を求める：

Wolfram Language code: Series[ArcCsc[x], {x, 1, 1}]
Wolfram Language code: Series[ArcCsc[x], {x, -1 / 2, 1}]

ArcCscはベキ級数に適用できる：

Wolfram Language code: ArcCsc[x + x ^ 2 + O[x, Infinity] ^ 4]

関数の恒等式と簡約  (3)

ArcCscを含む式を簡約する：

Wolfram Language code: FullSimplify[ArcCsc[Sqrt[(1/1 - x^2)]], 0 ≤ x ≤ 1]

逆関数を使って構築する：

Wolfram Language code: {ArcCsc[Csc[z]], Csc[ArcCsc[z]]}

PowerExpandを使ってArcCscの多価性を無視する：

Wolfram Language code: PowerExpand[%]

あるいは，追加的な仮定のもとで評価する：

Wolfram Language code: Refine[ArcCsc[Csc[z]], 0 < z < Pi / 2]

TrigToExpを使って対数によって表現する：

Wolfram Language code: ArcCsc[z]//TrigToExp

ExpToTrigを使って変換し直す：

Wolfram Language code: ExpToTrig[%]//FullSimplify

関数表現  (5)

ArcSinを使って表現する：

Wolfram Language code: ArcSin[(1/z)]//FullSimplify

逆ヤコビ関数を介して表現する：

Wolfram Language code: InverseJacobiDS[z, 0]
Wolfram Language code: InverseJacobiNS[z, 0]

Hypergeometric2F1を使って表現する：

Wolfram Language code: (Hypergeometric2F1[(1/2), (1/2), (3/2), (1/z^2)]/z)//FullSimplify

ArcCscはMeijerGによって表すことができる：

Wolfram Language code: MeijerGReduce[ArcCsc[x], x]
Wolfram Language code: Activate[%]//FullSimplify

ArcCscはDifferentialRootとして表すことができる：

Wolfram Language code: DifferentialRootReduce[ArcCsc[x], x]

アプリケーション  (3)

ArcCscの分枝切断線は実軸に沿っている：

Wolfram Language code: Plot3D[Im[ArcCsc[x - I y]], {x, -2, 2}, {y, -2, 2}]

微分方程式を解く：

Wolfram Language code: DSolve[2 x Sin[(y[x]/x)] - Cot[(y[x]/x)] y[x] + x Cot[(y[x]/x)] y'[x] == 0, y[x], x]//Quiet

d 次元超球のすべての点のペアの平均距離 s の分布：

Wolfram Language code: p[d_, s_] := d s ^ (d - 1) BetaRegularized[1 - s ^ 2 / 4, (d + 1) / 2, 1 / 2]

低次元分布は初等関数で表現できる：

Wolfram Language code: Table[FullSimplify[FunctionExpand[p[d, s]], s > 0], {d, 3}]

分布をプロットする：

Wolfram Language code: Plot[Evaluate[Table[p[d, s], {d, 10}]], {s, 0, 2}]

特性と関係  (5)

逆関数で構成する：

Wolfram Language code: {ArcCsc[Csc[z]], Csc[ArcCsc[z]]}

PowerExpandを使ってArcCscの多価性を無視する：

Wolfram Language code: PowerExpand[%]

別の方法として，追加的な仮定をして評価する：

Wolfram Language code: Refine[ArcCsc[Csc[z]], 0 < z < Pi / 2]

TrigToExpを使って対数で表す：

Wolfram Language code: ArcCsc[z]//TrigToExp

ExpToTrigを使ってもとに戻す：

Wolfram Language code: ExpToTrig[%]

ArcCscは角度をラジアンで与えるが，ArcCscDegreesは同じ角度を度で与える：

Wolfram Language code: ArcCsc[2]
Wolfram Language code: ArcCscDegrees[2]

FunctionExpandを使って逆三角関数の三角関数を代数関数に転換する：

Wolfram Language code: FunctionExpand[Tan[5ArcCsc[z]]]

結果を簡約する：

Wolfram Language code: Simplify[%]

Reduceを使ってArcCscを含む方程式を解く：

Wolfram Language code: Reduce[ArcCsc[z] + ArcCsc[z + 1] == Pi / 2, z]//Quiet
Wolfram Research (1988), ArcCsc, Wolfram言語関数， https://reference.wolfram.com/language/ref/ArcCsc.html （2021年に更新）.

テキスト

Wolfram Research (1988), ArcCsc, Wolfram言語関数， https://reference.wolfram.com/language/ref/ArcCsc.html （2021年に更新）.

CMS

Wolfram Language. 1988. "ArcCsc." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2021. https://reference.wolfram.com/language/ref/ArcCsc.html.

APA

Wolfram Language. (1988). ArcCsc. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ArcCsc.html

BibTeX

@misc{reference.wolfram_2026_arccsc, author="Wolfram Research", title="{ArcCsc}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/ArcCsc.html}", note=[Accessed: 16-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_arccsc, organization={Wolfram Research}, title={ArcCsc}, year={2021}, url={https://reference.wolfram.com/language/ref/ArcCsc.html}, note=[Accessed: 16-August-2026]}