ArcSinh

ArcSinh[z]

複素数の逆双曲線正弦を与える．

詳細

記号操作・数値操作の両方に適した数学関数である．
特別な引数の場合，ArcSinhは自動的に厳密値を計算する．
ArcSinhは任意の数値精度で評価できる．
ArcSinhは自動的にリストに縫い込まれる．
ArcSinh[z]は，複素平面上の〜そして〜の範囲で不連続な分枝切断線を持つ．
ArcSinhはIntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる． »

予備知識

ArcSinhは逆双曲線正弦関数である．ArcSinh[x]は，実数について，となるような，の双曲線角を表す．
ArcSinhは自動的にリストに縫い込まれる．特別な引数の場合，ArcSinhは自動的に厳密値を計算する．厳密な数式が引数として与えられると，ArcSinhは任意の数値精度に評価できることがある．ArcSinhを含む記号式の操作に便利なその他の演算には，FunctionExpand，TrigToExp，TrigExpand，Simplify，FullSimplifyがある．
ArcSinhは，複素引数について，によって定義される．ArcSinh[z]は複素平面上で不連続な分枝切断線を持つ．
関連する数学関数には，Sinh，ArcCosh，ArcSinがある．

例題

すべて開くすべて閉じる

例 (6)

数値的に評価する：

Wolfram Language code: ArcSinh[1.5]

実数の部分集合上でプロットする：

Wolfram Language code: Plot[ArcSinh[x], {x, -10, 10}]

複素数の部分集合上でプロットする：

Wolfram Language code: ComplexPlot3D[ArcSinh[z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

0における級数展開：

Wolfram Language code: Series[ArcSinh[x], {x, 0, 10}]

Infinityにおける漸近展開：

Wolfram Language code: Series[ArcSinh[x], {x, ∞, 3}]

特異点における漸近展開：

Wolfram Language code: Series[ArcSinh[x], {x, I, 3}, Assumptions -> x > 1]

スコープ (45)

数値評価 (6)

数値的に評価する：

Wolfram Language code: ArcSinh[1.0]

高精度で評価する：

Wolfram Language code: N[ArcSinh[1], 100]

出力精度は入力精度に従う：

Wolfram Language code: ArcSinh[1.000000000000000000000000000000000000000000000000000000]

複素引数について評価する：

Wolfram Language code: ArcSinh[1.5 + 0.7I]

ArcSinhを高精度で効率よく評価する：

Wolfram Language code: ArcSinh[1`500]//Timing

Wolfram Language code: ArcSinh[1`100000];//Timing

IntervalオブジェクトとCenteredIntervalオブジェクトを使って最悪の場合に保証される区間を計算する：

Wolfram Language code: ArcSinh[Interval[{-5 / 2, Sinh[2]}]]

Wolfram Language code: ArcSinh[CenteredInterval[3, 1 / 100]]

Wolfram Language code: ArcSinh[CenteredInterval[2 + 3I, (1 + I) / 100]]

Aroundを使って平均的な場合の統計区間を計算することもできる：

Wolfram Language code: ArcSinh[Around[.9, 0.1]]

配列の要素ごとの値を計算する：

Wolfram Language code: ArcSinh[{{I, I / Sqrt[2]}, {0, -I / Sqrt[2]}}]

MatrixFunctionを使って行列のArcSinh関数を計算することもできる：

Wolfram Language code: MatrixFunction[ArcSinh[#]&, {{I, I / Sqrt[2]}, {0, -I / Sqrt[2]}}]

特定の値 (4)

固定点におけるArcSinhの値：

Wolfram Language code: Table[ArcSinh[(n /2)I], {n, -2, 2}]

無限大における値：

Wolfram Language code: ArcSinh[Infinity]

Wolfram Language code: ArcSinh[ComplexInfinity]

ArcSinhの零点：

Wolfram Language code: ArcSinh[0]

方程式を満足するの値を求める：

Wolfram Language code: f[x_] := ArcSinh[x] - Log[2];

Wolfram Language code: sol = Solve[f[x] == 0, x]

値を代入する：

Wolfram Language code: xzero = x /. First[sol]

結果を可視化する：

Wolfram Language code: Plot[f[x], {x, 0, 1}, Epilog -> Style[Point[{xzero, f[xzero]}], PointSize[Large], Red]]

可視化 (3)

ArcSinh関数をプロットする：

Wolfram Language code: Plot[ArcSinh[x], {x, -50, 50}]

の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[ArcSinh[z]], {z, -3 - 3 I, 3 + 3 I}, IconizedObject[«PlotOptions»]]

の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[ArcSinh[z]], {z, -3 - 3 I, 3 + 3 I}, IconizedObject[«PlotOptions»]]

の極プロット：

Wolfram Language code:

Table[PolarPlot[ArcSinh[k ϕ], {ϕ, -10π, 10π}, Frame -> True, Exclusions -> None, PlotLabel -> "k=" <> ToString[k], PlotRange -> {{-6, 6}, {-6, 6}}, FrameTicks -> {{{-6, -3, 0, 3, 6}, None}, {{-6, -3, 0, 3, 6}, None}}], {k, 1, 4}]

関数の特性 (12)

ArcSinhは，すべての実数値と複素数値について定義される：

Wolfram Language code: FunctionDomain[ArcSinh[x], x]

Wolfram Language code: FunctionDomain[ArcSinh[z], z, Complexes]

ArcSinhは，すべての実数値に達する：

Wolfram Language code: FunctionRange[ArcSinh[x], x, y]

複素領域からの引数についての関数の範囲：

Wolfram Language code: FunctionRange[ArcSinh[z], z, y, Complexes]

ArcSinhは奇関数である：

Wolfram Language code: ArcSinh[-x]

ArcSinhには鏡特性 $sinh^(-1)(TemplateBox[{z}, Conjugate])=TemplateBox[{{{sinh, ^, {(, {-, 1}, )}}, (, z, )}}, Conjugate]$ がある：

Wolfram Language code: FullSimplify[ArcSinh[Conjugate[z]] == Conjugate[ArcSinh[z]]]

は実数上での解析関数である：

Wolfram Language code: FunctionAnalytic[ArcSinh[x], x]

複素数上では解析的でも有理型でもない：

Wolfram Language code: FunctionAnalytic[ArcSinh[x], x, Complexes]

Wolfram Language code: FunctionMeromorphic[ArcSinh[x], x]

ArcSinhは非減少である：

Wolfram Language code: FunctionMonotonicity[ArcSinh[x], x]

ArcSinhは単射である：

Wolfram Language code: FunctionInjective[ArcSinh[x], x]

Wolfram Language code: Plot[{ArcSinh[x], 1}, {x, -4, 4}]

ArcSinhは全射である：

Wolfram Language code: FunctionSurjective[ArcSinh[x], x]

Wolfram Language code: Plot[{ArcSinh[x], 10}, {x, -50000, 50000}, PlotRange -> {-12, 12}]

ArcSinhは非負でも非正でもない：

Wolfram Language code: FunctionSign[ArcSinh[x], x]

ArcSinhは特異点も不連続点も持たない：

Wolfram Language code: FunctionSingularities[ArcSinh[x], x]

Wolfram Language code: FunctionDiscontinuities[ArcSinh[x], x]

ArcSinhは凸でも凹でもない：

Wolfram Language code: FunctionConvexity[ArcSinh[x], x]

TraditionalFormによる表示：

Wolfram Language code: ArcSinh[x]//TraditionalForm

微分 (3)

一次導関数：

Wolfram Language code: D[ArcSinh[x], x]

高次導関数：

Wolfram Language code: Table[D[ArcSinh[x], {x, n}], {n, 1, 4}]

Wolfram Language code:

Plot[Evaluate[%], {x, -1, 1}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

次導関数の式：

Wolfram Language code: D[ArcSinh[x], {x, n}]

積分 (3)

ArcSinhの不定積分：

Wolfram Language code: Integrate[ArcSinh[x], x]

原点を中心とした区間におけるArcSinhの定積分は0である：

Wolfram Language code: Integrate[ArcSinh[x], {x, -2, 2}]

その他の積分例：

Wolfram Language code: Integrate[ArcSinh[x] x, x]

Wolfram Language code: Integrate[ArcSinh[x] ^ a, x]

級数展開： (4)

Seriesを使ってテイラー(Taylor)展開を求める：

Wolfram Language code: Series[ArcSinh[x], {x, 0, 7}]

の周りのArcSinhの最初の3つの近似をプロットする：

Wolfram Language code:

terms = Normal@Table[Series[ArcSinh[x], {x, 0, m}], {m, 1, 5, 2}];
Plot[{ArcSinh[x], terms}, {x, -1.5, 1.5}, PlotRange -> {{-1.5, 1.5}, All}]

ArcSinhの級数展開における一般項：

Wolfram Language code: SeriesCoefficient[ArcSinh[x], {x, 0, n}]

分岐点と分枝切断線における級数展開：

Wolfram Language code: Series[ArcSinh[x], {x, I, 4}]

Wolfram Language code: Series[ArcSinh[x], {x, -2I, 4}]

ArcSinhはベキ級数に適用できる：

Wolfram Language code: ArcSinh[Cos[x] + O[x] ^ 10]

積分変換 (2)

FourierTransformを使ってフーリエ(Fourier)変換を計算する：

Wolfram Language code: FourierTransform[ArcSinh[t], t, ω]

HankelTransform：

Wolfram Language code: HankelTransform[ArcSinh[r], r, s]

関数の恒等式と簡約 (3)

ArcSinhを含む式を簡約する：

Wolfram Language code: FullSimplify[Sinh[ArcSinh[x] + ArcSinh[y]]^4 - 2(2y^2 x^2 + x^2 + y^2)Sinh[ArcSinh[x] + ArcSinh[y]]^2 + (x^2 - y^2)^2]

TrigToExpを使い，対数を使ってArcSinhを表す：

Wolfram Language code: TrigToExp@ArcSinh[z]

Wolfram Language code: ExpToTrig[%]

実変数およびを仮定して展開する：

Wolfram Language code: ComplexExpand[ArcSinh[x + I y]]

関数表現 (5)

ArcCschを使って表現する：

Wolfram Language code: ArcCsch[1 / x]//FullSimplify

逆ヤコビ関数を介した表現：

Wolfram Language code: InverseJacobiCS[(1/z), 1]//FullSimplify

Wolfram Language code: InverseJacobiSC[z, 1]

Hypergeometric2F1を使って表現する：

Wolfram Language code: x Hypergeometric2F1[(1/2), (1/2), (3/2), -x^2]

ArcSinhはMeijerGによって表現することができる：

Wolfram Language code: MeijerGReduce[ArcSinh[x], x]

Wolfram Language code: Activate[%]

ArcSinhはDifferentialRootとして表すことができる：

Wolfram Language code: DifferentialRootReduce[ArcSinh[x], x]

アプリケーション (3)

ベースから指定のまでの双曲線の長さを計算する：

Wolfram Language code: Integrate[Sqrt[D[Sqrt[1 + t ^ 2], t] ^ 2 + 1], {t, 0, x}, Assumptions -> x > 0]

Wolfram Language code: N[% /. x -> 3, 20]

微分方程式を解く：

Wolfram Language code: DSolve[{(1 + x^2) y''[x] + x y'[x] == 1, y[0] == 0, y'[0] == 1}, y[x], x]

sinh‐Gordon方程式の解：

Wolfram Language code: u[x_, t_] := 2ArcSinh[JacobiCS[x - t, m]]

解をチェックする：

Wolfram Language code: FullSimplify[D[u[x, t], x, t] + Sinh[u[x, t]], JacobiNS[t - x, m] ^ 2 - JacobiCS[t - x, m] ^ 2 == 1]

解をプロットする：

Wolfram Language code: Plot3D[Evaluate[u[x, t] /. m -> 4 / 3], {x, -3, 2}, {t, 0, 5 / 2}]

特性と関係 (4)

逆関数で構成する：

Wolfram Language code: {ArcSinh[Sinh[z]], Sinh[ArcSinh[z]]}

PowerExpandを使ってArcSinhの多価性を無視する：

Wolfram Language code: PowerExpand[%]

別の方法として，追加的な仮定の下で評価する：

Wolfram Language code: Refine[ArcSinh[Sinh[z]], z∈Reals]

TrigToExpを使って対数でArcSinhを表現する：

Wolfram Language code: ArcSinh[z]//TrigToExp

Wolfram Language code: ExpToTrig[%]

Reduceを使って方程式をArcSinhについて解く：

Wolfram Language code: Reduce[Sinh[x] == y, x]

ArcSinhはいくつかの特殊関数の特別な場合である：

Wolfram Language code: x Hypergeometric2F1[1 / 2, 1 / 2, 3 / 2, -x ^ 2]

考えられる問題 (2)

一般にである：

Wolfram Language code: ArcSinh[Sinh[30. I]]

Wolfram Language code: Sinh[ArcSinh[30. I]]

慣用形の入力を使う場合には引数の前後にカッコが必要である：

Wolfram Language code: sinh^-1x

Wolfram Language code: sinh^-1(x)

おもしろい例題 (1)

を100,000桁まで計算し，最初と最後の20桁を示す：

Wolfram Language code: x = N[ArcSinh[1], 10 ^ 5];

Wolfram Language code: With[{s = ToString[x]}, Row[{StringTake[s, 20], "⋯", StringTake[s, -20]}]]

Top

その他のラーニングリソース

テクニカルサポート

Wolframソリューション

教育のためのWolframソリューション

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

ArcSinh

詳細

予備知識

例題

例 (6)

スコープ (45)

数値評価 (6)

特定の値 (4)

可視化 (3)

関数の特性 (12)

微分 (3)

積分 (3)

級数展開： (4)

積分変換 (2)

関数の恒等式と簡約 (3)

関数表現 (5)

アプリケーション (3)

特性と関係 (4)

考えられる問題 (2)

おもしろい例題 (1)

テキスト

CMS

APA

BibTeX

BibLaTeX

ArcSinh

詳細

予備知識

例題

例 (6)

スコープ (45)

数値評価 (6)

特定の値 (4)

可視化 (3)

関数の特性 (12)

微分 (3)

積分 (3)

級数展開： (4)

積分変換 (2)

関数の恒等式と簡約 (3)

関数表現 (5)

アプリケーション (3)

特性と関係 (4)

考えられる問題 (2)

おもしろい例題 (1)

関連項目

テクニカルノート

関連するガイド

関連リンク

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX