WOLFRAM

Wolfram 语言与系统参考资料中心

Arrow[{pt1,pt2}]

是一个图形基元，表示从 pt1 到 pt2 的一个箭头标记.

Arrow[{pt1,pt2},s]

表示一个箭头标记，两端从 pt1 和 pt2 分别缩回距离 s.

Arrow[{pt1,pt2},{s1,s2}]

从 pt1 缩回距离 s1，从 pt2 缩回距离 s2.

Arrow[curve,…]

表示遵从指定的 curve 的箭头标记.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
箭头规范  
箭头样式  
坐标规范  
应用  
属性和关系  
巧妙范例  
参见
相关指南
相关链接
历史
按以下格式引用：

Arrow

Arrow[{pt1,pt2}]

是一个图形基元，表示从 pt1 到 pt2 的一个箭头标记.

Arrow[{pt1,pt2},s]

表示一个箭头标记，两端从 pt1 和 pt2 分别缩回距离 s.

Arrow[{pt1,pt2},{s1,s2}]

从 pt1 缩回距离 s1，从 pt2 缩回距离 s2.

Arrow[curve,…]

表示遵从指定的 curve 的箭头标记.

更多信息

  • Arrow 可用于 Graphics 和 Graphics3D（二维和三维图形）.
  • 下列 curve 的具体说明可以用于 Graphics 中：
  • Line[…]分段线段
    BezierCurve[…]合成 Bezier 曲线
    BSplineCurve[…]B-样条曲线
    JoinedCurve[…]连接的曲线对象
  • 下列 curve 的具体说明可以用于 Graphics3D 中：
  • Line[…]分段线段
    BezierCurve[…]合成 Bezier 曲线
    BSplineCurve[…]B-样条曲线
    Tube[…]管状曲线对象
  • Arrow[Line[…]] 等价于 Arrow[…]. Arrow[Tube[…]] 生成一个基于管状的三维箭头.
  • Arrow[{pt1,pt2,…}] 表示箭杆穿过点序列 pti 的箭头标记.
  • 这些点的位置既可以用常规坐标 {x,y} 的形式指定，也可以用尺度缩放的坐标 Scaled[{x,y}]，或者ImageScaled 或 Offset 的形式指定. »
  • 箭杆由连接指定点的直线段序列构成.
  • Arrow[{pt1,pt2}] 缺省下绘制尾部在 pt1，头部在 pt2 的箭头标记.
  • 箭头标记的形式、方向和位置可以用 Arrowheads 指令进行指定. »
  • RGBColor 或 Thickness 一类的图形指令既应用于箭头标记的箭杆，也可以应用于其箭头头部. »
  • 指定箭头标记的明确指令来防止图形指令应用于一个箭头头部.
  • 在 Arrow[{pt1,pt2},s] 中，缩回距离 s 是在整个图形的普通坐标系统中进行测定，以使该箭头刚好触到 Disk[pti,s]. »
  • 如果整个图形没有设置 AspectRatio->Automatic，则指定的箭头标记的缩回距离可能会在图形中不同方向都具有相应的不同距离.

范例

打开所有单元 关闭所有单元

基本范例  (6)

一个二维箭头基元：

Wolfram Language code: Graphics[Arrow[{{1, 0}, {2, 1}, {3, 0}, {4, 1}}]]

一个三维箭头基元：

Wolfram Language code: Graphics3D[Arrow[{{1, 1, -1}, {2, 2, 0}, {3, 3, -1}, {4, 4, 0}}]]

一个使用管的全三维箭头基元：

Wolfram Language code: Graphics3D[{Red, Arrowheads[0.1], Arrow[Tube[{{1, 1, -1}, {2, 2, 0}, {3, 3, -1}, {4, 4, 0}}, 0.05]]}]

曲线型箭头：

Wolfram Language code: {Graphics[{Arrow[BezierCurve[{{0, 0}, {1, 1}, {2, -1}}]]}], Graphics3D[{Arrow[BSplineCurve[{{0, 0, 0}, {1, 1, 1}, {2, -1, 1}, {3, 0, 2}}]]}]}

双箭头标记：

Wolfram Language code: {Graphics[{Arrowheads[{-.1, .1}], Arrow[{{0, 0}, {1, 1 / 3}}]}], Graphics3D[{Arrowheads[{-.1, .1}], Arrow[{{0, 0, 0}, {2, 1, 1}}]}], Graphics3D[{Arrowheads[{-.1, .1}], Arrow[Tube[{{0, 0, 0}, {2, 1, 1}}]]}]}

不同样式的箭头标记：

Wolfram Language code: a = {Arrowheads[Large], Arrow[{{0, 0}, {1, .5}}]};
Wolfram Language code: {Graphics[{Dashed, a}], Graphics[{Red, a}], Graphics[{Thick, a}], Graphics[{Thick, Dashed, Red, a}]}

范围  (17)

箭头规范  (7)

直线箭头：

Wolfram Language code: Graphics[Arrow[{{0, 0}, {2, 1}}]]

锯齿形箭头：

Wolfram Language code: Graphics[Arrow[{{0, 0}, {2, 1}, {4, 0}}]]

线状和管状箭头：

Wolfram Language code: {Graphics[Arrow[Line[{{0, 0}, {2, 1}}]]], Graphics3D[Arrow[Line[{{0, 0, 0}, {2, 1, 1}}]]], Graphics3D[Arrow[Tube[{{0, 0, 0}, {2, 1, 1}}]]]}

曲线型箭头：

Wolfram Language code: {Graphics[Arrow[BezierCurve[{{0, 0}, {1, 2}, {4, 2}}]]], Graphics3D[Arrow[BSplineCurve[{{0, 0, 0}, {1, 2, 2}, {4, 2, 2}}]]], Graphics3D[Arrow[Tube[BSplineCurve[{{0, 0, 0}, {1, 2, 2}, {4, 2, 2}}]]]]}

多个不连通箭头：

Wolfram Language code: s = {{0, 0}, {2, 1.5}, {4, 0}};
Wolfram Language code: {Graphics[Arrow[Line[{s, s + 1}]]], Graphics[Arrow[BezierCurve[{s, s + 1}]]]}

指定缩回距离：

Wolfram Language code: {Graphics[{Arrow[{{0, 0}, {2, 1}}], Circle[{2, 1}, .3]}], Graphics[{Arrow[{{0, 0}, {2, 1}}, .3], Circle[{2, 1}, .3]}]}

对于曲线型箭头：

Wolfram Language code: {Graphics[{Arrow[BSplineCurve[{{0, 0}, {1, -1}, {2, 1}}]], Circle[{2, 1}, .3]}], Graphics[{Arrow[BSplineCurve[{{0, 0}, {1, -1}, {2, 1}}], .3], Circle[{2, 1}, .3]}]}

指定有线轴的三维箭头的缩回距离：

Wolfram Language code: {Graphics3D[{Opacity[.8], Arrow[{{0, 0, 0}, {2, 1, 0}}], Sphere[{2, 1, 0}, .3]}], Graphics3D[{Opacity[.8], Arrow[{{0, 0, 0}, {2, 1, 0}}, .3], Sphere[{2, 1, 0}, .3]}]}

箭头样式  (7)

不同粗度的箭头：

Wolfram Language code: Table[Graphics[{Thickness[i], Arrow[{{0, 0}, {2, 1}}]}], {i, {Tiny, Small, Medium, Large}}]
Wolfram Language code: Table[Graphics3D[{Thickness[i], Arrow[{{0, 0, 0}, {2, 1, 1}}]}], {i, {Tiny, Small, Medium, Large}}]

虚线箭头：

