AsymptoticLess

xx^*のときのまたはの条件を与える．

AsymptoticLess[f,g,{x₁,…,x_n}{,…,}]

{x₁,…,x_n}{,…,}のときのまたはの条件を与える．

詳細とオプション

「漸近的に未満」は，f は g のlittle-oである，f の次数は g よりも小さい，f は g よりも遅く大きくなる，f は g に支配されている等とも表現される．点 x^*はコンテキストから推測されることが多い．
「漸近的に未満」は順序関係で，であるすべての定数について x が x^*の近くにあるときにであることを意味する．
点の近くの関数や級数の単純で厳密な上限を表すために，また，方程式の解や複雑な計算の単純で厳密な上限を表すためにしばしば使われる．
有限極限点の x^*および {,…,}については以下のようになる．

	AsymptoticLess[f[x],g[x],xx^*]	すべてのについて $0<TemplateBox[{{x, -, {x, ^, }}}, Abs]<delta(c,x^)$ がを意味するが存在する
	AsymptoticLess[f[x₁,…,x_n],g[x₁,…,x_n],{x₁,…,x_n}{,…,}]	すべてのについて $0<TemplateBox[{{{, {{{x, _, 1}, -, {x, _, {(, 1, )}, ^, }}, ,, ..., ,, {{x, _, n}, -, {x, _, {(, n, )}, ^, }}}, }}}, Norm]<delta(epsilon,x^*)$ が $TemplateBox[{{f, (, {{x, _, 1}, ,, ..., ,, {x, _, n}}, )}}, Abs]<=c TemplateBox[{{g, (, {{x, _, 1}, ,, ..., ,, {x, _, n}}, )}}, Abs]$ を意味するが存在する

無限極限点については以下のようになる．

	AsymptoticLess[f[x],g[x],x∞]	すべてのについてがを意味するが存在する
	AsymptoticLess[f[x₁,…,x_n],g[x₁,…,x_n],{x₁,…,x_n}{∞,…,∞}]	すべてのについてが $TemplateBox[{{f, (, {{x, _, 1}, ,, ..., ,, {x, _, n}}, )}}, Abs]<=c TemplateBox[{{g, (, {{x, _, 1}, ,, ..., ,, {x, _, n}}, )}}, Abs]$ を意味するが存在する

g[x]が x^*付近で0の無限集合を持たない場合，AsymptoticLess[f[x],g[x],xx^*]はLimit[Abs[f[x]/g[x]],xx^*]0のときかつそのときに限り存在する．
次は，使用可能なオプションである．

Assumptions	$Assumptions	パラメータについての仮定
Direction	Reals	極限点に近付く方向
GenerateConditions	Automatic	パラメータについての条件を生成する
Method	Automatic	使用するメソッド
PerformanceGoal	"Quality"	何を最適化するか

次は，Directionの可能な設定である．

	Reals または "TwoSided"	両実数方向から
	"FromAbove" または -1	上，つまり大きい値から
	"FromBelow" または +1	下，つまり小さい値から
	Complexes	すべての複素方向から
	Exp[ θ]	の方向
	{dir₁,…,dir_n}	変数 x_iに方向 dir_iを使う

x^*におけるDirectionExp[ θ]は，曲線の接線が極限点 x^*に近付く方向を示す．

次は，GenerateConditionsの可能な設定である．

	Automatic	一般的ではない条件のみ
	True	すべての条件
	False	条件なし
	None	条件が必要な場合には未評価で返す

PerformanceGoalの可能な設定には，$PerformanceGoal，"Quality"，"Speed"がある．"Quality"設定のとき，Limitはより多くの問題を解いたりより簡単な結果を与えたりすることが多いが，より多くの時間とメモリが必要になる可能性がある．

例題

すべて開くすべて閉じる

例 (2)

のときであることを検証する：

Wolfram Language code: AsymptoticLess[x, x ^ 2, x -> ∞]

2つの関数を可視化する：

Wolfram Language code: Plot[{x, x ^ 2}, {x, 0, 10}, PlotLegends -> "Expressions"]

のときであることを検証する：

Wolfram Language code: AsymptoticLess[x + y, x ^ 2 + y ^ 2, {x, y} -> ∞]

2つの関数を可視化する：

Wolfram Language code: Plot3D[{x + y, x ^ 2 + y ^ 2}, {x, 0, 10}, {y, 0, 10}, PlotLegends -> "Expressions"]

スコープ (9)

厳密には正ではない関数を比較する：

Wolfram Language code: AsymptoticLess[x, -x ^ 2, x -> ∞]

が原点でより遅く発散することを示す：

Wolfram Language code: AsymptoticLess[(1/x), (1/x^2), x -> 0]

答は明示的なTrueまたはFalseではなく，ブール式かもしれない：

Wolfram Language code: AsymptoticLess[Sinh[p(x - 2)], Sin[x - 2], x -> 2]

