WOLFRAM

Wolfram 语言与系统参考资料中心

ArcSec[z]

给出复数 的反正割 .

更多信息
Details and Options Details and Options
背景
范例  
基本范例  
范围  
数值计算  
特殊值  
可视化  
Show More Show More
函数属性  
微分  
积分  
级数展开式  
函数恒等式和化简  
函数表示  
应用  
属性和关系  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

ArcSec

ArcSec[z]

给出复数 的反正割 .

更多信息

  • 数学函数，适宜于符号和数值计算.
  • 所有结果以弧度给出.
  • 对于处在 到 区间之外的实数 ，其结果总在 到 的范围之内，不包括 .
  • 对于某些特殊参数，ArcSec 自动计算出精确值.
  • ArcSec 可以计算到任意数值精度.
  • ArcSec 自动逐项作用于列表的各个元素.
  • ArcSec[z] 在复平面 上有一个分支切割，从 到 .
  • ArcSec 可与 Interval 和 CenteredInterval 对象一起使用. »

背景

范例

打开所有单元 关闭所有单元

基本范例  (5)

结果以弧度表示：

Wolfram Language code: ArcSec[2]

除以 Degree 已得到以度为单位的结果：

Wolfram Language code: ArcSec[2] / Degree//FullSimplify

在实数域子集上绘图：

Wolfram Language code: Plot[ArcSec[x], {x, -5, 5}]

在复数的子集上绘图：

Wolfram Language code: ComplexPlot3D[ArcSec[z], {z, -4 - 2I, 4 + 2I}, PlotLegends -> Automatic]

在 Infinity 处的渐近展开：

Wolfram Language code: Series[ArcSec[x], {x, ∞, 5}]

奇点处的渐近展开：

Wolfram Language code: Series[ArcSec[x], {x, 1, 3}, Assumptions -> x > 1]//Simplify

范围  (41)

数值计算  (6)

数值计算：

Wolfram Language code: ArcSec[5.0]

高精度求值：

Wolfram Language code: N[ArcSec[5], 50]

输出精度与输入精度一致：

Wolfram Language code: ArcSec[5.00000000000000000000000000000000000000000]

对复变量进行计算：

Wolfram Language code: ArcSec[0.5 + 2.3I]

在高精度条件下高效计算 ArcSec：

Wolfram Language code: ArcSec[5`500]//Timing
Wolfram Language code: ArcSec[5`100000];//Timing

用 Interval 和 CenteredInterval 对象计算最坏情况下的区间：

Wolfram Language code: ArcSec[Interval[{2, 5}]]
Wolfram Language code: ArcSec[CenteredInterval[-3, 1 / 100]]
Wolfram Language code: ArcSec[CenteredInterval[2 + 3I, (1 + I) / 100]]

或使用 Around 计算一般情况下的统计区间：

Wolfram Language code: ArcSec[Around[(2/Sqrt[3]), 0.1]]

计算数组中每个元素的值：

Wolfram Language code: ArcSec[{{Sqrt[2], -Sqrt[2]}, {0, -Sqrt[2]}}]

或用 MatrixFunction 以矩阵形式计算 ArcSec 函数：

