WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ArcSin[z]

複素数 の逆正弦を与える．

詳細
Details and Options Details and Options
予備知識
例題  
例  
スコープ  
数値評価  
特定の値  
可視化  
Show More Show More
関数の特性  
微分  
積分  
級数展開  
関数の恒等式と簡約  
関数表現  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

ArcSin

ArcSin[z]

複素数 の逆正弦を与える．

詳細

  • 記号操作・数値操作の両方に適した数学関数である．
  • 答はラジアンで求まる．
  • が実数で〜の区間にあるとき，答は必ず〜 の範囲にある．
  • 特別な引数の場合，ArcSinは自動的に厳密値を計算する．
  • ArcSinは任意の数値精度で評価できる．
  • ArcSinは自動的にリストに関数の並列的な適用を行う． »
  • ArcSin[z]は，複素 平面上，〜そして〜 の範囲で不連続な分枝切断線を持つ．
  • ArcSinはIntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる． »

予備知識

  • ArcSinは逆正弦関数である．ArcSin[x]は，実数 について， となるようなのラジアン角を表す．
  • ArcSinは自動的にリストに縫い込まれる．特別な引数の場合，ArcSinは自動的に厳密値を計算する．厳密な数式が引数として与えられると，ArcSinは任意の数値精度に評価できることがある．ArcSinを含む記号式の操作に便利なその他の演算には，FunctionExpand，TrigToExp，TrigExpand，Simplify，FullSimplifyがある．
  • ArcSinは，複素引数 について，sin^(-1)(z)=-ⅈ log(sqrt(TemplateBox[{{1, -, {z, ^, 2}}}, Abs]) ⅇ^(1/2 ⅈ arg(1-z^2))+ⅈ z)によって定義される．ArcSin[z]は複素 平面上で不連続な分枝切断線を持つ．
  • 関連する数学関数には，Sin，ArcCos，InverseHaversine，ArcSinhがある．

例題

すべて開く すべて閉じる

例  (6)

結果はラジアンである：

Wolfram Language code: ArcSin[1]

Degreeで割って結果を度で得る：

Wolfram Language code: ArcSin[1] / Degree//FullSimplify

実数の部分集合上でプロットする：

Wolfram Language code: Plot[ArcSin[x], {x, -1, 1}]

複素数の部分集合上でプロットする：

Wolfram Language code: ComplexPlot3D[ArcSin[z], {z, -4 - 2I, 4 + 2I}, PlotLegends -> Automatic]

0における級数展開：

Wolfram Language code: Series[ArcSin[x], {x, 0, 10}]

Infinityにおける漸近展開：

Wolfram Language code: Series[ArcSin[x], {x, ∞, 5}]

特異点における漸近展開：

Wolfram Language code: Series[ArcSin[x], {x, -1, 5}]

スコープ  (42)

数値評価  (6)

数値的に評価する：

Wolfram Language code: ArcSin[0.4]
Wolfram Language code: ArcSin[1.5]

高精度で評価する：

Wolfram Language code: N[ArcSin[1 / 3], 50]

出力の精度は入力の精度に従う：

Wolfram Language code: ArcSin[0.33333333333333333333333333333333333333333333]

ArcSinは，複素数を入力として取ることができる：

Wolfram Language code: ArcSin[2.5 + I]

ArcSinを高精度で効率よく評価する：

Wolfram Language code: ArcSin[0.4`500]//Timing
Wolfram Language code: ArcSin[0.4`100000];//Timing

自動縫込みを使って配列の要素ごとの値を計算する：

Wolfram Language code: ArcSin[{{1, 1 / Sqrt[2]}, {0, 1 / Sqrt[2]}}]

MatrixFunctionを使って行列のArcSin関数を計算することもできる：