パラメータを含む関数を比較する場合は，結果についての条件が生成されることがある：

Wolfram Language code: AsymptoticLess[(1/(x - 1)^p), (10/x - 1), x -> 1]

デフォルトで，関数の両側比較が行われる：

Wolfram Language code: AsymptoticLess[x^4, x^2 UnitStep[x], x -> 0]

のより大きい値を比較する場合は，は実際に $x^2 TemplateBox[{{x}}, UnitStepSeq]$ より小さい：

Wolfram Language code: AsymptoticLess[x^4, x^2 UnitStep[x], x -> 0, Direction -> "FromAbove"]

この関係は，のより小さい値については成り立たない：

Wolfram Language code: AsymptoticLess[x^4, x^2 UnitStep[x], x -> 0, Direction -> "FromBelow"]

2つの関数を可視化する：

Wolfram Language code: Plot[{x^4, x^2UnitStep[x]}, {x, -1, 1}, PlotTheme -> {"DashedLines", "Detailed"}]

Sqrtのような関数は，負の実数に沿って両方の実数方向で同じ関係があるかもしれない：

Wolfram Language code: AsymptoticLess[(Sqrt[z] - I)^3, (z + 1), z -> -1]

複素平面で上から近付く場合には，同じ関係が見られる：

Wolfram Language code: AsymptoticLess[(Sqrt[z] - I)^3, (z + 1), z -> -1, Direction -> -I]

しかし，複素平面で下から近付く場合は異なる結果になる：

Wolfram Language code: AsymptoticLess[(Sqrt[z] - I)^3, (z + 1), z -> -1, Direction -> I]

これは，軸が交差するときにSqrtの虚部の符号が逆になるところで分枝切断されているためである：

Wolfram Language code:

TableForm[Table[{-1 + Δ, Sqrt[-1 + Δ], Abs[Sqrt[-1 + Δ] - I]}, {Δ, {0.01, -0.01, 0.01I, -0.01I}}], TableHeadings -> {None, {z, Sqrt[z], HoldForm@Abs[Sqrt[z] - I]}}]

したがって，この関係は，一般に，複素平面では成り立たない：

Wolfram Language code: AsymptoticLess[(Sqrt[z] - I)^3, (z + 1), z -> -1, Direction -> Complexes]

4つの実数および複素数の方向から近付く場合の関数の相対サイズを可視化する：

Wolfram Language code:

Plot[{Abs[ (-1 + Δz/(Sqrt[-1 + Δz] - I)^3)], Abs[ (-1 + I Δz/(Sqrt[-1 + I Δz] - I)^3)]}, {Δz, -1, 1}, IconizedObject[«plot options»]]

多変量関数を比較する：

Wolfram Language code: AsymptoticLess[(x - 1)^2(y - 2), Sin[ x]Cos[3y / 4], {x, y} -> {1, 2}]

2つの関数のノルムを可視化する：

Wolfram Language code: Plot3D[{Abs[(x - 1)^2(y - 2)], Abs[Sin[ x]Cos[ 3y / 2]]}, {x, y}∈Disk[{1, 2}, .9], PlotTheme -> "Detailed"]

多変量関数を無限大で比較する：

Wolfram Language code: AsymptoticLess[ Exp[x]Log[y], x y, {x, y} -> {-∞, ∞}]

多変量関数を比較する際にパラメータを使用する：

Wolfram Language code: AsymptoticLess[Sinh[x]y, Sinh[a x]y ^ n, {x, y} -> {∞, 1}]

オプション (10)

Assumptions (1)

Assumptionsを使ってパラメータについての条件を指定する：

Wolfram Language code: AsymptoticLess[1, x ^ a, x -> 0, Assumptions -> a ≥ 0]

仮定が異なると結果も異なるかもしれない：

Wolfram Language code: AsymptoticLess[1, x ^ a, x -> 0, Assumptions -> a < 0]

Direction (5)

下からの関係を判定する：

Wolfram Language code: AsymptoticLess[x Sin[x], x UnitStep[x], x -> 0, Direction -> "FromBelow"]

同様に：

Wolfram Language code: AsymptoticLess[x Sin[x], x UnitStep[x], x -> 0, Direction -> 1]

上からの関係を判定する：

Wolfram Language code: AsymptoticLess[x Sin[x], x UnitStep[x], x -> 0, Direction -> "FromAbove"]

同様に：

Wolfram Language code: AsymptoticLess[x Sin[x], x UnitStep[x], x -> 0, Direction -> -1]

区分ごとの不連続点での関係を判定する：

Wolfram Language code: AsymptoticLess[4Cos[x / 2](x - 2), FractionalPart[x ^ 2]Sin[x], x -> 2, Direction -> "FromBelow"]

