WOLFRAM

Wolfram 语言与系统参考资料中心

ArcSinDegrees[z]

给出复数 的以度为单位的反正弦值.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
数值运算  
特殊值  
可视化  
Show More Show More
函数属性  
微分  
积分  
级数展开  
函数恒等和化简  
函数表示  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
技术笔记
相关指南
历史
按以下格式引用：

ArcSinDegrees

ArcSinDegrees[z]

给出复数 的以度为单位的反正弦值.

更多信息

  • ArcSinDegrees，以及其他反三角函数和三角函数在高中几何课程中学习的内容，在许多科学学科中也有应用.
  • 所有结果均以度为单位.
  • 对于 和 之间的实数 ，结果总是在 到 之间.
  • ArcSinDegrees[z] 返回直角三角形对边与斜边之比为 的角度 ，单位为度.
  • 对于某些特殊参数，ArcSinDegrees 会自动求出精确值.
  • ArcSinDegrees 可按任意数值精度求值.
  • ArcSinDegrees 自动线性作用于列表.
  • ArcSinDegrees[z] 在复平面 上有从 到 和 to 的分支切割不连续性.
  • ArcSinDegrees 可用于 Interval、CenteredInterval 和 Around 对象.
  • 数学函数，适用于符号和数字运算.

范例

打开所有单元 关闭所有单元

基本范例  (7)

结果以度为单位：

Wolfram Language code: ArcSinDegrees[1]

计算这个直角三角形的角 ABC：

手动计算：

Wolfram Language code: β = ArcSinDegrees[3 / 8]

该角的数值：

Wolfram Language code: %//N

求解反三角方程：

Wolfram Language code: Solve[ArcSinDegrees[x] == 60, x]

求解反三角不等式：

Wolfram Language code: Reduce[ArcSinDegrees[x] > 60, x]

将 ArcSinDegrees 应用于下列列表：

Wolfram Language code: ArcSinDegrees[{0, 1 / 2, 1 / Sqrt[2], Sqrt[3] / 2, 1}]

在实数子集上绘图：

Wolfram Language code: Plot[ArcSinDegrees[x], {x, -1, 1}]

0 处的级数展开：

Wolfram Language code: Series[ArcSinDegrees[x], {x, 0, 10}]

范围  (39)

数值运算  (6)

进行数值运算：

Wolfram Language code: ArcSinDegrees[0.4]
Wolfram Language code: ArcSinDegrees[1.5]

高精度运算：

Wolfram Language code: N[ArcSinDegrees[1 / 3], 50]

输出的精度与输入的精度一致：

Wolfram Language code: ArcSinDegrees[0.33333333333333333333333333333333333333333333]

ArcSinDegrees 可取复数输入：

Wolfram Language code: ArcSinDegrees[2.5 + I]

高精度高效运算 ArcSinDegrees：

Wolfram Language code: ArcSinDegrees[0.4`500]//Timing
Wolfram Language code: ArcSinDegrees[0.4`100000];//Timing

使用 Interval 和 CenteredInterval 对象计算最坏情况下的保证区间：

Wolfram Language code: ArcSinDegrees[Interval[{-1 / 3, 1 / 2}]]
Wolfram Language code: ArcSinDegrees[CenteredInterval[1 / 2, 1 / 100]]
Wolfram Language code: ArcSinDegrees[CenteredInterval[2 + 3I, (1 + I) / 100]]

或者使用 Around 计算平均情况统计区间：

Wolfram Language code: ArcSinDegrees[Around[.9, 0.01]]

计算数组的元素值：

Wolfram Language code: ArcSinDegrees[{{1, 1 / Sqrt[2]}, {0, 1 / Sqrt[2]}}]

或使用 MatrixFunction 计算矩阵 ArcSinDegrees 函数：

