WOLFRAM

Wolfram 语言与系统参考资料中心

ArcTanh[z]

给出复数 的反双曲正切函数 .

更多信息
Details and Options Details and Options
背景
范例  
基本范例  
范围  
数值计算  
特殊值  
可视化  
Show More Show More
函数属性  
微分  
积分  
级数展开式  
函数属性和化简  
函数表示  
应用  
属性和关系  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

ArcTanh

ArcTanh[z]

给出复数 的反双曲正切函数 .

更多信息

  • 数学函数，适宜于符号和数值计算.
  • 对于某些特殊参数，ArcTanh 自动计算出精确值.
  • ArcTanh 可以计算到任意数值精度.
  • ArcTanh 自动逐项作用于列表的各个元素.
  • ArcTanh[z] 在复平面 上有分支切割，从 到 ，从 到 .
  • ArcTanh 可与 Interval 和 CenteredInterval 对象一起使用. »

背景

范例

打开所有单元 关闭所有单元

基本范例  (6)

数值计算：

Wolfram Language code: ArcTanh[0.5]

在实数域子集上绘图：

Wolfram Language code: Plot[ArcTanh[x], {x, -1, 1}]

在复数的子集上绘图：

Wolfram Language code: ComplexPlot3D[ArcTanh[z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

在原点进行级数展开：

Wolfram Language code: Series[ArcTanh[x], {x, 0, 20}]

在 Infinity 处的渐近展开：

Wolfram Language code: Series[ArcTanh[x], {x, ∞, 3}]

奇点处的渐近展开：

Wolfram Language code: Series[ArcTanh[x], {x, -1, 3}]

范围  (42)

数值计算  (6)

数值计算：

Wolfram Language code: ArcTanh[0.5]

高精度求值：

Wolfram Language code: N[ArcTanh[1 / 2], 50]

输出精度与输入精度一致：

Wolfram Language code: ArcTanh[0.50000000000000000000000000000000000000000]

计算复变量：

Wolfram Language code: ArcTanh[2.5 + I]

在高精度条件下高效计算 ArcTanh：

Wolfram Language code: ArcTanh[0.5`500]//Timing
Wolfram Language code: ArcTanh[0.5`100000];//Timing

用 Interval 和 CenteredInterval 对象计算最坏情况下的区间：

Wolfram Language code: ArcTanh[Interval[{1, Tanh[5]}]]
Wolfram Language code: ArcTanh[CenteredInterval[1 / 2, 1 / 100]]
Wolfram Language code: ArcTanh[CenteredInterval[2 + 3I, (1 + I) / 100]]

或使用 Around 计算一般情况下的统计区间：

Wolfram Language code: ArcTanh[Around[.9, 0.1]]

计算数组中每个元素的值：

Wolfram Language code: ArcTanh[{{I, -I }, {0, -I}}]

或用 MatrixFunction 以矩阵形式计算 ArcTanh 函数：

Wolfram Language code: MatrixFunction[ArcTanh[#]&, {{I, -I }, {0, -I}}]

特殊值  (4)

ArcTanh 在固定点上的值：

Wolfram Language code: Table[ArcTanh[n], {n, -1, 1}]

无穷处的值：

Wolfram Language code: ArcTanh[Infinity]
Wolfram Language code: ArcTanh[ComplexInfinity]

ArcTanh 的零点：

Wolfram Language code: ArcTanh[0]

求满足方程 的 的值：

Wolfram Language code: f[x_] := ArcTanh[x] - Log[2];
Wolfram Language code: sol = Solve[f[x] == 0, x]

替换为值：

Wolfram Language code: xzero = x /. First[sol]

可视化结果：

Wolfram Language code: Plot[f[x], {x, 0, 1}, Epilog -> Style[Point[{xzero, f[xzero]}], PointSize[Large], Red]]

可视化  (3)

绘制 ArcTanh 函数：

Wolfram Language code: Plot[ArcTanh[x], {x, -1, 1}]

绘制 的实部：

Wolfram Language code: ComplexContourPlot[Re[ArcTanh[z]], {z, -3 - 3 I, 3 + 3 I}, Contours -> 24]

绘制 的虚部：

Wolfram Language code: ComplexContourPlot[Im[ArcTanh[z]], {z, -3 - 3 I, 3 + 3 I}, Contours -> 24]

，绘制极坐标图：

Wolfram Language code: Table[PolarPlot[ArcTanh[k ϕ], {ϕ, -π, π}, Frame -> True , PlotLabel -> "k=" <> ToString[k], PlotRange -> {{-5, 5}, {0, 5}}], {k, 1, 4}]

函数属性  (11)

ArcTanh 是针对区间 内的所有实数定义的：

Wolfram Language code: FunctionDomain[ArcTanh[x], x]

复定义域：

Wolfram Language code: FunctionDomain[ArcTanh[z], z, Complexes]

ArcTanh 获得所有实数值：

Wolfram Language code: FunctionRange[ArcTanh[x], x, y]

复定义域参数的值域范围：

Wolfram Language code: FunctionRange[ArcTanh[z], z, y, Complexes]

ArcTanh 是一个奇函数：

Wolfram Language code: ArcTanh[-x]

ArcTanh 不是解析函数：

Wolfram Language code: FunctionAnalytic[ArcTanh[x], x]

也不是亚纯函数：

Wolfram Language code: FunctionMeromorphic[ArcTanh[x], x]

ArcTanh 在其实数域上递增：

Wolfram Language code: FunctionMonotonicity[{ArcTanh[x], -1 < x < 1}, x, StrictInequalities -> True]

ArcTanh 是单射函数：

Wolfram Language code: FunctionInjective[ArcTanh[x], x]
Wolfram Language code: Plot[{ArcTanh[x], 1}, {x, -1, 1}]

ArcTanh 是满射函数：

Wolfram Language code: FunctionSurjective[ArcTanh[x], x]
Wolfram Language code: Plot[{ArcTanh[x], 5}, {x, -1, 1}]

ArcTanh 既不是非负，也不是非正：

Wolfram Language code: FunctionSign[ArcTanh[x], x]

函数在 (-∞,-1] 和 [1,∞) 内有奇点和断点：

Wolfram Language code: FunctionSingularities[ArcTanh[x], x]
Wolfram Language code: FunctionDiscontinuities[ArcTanh[x], x]

ArcTanh 既不凸，也不凹：

Wolfram Language code: FunctionConvexity[ArcTanh[x], x]

TraditionalForm 格式输出：

Wolfram Language code: ArcTan[x]//TraditionalForm

微分  (3)

一阶导数：

Wolfram Language code: D[ArcTanh[x], x]

高阶导数：

Wolfram Language code: Table[D[ArcTanh[x], {x, n}], {n, 1, 4}]
Wolfram Language code: Plot[Evaluate[%], {x, -1, 1}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

阶导数的公式：

Wolfram Language code: D[ArcTanh[x], {x, n}]

积分  (3)

ArcTanh 的不定积分：

Wolfram Language code: Integrate[ArcTanh[x], x]

在以原点为中心的区间上，ArcTanh 的定积分为0；

Wolfram Language code: Integrate[ArcTanh[x], {x, -0.5, 0.5}]

更多积分：

Wolfram Language code: Integrate[x ArcTanh[x], x]
Wolfram Language code: Integrate[x ^ k ArcTanh[x], x]

级数展开式  (4)

使用 Series 求泰勒级数展开式；

Wolfram Language code: Series[ArcTanh[x], {x, 0, 7}]

绘制 ArcTanh 在 处的前三个近似式：

Wolfram Language code: terms = Normal@Table[Series[ArcTanh[x], {x, 0, m}], {m, 1, 5, 2}]; Plot[{ArcTanh[x], terms}, {x, -1, 1}, PlotRange -> {{-1, 1}, {-3, 3}}]

ArcTanh 级数展开式的通项:

Wolfram Language code: SeriesCoefficient[ArcTanh[x], {x, 0, n}]

在分支点和分支切口处求级数展开式：

Wolfram Language code: Series[ArcTanh[x], {x, 1, 1}]
Wolfram Language code: Series[ArcTanh[x], {x, 2, 1}]

ArcTanh 可用于幂级数：

Wolfram Language code: Tanh[x] + O[x] ^ 10
Wolfram Language code: ArcTanh[%]

函数属性和化简  (3)

化简含有 ArcTanh 的表达式：

Wolfram Language code: FullSimplify[Tanh[ArcTanh[x] + ArcTanh[y]] - (x + y/1 + x y)]

用 Log 表示 ArcTanh：

Wolfram Language code: TrigToExp[ArcTanh[z]]

转换回去：

Wolfram Language code: ExpToTrig[%]

假定实数变量 和 的情况下进行展开：

Wolfram Language code: ComplexExpand[ArcTanh[x + I y]]

函数表示  (5)

使用 ArcCoth 表示：

Wolfram Language code: ArcCoth[1 / x]//FullSimplify

通过逆 Jacobi 函数表示：

Wolfram Language code: InverseJacobiNS[(1/z), 1]//FullSimplify
Wolfram Language code: InverseJacobiSN[z, 1]

ArcTanh 是超几何函数 Hypergeometric2F1 的特例：

Wolfram Language code: x Hypergeometric2F1[(1/2), 1, (3/2), x^2]

ArcTanh 可用 MeijerG 表示：

Wolfram Language code: MeijerGReduce[ArcTanh[x], x]
Wolfram Language code: Activate[%]

ArcTanh 可用 DifferentialRoot 表示：

Wolfram Language code: DifferentialRootReduce[ArcTanh[x], x]

应用  (3)

求速度相当于 0.999 倍光速的快度：

Wolfram Language code: ArcTanh[0.999]

ArcTanh 的分支切割：

Wolfram Language code: Plot3D[Im[ArcTanh[x + I y]], {x, -2, 2}, {y, -1, 1}]

解微分方程：

Wolfram Language code: DSolve[Sqrt[x - 1]Sqrt[x + 1]y'[x] == 1, y[x], x]

属性和关系  (2)

用 Log 表示 ArcTanh：

Wolfram Language code: TrigToExp[ArcTanh[z]]

反向变换：

Wolfram Language code: ExpToTrig[%]

ArcTanh 是某些特殊函数的特例：

Wolfram Language code: x Hypergeometric2F1[1 / 2, 1, 3 / 2, x ^ 2]
Wolfram Research (1988)，ArcTanh，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ArcTanh.html （更新于 2021 年）.

文本

Wolfram Research (1988)，ArcTanh，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ArcTanh.html （更新于 2021 年）.

CMS

Wolfram 语言. 1988. "ArcTanh." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2021. https://reference.wolfram.com/language/ref/ArcTanh.html.

APA

Wolfram 语言. (1988). ArcTanh. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ArcTanh.html 年

BibTeX

@misc{reference.wolfram_2026_arctanh, author="Wolfram Research", title="{ArcTanh}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/ArcTanh.html}", note=[Accessed: 09-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_arctanh, organization={Wolfram Research}, title={ArcTanh}, year={2021}, url={https://reference.wolfram.com/language/ref/ArcTanh.html}, note=[Accessed: 09-September-2026]}