Wolfram Language code: {Graphics[{Dashed, Arrow[{{0, 0}, {2, 1}}]}], Graphics[{Dotted, Arrow[{{0, 0}, {2, 1}}]}], Graphics[{DotDashed, Arrow[{{0, 0}, {2, 1}}]}]}
Wolfram Language code: {Graphics3D[{Dashed, Arrow[{{0, 0, 0}, {2, 1, 1}}]}], Graphics3D[{Dotted, Arrow[{{0, 0, 0}, {2, 1, 1}}]}], Graphics3D[{DotDashed, Arrow[{{0, 0, 0}, {2, 1, 1}}]}]}

彩色箭头：

Wolfram Language code: Table[Graphics[{c, Arrow[{{0, 0}, {2, 1}}]}], {c, {Red, Green, Blue}}]
Wolfram Language code: Table[Graphics3D[{c, Arrow[{{0, 0, 0}, {2, 1, 1}}]}], {c, {Red, Green, Blue}}]

不同尺寸的二维箭头：

Wolfram Language code: Table[Graphics[{Arrowheads[i], Arrow[{{0, 0}, {1, .5}}]}], {i, {Tiny, Small, Medium, Large}}]
Wolfram Language code: Table[Graphics[{Arrowheads[i], Arrow[BezierCurve[{{0, 0}, {1, -1}, {2, 1}}]]}], {i, {.1, .2, .3, .4}}]

头部尺寸不同的三维箭头：

Wolfram Language code: Table[Graphics3D[{Arrowheads[i], Arrow[{{0, 0, 0}, {2, 1, 1}}]}], {i, {Tiny, Small, Medium, Large}}]
Wolfram Language code: Table[Graphics3D[{Arrowheads[i], Arrow[Tube[{{0, 0, 0}, {2, 1, 1}}, 0.02]]}], {i, {Tiny, Small, Medium, Large}}]

Graphics 可以用作二维和三维箭头的头部：

Wolfram Language code: h = Graphics[Line[{{-1, 1 / 2}, {0, 0}, {-1, -1 / 2}, {-1, 1 / 2}}]];
Wolfram Language code: {Graphics[{Arrowheads[{{-.1, 0, {h, 1}}, {.1, 1, {h, 1}}}], Arrow[{{0, 0}, {2, 1}}]}], Graphics[{Arrowheads[{{-.1, 0, {h, 1}}, {.1, 1, {h, 1}}}], Arrow[BezierCurve[{{0, 0}, {1, -1}, {2, 1}}]]}]}
Wolfram Language code: h = Graphics[{Green, Polygon[{{-1, 1 / 2}, {0, 0}, {-1, -1 / 2}, {-1, 1 / 2}}]}];
Wolfram Language code: Graphics3D[{Arrowheads[{{-.1, 0, {h, 1}}, {.1, 1, {h, 1}}}, Appearance -> "Projected"], Arrow[{{0, 0, 0}, {2, 1, 1}}]}]

使用 Graphics3D 指定箭头头部：

Wolfram Language code: h = Graphics3D[Line[{{-1, 1 / 2, 0}, {0, 0, 0}, {-1, -1 / 2, 0}, {-1, 1 / 2, 0}}]];
Wolfram Language code: {Graphics3D[{Arrowheads[{{-.1, 0, {h, 1}}, {.1, 1, {h, 1}}}], Arrow[{{0, 0, 0}, {2, 1, 1}}]}], Graphics3D[{Arrowheads[{{-.1, 0, {h, 1}}, {.1, 1, {h, 1}}}], Arrow[BSplineCurve[{{0, 0, 0}, {.5, 1, 1}, {2, 1, 1}}]]}]}

坐标规范  (3)

用 Scaled 坐标：

Wolfram Language code: Graphics[Arrow[{Scaled[{0, .2}], Scaled[{1, .8}]}], Frame -> True]
Wolfram Language code: Graphics3D[{Arrow[{Scaled[{0, .2, 0}], Scaled[{1, .8, 0.8}]}]}, Axes -> True]
Wolfram Language code: Graphics3D[{Arrow[Tube[{Scaled[{0, .2, 0}], Scaled[{1, .8, 0.8}]}]]}, Axes -> True]

用 ImageScaled 坐标：

Wolfram Language code: Graphics[Arrow[{ImageScaled[{0, .2}], ImageScaled[{1, .8}]}], Frame -> True]

用 Offset 坐标：

Wolfram Language code: Graphics[Arrow[{Offset[{10, 20}, {0, 0}], Offset[{-10, -20}, {1, 1}]}], Frame -> True]

应用  (7)

为图形制作程序注释：

Wolfram Language code: Plot[Sin[x], {x, 0, 2Pi}, Epilog -> {Arrow[{{3Pi / 2, 1 / 2}, {Pi, 0}}], Text["Zero", {3Pi / 2, 1 / 2}, {-1, -1}]}]
Wolfram Language code: Show[Plot3D[Sin[x]Sin[y], {x, 0, 2Pi}, {y, 0, 2Pi}, Mesh -> None, PlotRange -> {-1, 4}, BoxRatios -> Automatic], Graphics3D[{Arrow[{{Pi, Pi, 4}, {Pi / 2, Pi / 2, 1}}], Arrow[{{Pi, Pi, 4}, {3Pi / 2, 3Pi / 2, 1}}], Text[Panel["Maximum", FrameMargins -> 0], {Pi, Pi, 4}]}]]

矢量场的简单显示：

Wolfram Language code: With[{f = {v, u} / 5 - 1}, Graphics[Table[Arrow[{{u, v}, f + {u, v}}], {u, 0, 10}, {v, 0, 10}]]]
Wolfram Language code: With[{f = {v, u, 0} / 5 - 1}, Graphics3D[Table[Arrow[{{u, v, 0}, f + {u, v, 0}}], {u, 0, 10}, {v, 0, 10}]]]
Wolfram Language code: With[{f = {v, u, 0} / 5 - 1}, Graphics3D[Table[Arrow[Tube[{{u, v, 0}, f + {u, v, 0}}]], {u, 0, 10}, {v, 0, 10}]]]

VectorPlot 和 VectorPlot3D 使用 Arrow：

Wolfram Language code: VectorPlot[{x, -y}, {x, -3, 3}, {y, -3, 3}, VectorColorFunction -> "Rainbow"]
Wolfram Language code: VectorPlot3D[{x, y - 2 x, z - x}, {x, -3, 3}, {y, -3, 3}, {z, -3, 3}, VectorColorFunction -> "Rainbow", VectorMarkers -> "Arrow"]

将 Arrow 用作 GraphPlot 的 EdgeRenderingFunction：