Wolfram Language code: AsymptoticLess[4Cos[x / 2](x - 2), FractionalPart[x ^ 2]Sin[x], x -> 2, Direction -> "FromAbove"]

片方の方向でうまくいかないので，両方からもうまくいかない：

Wolfram Language code: AsymptoticLess[4Cos[x / 2](x - 2), FractionalPart[x ^ 2]Sin[x], x -> 2, Direction -> "TwoSided"]

2関数とその割合を可視化する：

Wolfram Language code:

Plot[{4Cos[x / 2](x - 2), FractionalPart[x ^ 2]Sin[x], Abs[4Cos[x / 2](x - 2) / FractionalPart[x ^ 2]Sin[x]]}, {x, 1.5, 2.5}, PlotLegends -> "Expressions"]

極における関係は近付く方向には無関係である：

Wolfram Language code: AsymptoticLess[Tan[x], ((2/2x - π))^2, x -> π / 2, Direction -> "FromBelow"]

Wolfram Language code: AsymptoticLessEqual[Tan[x], ((2/2x - π))^2, x -> π / 2, Direction -> "FromAbove"]

Wolfram Language code: AsymptoticLessEqual[Tan[x], ((2/2x - π))^2, x -> π / 2, Direction -> ℝ]

Wolfram Language code: AsymptoticLessEqual[Tan[x], ((2/2x - π))^2, x -> π / 2, Direction -> ℂ]

分枝切断線における関係を判定する：

Wolfram Language code: AsymptoticLess[ Sqrt[x - 1] - I, Sqrt[Tanh[x]], x -> 0, Direction -> +I]

Wolfram Language code: AsymptoticLess[ Sqrt[x - 1] - I, Sqrt[Tanh[x]], x -> 0, Direction -> -I]

Wolfram Language code: AsymptoticLess[ Sqrt[x - 1] - I, Sqrt[Tanh[x]], x -> 0, Direction -> Reals]

Wolfram Language code: AsymptoticLess[ Sqrt[x - 1] - I, Sqrt[Tanh[x]], x -> 0, Direction -> Complexes]

異なる象限から近付く際の，その関係を計算する：

Wolfram Language code: f[x_, y_] := Sin[x y]

Wolfram Language code: g[x_, y_] := x + Abs[y]

第1象限から原点に近付く：

Wolfram Language code: AsymptoticLess[f[x, y], g[x, y], {x, y} -> {0, 0}, Direction -> "FromAbove"]

同様に：

Wolfram Language code: AsymptoticLess[f[x, y], g[x, y], {x, y} -> {0, 0}, Direction -> {"FromAbove", "FromAbove"}]

第2象限から原点に近付く：

Wolfram Language code: AsymptoticLess[f[x, y], g[x, y], {x, y} -> {0, 0}, Direction -> {"FromBelow", "FromAbove"}]

右半平面から原点に近付く：

Wolfram Language code: AsymptoticLess[f[x, y], g[x, y], {x, y} -> {0, 0}, Direction -> {"FromAbove", Reals}]

下半平面から原点に近付く：

Wolfram Language code: AsymptoticLess[f[x, y], g[x, y], {x, y} -> {0, 0}, Direction -> {Reals, "FromBelow"}]

に沿った部分以外は原点近くで小さくなる関数の割合を可視化する：

Wolfram Language code: DensityPlot[Abs[f[x, y] / g[x, y]], {x, -1, 1}, {y, -1, 1}, PlotLegends -> Automatic, ClippingStyle -> Automatic]//Quiet

GenerateConditions (3)

条件を述べずに結果を返す：

Wolfram Language code: AsymptoticLess[x ^ n, 1, x -> 0, GenerateConditions -> False]

この結果は n>0のときにのみ有効である：

Wolfram Language code: AsymptoticLessEqual[x ^ n, 1, x -> 0]

結果がパラメータの値に依存するときは，未評価で返される：

Wolfram Language code: AsymptoticLess[Exp[-a x], 1, x -> ∞, GenerateConditions -> None]

デフォルトで，結果を保証する条件が生成される：

Wolfram Language code: AsymptoticLess[Exp[-a x], 1, x -> ∞]

デフォルトで，特殊な値でしか結果が無効にならない場合は，条件は生成されない：

Wolfram Language code: AsymptoticLess[x y, (x - a)^2 + y^2, {x, y} -> {0, 0}]

GenerateConditions->Trueのときは，これらの一般的ではない条件も報告される：

Wolfram Language code: AsymptoticLess[x y, (x - a)^2 + y^2, {x, y} -> {0, 0}, GenerateConditions -> True]

PerformanceGoal (1)

PerformanceGoalを使って潜在的に高価な計算を回避する：

Wolfram Language code:

f = 2 y z^2 - z^3 + y (x - 2 y + 3 z)^2 - z (x - 2 y + 3 z)^2;
g = y^2 - 2 y z + z^2 - y (x - 2 y + 3 z) + z (x - 2 y + 3 z) + (x - 2 y + 3 z)^2;