Wolfram Language code: MatrixFunction[ArcSin[#]&, {{1, 1 / Sqrt[2]}, {0, 1 / Sqrt[2]}}]

IntervalオブジェクトとCenteredIntervalオブジェクトを使って最悪の場合に保証される区間を計算する：

Wolfram Language code: ArcSin[Interval[{-1 / 3, 1 / 2}]]
Wolfram Language code: ArcSin[CenteredInterval[1 / 2, 1 / 100]]
Wolfram Language code: ArcSin[CenteredInterval[2 + 3I, (1 + I) / 100]]

Aroundを使って平均的な場合の統計区間を計算することもできる：

Wolfram Language code: ArcSin[Around[.9, 0.1]]

特定の値  (4)

固定点におけるArcSinの値：

Wolfram Language code: Table[ArcSin[(n /2)], {n, -2, 2}]

無限大における値：

Wolfram Language code: ArcSin[Infinity]
Wolfram Language code: ArcSin[ComplexInfinity]

ArcSinの零点：

Wolfram Language code: ArcSin[0]

方程式 を満足する の値を求める：

Wolfram Language code: f[x_] := ArcSin[x] - (π/3);
Wolfram Language code: sol = Solve[f[x] == 0, x]

値を代入する：

Wolfram Language code: xzero = x /. First[sol]

結果を可視化する：

Wolfram Language code: Plot[f[x], {x, -1, 1}, Epilog -> Style[Point[{xzero, f[xzero]}], PointSize[Large], Red]]

可視化  (3)

ArcSin関数をプロットする：

Wolfram Language code: Plot[ArcSin[x], {x, -1, 1}]

の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[ArcSin[z]], {z, -3π - 3I, 3π + 3I}, IconizedObject[«PlotOptions»]]

の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[ArcSin[z]], {z, -π - 3I, π + 3I}, Contours -> 24]

の極プロット：

Wolfram Language code: Table[PolarPlot[ArcSin[k ϕ], {ϕ, -π, π}, Sequence[Frame -> True, FrameTicks -> {{{-1, 0, 1}, None}, {{-1, 0, 1}, None}}, PlotLabel -> "k=" <> ToString[k], PlotRange -> All]], {k, 1, 4}]

関数の特性  (11)

ArcSinは，区間からのすべての実数について定義される：

Wolfram Language code: FunctionDomain[ArcSin[x], x]

複素領域は平面全体である：

Wolfram Language code: FunctionDomain[ArcSin[z], z, Complexes]

ArcSinは区間からのすべての実数値に達する：

Wolfram Language code: FunctionRange[ArcSin[x], x, y]

複素平面からの引数についての関数の範囲：

Wolfram Language code: FunctionRange[ArcSin[z], z, y, Complexes]

ArcSinは奇関数である：

Wolfram Language code: ArcSin[-x]

ArcSinは解析関数ではない：

Wolfram Language code: FunctionAnalytic[ArcSin[x], x]

有理型でもない：

Wolfram Language code: FunctionMeromorphic[ArcSin[x], x]

ArcSinは，非減少でも非増加でもない：

Wolfram Language code: FunctionMonotonicity[ArcSin[x], x]

実数領域上で単調である：

Wolfram Language code: FunctionMonotonicity[{ArcSin[x], -1 ≤ x ≤ 1}, x]

ArcSinは単射である：

Wolfram Language code: FunctionInjective[ArcSin[x], x]
Wolfram Language code: Plot[{ArcSin[x], 1 / 2}, {x, -2π, 2π}]

ArcSinは全射ではない：

Wolfram Language code: FunctionSurjective[ArcSin[x], x]
Wolfram Language code: Plot[{ArcSin[x], 2}, {x, -2π, 2π}]

ArcSinは非負でも非正でもない：

Wolfram Language code: FunctionSign[ArcSin[x], x]

ArcSinは，(-∞,-1]と[1,∞)において，特異点と不連続点の両方を持つ：

Wolfram Language code: FunctionSingularities[ArcSin[x], x]
Wolfram Language code: FunctionDiscontinuities[ArcSin[x], x]

ArcSinは凸でも凹でもない：

Wolfram Language code: FunctionConvexity[ArcSin[x], x]

TraditionalFormによる表示：

Wolfram Language code: ArcSin[z]//TraditionalForm

微分  (3)

一次導関数：

Wolfram Language code: D[ArcSin[x], x]

高次導関数：

