WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ArcSecDegrees[z]

複素数 の逆正割を度を単位として与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
数値評価  
特定の値  
可視化  
Show More Show More
関数の特性  
微分  
積分  
級数展開  
関数の恒等式と簡約  
関数表現  
アプリケーション  
特性と関係  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

ArcSecDegrees

ArcSecDegrees[z]

複素数 の逆正割を度を単位として与える．

詳細

  • ArcSecDegreesは，その他の逆三角関数および三角関数とともに，高等学校の幾何の授業で学ばれ，多くの科学分野で使われている．
  • 結果はすべて度を単位として与えられる．
  • からまでの区間の外の実数 については，結果は常にを除いてからまでの範囲になる．
  • ArcSecDegrees[z]は角 を度を単位として返す．直角三角形のこの角に対する隣辺と対辺の比は である．
  • 特別な引数の場合，ArcSecDegreesは，自動的に厳密値を計算する．
  • ArcSecDegreesは任意の数値精度で評価できる．
  • ArcSecDegreesは自動的にリストに縫い込まれる．
  • ArcSecDegrees[z]は，複素 平面上のからまでに不連続な分枝切断線を持つ．
  • ArcSecDegreesは，Interval，CenteredInterval，Aroundの各オブジェクトに使うことができる．
  • 記号操作・数値操作の両方に適した数学関数である．

例題

すべて開く すべて閉じる

例  (7)

結果の単位は度である：

Wolfram Language code: ArcSecDegrees[2]

次の直角三角形の角BACを計算する：

手計算で求める：

Wolfram Language code: β = ArcSecDegrees[8 / 3]

この角度の数値：

Wolfram Language code: %//N

逆三角関数の方程式を解く：

Wolfram Language code: Solve[ArcSecDegrees[x] == 60, x]

逆三角関数の不等式を解く：

Wolfram Language code: Reduce[ArcSecDegrees[x] > 60, x]

ArcSecDegreesを以下のリストに適用する：

Wolfram Language code: ArcSecDegrees[{1, Sqrt[2] (-1 + Sqrt[3]), (2/Sqrt[3]), Sqrt[2], 2, Sqrt[2] (1 + Sqrt[3])}]

実数の部分集合上でプロットする：

Wolfram Language code: Plot[ArcSecDegrees[x], {x, -5, 5}]

Infinityにおける漸近展開：

Wolfram Language code: Series[ArcSecDegrees[x], {x, ∞, 5}]

スコープ  (37)

数値評価  (6)

数値的に評価する：

Wolfram Language code: ArcSecDegrees[5.0]

高精度で評価する：

Wolfram Language code: N[ArcSecDegrees[5], 50]

出力の精度は入力の精度に従う：

Wolfram Language code: ArcSecDegrees[5.00000000000000000000000000000000000000000]

複素引数について評価する：

Wolfram Language code: ArcSecDegrees[0.5 + 2.3I]

ArcSecDegreesを高精度で効率的に評価する：

Wolfram Language code: ArcSecDegrees[5`500]//Timing
Wolfram Language code: ArcSecDegrees[5`100000];//Timing

IntervalオブジェクトとCenteredIntervalオブジェクトを使って最悪の場合に保証される区間を計算する：

Wolfram Language code: ArcSecDegrees[Interval[{2, 5}]]
Wolfram Language code: ArcSecDegrees[CenteredInterval[-3, 1 / 100]]
Wolfram Language code: ArcSecDegrees[CenteredInterval[2 + 3I, (1 + I) / 100]]

Aroundを使って平均的な場合の統計的区間を計算することもできる：

Wolfram Language code: ArcSecDegrees[Around[(2/Sqrt[3]), 0.01]]

配列の要素ごとの値を計算する：

Wolfram Language code: ArcSecDegrees[{{Sqrt[2], -Sqrt[2]}, {0, -Sqrt[2]}}]

