WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ArcSinDegrees[z]

複素数 の逆正弦を度を単位として与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
数値評価  
特定の値  
可視化  
Show More Show More
関数の特性  
微分  
積分  
級数展開  
関数の恒等式と簡約  
関数表現  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

ArcSinDegrees

ArcSinDegrees[z]

複素数 の逆正弦を度を単位として与える．

詳細

  • ArcSinDegreesは，その他の逆三角関数および三角関数とともに，高等学校の幾何の授業で学ばれ，多くの科学分野で使われている．
  • 結果はすべて度を単位として与えられる．
  • からまでの実数 については，結果は常にからまでの範囲になる．
  • ArcSinDegrees[z]は，直角三角形の斜辺に対する対辺の比が となる角度 を度を単位として返す．
  • 特別な引数の場合，ArcSinDegreesは，自動的に厳密値を計算する．
  • ArcSinDegreesは任意の数値精度で評価できる．
  • ArcSinDegreesは自動的にリストに縫い込まれる．
  • ArcSinDegrees[z]は，複素 平面上のからまでおよびからまでに不連続な分枝切断線を持つ．
  • ArcSinDegreesは，Interval，CenteredInterval，Aroundの各オブジェクトに使うことができる．
  • 記号操作・数値操作の両方に適した数学関数である．

例題

すべて開く すべて閉じる

例  (7)

結果の単位は度である：

Wolfram Language code: ArcSinDegrees[1]

次の直角三角形の角ABCを計算する：

手計算で求める：

Wolfram Language code: β = ArcSinDegrees[3 / 8]

この角度の数値：

Wolfram Language code: %//N

逆三角関数の方程式を解く：

Wolfram Language code: Solve[ArcSinDegrees[x] == 60, x]

逆三角関数の不等式を解く：

Wolfram Language code: Reduce[ArcSinDegrees[x] > 60, x]

ArcSinDegreesを以下のリストに適用する：

Wolfram Language code: ArcSinDegrees[{0, 1 / 2, 1 / Sqrt[2], Sqrt[3] / 2, 1}]

実数の部分集合上でプロットする：

Wolfram Language code: Plot[ArcSinDegrees[x], {x, -1, 1}]

0における級数展開：

Wolfram Language code: Series[ArcSinDegrees[x], {x, 0, 10}]

スコープ  (39)

数値評価  (6)

数値的に評価する：

Wolfram Language code: ArcSinDegrees[0.4]
Wolfram Language code: ArcSinDegrees[1.5]

高精度で評価する：

Wolfram Language code: N[ArcSinDegrees[1 / 3], 50]

出力の精度は入力の精度に従う：

Wolfram Language code: ArcSinDegrees[0.33333333333333333333333333333333333333333333]

ArcSinDegreesは複素数入力を取る：

Wolfram Language code: ArcSinDegrees[2.5 + I]

ArcSinDegreesを高精度で効率的に評価する：

Wolfram Language code: ArcSinDegrees[0.4`500]//Timing
Wolfram Language code: ArcSinDegrees[0.4`100000];//Timing

IntervalオブジェクトとCenteredIntervalオブジェクトを使って最悪の場合に保証される区間を計算する：

Wolfram Language code: ArcSinDegrees[Interval[{-1 / 3, 1 / 2}]]
Wolfram Language code: ArcSinDegrees[CenteredInterval[1 / 2, 1 / 100]]
Wolfram Language code: ArcSinDegrees[CenteredInterval[2 + 3I, (1 + I) / 100]]

Aroundを使って平均的な場合の統計的区間を計算することもできる：

Wolfram Language code: ArcSinDegrees[Around[.9, 0.01]]

配列の要素ごとの値を計算する：

Wolfram Language code: ArcSinDegrees[{{1, 1 / Sqrt[2]}, {0, 1 / Sqrt[2]}}]

MatrixFunctionを使って行列のArcSinDegrees関数を計算することもできる：

