Wolfram 语言与系统参考资料中心

ArcSinh

参见
- Sinh
- ArcCosh
- ArcSin
- TrigToExp
- TrigExpand
相关指南
技术笔记
- 初等超越函数

ArcSinh

ArcSinh[z]

给出复数的反双曲正弦函数 .

背景

ArcSinh 是反双曲正弦函数. 对实数，ArcSinh[x] 表示满足的双曲角度且 .
ArcSinh 自动逐项作用于列表. 对某些特定变量值，ArcSinh 自动计算出精确值. 当给出精确数值表达式作为变量时，ArcSinh 可以算出任意精度的数值结果. 对包含 ArcSinh 的符号表达式，适用的操作运算有 FunctionExpand、TrigToExp、TrigExpand、Simplify 和 FullSimplify.
对复变量，ArcSinh 的定义为 . ArcSinh[z] 在复平面上有一个不连续的分支切割.
与之相关的数学函数有 Sinh、ArcCosh 和 ArcSin.

范例

打开所有单元关闭所有单元

基本范例 (6)

数值计算：

Wolfram Language code: ArcSinh[1.5]

在实数域子集上绘图：

Wolfram Language code: Plot[ArcSinh[x], {x, -10, 10}]

在复数的子集上绘图：

Wolfram Language code: ComplexPlot3D[ArcSinh[z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

在 0 处的级数展开：

Wolfram Language code: Series[ArcSinh[x], {x, 0, 10}]

在 Infinity 处的渐近展开：

Wolfram Language code: Series[ArcSinh[x], {x, ∞, 3}]

奇点处的渐近展开：

Wolfram Language code: Series[ArcSinh[x], {x, I, 3}, Assumptions -> x > 1]

范围 (45)

数值计算 (6)

数值计算：

Wolfram Language code: ArcSinh[1.0]

高精度求值：

Wolfram Language code: N[ArcSinh[1], 100]

输出精度与输入精度一致：

Wolfram Language code: ArcSinh[1.000000000000000000000000000000000000000000000000000000]

对复数参数进行计算：

Wolfram Language code: ArcSinh[1.5 + 0.7I]

在高精度条件下高效计算 ArcSinh：

Wolfram Language code: ArcSinh[1`500]//Timing

Wolfram Language code: ArcSinh[1`100000];//Timing

用 Interval 和 CenteredInterval 对象计算最坏情况下的区间：

Wolfram Language code: ArcSinh[Interval[{-5 / 2, Sinh[2]}]]

Wolfram Language code: ArcSinh[CenteredInterval[3, 1 / 100]]

Wolfram Language code: ArcSinh[CenteredInterval[2 + 3I, (1 + I) / 100]]

或使用 Around 计算一般情况下的统计区间：

Wolfram Language code: ArcSinh[Around[.9, 0.1]]

计算数组中每个元素的值：

Wolfram Language code: ArcSinh[{{I, I / Sqrt[2]}, {0, -I / Sqrt[2]}}]

或用 MatrixFunction 以矩阵形式计算 ArcSinh 函数：

Wolfram Language code: MatrixFunction[ArcSinh[#]&, {{I, I / Sqrt[2]}, {0, -I / Sqrt[2]}}]

特殊值 (4)

ArcSinh 在固定点上的值：

Wolfram Language code: Table[ArcSinh[(n /2)I], {n, -2, 2}]

无穷处的值：

Wolfram Language code: ArcSinh[Infinity]

Wolfram Language code: ArcSinh[ComplexInfinity]

ArcSinh 的零点：

Wolfram Language code: ArcSinh[0]

求满足方程的的值：

Wolfram Language code: f[x_] := ArcSinh[x] - Log[2];

Wolfram Language code: sol = Solve[f[x] == 0, x]

代入值：

Wolfram Language code: xzero = x /. First[sol]

可视化结果：

Wolfram Language code: Plot[f[x], {x, 0, 1}, Epilog -> Style[Point[{xzero, f[xzero]}], PointSize[Large], Red]]

可视化 (3)

绘制 ArcSinh 函数：

Wolfram Language code: Plot[ArcSinh[x], {x, -50, 50}]

绘制的实部：

Wolfram Language code: ComplexContourPlot[Re[ArcSinh[z]], {z, -3 - 3 I, 3 + 3 I}, IconizedObject[«PlotOptions»]]

绘制的虚部：

Wolfram Language code: ComplexContourPlot[Im[ArcSinh[z]], {z, -3 - 3 I, 3 + 3 I}, IconizedObject[«PlotOptions»]]

，绘制极坐标图：

Wolfram Language code:

Table[PolarPlot[ArcSinh[k ϕ], {ϕ, -10π, 10π}, Frame -> True, Exclusions -> None, PlotLabel -> "k=" <> ToString[k], PlotRange -> {{-6, 6}, {-6, 6}}, FrameTicks -> {{{-6, -3, 0, 3, 6}, None}, {{-6, -3, 0, 3, 6}, None}}], {k, 1, 4}]

函数属性 (12)

ArcSinh 是针对所有实数和复数定义的：

Wolfram Language code: FunctionDomain[ArcSinh[x], x]

Wolfram Language code: FunctionDomain[ArcSinh[z], z, Complexes]

ArcSinh 获取所有实数值：

Wolfram Language code: FunctionRange[ArcSinh[x], x, y]

复定义域参数的值域范围：

Wolfram Language code: FunctionRange[ArcSinh[z], z, y, Complexes]

ArcSinh 是一个奇函数：

Wolfram Language code: ArcSinh[-x]

ArcSinh 具有镜像属性 $sinh^(-1)(TemplateBox[{z}, Conjugate])=TemplateBox[{{{sinh, ^, {(, {-, 1}, )}}, (, z, )}}, Conjugate]$ ：

Wolfram Language code: FullSimplify[ArcSinh[Conjugate[z]] == Conjugate[ArcSinh[z]]]

在实数上是的解析函数：

Wolfram Language code: FunctionAnalytic[ArcSinh[x], x]

在复数上，既不是解析函数也不是亚纯函数：

Wolfram Language code: FunctionAnalytic[ArcSinh[x], x, Complexes]

Wolfram Language code: FunctionMeromorphic[ArcSinh[x], x]

ArcSinh 非递减：

Wolfram Language code: FunctionMonotonicity[ArcSinh[x], x]

ArcSinh 是单射函数：

Wolfram Language code: FunctionInjective[ArcSinh[x], x]

Wolfram Language code: Plot[{ArcSinh[x], 1}, {x, -4, 4}]

ArcSinh 是满射函数：

Wolfram Language code: FunctionSurjective[ArcSinh[x], x]

Wolfram Language code: Plot[{ArcSinh[x], 10}, {x, -50000, 50000}, PlotRange -> {-12, 12}]

ArcSinh 既不是非负，也不是非正：

Wolfram Language code: FunctionSign[ArcSinh[x], x]

ArcSinh 没有奇点和断点：

Wolfram Language code: FunctionSingularities[ArcSinh[x], x]

Wolfram Language code: FunctionDiscontinuities[ArcSinh[x], x]

ArcSinh 既不凸，也不凹：

Wolfram Language code: FunctionConvexity[ArcSinh[x], x]

TraditionalForm 格式输出：

Wolfram Language code: ArcSinh[x]//TraditionalForm

微分 (3)

一阶导数：

Wolfram Language code: D[ArcSinh[x], x]

高阶导数：

Wolfram Language code: Table[D[ArcSinh[x], {x, n}], {n, 1, 4}]

Wolfram Language code:

Plot[Evaluate[%], {x, -1, 1}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

阶导数的公式：

Wolfram Language code: D[ArcSinh[x], {x, n}]

积分 (3)

ArcSinh 的不定积分：

Wolfram Language code: Integrate[ArcSinh[x], x]

在以原点为中心的区间上，ArcSinh 的定积分为0：

Wolfram Language code: Integrate[ArcSinh[x], {x, -2, 2}]

更多积分：

Wolfram Language code: Integrate[ArcSinh[x] x, x]

Wolfram Language code: Integrate[ArcSinh[x] ^ a, x]

级数展开式 (4)

使用 Series 求泰勒级数展开式：

Wolfram Language code: Series[ArcSinh[x], {x, 0, 7}]

绘制 ArcSinh 在处的前三个近似式：

Wolfram Language code:

terms = Normal@Table[Series[ArcSinh[x], {x, 0, m}], {m, 1, 5, 2}];
Plot[{ArcSinh[x], terms}, {x, -1.5, 1.5}, PlotRange -> {{-1.5, 1.5}, All}]

ArcSinh 级数展开式的通项:

Wolfram Language code: SeriesCoefficient[ArcSinh[x], {x, 0, n}]

在分支点和分支切口处求级数展开：

Wolfram Language code: Series[ArcSinh[x], {x, I, 4}]

Wolfram Language code: Series[ArcSinh[x], {x, -2I, 4}]

ArcSinh 可被应用于幂级数：

Wolfram Language code: ArcSinh[Cos[x] + O[x] ^ 10]

积分变换 (2)

用 FourierTransform 计算傅立叶变换：

Wolfram Language code: FourierTransform[ArcSinh[t], t, ω]

HankelTransform:

Wolfram Language code: HankelTransform[ArcSinh[r], r, s]

函数恒等式和化简 (3)

化简含有 ArcSinh 的表达式：

Wolfram Language code: FullSimplify[Sinh[ArcSinh[x] + ArcSinh[y]]^4 - 2(2y^2 x^2 + x^2 + y^2)Sinh[ArcSinh[x] + ArcSinh[y]]^2 + (x^2 - y^2)^2]

通过 TrigToExp 用对数来表示 ArcSinh：

Wolfram Language code: TrigToExp@ArcSinh[z]

Wolfram Language code: ExpToTrig[%]

假定实数变量和的情况下进行展开：

Wolfram Language code: ComplexExpand[ArcSinh[x + I y]]

函数表示 (5)

使用 ArcCsch 表示：

Wolfram Language code: ArcCsch[1 / x]//FullSimplify

通过逆 Jacobi 函数表示：

Wolfram Language code: InverseJacobiCS[(1/z), 1]//FullSimplify

Wolfram Language code: InverseJacobiSC[z, 1]

使用 Hypergeometric2F1 表示：

Wolfram Language code: x Hypergeometric2F1[(1/2), (1/2), (3/2), -x^2]

可用 MeijerG 表示ArcSinh：

Wolfram Language code: MeijerGReduce[ArcSinh[x], x]

Wolfram Language code: Activate[%]

ArcSinh 可被表示为 DifferentialRoot：

Wolfram Language code: DifferentialRootReduce[ArcSinh[x], x]

应用 (3)

计算双曲线从基底到给定之间的长度：

Wolfram Language code: Integrate[Sqrt[D[Sqrt[1 + t ^ 2], t] ^ 2 + 1], {t, 0, x}, Assumptions -> x > 0]

Wolfram Language code: N[% /. x -> 3, 20]

求解一个微分方程：

Wolfram Language code: DSolve[{(1 + x^2) y''[x] + x y'[x] == 1, y[0] == 0, y'[0] == 1}, y[x], x]

Sinh-Gordon 方程的解：

Wolfram Language code: u[x_, t_] := 2ArcSinh[JacobiCS[x - t, m]]

检验解：

Wolfram Language code: FullSimplify[D[u[x, t], x, t] + Sinh[u[x, t]], JacobiNS[t - x, m] ^ 2 - JacobiCS[t - x, m] ^ 2 == 1]

绘制解：

Wolfram Language code: Plot3D[Evaluate[u[x, t] /. m -> 4 / 3], {x, -3, 2}, {t, 0, 5 / 2}]

属性和关系 (4)

与反函数合成：

Wolfram Language code: {ArcSinh[Sinh[z]], Sinh[ArcSinh[z]]}

利用 PowerExpand 去掉 ArcSinh 的多值性：

Wolfram Language code: PowerExpand[%]

也可在附加假设条件下计算：

Wolfram Language code: Refine[ArcSinh[Sinh[z]], z∈Reals]

利用 TrigToExp 通过对数表示 ArcSinh：

Wolfram Language code: ArcSinh[z]//TrigToExp

Wolfram Language code: ExpToTrig[%]

利用 Reduce 通过 ArcSinh 求解一个方程：

Wolfram Language code: Reduce[Sinh[x] == y, x]

ArcSinh 是某些特殊函数的特殊情况：

Wolfram Language code: x Hypergeometric2F1[1 / 2, 1 / 2, 3 / 2, -x ^ 2]

可能存在的问题 (2)

一般地，：

Wolfram Language code: ArcSinh[Sinh[30. I]]

Wolfram Language code: Sinh[ArcSinh[30. I]]

当在传统形式中使用输入时，自变量需要圆括号：

Wolfram Language code: sinh^-1x

Wolfram Language code: sinh^-1(x)

巧妙范例 (1)

计算到的100000 位，并显示前20位和后20位：

Wolfram Language code: x = N[ArcSinh[1], 10 ^ 5];

Wolfram Language code: With[{s = ToString[x]}, Row[{StringTake[s, 20], "⋯", StringTake[s, -20]}]]

Top

更多学习资源

技术支持

Wolfram 解决方案

Wolfram 的教育解决方案

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

ArcSinh

更多信息

背景

范例

基本范例 (6)

范围 (45)

数值计算 (6)

特殊值 (4)

可视化 (3)

函数属性 (12)

微分 (3)

积分 (3)

级数展开式 (4)

积分变换 (2)

函数恒等式和化简 (3)

函数表示 (5)

应用 (3)

属性和关系 (4)

可能存在的问题 (2)

巧妙范例 (1)

文本

CMS

APA

BibTeX

BibLaTeX

ArcSinh

更多信息

背景

范例

基本范例 (6)

范围 (45)

数值计算 (6)

特殊值 (4)

可视化 (3)

函数属性 (12)

微分 (3)

积分 (3)

级数展开式 (4)

积分变换 (2)

函数恒等式和化简 (3)

函数表示 (5)

应用 (3)

属性和关系 (4)

可能存在的问题 (2)

巧妙范例 (1)

参见

技术笔记

相关指南

相关链接

历史

文本

CMS

APA

BibTeX

BibLaTeX