MatrixFunctionを使って行列のArcSecDegrees関数を計算することもできる：

Wolfram Language code: MatrixFunction[ArcSecDegrees[#]&, {{Sqrt[2], -Sqrt[2]}, {0, -Sqrt[2]}}]

特定の値  (5)

固定点におけるArcSecDegreesの値：

Wolfram Language code: ArcSecDegrees[{-Sqrt[2], -(2/Sqrt[3]), (2/Sqrt[3]), Sqrt[2]}]

単純な厳密値は自動的に生成される：

Wolfram Language code: ArcSecDegrees[(2/Sqrt[3])]

無限大における値：

Wolfram Language code: ArcSecDegrees[Infinity]
Wolfram Language code: ArcSecDegrees[ComplexInfinity]

ArcSecDegreesの零点：

Wolfram Language code: ArcSecDegrees[1]

方程式を満足する の値を求める：

Wolfram Language code: f[x_] := ArcSecDegrees[x] - 60;
Wolfram Language code: sol = Solve[f[x] == 0, x]

値を代入する：

Wolfram Language code: xzero = x /. First[sol]

結果を可視化する：

Wolfram Language code: Plot[f[x], {x, 1, 3}, Rule[...]]

可視化  (4)

ArcSecDegrees関数をプロットする：

Wolfram Language code: Plot[ArcSecDegrees[x], {x, -3, 3}]

複素数の部分集合上でプロットする：

Wolfram Language code: ComplexPlot3D[ArcSecDegrees[z], {z, -4 - 2I, 4 + 2I}, Rule[...]]

ArcSecDegreesの実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[ArcSecDegrees[z]], {z, -2 - 2I, 2 + 2I}, IconizedObject[«PlotOptions»]]

ArcSecDegreesの虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[ArcSecDegrees[z]], {z, -2 - 2I, 2 + 2I}, IconizedObject[«PlotOptions»]]

ArcSecDegreesの極プロット：

Wolfram Language code: Table[PolarPlot[ArcSecDegrees[k ϕ], {ϕ, -4π, 4π}, ...], {k, 1, 4}]

関数の特性  (10)

ArcSecDegreesは，区間からのものを除くすべての実数値について定義される：

Wolfram Language code: FunctionDomain[ArcSecDegrees[x], x]

複素領域：

Wolfram Language code: FunctionDomain[ArcSecDegrees[z], z, Complexes]

ArcSecDegreesは，を除く区間からのすべての実数値に到達する：

Wolfram Language code: FunctionRange[ArcSecDegrees[x], x, y]

複素数値の範囲：

Wolfram Language code: FunctionRange[ArcSecDegrees[x], x, y, Complexes]

ArcSecDegreesは解析関数ではない：

Wolfram Language code: FunctionAnalytic[ArcSecDegrees[x], x]

有理型でもない：

Wolfram Language code: FunctionMeromorphic[ArcSecDegrees[x], x]

ArcSecDegreesは特定の範囲で単調である：

Wolfram Language code: FunctionMonotonicity[ArcSecDegrees[x], x]
Wolfram Language code: FunctionMonotonicity[{ArcSecDegrees[x], x ≤ -1 }, x]
Wolfram Language code: FunctionMonotonicity[{ArcSecDegrees[x], x ≥ 1}, x]
Wolfram Language code: Plot[ArcSecDegrees[x], {x, 1, 3}]

ArcSecDegreesは単射である：

Wolfram Language code: FunctionInjective[ArcSecDegrees[x], x]
Wolfram Language code: Plot[{ArcSecDegrees[x], 30}, {x, -5, 5}]

ArcSecDegreesは全射ではない：

Wolfram Language code: FunctionSurjective[ArcSecDegrees[x], x]
Wolfram Language code: Plot[{ArcSecDegrees[x], 90}, {x, -5, 5}]

ArcSecDegreesは，その実領域上で非負である：

Wolfram Language code: FunctionSign[{ArcSecDegrees[x], x ≤ -1 || x ≥ 1}, x]

[-1,1]の x について特異点と不連続点を持つ：

Wolfram Language code: FunctionSingularities[ArcSecDegrees[x], x]
Wolfram Language code: FunctionDiscontinuities[ArcSecDegrees[x], x]

ArcSecDegreesは凸でも凹でもない：

Wolfram Language code: FunctionConvexity[ArcSecDegrees[x], x]

x が[1,∞)のとき，ArcSecDegreesは凸である：

Wolfram Language code: FunctionConvexity[{ArcSecDegrees[x], x >= 1}, x]
Wolfram Language code: Plot[ArcSecDegrees[x], {x, 1, 10}]

TraditionalFormによる表示：

Wolfram Language code: ArcSecDegrees[α]//TraditionalForm

微分  (3)

一次導関数：

Wolfram Language code: D[ArcSecDegrees[x], x]

高次導関数：

Wolfram Language code: Table[D[ArcSecDegrees[x], {x, n}], {n, 1, 4}]//FullSimplify
Wolfram Language code: Plot[Evaluate[%], {x, -3, 3}, Rule[...]]

次導関数の式：

Wolfram Language code: D[ArcSecDegrees[x], {x, n}]

積分  (2)

ArcSecDegreesの不定積分：

Wolfram Language code: Integrate[ArcSecDegrees[x], x]

区間上での定積分：

Wolfram Language code: Integrate[ArcSecDegrees[x], {x, 1, 2}]

級数展開  (4)

Seriesを使ってテイラー(Taylor)展開を求める：

Wolfram Language code: Series[ArcSecDegrees[x], {x, 2, 4}]

周囲のArcSecDegreesの最初の3つの近似をプロットする：

Wolfram Language code: terms = Normal@Table[Series[ArcSecDegrees[x], {x, 2, m}], {m, 1, 3}]; Plot[{ArcSecDegrees[x], terms}, {x, 1, 3}, PlotRange -> All]

分岐点と分枝切断線で級数展開を求める：

Wolfram Language code: Series[ArcSecDegrees[x], {x, 1, 1}]//FullSimplify
Wolfram Language code: Series[ArcSecDegrees[x], {x, -1 / 2, 1}]

特異点における漸近展開：

Wolfram Language code: Series[ArcSecDegrees[x], {x, 1, 3}, Assumptions -> x > 1]//Simplify

ArcSecDegreesはベキ級数に適用できる：

Wolfram Language code: ArcSecDegrees[x + x ^ 2 + O[x, Infinity] ^ 4]

関数の恒等式と簡約  (2)

ArcSecDegreesを含む式を簡約する：

Wolfram Language code: FullSimplify[ArcSecDegrees[Sqrt[(1/1 - x^2)]], 0 ≤ x ≤ 1]

TrigToExpを使って対数と平方根を介して表現する：

Wolfram Language code: ArcSecDegrees[z]//TrigToExp

関数表現  (1)

ArcCosDegreesを使って表す：

Wolfram Language code: ArcCosDegrees[(1/z)]//FullSimplify

アプリケーション  (6)

逆三角関数方程式を解く：

Wolfram Language code: Solve[ArcSecDegrees[α x + β] == 4, x]
Wolfram Language code: Solve[ArcSecDegrees[z]^2 + 3 ArcSecDegrees[z] == 2, z]

逆三角関数の方程式をパラメータで解く：

Wolfram Language code: Reduce[ArcSecDegrees[SecDegrees[z]] == w, z]

Reduceを使ってArcSecDegreesを含む不等式を解く：

Wolfram Language code: Reduce[ArcSecDegrees[x] > 60, x]

超越方程式の数値根を求める：

Wolfram Language code: FindRoot[ArcSecDegrees[z]^2 + 2 ArcSecDegrees[z + 1 / 3] == 3, {z, 1 / 2, 3}]//Chop