Wolfram Language code: Table[D[ArcSin[x], {x, n}], {n, 1, 4}]
Wolfram Language code: Plot[Evaluate[%], {x, -1, 1}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

次導関数の式：

Wolfram Language code: D[ArcSin[x], {x, n}]

積分  (3)

ArcSinの不定積分：

Wolfram Language code: Integrate[ArcSin[x], x]

原点を中心とした区間上のArcSinの定積分は0である：

Wolfram Language code: Integrate[ArcSin[x], {x, -1, 1}]

その他の積分例：

Wolfram Language code: Integrate[ArcCos[x] ArcSin[x], x]
Wolfram Language code: Integrate[ArcSin[z]^a, z]

級数展開  (4)

Seriesを使ってテイラー(Taylor)展開を求める：

Wolfram Language code: Series[ArcSin[x], {x, 0, 7}]

の周りのArcSinの最初の3つの近似をプロットする：

Wolfram Language code: terms = Normal@Table[Series[ArcSin[x], {x, 0, m}], {m, 1, 5, 2}]; Plot[{ArcSin[x], terms}, {x, -1, 1}, PlotRange -> {{-1, 1}, All}]

ArcSinの級数展開における一般項：

Wolfram Language code: SeriesCoefficient[ArcSin[x], {x, 0, n}]

分岐点と分枝切断線における級数展開を求める：

Wolfram Language code: Series[ArcSin[x], {x, 1, 1}]
Wolfram Language code: Series[ArcSin[x], {x, -2, 1}]

ArcSinはベキ級数に適用できる：

Wolfram Language code: ArcSin[x + (x^2/2) + (x^3/3) + O[x]^4]

関数の恒等式と簡約  (3)

ArcSinを含む式を簡約する：

Wolfram Language code: FullSimplify[ArcSin[Sqrt[1 - x^2]], 0 ≤ x ≤ 1]

TrigToExpを使って対数と平方根を介して表現する：

Wolfram Language code: TrigToExp@ArcSin[z]
Wolfram Language code: ExpToTrig[%]

実変数 および を仮定して展開する：

Wolfram Language code: ComplexExpand[ArcSin[x + I y]]

関数表現  (5)

ArcCscを使って表現する：

Wolfram Language code: ArcCsc[1 / x]//FullSimplify

逆ヤコビ関数を介した表現：

Wolfram Language code: (π/2) - InverseJacobiCN[z, 0]//FullSimplify
Wolfram Language code: InverseJacobiDS[(1/z), 0]//FullSimplify

Hypergeometric2F1を使って表現する：

Wolfram Language code: (π/2) - z HypergeometricPFQ[{(1/2), (1/2)}, {(3/2)}, z^2]//FullSimplify

MeijerGによる表現：

Wolfram Language code: MeijerGReduce[ArcSin[x], x]
Wolfram Language code: Activate[%]

ArcSinはDifferentialRootとして表すことができる：

Wolfram Language code: DifferentialRootReduce[ArcSin[x], x]

アプリケーション  (6)

ArcSinの実部と虚部をプロットする：

Wolfram Language code: Plot[{Re[ArcSin[x]], Im[ArcSin[x]]}, {x, -2, 2}, PlotStyle -> Thick]

ArcSinのリーマン(Riemann)面をプロットする：

Wolfram Language code: ParametricPlot3D[Evaluate[{Re[Sin[u + I v]], Im[Sin[u + I v]], u}], {u, 0, 4π}, {v, -2, 2}]

2つの3Dベクトル間の角度を求める：

Wolfram Language code: With[{v = Normalize[{1, 1, -2}], u = Normalize[{1, 1, 1}]}, ArcSin[Norm[Cross[v, u]]]]

Lévyの第2逆正弦法則をモデリングする：

Wolfram Language code: {With[{n = 1000}, ListPlot[MapIndexed[{#1, #2[[1]] / n}&, Sort[Table[Position[FoldList[Plus, 0, RandomChoice[{-1, 1}, n]], 0][[-1, 1]] / n, {n}]]]]], Plot[2 / Pi ArcSin[Sqrt[x]], {x, 0, 1}]}

ArcSin微分方程式を解く：

Wolfram Language code: DSolve[Sqrt[1 - z^2]w'[z] == 1, w[z], z]

楕円から単位円板への等角写像：

Wolfram Language code: w[z_, {a_, b_}] := With[{q = (a - b) ^ 2 / (a + b) ^ 2, e = Sqrt[a ^ 2 - b ^ 2]}, EllipticTheta[1, ArcSin[z / e], q] / EllipticTheta[4, ArcSin[z / e], q]]

写像を可視化する：

Wolfram Language code: ParametricPlot[{Re[w[ρ (2 Cos[φ] + I Sin[φ]), {2, 1}]], Im[w[ρ (2 Cos[φ] + I Sin[φ]), {2, 1}]]}, {ρ, 0, 1}, {φ, 0, 2Pi}, Mesh -> 15]

特性と関係  (9)

逆関数で構成する：

Wolfram Language code: {Sin[ArcSin[z]], ArcSin[Sin[z]]}

PowerExpandを使ってArcSinの多価性を無視する：

Wolfram Language code: PowerExpand[%]

別の方法として，追加的な仮定の下で評価する：

Wolfram Language code: Refine[ArcSin[Sin[z]], 0 < z < Pi / 2]

TrigToExpを使って対数と平方根で表す：

Wolfram Language code: ArcSin[z]//TrigToExp
Wolfram Language code: ExpToTrig[%]

以下はArcSin関数の分枝切断線を示す：

Wolfram Language code: Plot3D[Im[ArcSin[x + I y]], {x, -2, 2}, {y, -2, 2}]

ArcSinは角度をラジアンで与えるのに対し，ArcSinDegreesは同じ角度を度で与える：

Wolfram Language code: ArcSin[1]
Wolfram Language code: ArcSinDegrees[1]

実変数を仮定して展開する：

Wolfram Language code: ComplexExpand[ArcSin[x + I y]]

逆三角方程式を解く：

Wolfram Language code: Reduce[ArcSin[z]^2 + 3 ArcSin[z] == 2, z]
Wolfram Language code: Reduce[ArcSin[Sin[z]] == w, z]

ゼロについて解く：

Wolfram Language code: Reduce[ArcSin[α x + β] == 0, x]

ラプラス(Laplace)変換：

Wolfram Language code: LaplaceTransform[ArcSin[t], t, s]

ArcSinはさまざまな数学関数の特殊ケースである：

Wolfram Language code: {(π/2) - InverseJacobiCD[z, 0], InverseJacobiCS[(I/z), 1], -(Sqrt[π]/2) MeijerG[{{1, 1, 1}, {}}, {{1}, {0, (1/2)}}, I z, (1/2)]}//FullSimplify

考えられる問題  (4)

一般に である：

Wolfram Language code: ArcSin[Sin[30.]]
Wolfram Language code: Sin[ArcSin[30.]]

分枝切断線においては，機械精度の入力が数値的に間違った答を返すことがある：

Wolfram Language code: ArcSin[-2 + I ((Pi + 1) ^ 2 - Pi ^ 2 - 2Pi - 1 - Exp[-Pi ^ 4])]//N
Wolfram Language code: ArcSin[-2 + I ((Pi + 1) ^ 2 - Pi ^ 2 - 2Pi - 1 - Exp[-Pi ^ 4])]//N[#, 30]&

出力精度は入力精度よりもはるかに低くなることがある：

Wolfram Language code: ArcSin[0.99999999999999999999999999999999999999999999]

慣用形では，引数の周りに丸カッコが必要である：

Wolfram Language code: sin^-1x
Wolfram Language code: sin^-1(x)

おもしろい例題  (3)

ネストした積分：

Wolfram Language code: NestList[Integrate[#, x]&, ArcSin[x], 4]

反復を使って数値を計算する：

Wolfram Language code: arcSin[x_ ? (InexactNumberQ[#] && 0 < # < 1&)] := FixedPoint[Function[ξ, ξ + 1 / Cos[ξ](x - Sin[ξ])], x]
Wolfram Language code: {arcSin[N[7 / 11, 20]], ArcSin[N[7 / 11, 20]]}

整数点でArcSinをプロットする：

Wolfram Language code: ArrayPlot[Table[FractionalPart[Abs[ArcSin[x y]]], {x, -20, 20}, {y, -20, 20}]]
Wolfram Research (1988), ArcSin, Wolfram言語関数， https://reference.wolfram.com/language/ref/ArcSin.html （2021年に更新）.

テキスト

Wolfram Research (1988), ArcSin, Wolfram言語関数， https://reference.wolfram.com/language/ref/ArcSin.html （2021年に更新）.

CMS

Wolfram Language. 1988. "ArcSin." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2021. https://reference.wolfram.com/language/ref/ArcSin.html.

APA

Wolfram Language. (1988). ArcSin. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ArcSin.html

BibTeX

@misc{reference.wolfram_2026_arcsin, author="Wolfram Research", title="{ArcSin}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/ArcSin.html}", note=[Accessed: 13-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_arcsin, organization={Wolfram Research}, title={ArcSin}, year={2021}, url={https://reference.wolfram.com/language/ref/ArcSin.html}, note=[Accessed: 13-August-2026]}