Wolfram Language code: MatrixFunction[ArcSinDegrees[#]&, {{1, 1 / Sqrt[2]}, {0, 1 / Sqrt[2]}}]

特定の値  (5)

固定点におけるArcSinDegreesの値：

Wolfram Language code: Table[ArcSinDegrees[(n/2)], {n, -2, 2}]

単純な厳密値は自動的に生成される：

Wolfram Language code: ArcSinDegrees[(1/Sqrt[2])]

無限大における値：

Wolfram Language code: ArcSinDegrees[Infinity]
Wolfram Language code: ArcSinDegrees[ComplexInfinity]

ArcSinDegreesの零点：

Wolfram Language code: ArcSinDegrees[0]

方程式を満足する の値を求める：

Wolfram Language code: f[x_] := ArcSinDegrees[x] - 60;
Wolfram Language code: sol = Solve[f[x] == 0, x]

値を代入する：

Wolfram Language code: xzero = x /. First[sol]

結果を可視化する：

Wolfram Language code: Plot[f[x], {x, -1, 1}, Rule[...]]

可視化  (4)

ArcSinDegrees関数をプロットする：

Wolfram Language code: Plot[ArcSinDegrees[x], {x, -1, 1}]

複素数の部分集合上でプロットする：

Wolfram Language code: ComplexPlot3D[ArcSinDegrees[z], {z, -4 - 2I, 4 + 2I}, Rule[...]]

ArcSinDegreesの実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[ArcSinDegrees[z]], {z, -3π - 3I, 3π + 3I}, ...]

ArcSinDegreesの虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[ArcSinDegrees[z]], {z, -π - 3I, π + 3I}, Rule[...]]

ArcSinDegreesの極プロット：

Wolfram Language code: Table[PolarPlot[ArcSinDegrees[k ϕ], {ϕ, -π, π}, ...], {k, 1, 4}]

関数の特性  (11)

ArcSinDegreesは，区間のすべての実数値について定義される：

Wolfram Language code: FunctionDomain[ArcSinDegrees[x], x]

複素領域は平面全体である：

Wolfram Language code: FunctionDomain[ArcSinDegrees[z], z, Complexes]

ArcSinDegreesは，区間のすべての実数値に達する：

Wolfram Language code: FunctionRange[ArcSinDegrees[x], x, y]

複素数値の範囲：

Wolfram Language code: FunctionRange[ArcSinDegrees[x], x, y, Complexes]

ArcSinDegreesは奇関数である：

Wolfram Language code: ArcSinDegrees[-x]

ArcSinDegreesは解析関数ではない：

Wolfram Language code: FunctionAnalytic[ArcSinDegrees[x], x]

有理型でもない：

Wolfram Language code: FunctionMeromorphic[ArcSinDegrees[x], x]

ArcSinDegreesは減少も増加もしない：

Wolfram Language code: FunctionMonotonicity[ArcSinDegrees[x], x]

実数領域上で単調である：

Wolfram Language code: FunctionMonotonicity[{ArcSinDegrees[x], -1 ≤ x ≤ 1}, x]

ArcSinDegreesは単射である：

Wolfram Language code: FunctionInjective[ArcSinDegrees[x], x]
Wolfram Language code: Plot[{ArcSinDegrees[x], 1 / 2}, {x, -2π, 2π}]

ArcSinDegreesは全射ではない：

Wolfram Language code: FunctionSurjective[ArcSinDegrees[x], x]
Wolfram Language code: Plot[{ArcSinDegrees[x], 2}, {x, -3, 3}]

ArcSinDegreesは非負でも非正でもない：

Wolfram Language code: FunctionSign[ArcSinDegrees[x], x]

ArcSinDegreesは，(-∞,-1]と[1,∞)で特異点と不連続点の両方を持つ：

Wolfram Language code: FunctionSingularities[ArcSinDegrees[x], x]
Wolfram Language code: FunctionDiscontinuities[ArcSinDegrees[x], x]

ArcSinDegreesは凸でも凹でもない：

Wolfram Language code: FunctionConvexity[ArcSinDegrees[x], x]

ArcSinDegreesは，x が[-1,0]のときは凸である：

Wolfram Language code: FunctionConvexity[{ArcSinDegrees[x], -1 <= x <= 0}, x]
Wolfram Language code: Plot[ArcSinDegrees[x], {x, -1, 0}]

TraditionalFormによる表示：

Wolfram Language code: ArcSinDegrees[α]//TraditionalForm

微分  (3)

一次導関数：

Wolfram Language code: D[ArcSinDegrees[x], x]

高次導関数：

Wolfram Language code: Table[D[ArcSinDegrees[x], {x, n}], {n, 1, 4}]
Wolfram Language code: Plot[Evaluate[%], {x, -1, 1}, Rule[...]]

次導関数の式：

Wolfram Language code: D[ArcSinDegrees[x], {x, n}]

積分  (2)

ArcSinDegreesの不定積分：

Wolfram Language code: Integrate[ArcSinDegrees[x], x]

原点を中心とする区間におけるArcSinDegreesの定積分は0である：

Wolfram Language code: Integrate[ArcSinDegrees[x], {x, -1, 1}]

級数展開  (5)

Seriesを使ってテイラー(Taylor)展開を求める：

Wolfram Language code: Series[ArcSinDegrees[x], {x, 0, 7}]

付近のArcSinDegreesの最初の3つの近似をプロットする：

Wolfram Language code: terms = Normal@Table[Series[ArcSinDegrees[x], {x, 0, m}], {m, 1, 5, 2}]; Plot[{ArcSinDegrees[x], terms}, {x, -1, 1}, PlotRange -> {{-1, 1}, All}]

Infinityにおける漸近展開：

Wolfram Language code: Series[ArcSinDegrees[x], {x, ∞, 5}]

特異点における漸近展開：

Wolfram Language code: Series[ArcSinDegrees[x], {x, -1, 5}]

分岐点と分枝切断線における級数展開を求める：

Wolfram Language code: Series[ArcSinDegrees[x], {x, 1, 1}]
Wolfram Language code: Series[ArcSinDegrees[x], {x, -2, 1}]

ArcSinDegreesはベキ級数に適用できる：

Wolfram Language code: ArcSinDegrees[x + (x^2/2) + (x^3/3) + O[x]^4]

関数の恒等式と簡約  (2)

ArcSinDegreesを含む式を簡約する：

Wolfram Language code: FullSimplify[ArcSinDegrees[Sqrt[1 - x^2]], 0 ≤ x ≤ 1]

TrigToExpを使って対数と平方根を介して表現する：

Wolfram Language code: TrigToExp@ArcSinDegrees[z]

関数表現  (1)

ArcCscDegreesを使って表す：

Wolfram Language code: ArcCscDegrees[1 / x]//FullSimplify

アプリケーション  (9)

逆三角関数の方程式を解く：

Wolfram Language code: Solve[ArcSinDegrees[z]^2 + 3 ArcSinDegrees[z] == 2, z]

逆三角関数の方程式をパラメータで解く：

Wolfram Language code: Reduce[ArcSinDegrees[SinDegrees[z]] == w, z]

ArcSinDegreesの零点を取得する：

Wolfram Language code: Reduce[ArcSinDegrees[α x + β] == 0, x]

Reduceを使ってArcSinDegreesを含む不等式を解く：

Wolfram Language code: Reduce[ArcSinDegrees[x] > 60, x]

超越方程式の数値根を求める：

Wolfram Language code: FindRoot[ArcSinDegrees[z] + 15 ArcSinDegrees[z + 1 / 3] == 3, {z, -1, 1}]//Chop

関数をプロットして解が正しいかどうかをチェックする：

Wolfram Language code: Plot[ArcSinDegrees[z] + 15 ArcSinDegrees[z + 1 / 3] - 3, {z, -1, 1}]

ArcSinDegreesの実部と虚部をプロットする：

Wolfram Language code: ReImPlot[ArcSinDegrees[x], {x, -2, 2}]

ArcSinDegreesのリーマン面をプロットする：

Wolfram Language code: ParametricPlot3D[Evaluate[{Re[SinDegrees[u + I v]], Im[SinDegrees[u + I v]], u}], {u, 0, 720}, {v, -450, 450}]

2つの3Dベクトル間の角度を求める：

Wolfram Language code: With[{v = Normalize[{1, 1, -2}], u = Normalize[{1, 1, 1}]}, ArcSinDegrees[Norm[Cross[v, u]]]]

ArcSinDegreesと三角関数のさまざまな組合せ：

Wolfram Language code: {TanDegrees[ArcSinDegrees[z]], TanDegrees[ArcSinDegrees[1 / z]], CotDegrees[ArcSinDegrees[z]], SinDegrees[ArcSinDegrees[z ^ 2]]}

特性と関係  (5)

逆三角関数による構成：

Wolfram Language code: {SinDegrees[ArcSinDegrees[z]], ArcSinDegrees[SinDegrees[z]]}

PowerExpandを使ってArcSinDegreesの多価性を無視する：

Wolfram Language code: PowerExpand[%]

追加的な仮定を使って評価することもできる：

Wolfram Language code: Refine[ArcSinDegrees[SinDegrees[z]], 0 < z < 90]

以下はArcSinDegrees関数の分枝切断線を示している：

Wolfram Language code: Plot3D[Im[ArcSinDegrees[x + I y]], {x, -2, 2}, {y, -2, 2}]

ArcSinDegreesは角度を度で与えるが，ArcSinは同じ角度をラジアンで与える：

Wolfram Language code: ArcSinDegrees[1]
Wolfram Language code: ArcSin[1]

ArcSinDegreesにFunctionExpandを適用すると三角関数の式がラジアン単位で生成される：

Wolfram Language code: FunctionExpand[ArcSinDegrees[x]]
Wolfram Language code: FunctionExpand[ArcSinDegrees[x ^ 2]ArcSinDegrees[120 - x / 2]]

TrigToExpの出力にExpToTrigを適用すると三角関数がラジアン単位で生成される：

Wolfram Language code: ArcSinDegrees[z]//TrigToExp
Wolfram Language code: ExpToTrig[%]

考えられる問題  (3)

一般的に である：

Wolfram Language code: ArcSinDegrees[SinDegrees[30.]]
Wolfram Language code: SinDegrees[ArcSinDegrees[30.]]

分枝切断線上では，機械精度入力は数値的に正しくない答を与えることがある：

Wolfram Language code: ArcSinDegrees[-2 + I ((Pi + 1) ^ 2 - Pi ^ 2 - 2Pi - 1 - Exp[-Pi ^ 4])]//N
Wolfram Language code: ArcSinDegrees[-2 + I ((Pi + 1) ^ 2 - Pi ^ 2 - 2Pi - 1 - Exp[-Pi ^ 4])]//N[#, 30]&

出力精度は入力精度をはるかに下回ることがある：

Wolfram Language code: ArcSinDegrees[0.99999999999999999999999999999999999999999999]

おもしろい例題  (3)

ArcSinDegreesを含む三角関数の方程式を解く：

Wolfram Language code: Reduce[ArcSinDegrees[z] + ArcSinDegrees[z - 1 / 2] == 90, z]//Quiet

この角の度を単位とした数値：

Wolfram Language code: %//N

反復でArcSinDegreesの数値を計算する：

Wolfram Language code: ArcSindeg[x_ ? (InexactNumberQ[#] && 0 < # < 1&)] := FixedPoint[Function[ξ, ξ + 1 / CosDegrees[ξ](x - SinDegrees[ξ])], x]
Wolfram Language code: {ArcSindeg[N[7 / 11, 20]], ArcSinDegrees[N[7 / 11, 20]]}

ArcSinDegreesを整数点でプロットする：

Wolfram Language code: ArrayPlot[Table[FractionalPart[Abs[ArcSinDegrees[x y]]], {x, -40, 40}, {y, -40, 40}]]
Wolfram Research (2024), ArcSinDegrees, Wolfram言語関数， https://reference.wolfram.com/language/ref/ArcSinDegrees.html.

テキスト

Wolfram Research (2024), ArcSinDegrees, Wolfram言語関数， https://reference.wolfram.com/language/ref/ArcSinDegrees.html.

CMS

Wolfram Language. 2024. "ArcSinDegrees." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/ArcSinDegrees.html.

APA

Wolfram Language. (2024). ArcSinDegrees. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ArcSinDegrees.html

BibTeX

@misc{reference.wolfram_2026_arcsindegrees, author="Wolfram Research", title="{ArcSinDegrees}", year="2024", howpublished="\url{https://reference.wolfram.com/language/ref/ArcSinDegrees.html}", note=[Accessed: 07-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_arcsindegrees, organization={Wolfram Research}, title={ArcSinDegrees}, year={2024}, url={https://reference.wolfram.com/language/ref/ArcSinDegrees.html}, note=[Accessed: 07-August-2026]}