Wolfram Language code: AsymptoticLess[f, g, {x, y, z} -> {0, 0, 0}, PerformanceGoal -> "Speed"]//AbsoluteTiming

デフォルト設定では，使用可能なすべての手法を使って結果を得ようとする：

Wolfram Language code: AsymptoticEqual[f, g, {x, y, z} -> {0, 0, 0}]//AbsoluteTiming

アプリケーション (18)

基本的なアプリケーション (4)

0においてであることを示す：

Wolfram Language code: {AsymptoticLess[x^3, x^2, x -> 0], AsymptoticLess[x^2, x, x -> 0], AsymptoticLess[x^1, x^0, x -> 0]}

これを記号的に証明する：

Wolfram Language code: AsymptoticLess[x^k, x^l, x -> 0, Assumptions -> {k, l}∈ℤ && k > l ≥ 0]

関数を可視化する：

Wolfram Language code: Plot[{1, Abs[x], Abs[x^2], Abs[x^3]}, {x, -1, 1}, PlotLegends -> "Expressions"]

この関係はすべての実数ベキに及ぶ：

Wolfram Language code: AsymptoticLess[x^k, x^l, x -> 0, Assumptions -> k > l]

分数ベキと負のベキで関数を可視化する：

Wolfram Language code: Plot[{Abs[1 / x], Abs[1 / Sqrt[x]], 1, Abs[Sqrt[x]], Abs[x]}, {x, -1, 1}, PlotLegends -> "Expressions"]

∞においてであることを示す：

Wolfram Language code: {AsymptoticLess[1, x, x -> ∞], AsymptoticLess[x, x^2, x -> ∞], AsymptoticLess[x^2, x^3, x -> ∞]}

これを記号的に証明する：

Wolfram Language code: AsymptoticLess[x^k, x^l, x -> ∞, Assumptions -> {k, l}∈ℤ && 0 ≤ k < l]

この関係を対数プロットで可視化する：

Wolfram Language code: LogPlot[{1, Abs[x], Abs[x^2], Abs[x^3]}, {x, 10, 100}, PlotLegends -> "Expressions"]

この関係はすべての実数ベキに及ぶ：

Wolfram Language code: AsymptoticLess[x^k, x^l, x -> ∞, Assumptions -> k < l]

分数ベキと負のベキで関数を可視化する：

Wolfram Language code: LogPlot[{Abs[1 / x], Abs[1 / Sqrt[x]], 1, Abs[Sqrt[x]], Abs[x]}, {x, 10, 100}, PlotLegends -> "Expressions"]

0においてであることを示す：

Wolfram Language code: AsymptoticLess[x^2Sin[1 / x], x, x -> 0]

この関係は， $TemplateBox[{{{x, ^, 2}, , {sin, (, {1, /, x}, )}}}, Abs]<=x^2$ であるという事実から推測される：

Wolfram Language code:

Plot[{Abs[x^2Sin[1 / x]], Abs[x], x^2}, {x, -2 / 3, 2 / 3}, PlotStyle -> {Automatic, Automatic, Dashed}, PlotLegends -> "Expressions"]

∞においてであることを示す：

Wolfram Language code: AsymptoticLess[x, x^2(Sin[x] + 2), x -> ∞]

Wolfram Language code: LogPlot[{x, x^2(Sin[x] + 2)}, {x, 1, 100}, PlotLegends -> "Expressions"]

絶対誤差と相対誤差 (2)

のときなら，関数はのときに小さい絶対誤差でを近似する．のときに，が小さい絶対誤差でを近似することを示す：

Wolfram Language code: AsymptoticLess[Exp[x] - 1, 1, x -> 0]

もまた，のときに小さい絶対誤差でを近似することを示す：

Wolfram Language code: AsymptoticLess[Exp[x] - (1 + x), 1, x -> 0]

のときに，が小さい絶対誤差でを近似することを示す：

Wolfram Language code: AsymptoticLess[Cosh[x] - Exp[x] / 2, 1, x -> ∞]

のときに，が小さい絶対誤差でを近似することを示す：

Wolfram Language code: AsymptoticLess[Cosh[x] - Exp[-x] / 2, 1, x -> -∞]

のときなら，関数はのときに小さい相対誤差でを近似する．のときに，が小さい相対誤差でを近似することを示す：

Wolfram Language code: AsymptoticLess[Exp[x] - (1 + x), 1 + x, x -> 0]

のときに，が小さい相対誤差でを近似することを示す：

Wolfram Language code: AsymptoticLess[((1/x) + (1/x^2)) - (1/x^2), (1/x^2), x -> 0]

しかし，上記の近似は小さい絶対誤差を持たない：

