WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ArcTanh[z]

複素数 の逆双曲線正接を与える．

詳細
Details and Options Details and Options
予備知識
例題  
例  
スコープ  
数値評価  
特定の値  
可視化  
Show More Show More
関数の特性  
微分  
積分  
級数展開  
関数の恒等式と簡約  
関数表現  
アプリケーション  
特性と関係  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

ArcTanh

ArcTanh[z]

複素数 の逆双曲線正接を与える．

詳細

  • 記号操作・数値操作の両方に適した数学関数である．
  • 特別な引数の場合，ArcTanhは自動的に厳密値を計算する．
  • ArcTanhは任意の数値精度で評価できる．
  • ArcTanhは自動的にリストに並列的な関数の適用を行う．
  • ArcTanh[z]は，複素 平面上，〜そして〜の範囲で不連続な分枝切断線を持つ．
  • ArcTanhはIntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる． »

予備知識

  • ArcTanhは，逆双曲線正接関数である．ArcTanh[x]は，実数 x について， となるようなの双曲線角度を表す．
  • ArcTanhは自動的にリストに縫い込まれる．特別な引数の場合，ArcTanhは自動的に厳密値を計算する．厳密な数式が引数として与えられると，ArcTanhは任意の数値精度に評価できることがある．ArcTanhを含む記号式の操作に役立つその他の演算には，FunctionExpand，TrigToExp，TrigExpand，Simplify，FullSimplify等がある．
  • ArcTanhは，複素引数 については，によって定義される．ArcTanh[z]は複素 平面上で不連続な分枝切断線を持つ．
  • 関連する数学関数には，Tanh，ArcCoth，ArcTanがある．

例題

すべて開く すべて閉じる

例  (6)

数値的に評価する：

Wolfram Language code: ArcTanh[0.5]

実数の部分集合上でプロットする：

Wolfram Language code: Plot[ArcTanh[x], {x, -1, 1}]

複素数の部分集合上でプロットする：

Wolfram Language code: ComplexPlot3D[ArcTanh[z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

原点付近の級数展開：

Wolfram Language code: Series[ArcTanh[x], {x, 0, 20}]

Infinityにおける漸近展開：

Wolfram Language code: Series[ArcTanh[x], {x, ∞, 3}]

特異点における漸近展開：

Wolfram Language code: Series[ArcTanh[x], {x, -1, 3}]

スコープ  (42)

数値評価  (6)

数値的に評価する：

Wolfram Language code: ArcTanh[0.5]

高精度で評価する：

Wolfram Language code: N[ArcTanh[1 / 2], 50]

出力精度は入力精度に従う：

Wolfram Language code: ArcTanh[0.50000000000000000000000000000000000000000]

複素引数について評価する：

Wolfram Language code: ArcTanh[2.5 + I]

ArcTanhを高精度で効率よく評価する：

Wolfram Language code: ArcTanh[0.5`500]//Timing
Wolfram Language code: ArcTanh[0.5`100000];//Timing

IntervalオブジェクトとCenteredIntervalオブジェクトを使って最悪の場合に保証される区間を計算する：

Wolfram Language code: ArcTanh[Interval[{1, Tanh[5]}]]
Wolfram Language code: ArcTanh[CenteredInterval[1 / 2, 1 / 100]]
Wolfram Language code: ArcTanh[CenteredInterval[2 + 3I, (1 + I) / 100]]

Aroundを使って平均的な場合の統計区間を計算することもできる：

Wolfram Language code: ArcTanh[Around[.9, 0.1]]

配列の要素ごとの値を計算する：

Wolfram Language code: ArcTanh[{{I, -I }, {0, -I}}]

MatrixFunctionを使って行列のArcTanh関数を計算することもできる：

Wolfram Language code: MatrixFunction[ArcTanh[#]&, {{I, -I }, {0, -I}}]

特定の値  (4)

固定点におけるArcTanhの値：

Wolfram Language code: Table[ArcTanh[n], {n, -1, 1}]

無限大における値：

Wolfram Language code: ArcTanh[Infinity]
Wolfram Language code: ArcTanh[ComplexInfinity]

ArcTanhの零点：

Wolfram Language code: ArcTanh[0]

方程式 を満足する の値を求める：

Wolfram Language code: f[x_] := ArcTanh[x] - Log[2];
Wolfram Language code: sol = Solve[f[x] == 0, x]

値を代入する：

Wolfram Language code: xzero = x /. First[sol]

結果を可視化する：

Wolfram Language code: Plot[f[x], {x, 0, 1}, Epilog -> Style[Point[{xzero, f[xzero]}], PointSize[Large], Red]]

可視化  (3)

ArcTanh関数をプロットする：

Wolfram Language code: Plot[ArcTanh[x], {x, -1, 1}]

の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[ArcTanh[z]], {z, -3 - 3 I, 3 + 3 I}, Contours -> 24]

の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[ArcTanh[z]], {z, -3 - 3 I, 3 + 3 I}, Contours -> 24]

の極プロット：

Wolfram Language code: Table[PolarPlot[ArcTanh[k ϕ], {ϕ, -π, π}, Frame -> True , PlotLabel -> "k=" <> ToString[k], PlotRange -> {{-5, 5}, {0, 5}}], {k, 1, 4}]

関数の特性  (11)

ArcTanhは区間からのすべての実数値について定義される：

Wolfram Language code: FunctionDomain[ArcTanh[x], x]

複素領域：

Wolfram Language code: FunctionDomain[ArcTanh[z], z, Complexes]

ArcTanhはすべての実数値に達する：

Wolfram Language code: FunctionRange[ArcTanh[x], x, y]

複素領域からの引数についての関数の範囲：

Wolfram Language code: FunctionRange[ArcTanh[z], z, y, Complexes]

ArcTanhは奇関数である：

Wolfram Language code: ArcTanh[-x]

ArcTanhは解析関数ではない：

Wolfram Language code: FunctionAnalytic[ArcTanh[x], x]

有理型でもない：

Wolfram Language code: FunctionMeromorphic[ArcTanh[x], x]

ArcTanhは実数領域上で増加する：

Wolfram Language code: FunctionMonotonicity[{ArcTanh[x], -1 < x < 1}, x, StrictInequalities -> True]

ArcTanhは単射である：

Wolfram Language code: FunctionInjective[ArcTanh[x], x]
Wolfram Language code: Plot[{ArcTanh[x], 1}, {x, -1, 1}]

ArcTanhは全射である：

Wolfram Language code: FunctionSurjective[ArcTanh[x], x]
Wolfram Language code: Plot[{ArcTanh[x], 5}, {x, -1, 1}]

ArcTanhは非負でも非正でもない：

Wolfram Language code: FunctionSign[ArcTanh[x], x]

(-∞,-1]と[1,∞)に特異点と不連続点の両方を持つ：

Wolfram Language code: FunctionSingularities[ArcTanh[x], x]
Wolfram Language code: FunctionDiscontinuities[ArcTanh[x], x]

ArcTanhは凸でも凹でもない：

Wolfram Language code: FunctionConvexity[ArcTanh[x], x]

TraditionalFormによる表示：

Wolfram Language code: ArcTan[x]//TraditionalForm

微分  (3)

一次導関数：

Wolfram Language code: D[ArcTanh[x], x]

高次導関数：

Wolfram Language code: Table[D[ArcTanh[x], {x, n}], {n, 1, 4}]
Wolfram Language code: Plot[Evaluate[%], {x, -1, 1}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

次導関数の式：

Wolfram Language code: D[ArcTanh[x], {x, n}]

積分  (3)

ArcTanhの不定積分：

Wolfram Language code: Integrate[ArcTanh[x], x]

原点を中心とする区間上でのArcTanhの定積分は0である：

Wolfram Language code: Integrate[ArcTanh[x], {x, -0.5, 0.5}]

その他の積分例：

Wolfram Language code: Integrate[x ArcTanh[x], x]
Wolfram Language code: Integrate[x ^ k ArcTanh[x], x]

級数展開  (4)

Seriesを使ってテイラー(Taylor)展開を求める：

Wolfram Language code: Series[ArcTanh[x], {x, 0, 7}]

の周りのArcTanhについての最初の3つの近似をプロットする：

Wolfram Language code: terms = Normal@Table[Series[ArcTanh[x], {x, 0, m}], {m, 1, 5, 2}]; Plot[{ArcTanh[x], terms}, {x, -1, 1}, PlotRange -> {{-1, 1}, {-3, 3}}]

ArcTanhの級数展開における一般項：

Wolfram Language code: SeriesCoefficient[ArcTanh[x], {x, 0, n}]

分岐点と分枝切断線における級数展開を求める：

Wolfram Language code: Series[ArcTanh[x], {x, 1, 1}]
Wolfram Language code: Series[ArcTanh[x], {x, 2, 1}]

ArcTanhはベキ級数に適用できる：

Wolfram Language code: Tanh[x] + O[x] ^ 10
Wolfram Language code: ArcTanh[%]

関数の恒等式と簡約  (3)

ArcTanhを含む式を簡約する：

Wolfram Language code: FullSimplify[Tanh[ArcTanh[x] + ArcTanh[y]] - (x + y/1 + x y)]

Logを使ってArcTanhを表す：

Wolfram Language code: TrigToExp[ArcTanh[z]]

変換し直す：

Wolfram Language code: ExpToTrig[%]

実変数 および を仮定して展開する：

Wolfram Language code: ComplexExpand[ArcTanh[x + I y]]

関数表現  (5)

ArcCothを使って表現する：

Wolfram Language code: ArcCoth[1 / x]//FullSimplify

逆ヤコビ関数を介して表現する：

Wolfram Language code: InverseJacobiNS[(1/z), 1]//FullSimplify
Wolfram Language code: InverseJacobiSN[z, 1]

ArcTanhは超幾何関数Hypergeometric2F1の特殊ケースである：

Wolfram Language code: x Hypergeometric2F1[(1/2), 1, (3/2), x^2]

ArcTanhはMeijerGによって表現できる：

Wolfram Language code: MeijerGReduce[ArcTanh[x], x]
Wolfram Language code: Activate[%]

ArcTanhはDifferentialRootとして表すことができる：

Wolfram Language code: DifferentialRootReduce[ArcTanh[x], x]

アプリケーション  (3)

光速の0.999倍に相当する速さを求める：

Wolfram Language code: ArcTanh[0.999]

ArcTanhの分枝切断線：

Wolfram Language code: Plot3D[Im[ArcTanh[x + I y]], {x, -2, 2}, {y, -1, 1}]

微分方程式を解く：

Wolfram Language code: DSolve[Sqrt[x - 1]Sqrt[x + 1]y'[x] == 1, y[x], x]

特性と関係  (2)

Logを使ってArcTanhを表す：

Wolfram Language code: TrigToExp[ArcTanh[z]]

もとに戻す：

Wolfram Language code: ExpToTrig[%]

ArcTanhはある種の特殊関数の特殊なケースである：

Wolfram Language code: x Hypergeometric2F1[1 / 2, 1, 3 / 2, x ^ 2]
Wolfram Research (1988), ArcTanh, Wolfram言語関数， https://reference.wolfram.com/language/ref/ArcTanh.html （2021年に更新）.

テキスト

Wolfram Research (1988), ArcTanh, Wolfram言語関数， https://reference.wolfram.com/language/ref/ArcTanh.html （2021年に更新）.

CMS

Wolfram Language. 1988. "ArcTanh." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2021. https://reference.wolfram.com/language/ref/ArcTanh.html.

APA

Wolfram Language. (1988). ArcTanh. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ArcTanh.html

BibTeX

@misc{reference.wolfram_2026_arctanh, author="Wolfram Research", title="{ArcTanh}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/ArcTanh.html}", note=[Accessed: 19-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_arctanh, organization={Wolfram Research}, title={ArcTanh}, year={2021}, url={https://reference.wolfram.com/language/ref/ArcTanh.html}, note=[Accessed: 19-August-2026]}