Wolfram Language code: GraphPlot[Table[i -> Mod[i + 1, 6], {i, 0, 5}], EdgeShapeFunction -> (Arrow[#1]&), PlotStyle -> Arrowheads[Medium]]
Wolfram Language code: PolyhedronData["Dodecahedron", "Skeleton", "Rule"]
Wolfram Language code: GraphPlot3D[%, EdgeShapeFunction -> (Arrow[#1]&)]

定义一个带注释的箭头基元：

Wolfram Language code: AnnotatedArrow[p_, q_, label_] := {Arrowheads[{{-.1, 0}, {.1, .5, Graphics[Inset[Style[label, Medium], {Center, Top}]]}, {.1, 1}}], Arrow[{p, q}]}
Wolfram Language code: Graphics[{AnnotatedArrow[{-1, 0}, {1, 0}, "diameter = 2"], Circle[]}]
Wolfram Language code: Graphics[{AnnotatedArrow[1 / Sqrt[2]{-1, -1}, 1 / Sqrt[2]{1, 1}, "*d* = 2"], Circle[]}]

平行标注尺寸：

Wolfram Language code: ParallelDim[p_, q_, offset_, label_] := {Arrowheads[{{-.1, 0}, {.1, 0, Graphics[Line[{{0, 1}, {0, -1}}]]}, {.1, .5, Graphics[Inset[Style[label, Medium], {Center, Top}]]}, {.1, 1, Graphics[Line[{{0, 1}, {0, -1}}]]}, {.1, 1}}], Arrow[{p + offset, q + offset}]}
Wolfram Language code: Graphics[{Thick, Line[{{0, 0}, {1, 1}, {1, 0}, {0, 0}}], Thin, ParallelDim[{0, 0}, {1, 1}, {-.1, .1}, Sqrt[2]]}]

显示曲线上的方向：

Wolfram Language code: Graphics[{Arrowheads[{Table[{0.04, i}, {i, 0.04, 1, 0.05}], Table[{0.04, i}, {i, 0.04, 1, 0.2}]}], Arrow[JoinedCurve[{{Line[{{2, 3}, {0.8125, 0.625}}], BezierCurve[{{0.6875, 0.375}, {0.375, 0.25}, {1.125, 0.25}}, SplineDegree -> 2], BezierCurve[{{0.8125, 0.375}, {0.9375, 0.625}}], Line[{{1.3125, 1.375}, {2.4375, 1.375}, {2.8125, 0.625}}], BezierCurve[{{2.9375, 0.375}, {2.625, 0.25}, {3.625, 0.25}}, SplineDegree -> 2], BezierCurve[{{3.3125, 0.375}, {3.1875, 0.625}}]}, {Line[{{1.875, 2.5}, {1.375, 1.5}, {2.375, 1.5}}]}}, CurveClosed -> True]]}]
Wolfram Language code: ListLinePlot[Table[{Sin[3t], Cos[5t]}, {t, 0, 2Pi, 2Pi / 50}], Axes -> False] /. Line[rest_] :> {Arrowheads[Table[0.05, {i, 0, 1, .02}]], Arrow[BSplineCurve@rest]}

属性和关系  (1)

用 Arrowheads 设置坐标轴的样式：

Wolfram Language code: Plot[x ^ 3, {x, -1, 1}, AxesStyle -> Arrowheads[{-0.05, 0.05}]]

巧妙范例  (4)

一组随机箭头：

Wolfram Language code: Graphics[Table[{Hue[RandomReal[]], Arrow[RandomReal[1, {2, 2}]]}, {75}]]
Wolfram Language code: Graphics3D[Table[{Hue[RandomReal[]], Arrow[Tube[RandomReal[1, {2, 3}], Scaled[0.007]]]}, {50}]]

一个箭轮：

Wolfram Language code: Graphics[Table[{Hue[k / 40], Arrow[{{0, 0}, {Cos[2k Pi / 40], Sin[2k Pi / 40]}}]}, {k, 40}]]

沿椭圆曲线的正切向量：

Wolfram Language code: With[{f = {Cos[x] + Sin[x], Sin[x]}}, Graphics[Table[{Hue[t / (2Pi), 1, .8], Arrow[{f, Normalize[D[f, x]] + f}]} /. x -> t, {t, 0, 2Pi, .1}]]]

使用投映箭头的告示牌树：

Wolfram Language code: tree = \!\(\*GraphicsBox[«2»]\);
Wolfram Language code: Graphics3D[{Arrowheads[{{.1, 1, tree}}, Appearance -> "Projected"], Arrow[{{0, 0, 0}, {0, -0, 0.001}}], Green, Cuboid[{-10, -10, -3}, {10, 10, -2.8}]}]
Wolfram Research (2007)，Arrow，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Arrow.html （更新于 2010 年）.

文本

Wolfram Research (2007)，Arrow，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Arrow.html （更新于 2010 年）.

CMS

Wolfram 语言. 2007. "Arrow." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2010. https://reference.wolfram.com/language/ref/Arrow.html.

APA

Wolfram 语言. (2007). Arrow. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Arrow.html 年

BibTeX

@misc{reference.wolfram_2026_arrow, author="Wolfram Research", title="{Arrow}", year="2010", howpublished="\url{https://reference.wolfram.com/language/ref/Arrow.html}", note=[Accessed: 18-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_arrow, organization={Wolfram Research}, title={Arrow}, year={2010}, url={https://reference.wolfram.com/language/ref/Arrow.html}, note=[Accessed: 18-August-2026]}