この関数をプロットして解が正しいかどうかをチェックする：

Wolfram Language code: Plot[ArcSecDegrees[z]^2 + 2 ArcSecDegrees[z + 1 / 3] - 3, {z, 1 / 2, 3 / 2}]

ArcSecDegreesの実部と虚部をプロットする：

Wolfram Language code: ReImPlot[ArcSecDegrees[x], {x, -5, 5}]

ArcSecDegreesと三角関数のさまざまな組合せ：

Wolfram Language code: {TanDegrees[ArcSecDegrees[z]], TanDegrees[ArcSecDegrees[1 / z]], CotDegrees[ArcSecDegrees[z]], SinDegrees[ArcSecDegrees[z]]}

特性と関係  (6)

逆三角関数による構成：

Wolfram Language code: {ArcSecDegrees[SecDegrees[z]], SecDegrees[ArcSecDegrees[z]]}

PowerExpandを使ってArcSecDegreesが複数の値を持つことを無視する：

Wolfram Language code: PowerExpand[%]

あるいは，追加的な仮定のもとで評価する：

Wolfram Language code: Refine[ArcSecDegrees[SecDegrees[z]], 0 < z < 90]

FunctionExpandを使って逆三角関数の三角関数を代数関数に変換する：

Wolfram Language code: FunctionExpand[TanDegrees[ArcSecDegrees[z]]]

結果を簡約する：

Wolfram Language code: FullSimplify[%]

以下は，ArcSecDegrees関数の分枝切断線を示している：

Wolfram Language code: Plot3D[Im[ArcSecDegrees[x + I y]], {x, -2, 2}, {y, -2, 2}]

ArcSecDegreesは角度を度で与えるが，ArcSecは同じ角度をラジアンで与える：

Wolfram Language code: ArcSecDegrees[2]
Wolfram Language code: ArcSec[2]

ArcSecDegreesにFunctionExpandを適用すると，三角関数の式がラジアン単位で生成される：

Wolfram Language code: FunctionExpand[ArcSecDegrees[x]]
Wolfram Language code: FunctionExpand[ArcSecDegrees[x ^ 2]ArcSecDegrees[120 - x / 2]]

TrigToExpの出力にExpToTrigを適用すると，三角関数がラジアン単位で生成される：

Wolfram Language code: ArcSecDegrees[z]//TrigToExp
Wolfram Language code: ExpToTrig[%]

おもしろい例題  (2)

ArcSecDegreesを含む三角関数の方程式を解く：

Wolfram Language code: Reduce[ArcSecDegrees[z] + ArcSecDegrees[z + 1] == 90, z]//Quiet

この角の度を単位にした数値：

Wolfram Language code: %//N

整数点でArcSecDegreesをプロットする：

Wolfram Language code: ArrayPlot[Table[FractionalPart[Abs[ArcSecDegrees[x y]]], {x, -40, 40}, {y, -40, 40}]]
Wolfram Research (2024), ArcSecDegrees, Wolfram言語関数， https://reference.wolfram.com/language/ref/ArcSecDegrees.html.

テキスト

Wolfram Research (2024), ArcSecDegrees, Wolfram言語関数， https://reference.wolfram.com/language/ref/ArcSecDegrees.html.

CMS

Wolfram Language. 2024. "ArcSecDegrees." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/ArcSecDegrees.html.

APA

Wolfram Language. (2024). ArcSecDegrees. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ArcSecDegrees.html

BibTeX

@misc{reference.wolfram_2026_arcsecdegrees, author="Wolfram Research", title="{ArcSecDegrees}", year="2024", howpublished="\url{https://reference.wolfram.com/language/ref/ArcSecDegrees.html}", note=[Accessed: 08-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_arcsecdegrees, organization={Wolfram Research}, title={ArcSecDegrees}, year={2024}, url={https://reference.wolfram.com/language/ref/ArcSecDegrees.html}, note=[Accessed: 08-August-2026]}