Wolfram Language code: MatrixFunction[ArcSinDegrees[#]&, {{1, 1 / Sqrt[2]}, {0, 1 / Sqrt[2]}}]

特殊值  (5)

固定点的 ArcSinDegrees 值：

Wolfram Language code: Table[ArcSinDegrees[(n/2)], {n, -2, 2}]

简单精确的数值会自动生成：

Wolfram Language code: ArcSinDegrees[(1/Sqrt[2])]

无穷大时的值：

Wolfram Language code: ArcSinDegrees[Infinity]
Wolfram Language code: ArcSinDegrees[ComplexInfinity]

ArcSinDegrees 的零点：

Wolfram Language code: ArcSinDegrees[0]

求满足方程 的 的值：

Wolfram Language code: f[x_] := ArcSinDegrees[x] - 60;
Wolfram Language code: sol = Solve[f[x] == 0, x]

代入数值：

Wolfram Language code: xzero = x /. First[sol]

将结果可视化：

Wolfram Language code: Plot[f[x], {x, -1, 1}, Rule[...]]

可视化  (4)

绘制 ArcSinDegrees 函数：

Wolfram Language code: Plot[ArcSinDegrees[x], {x, -1, 1}]

在虚数子集上绘图：

Wolfram Language code: ComplexPlot3D[ArcSinDegrees[z], {z, -4 - 2I, 4 + 2I}, Rule[...]]

绘制 ArcSinDegrees 的实部：

Wolfram Language code: ComplexContourPlot[Re[ArcSinDegrees[z]], {z, -3π - 3I, 3π + 3I}, ...]

绘制 ArcSinDegrees 的虚部：

Wolfram Language code: ComplexContourPlot[Im[ArcSinDegrees[z]], {z, -π - 3I, π + 3I}, Rule[...]]

使用 ArcSinDegrees 绘制极坐标图：

Wolfram Language code: Table[PolarPlot[ArcSinDegrees[k ϕ], {ϕ, -π, π}, ...], {k, 1, 4}]

函数属性  (11)

ArcSinDegrees 对区间 中的所有实数值有定义：

Wolfram Language code: FunctionDomain[ArcSinDegrees[x], x]

复数域是整个平面：

Wolfram Language code: FunctionDomain[ArcSinDegrees[z], z, Complexes]

ArcSinDegrees 可取区间 内的所有实数值：

Wolfram Language code: FunctionRange[ArcSinDegrees[x], x, y]

复数值的取值范围：

Wolfram Language code: FunctionRange[ArcSinDegrees[x], x, y, Complexes]

ArcSinDegrees 是奇函数：

Wolfram Language code: ArcSinDegrees[-x]

ArcSinDegrees 不是解析函数：

Wolfram Language code: FunctionAnalytic[ArcSinDegrees[x], x]

也不是半纯函数：

Wolfram Language code: FunctionMeromorphic[ArcSinDegrees[x], x]

ArcSinDegrees 既不是非递减也不是非递增：

Wolfram Language code: FunctionMonotonicity[ArcSinDegrees[x], x]

它在实域上是单调函数：

Wolfram Language code: FunctionMonotonicity[{ArcSinDegrees[x], -1 ≤ x ≤ 1}, x]

ArcSinDegrees 是单射函数：

Wolfram Language code: FunctionInjective[ArcSinDegrees[x], x]
Wolfram Language code: Plot[{ArcSinDegrees[x], 1 / 2}, {x, -2π, 2π}]

ArcSinDegrees 不是满射函数：

Wolfram Language code: FunctionSurjective[ArcSinDegrees[x], x]
Wolfram Language code: Plot[{ArcSinDegrees[x], 2}, {x, -3, 3}]

ArcSinDegrees 既不是非负也不是非正：

Wolfram Language code: FunctionSign[ArcSinDegrees[x], x]

ArcSinDegrees 在 (-∞,-1] 和 [1,∞) 区间内具有奇异性和不连续性：

Wolfram Language code: FunctionSingularities[ArcSinDegrees[x], x]
Wolfram Language code: FunctionDiscontinuities[ArcSinDegrees[x], x]

ArcSinDegrees 既不凸也不凹：

Wolfram Language code: FunctionConvexity[ArcSinDegrees[x], x]

ArcSinDegrees 对于 x 在 [-1,0] 区间内为凹函数：

Wolfram Language code: FunctionConvexity[{ArcSinDegrees[x], -1 <= x <= 0}, x]
Wolfram Language code: Plot[ArcSinDegrees[x], {x, -1, 0}]

TraditionalForm 格式：

Wolfram Language code: ArcSinDegrees[α]//TraditionalForm

微分  (3)

一阶导数：

Wolfram Language code: D[ArcSinDegrees[x], x]

更高阶导数：

Wolfram Language code: Table[D[ArcSinDegrees[x], {x, n}], {n, 1, 4}]
Wolfram Language code: Plot[Evaluate[%], {x, -1, 1}, Rule[...]]

阶导数的公式：

Wolfram Language code: D[ArcSinDegrees[x], {x, n}]

积分  (2)

ArcSinDegrees 的不定积分：

Wolfram Language code: Integrate[ArcSinDegrees[x], x]

ArcSinDegrees 在以原点为中心的区间上的定积分为 0：

Wolfram Language code: Integrate[ArcSinDegrees[x], {x, -1, 1}]

级数展开  (5)

使用 Series 求泰勒展开式：

Wolfram Language code: Series[ArcSinDegrees[x], {x, 0, 7}]

在 周围绘制 ArcSinDegrees 前三个近似：

Wolfram Language code: terms = Normal@Table[Series[ArcSinDegrees[x], {x, 0, m}], {m, 1, 5, 2}]; Plot[{ArcSinDegrees[x], terms}, {x, -1, 1}, PlotRange -> {{-1, 1}, All}]

Infinity 处的渐近展开：

Wolfram Language code: Series[ArcSinDegrees[x], {x, ∞, 5}]

奇点处的渐近展开：

Wolfram Language code: Series[ArcSinDegrees[x], {x, -1, 5}]

求分支点和分支切割处的级数展开式：

Wolfram Language code: Series[ArcSinDegrees[x], {x, 1, 1}]
Wolfram Language code: Series[ArcSinDegrees[x], {x, -2, 1}]

ArcSinDegrees 可以应用于幂级数：

Wolfram Language code: ArcSinDegrees[x + (x^2/2) + (x^3/3) + O[x]^4]

函数恒等和化简  (2)

化简与 ArcSinDegrees 相关的表达式：

Wolfram Language code: FullSimplify[ArcSinDegrees[Sqrt[1 - x^2]], 0 ≤ x ≤ 1]

使用 TrigToExp 通过对数和平方根进行表达：

Wolfram Language code: TrigToExp@ArcSinDegrees[z]

函数表示  (1)

使用 ArcCscDegrees 进行表示：

Wolfram Language code: ArcCscDegrees[1 / x]//FullSimplify

应用  (9)

求解反三角方程：

Wolfram Language code: Solve[ArcSinDegrees[z]^2 + 3 ArcSinDegrees[z] == 2, z]

求解带参数的反三角方程：

Wolfram Language code: Reduce[ArcSinDegrees[SinDegrees[z]] == w, z]

求 ArcSinDegrees 的零点：

Wolfram Language code: Reduce[ArcSinDegrees[α x + β] == 0, x]

使用 Reduce 求解关于 ArcSinDegrees 的不等式：

Wolfram Language code: Reduce[ArcSinDegrees[x] > 60, x]

通过数值求出超越方程的根：

Wolfram Language code: FindRoot[ArcSinDegrees[z] + 15 ArcSinDegrees[z + 1 / 3] == 3, {z, -1, 1}]//Chop

绘制函数图，检查解是否正确：

Wolfram Language code: Plot[ArcSinDegrees[z] + 15 ArcSinDegrees[z + 1 / 3] - 3, {z, -1, 1}]

绘制 ArcSinDegrees 的实部和虚部：

Wolfram Language code: ReImPlot[ArcSinDegrees[x], {x, -2, 2}]

绘制 ArcSinDegrees 的黎曼曲面：

Wolfram Language code: ParametricPlot3D[Evaluate[{Re[SinDegrees[u + I v]], Im[SinDegrees[u + I v]], u}], {u, 0, 720}, {v, -450, 450}]

找出两个三维向量之间的夹角：

Wolfram Language code: With[{v = Normalize[{1, 1, -2}], u = Normalize[{1, 1, 1}]}, ArcSinDegrees[Norm[Cross[v, u]]]]

ArcSinDegrees 与三角函数的不同组合：

Wolfram Language code: {TanDegrees[ArcSinDegrees[z]], TanDegrees[ArcSinDegrees[1 / z]], CotDegrees[ArcSinDegrees[z]], SinDegrees[ArcSinDegrees[z ^ 2]]}

属性和关系  (5)

复合反三角函数：

Wolfram Language code: {SinDegrees[ArcSinDegrees[z]], ArcSinDegrees[SinDegrees[z]]}

使用 PowerExpand 可忽略 ArcSinDegrees 的多值性：

Wolfram Language code: PowerExpand[%]

或者，根据其他假设进行运算：

Wolfram Language code: Refine[ArcSinDegrees[SinDegrees[z]], 0 < z < 90]

可以看到 ArcSinDegrees 函数的分支切割：

Wolfram Language code: Plot3D[Im[ArcSinDegrees[x + I y]], {x, -2, 2}, {y, -2, 2}]

ArcSinDegrees 给出的角度以度数为单位，而 ArcSin 给出的角度以弧度为单位：

Wolfram Language code: ArcSinDegrees[1]
Wolfram Language code: ArcSin[1]

将 FunctionExpand 应用于 ArcSinDegrees 可生成以弧度为单位的三角函数表达式：

Wolfram Language code: FunctionExpand[ArcSinDegrees[x]]
Wolfram Language code: FunctionExpand[ArcSinDegrees[x ^ 2]ArcSinDegrees[120 - x / 2]]

ExpToTrig 应用于 TrigToExp 的输出，将生成以弧度为单位的三角函数：

Wolfram Language code: ArcSinDegrees[z]//TrigToExp
Wolfram Language code: ExpToTrig[%]

可能存在的问题  (3)

一般情况下 ：

Wolfram Language code: ArcSinDegrees[SinDegrees[30.]]
Wolfram Language code: SinDegrees[ArcSinDegrees[30.]]

分支切割时，机器精度输入可能会给出数值错误的答案：

Wolfram Language code: ArcSinDegrees[-2 + I ((Pi + 1) ^ 2 - Pi ^ 2 - 2Pi - 1 - Exp[-Pi ^ 4])]//N
Wolfram Language code: ArcSinDegrees[-2 + I ((Pi + 1) ^ 2 - Pi ^ 2 - 2Pi - 1 - Exp[-Pi ^ 4])]//N[#, 30]&

输出的精度可能远远低于输入的精度：

Wolfram Language code: ArcSinDegrees[0.99999999999999999999999999999999999999999999]

巧妙范例  (3)

求解关于 ArcSinDegrees 的三角方程：

Wolfram Language code: Reduce[ArcSinDegrees[z] + ArcSinDegrees[z - 1 / 2] == 90, z]//Quiet

该角度的数值，单位为度：

Wolfram Language code: %//N

通过迭代计算 ArcSinDegrees 的数值：

Wolfram Language code: ArcSindeg[x_ ? (InexactNumberQ[#] && 0 < # < 1&)] := FixedPoint[Function[ξ, ξ + 1 / CosDegrees[ξ](x - SinDegrees[ξ])], x]
Wolfram Language code: {ArcSindeg[N[7 / 11, 20]], ArcSinDegrees[N[7 / 11, 20]]}

在整数点处绘制 ArcSinDegrees：

Wolfram Language code: ArrayPlot[Table[FractionalPart[Abs[ArcSinDegrees[x y]]], {x, -40, 40}, {y, -40, 40}]]
Wolfram Research (2024)，ArcSinDegrees，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ArcSinDegrees.html.

文本

Wolfram Research (2024)，ArcSinDegrees，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ArcSinDegrees.html.

CMS

Wolfram 语言. 2024. "ArcSinDegrees." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/ArcSinDegrees.html.

APA

Wolfram 语言. (2024). ArcSinDegrees. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ArcSinDegrees.html 年

BibTeX

@misc{reference.wolfram_2026_arcsindegrees, author="Wolfram Research", title="{ArcSinDegrees}", year="2024", howpublished="\url{https://reference.wolfram.com/language/ref/ArcSinDegrees.html}", note=[Accessed: 13-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_arcsindegrees, organization={Wolfram Research}, title={ArcSinDegrees}, year={2024}, url={https://reference.wolfram.com/language/ref/ArcSinDegrees.html}, note=[Accessed: 13-August-2026]}