Wolfram Language code: MatrixFunction[ArcSec[#]&, {{Sqrt[2], -Sqrt[2]}, {0, -Sqrt[2]}}]

特殊值  (5)

ArcSec 在固定点上的值：

Wolfram Language code: Table[ArcSec[n], {n, -2, 2}]

自动生成简单精确值：

Wolfram Language code: ArcSec[(2/Sqrt[3])]

无穷处的值：

Wolfram Language code: ArcSec[Infinity]
Wolfram Language code: ArcSec[ComplexInfinity]

ArcSec 的零点：

Wolfram Language code: ArcSec[1]

求满足方程 的 值：

Wolfram Language code: f[x_] := ArcSec[x] - (π/3);
Wolfram Language code: sol = Solve[f[x] == 0, x]

替换为值：

Wolfram Language code: xzero = x /. First[sol]

可视化结果：

Wolfram Language code: Plot[f[x], {x, 1, 3}, Epilog -> Style[Point[{xzero, f[xzero]}], PointSize[Large], Red]]

可视化  (3)

绘制 ArcSec 函数：

Wolfram Language code: Plot[ArcSec[x], {x, -3, 3}]

绘制 的实部：

Wolfram Language code: ComplexContourPlot[Re[ArcSec[z]], {z, -2 - 2I, 2 + 2I}, IconizedObject[«PlotOptions»]]

绘制 的虚部：

Wolfram Language code: ComplexContourPlot[Im[ArcSec[z]], {z, -2 - 2I, 2 + 2I}, IconizedObject[«PlotOptions»]]

，绘制极坐标图：

Wolfram Language code: Table[PolarPlot[ArcSec[k ϕ], {ϕ, -5π, 5π}, Sequence[Frame -> True, PlotLabel -> "k=" <> ToString[k], PlotRange -> {{-2, 3}, {-3, 2}}]], {k, 1, 4}]

函数属性  (10)

ArcSec 对区间 之外的所有实数有定义：

Wolfram Language code: FunctionDomain[ArcSec[x], x]

复定义域：:

Wolfram Language code: FunctionDomain[ArcSec[z], z, Complexes]

ArcSec 的值域位于 到 ：

Wolfram Language code: FunctionRange[ArcSec[x], x, y]

参数取复定义域内的值时的值域：

Wolfram Language code: FunctionRange[ArcSec[z], z, y, Complexes]

ArcSec 不是解析函数：

Wolfram Language code: FunctionAnalytic[ArcSec[x], x]

也不是亚纯函数：

Wolfram Language code: FunctionMeromorphic[ArcSec[x], x]

ArcSec 在特定范围内是单调的：

Wolfram Language code: FunctionMonotonicity[ArcSec[x], x]
Wolfram Language code: FunctionMonotonicity[{ArcSec[x], x ≤ -1 }, x]
Wolfram Language code: FunctionMonotonicity[{ArcSec[x], x ≥ 1}, x]
Wolfram Language code: Plot[ArcSec[x], {x, 1, 3}]

ArcSec 是单射函数：

Wolfram Language code: FunctionInjective[ArcSec[x], x]
Wolfram Language code: Plot[{ArcSec[x], 1 / 2}, {x, -5, 5}]

ArcSec 不是满射函数：

Wolfram Language code: FunctionSurjective[ArcSec[x], x]
Wolfram Language code: Plot[{ArcSec[x], π / 2}, {x, -5, 5}]

ArcSec 在其实定义域上非负：

Wolfram Language code: FunctionSign[{ArcSec[x], x ≤ -1 || x ≥ 1}, x]

对于 x，函数在 [-1,1] 内有奇点和断点：

Wolfram Language code: FunctionSingularities[ArcSec[x], x]
Wolfram Language code: FunctionDiscontinuities[ArcSec[x], x]

ArcSec 既不凸，也不凹：

Wolfram Language code: FunctionConvexity[ArcSec[x], x]

TraditionalForm 格式：

Wolfram Language code: ArcSec[x]//TraditionalForm

微分  (3)

一阶导数：

Wolfram Language code: D[ArcSec[x], x]

高阶导数：

Wolfram Language code: Table[D[ArcSec[x], {x, n}], {n, 1, 4}]//FullSimplify
Wolfram Language code: Plot[Evaluate[%], {x, -3, 3}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

阶导数的公式：

Wolfram Language code: D[ArcSec[x], {x, n}]

积分  (3)

ArcSec 的不定积分：

Wolfram Language code: Integrate[ArcSec[x], x]

区间 上的定积分：

Wolfram Language code: Integrate[ArcSec[x], {x, 1, 2}]

更多积分：

Wolfram Language code: Integrate[x ArcSec[x], x]
Wolfram Language code: Integrate[z ^ k ArcSec[z], z]

级数展开式  (3)

使用 Series 求泰勒级数展开式：

Wolfram Language code: Series[ArcSec[x], {x, 2, 4}]

绘制 ArcSec 在 处的前三个近似式：

Wolfram Language code: terms = Normal@Table[Series[ArcSec[x], {x, 2, m}], {m, 1, 3}]; Plot[{ArcSec[x], terms}, {x, 1, 3}, PlotRange -> {{1, 3}, {0, 2}}]

求分支点上和分支切割的级数展开式：

Wolfram Language code: Series[ArcSec[x], {x, 1, 1}]//FullSimplify
Wolfram Language code: Series[ArcSec[x], {x, -1 / 2, 1}]

ArcSec 可被应用于幂级数：

Wolfram Language code: ArcSec[x + x ^ 2 + O[x, Infinity] ^ 4]

函数恒等式和化简  (3)

化简含有 ArcSec 的表达式：

Wolfram Language code: FullSimplify[ArcSec[Sqrt[(1/1 - x^2)]], 0 ≤ x ≤ 1]

通过 TrigToExp 用对数来表示：

Wolfram Language code: ArcSec[z]//TrigToExp

用 ExpToTrig 转换回去：

Wolfram Language code: ExpToTrig[%]//FullSimplify

假定实数变量 和 的情况下进行展开：

Wolfram Language code: ComplexExpand[ArcSec[x + I y]]

函数表示  (5)

使用 ArcCos 表示：

Wolfram Language code: ArcCos[(1/z)]//FullSimplify

通过逆 Jacobi 函数表示：

Wolfram Language code: InverseJacobiCD[(1/z), 0]//FullSimplify
Wolfram Language code: InverseJacobiCN[(1/z), 0]//FullSimplify

使用 Hypergeometric2F1 表示：

Wolfram Language code: (π/2) - (Hypergeometric2F1[(1/2), (1/2), (3/2), (1/x^2)]/x)//FullSimplify

可用 MeijerG 来表示 ArcSec：

Wolfram Language code: MeijerGReduce[ArcSec[x], x]
Wolfram Language code: Activate[%]//FullSimplify

ArcSec 可被表示为 DifferentialRoot：

Wolfram Language code: DifferentialRootReduce[ArcSec[x], x]

应用  (3)

ArcSec 沿实轴延伸的分支切割：

Wolfram Language code: Plot3D[Im[ArcSec[x + I y]], {x, -2, 2}, {y, -2, 2}]

解微分方程：

Wolfram Language code: DSolve[Cos[y[x]] (1 - x Cos[y[x]]) + x Log[x] Sin[y[x]] Derivative[1][y][x] == 0, y[x], x]//Quiet

使用 Parallelize 加快计算速度，可视化多个复三角函数：

Wolfram Language code: $TrigFunctions = {Sin, Cos, Sec, Csc, Tan, Cot, ArcSin, ArcCos, ArcSec, ArcCsc, ArcTan, ArcCot};
Wolfram Language code: Parallelize@Table[Plot3D[Abs[f[x + I y]], {x, -2, 2}, {y, -2, 2}, MeshFunctions -> Function@@@{{{x, y, z}, Re[f[x + I y]]}, {{x, y, z}, Im[f[x + I y]]}}, MeshShading -> {{Orange, None}, {None, Green}}, PlotLabel -> f, Ticks -> None, ImageSize -> 100], {f, $TrigFunctions}]

属性和关系  (5)

与反函数组合：

Wolfram Language code: {ArcSec[Sec[z]], Sec[ArcSec[z]]}

利用 PowerExpand 去掉 ArcSec 的多值性：

Wolfram Language code: PowerExpand[%]

也可在附加假设条件下计算：

Wolfram Language code: Refine[ArcSec[Sec[z]], 0 < z < Pi / 2]

利用 TrigToExp 以对数的形式表示：

Wolfram Language code: ArcSec[z]//TrigToExp

利用 ExpToTrig 反向变换：

Wolfram Language code: ExpToTrig[%]

ArcSec 给出以弧度为单位的角，ArcSecDegrees 给出相同的角，但以度为单位：

Wolfram Language code: ArcSec[2]
Wolfram Language code: ArcSecDegrees[2]

利用 FunctionExpand 将反三角函数的三角函数变换成代数函数：

Wolfram Language code: FunctionExpand[Tan[5ArcSec[z]]]

简化结果：

Wolfram Language code: Simplify[%]

利用 Reduce 求解包含 ArcSec 的方程：

Wolfram Language code: Reduce[ArcSec[z] + ArcSec[z + 1] == Pi / 2, z]//Quiet
Wolfram Research (1988)，ArcSec，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ArcSec.html （更新于 2021 年）.

文本

Wolfram Research (1988)，ArcSec，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ArcSec.html （更新于 2021 年）.

CMS

Wolfram 语言. 1988. "ArcSec." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2021. https://reference.wolfram.com/language/ref/ArcSec.html.

APA

Wolfram 语言. (1988). ArcSec. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ArcSec.html 年

BibTeX

@misc{reference.wolfram_2026_arcsec, author="Wolfram Research", title="{ArcSec}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/ArcSec.html}", note=[Accessed: 09-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_arcsec, organization={Wolfram Research}, title={ArcSec}, year={2021}, url={https://reference.wolfram.com/language/ref/ArcSec.html}, note=[Accessed: 09-August-2026]}