Wolfram Language code: AsymptoticLess[((1/x) + (1/x^2)) - (1/x^2), 1, x -> 0]

同様に，スターリング(Stirling)の公式によるの近似は，のときに小さい相対誤差を持つ：

Wolfram Language code: AsymptoticLess[n! - Sqrt[2π n](n / E)^n, Sqrt[2π n](n / E)^n, n -> ∞]

しかし，小さい絶対誤差は持たない：

Wolfram Language code: AsymptoticLess[n! - Sqrt[2π n](n / E)^n, 1, n -> ∞]

漸近近似 (6)

は関数であり，は付近におけるの近似であるとする．この場合，においてなら，この近似は漸近的である．言い換えるなら，剰余または誤差は近似より漸近的に小さい．がにおいての漸近的な近似であることを示す：

Wolfram Language code: AsymptoticLess[(x^2 + x + 1) - 1, 1, x -> 0]

はにおけるの漸近近似であることを示す：

Wolfram Language code: AsymptoticLess[(x^2 + x + 1) - (x + 1), x + 1, x -> 0]

はにおけるの漸近近似ではないことを示す：

Wolfram Language code: AsymptoticLess[(x^2 + x + 1) - 1.5, 1.5, x -> 0]

スターリングの公式はのときの漸近近似であることを示す：

Wolfram Language code: AsymptoticLess[n! - Sqrt[2π n](n / E)^n, Sqrt[2π n](n / E)^n, n -> ∞]

はのときの漸近近似であることを示す：

Wolfram Language code: AsymptoticLess[PrimePi[x] - x / Log[x], x / Log[x], x -> ∞]

Seriesは，初等関数および特殊関数の漸近近似を生成する．例えば，におけるの次数-10の近似を生成する：

Wolfram Language code: sin = Normal@Series[Sin[x], {x, 0, 10}]

この級数が漸近的であることを示す：

Wolfram Language code: AsymptoticLess[Sin[x] - sin, sin, x -> 0]

0におけるCot[x]の漸近級数を求める：

Wolfram Language code: cot = Normal@Series[Cot[x], {x, 0, 5}]

Wolfram Language code: AsymptoticLess[Cot[x] - cot, cot, x -> 0]

Gamma[x]の級数が-1において漸近的であることを示す：

Wolfram Language code: gamma = Normal@Series[Gamma[x], {x, -1, 2}]

Wolfram Language code: AsymptoticLess[Gamma[x] - gamma, gamma, x -> -1]

0におけるの漸近近似を求める：

Wolfram Language code: expr = Normal@Series[Log[Sin[x]]^1 / 3, {x, 0, 3}]

Wolfram Language code: AsymptoticLess[Log[Sin[x]]^1 / 3 - expr, expr, x -> 0]

近似される関数が近似点のすべての近傍で0に無限回近付く場合は，漸近近似が微妙になるかもしれない．例として，近くにおけるの漸近展開について考える：

Wolfram Language code: besselJ = Normal@Series[BesselJ[1, x], {x, ∞, 2}]

ベッセル関数のすべての零点において近似が完全に0ではないので，この近似は漸近的ではない：

Wolfram Language code: {BesselJ[1, x], besselJ} /. x -> BesselJZero[1, 25]//N

一般的に0に近付く割合にもかかわらず，は無限回侵害される：

Wolfram Language code: Plot[(besselJ - BesselJ[1, x]/besselJ), {x, 1, 40}, PlotTheme -> "Detailed", PlotPoints -> 200, PlotRange -> 0.003]

一方，決して0にならないハンケル関数の近似について考える：

Wolfram Language code: hankel1 = Normal@Series[HankelH1[1, x], {x, ∞, 2}]//Expand

この近似は漸近的である：

Wolfram Language code: AsymptoticLess[HankelH1[1, x] - hankel1, hankel1, x -> ∞]

第2種ハンケル関数の近似も漸近的である：

Wolfram Language code: hankel2 = Normal@Series[HankelH2[1, x], {x, ∞, 2}]//Expand

Wolfram Language code: AsymptoticLess[HankelH2[1, x] - hankel2, hankel2, x -> ∞]//Quiet

なので，そのような近似2つの和であるこの近似はほぼ漸近的であると理解できる：

Wolfram Language code: FullSimplify[besselJ == (hankel1 + hankel2/2)]

あるいは，近くにおけるの漸近近似について考える：

Wolfram Language code: besselJP1 = Normal@Series[1 + BesselJ[1, x], {x, ∞, 2}]//Expand

これは，真に漸近的な近似である：

Wolfram Language code: AsymptoticLess[1 + BesselJ[1, x] - besselJP1, besselJP1, x -> ∞]

近似の割合の限界と関数が一定してに近付く：

Wolfram Language code: Plot[Abs[(1 + BesselJ[1, x] - besselJP1/besselJP1)], {x, 1, 40}, PlotTheme -> "Detailed"]

AsymptoticIntegrateを使って定積分の漸近近似を生成する．例えば，のときのの漸近近似を求め，厳密値と比較する：

Wolfram Language code: {approx, exact} = {AsymptoticIntegrate[E ^ (t x), {t, 0, 1}, {x, 0, 3}] , Integrate[E ^ (t x), {t, 0, 1}]}

Wolfram Language code: AsymptoticLess[exact - approx, approx, x -> 0]

より少ない項数で漸近近似を行う：

Wolfram Language code: approx2 = AsymptoticIntegrate[E ^ (t x), {t, 0, 1}, {x, 0, 1}]

この近似は，厳密積分についても最初の近似についても漸近的である：

Wolfram Language code: AsymptoticLess[exact - approx2, approx2, x -> 0]

Wolfram Language code: AsymptoticLess[approx - approx2, approx2, x -> 0]

AsymptoticIntegrateを使って不定積分の漸近近似を生成する．ただし，その場合に積分定数を考慮に入れる必要がある．のときのの近似について考える：

Wolfram Language code: {approx, exact} = {AsymptoticIntegrate[Sin[x], x, {x, 0, 3}], Integrate[Sin[x], x]}

この近似が漸近的であることを示す：

Wolfram Language code: AsymptoticLess[exact - approx, approx, x -> 0]

しかし，この近似は，展開点における値をマッチした後では漸近的である：

Wolfram Language code: AsymptoticLess[exact - approx - (exact - approx /. x -> 0), approx, x -> 0]

のときのの異なる2つの漸近近似を計算する：

Wolfram Language code: approx2 = AsymptoticIntegrate[x^x, x, {x, 0, 2}]

Wolfram Language code: approx1 = AsymptoticIntegrate[x^x, x, {x, 0, 1}]

比較すべき記号結果はないが，この過程が漸近的であると示すことはできる：

Wolfram Language code: AsymptoticLess[approx2 - approx1, approx1, x -> 0]

AsymptoticDSolveValueを使って微分方程式の漸近近似を生成する：

Wolfram Language code: deqn = {y''[x] - (x ^ 4 + E ^ x Sin[x]) y[x] == 0 == 0, y[0] == 0, y'[0] == 2};

Wolfram Language code: approx = AsymptoticDSolveValue[deqn, y[x], {x, 0, 8}]

比較すべき厳密な結果はないが，この過程が漸近的であると示すことはできる：

Wolfram Language code: approx2 = AsymptoticDSolveValue[deqn, y[x], {x, 0, 12}]

Wolfram Language code: AsymptoticLess[approx2 - approx, approx, x -> 0]

NDSolveValueを使って得られた数値解の値と比較する：

Wolfram Language code: nsol = NDSolveValue[deqn, y[x], {x, 0, 0.5}]

Wolfram Language code: Table[nsol - approx2, {x, 0, 0.5, 0.1}]

漸近尺度と漸近級数 (2)

方程式列は，においてであるときかつそのときに限りにおける漸近尺度である．関数の有限リストが漸近尺度かどうかをチェックする関数を書く：

Wolfram Language code:

AsymptoticScaleQ[list_, x_ -> x0_, o : OptionsPattern[]] := BlockMap[AsymptoticLess[#[[2]], #[[1]], x -> x0, o]&, list, 2, 1]

整数ベキはにおいて，のとき $TemplateBox[{≻, "≻", {1, /, {(, {x, ^, 3}, )}}, {1, /, {(, {x, ^, 2}, )}}, {1, /, x}, 1, x, {x, ^, 2}, {x, ^, 3}}, RowWithSeparators]$ の漸近尺度を与える：

Wolfram Language code: AsymptoticScaleQ[{1 / x^3, 1 / x^2, 1 / x, 1, x, x ^ 2, x ^ 3}, x -> 0]

これらは，においても漸近尺度を形成するが，順序は逆になる：

Wolfram Language code: AsymptoticScaleQ[{x^3, x^2, x, 1, (1/x), (1/x^2), (1/x^3)}, x -> ∞]

のベキは，のとき $TemplateBox[{≻, "≻", 1, {1, /, {(, {log, (, x, )}, )}}, {1, /, {(, {{log, ^, 2}, (, x, )}, )}}, {1, /, {(, {{log, ^, 3}, (, x, )}, )}}}, RowWithSeparators]$ となる漸近尺度を形成する：

Wolfram Language code: AsymptoticScaleQ[{1, 1 / Log[x], 1 / Log[x]^2, 1 / Log[x]^3}, x -> ∞]

とを使って，のとき $TemplateBox[{≻, "≻", 1, x, {{x, ^, 2}, , {log, (, x, )}}, {x, ^, 2}, {{x, ^, 3}, , {log, (, x, )}}, {x, ^, 3}, {{x, ^, 4}, , {log, (, x, )}}}, RowWithSeparators]$ となる漸近尺度を形成する：

Wolfram Language code: AsymptoticScaleQ[{1, x, x^2 Log[x], x^2, x^3Log[x], x^3, x^4Log[x]}, x -> 0, Direction -> -1]

であれば，のときであることを示す：

Wolfram Language code: Table[Exp[x]x^-α, {α, Sort[RandomReal[10, 5]]}]

Wolfram Language code: AsymptoticScaleQ[%, x -> ∞]

ある点で漸近順序で関数をソートする関数を書く：

Wolfram Language code:

AsymptoticSort[list_List, x_ -> x0_, o : OptionsPattern[]] := 
	Sort[list, AsymptoticLess[#1, #2, x -> x0, o]&]

整数ベキ関数のランダムなリストを生成する：

Wolfram Language code: pows = RandomSample[Table[x^i, {i, -3, 3}]]

においてこのリストを漸近的にソートする：

Wolfram Language code: AsymptoticSort[pows, x -> 0]

Wolfram Language code: LogPlot[Evaluate[Abs[%]], {x, -1 / 2, 1 / 2}, PlotLegends -> "Expressions"]

において同じリストを漸近的にソートする：

Wolfram Language code: AsymptoticSort[pows, x -> ∞]

Wolfram Language code: LogPlot[Evaluate[Abs[%]], {x, 10, 100}, PlotLegends -> "Expressions"]

計算の複雑性 (4)

単純なソートアルゴリズム（バブルソート，挿入ソート）は n 個のオブジェクトをソートするのに約 a n²ステップを要する．これに対し，最適化された一般的アルゴリズム（ヒープソート，マージソート）はソートを行うのに約 b n Log[n]のステップを要する．大量のオブジェクトに対しては，最適化されたアルゴリズムの方が常にソート時間が短くて済むことを示す：

Wolfram Language code: AsymptoticLess[b n Log[n], a n^2, n -> ∞]

ある種の特別なアルゴリズム（分布数え上げソート，基数ソート）は，考えられる入力についての情報が事前に分かっているので，c n 時間で実行することができる．使える場合には，これらの方が最適化アルゴリズムよりも速い：

Wolfram Language code: AsymptoticLess[c n, b n Log[n], n -> ∞]

3つの時間スケールの増大を可視化する：

Wolfram Language code:

LogPlot[{n^2, n Log[n], n}, {n, 10, 1000}, PlotLegends -> "Expressions", PlotLabel -> Row[{n∈o[n Log[n]], n Log[n]∈o[n^2]}, Spacer[10]]]

バブルソートでは，隣接近傍が比較され，順序が狂っている場合には入れ替えられる．1回のパス（n-1 回の比較）の後で最大要素が末尾になる．このプロセスが残りの n-1個の要素に対して行われ，先頭の2つの要素が残るまでこれが繰り返される．比較と入替えが c ステップだとすると，ソートのステップ総数は次のようになる：

Wolfram Language code: Sum[c(i - 1), {i, n, 2, -1}]

多項式は二次の項だけで漸近的に近似される：

Wolfram Language code: AsymptoticLess[(1/2) (-c n + c n^2) - (c n^2/2), (c n^2/2), n -> ∞]

マージソートでは，要素のリストが2つに分割され，半分ずつソートされ，最後に2つの部分が結合される．であるから，ソート時間T[n]は中間を計算する一定の時間 b，各半分をソートする時間2T[n/2]，2つの半分を結合するための要素数の倍数 a n の合計になる：

Wolfram Language code: reqn = T[n] == 2T[n / 2] + a n + b

再帰方程式を解いて n 個の要素をソートする時間 t を求める：

Wolfram Language code: t = RSolveValue[reqn, T[n], n]//Expand

この式は，式の最終項だけで漸近的に近似される：

Wolfram Language code: AsymptoticLess[t - n (a Log[n]/Log[2]), n(a Log[n]/Log[2]), n -> ∞]

巡回セールスマン問題(TSP)は個の都市を繋ぐ最短経路を求めるものである．馬鹿正直なアルゴリズムは通りの経路すべてを試そうとする．Held–Karpアルゴリズムは，それよりも効率よく約ステップに短縮する．であるからHeld–Karpアルゴリズムの方が速いことを示す：

Wolfram Language code: AsymptoticLess[n ^ 2 2^n, n!, n -> ∞]

どちらのアルゴリズムも巡回セールスマン問題の複雑性クラスは，時間で解ける問題のEXPTIMと同じくらいであることを示している．Held–Karpアルゴリズムは，のを使うだけで十分である：

Wolfram Language code: AsymptoticLess[n^2 2^n, 2^2n, n -> ∞]

階乗については，のようにより高次の多項式を使う必要がある：

Wolfram Language code: AsymptoticLess[n!, 2^n^2, n -> ∞]

解の近似は回で求まるので，巡回セールスマン問題の近似は多項式時間で可解な問題の複雑性クラスPに属する．どの多項式アルゴリズムも指数アルゴリズムよりも速い．つまりである：

Wolfram Language code: AsymptoticLess[n^k, 2^n, n -> ∞]

特性と関係 (10)

AsymptoticLessは反射的ではない．つまり，である：

Wolfram Language code: AsymptoticLess[f[x], f[x], x -> x0]

推移的関係はある．つまり，かつならということを意味する：

Wolfram Language code: {f, g, h} = {x, x^2, x^3};

Wolfram Language code: {AsymptoticLess[f, g, x -> ∞], AsymptoticLess[g, h, x -> ∞], AsymptoticLess[f, h, x -> ∞]}

そして，反対称関係である．つまり，ならということになる：

Wolfram Language code: {f, g} = {x, x^2};

Wolfram Language code: {AsymptoticLess[f, g, x -> ∞], AsymptoticLess[g, f, x -> ∞]}

Limit[Abs[f[x]/g[x]],xx₀]0のときかつそのときに限りAsymptoticLess[f[x],g[x],xx₀]である：

Wolfram Language code: {f, g} = {x, x^2};

Wolfram Language code: {AsymptoticLess[f, g, x -> ∞], Limit[Abs[f / g], x -> ∞]}

Wolfram Language code: {f, g} = {x^2, x^3 / (1 + x)};

Wolfram Language code: {AsymptoticLess[f, g, x -> ∞], Limit[Abs[f / g], x -> ∞]}

特に，極限が存在しなければならない：

Wolfram Language code: {f, g} = {Sin[x], x Cos[x]};

Wolfram Language code: {AsymptoticLess[f, g, x -> ∞], Limit[Abs[f / g], x -> ∞]}

ならである：

Wolfram Language code: {f, g} = {x, x^2};

Wolfram Language code: {AsymptoticLess[f, g, x -> ∞], AsymptoticLessEqual[f, g, x -> ∞]}

ならである：

Wolfram Language code: {f, g} = {x, x^2};

Wolfram Language code: {AsymptoticLess[f, g, x -> ∞], AsymptoticGreater[g, f, x -> ∞]}

ならである：

Wolfram Language code: {f, g} = {x, x^2};

Wolfram Language code: {AsymptoticLess[f, g, x -> ∞], AsymptoticGreaterEqual[g, f, x -> ∞]}

ならである：

Wolfram Language code: {f, g} = {x, x^2};

Wolfram Language code: {AsymptoticLess[f, g, x -> ∞], !AsymptoticEquivalent[f, g, x -> ∞]}

ならである：

Wolfram Language code: {f, g} = {x, x^2};

Wolfram Language code: {AsymptoticLess[f, g, x -> ∞], !AsymptoticEqual[f, g, x -> ∞]}

かつなら，である：

Wolfram Language code: {f, g, h} = {x, x^2, x^3 / (1 + x)};

Wolfram Language code: {AsymptoticLess[f, g, x -> ∞], AsymptoticLessEqual[g, h, x -> ∞], AsymptoticLess[f, h, x -> ∞]}

かつならである：

Wolfram Language code: {f, g, h} = {x, x^2, x^3 / (1 + x)};

Wolfram Language code: {AsymptoticLess[f, g, x -> ∞], AsymptoticEqual[g, h, x -> ∞], AsymptoticLess[f, h, x -> ∞]}

かつならである：

Wolfram Language code: {f, g, h} = {x, x^2, x^3 / (1 + x)};

Wolfram Language code: {AsymptoticLess[f, g, x -> ∞], AsymptoticEquivalent[g, h, x -> ∞], AsymptoticLess[f, h, x -> ∞]}

Top

その他のラーニングリソース

テクニカルサポート

Wolframソリューション

教育のためのWolframソリューション

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

AsymptoticLess

詳細とオプション

例題

例 (2)

スコープ (9)

オプション (10)

Assumptions (1)

Direction (5)

GenerateConditions (3)

PerformanceGoal (1)

アプリケーション (18)

基本的なアプリケーション (4)

絶対誤差と相対誤差 (2)

漸近近似 (6)

漸近尺度と漸近級数 (2)

計算の複雑性 (4)

特性と関係 (10)

テキスト

CMS

APA

BibTeX

BibLaTeX

AsymptoticLess

詳細とオプション

例題

例 (2)

スコープ (9)

オプション (10)

Assumptions (1)

Direction (5)

GenerateConditions (3)

PerformanceGoal (1)

アプリケーション (18)

基本的なアプリケーション (4)

絶対誤差と相対誤差 (2)

漸近近似 (6)

漸近尺度と漸近級数 (2)

計算の複雑性 (4)

特性と関係 (10)

関連項目

関連するガイド

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX