Wolfram 语言与系统参考资料中心

AsymptoticLess

AsymptoticLess[f,g,xx^*]

给出当 xx^* 时或的条件.

AsymptoticLess[f,g,{x₁,…,x_n}{,…,}]

给出当 {x₁,…,x_n}{,…,} 时或的条件.

范例

打开所有单元关闭所有单元

基本范例 (2)

验证当时，：

Wolfram Language code: AsymptoticLess[x, x ^ 2, x -> ∞]

可视化两个函数：

Wolfram Language code: Plot[{x, x ^ 2}, {x, 0, 10}, PlotLegends -> "Expressions"]

验证当时，：

Wolfram Language code: AsymptoticLess[x + y, x ^ 2 + y ^ 2, {x, y} -> ∞]

可视化两个函数：

Wolfram Language code: Plot3D[{x + y, x ^ 2 + y ^ 2}, {x, 0, 10}, {y, 0, 10}, PlotLegends -> "Expressions"]

范围 (9)

比较不是严格为正 (positive) 的函数:

Wolfram Language code: AsymptoticLess[x, -x ^ 2, x -> ∞]

证明在原点处比发散得慢：

Wolfram Language code: AsymptoticLess[(1/x), (1/x^2), x -> 0]

答案可能是布尔表达式，而不是明确的 True 或 False：

Wolfram Language code: AsymptoticLess[Sinh[p(x - 2)], Sin[x - 2], x -> 2]

当比较有参数的函数时，可能会针对结果给出条件：

Wolfram Language code: AsymptoticLess[(1/(x - 1)^p), (10/x - 1), x -> 1]

缺省情况下，在两个方向上对函数进行比较：

Wolfram Language code: AsymptoticLess[x^4, x^2 UnitStep[x], x -> 0]

当比较较大的值时，实际上小于 $x^2 TemplateBox[{{x}}, UnitStepSeq]$ ：

Wolfram Language code: AsymptoticLess[x^4, x^2 UnitStep[x], x -> 0, Direction -> "FromAbove"]

但对于较小的值，这种关系不再成立：

Wolfram Language code: AsymptoticLess[x^4, x^2 UnitStep[x], x -> 0, Direction -> "FromBelow"]

可视化两个函数：

Wolfram Language code: Plot[{x^4, x^2UnitStep[x]}, {x, -1, 1}, PlotTheme -> {"DashedLines", "Detailed"}]

像 Sqrt 这样的函数可能在负实数的两个实数方向上具有相同的关系：

Wolfram Language code: AsymptoticLess[(Sqrt[z] - I)^3, (z + 1), z -> -1]

如果从复平面的上方接近，可以看到同样的关系：

Wolfram Language code: AsymptoticLess[(Sqrt[z] - I)^3, (z + 1), z -> -1, Direction -> -I]

然而，如果从复平面的下方接近会得到不同的结果：

Wolfram Language code: AsymptoticLess[(Sqrt[z] - I)^3, (z + 1), z -> -1, Direction -> I]

这是由于在与坐标轴相交时 Sqrt 的虚部的符号发生了反转：

Wolfram Language code:

TableForm[Table[{-1 + Δ, Sqrt[-1 + Δ], Abs[Sqrt[-1 + Δ] - I]}, {Δ, {0.01, -0.01, 0.01I, -0.01I}}], TableHeadings -> {None, {z, Sqrt[z], HoldForm@Abs[Sqrt[z] - I]}}]

因而，总的来说，这种关系在复平面上不成立：

Wolfram Language code: AsymptoticLess[(Sqrt[z] - I)^3, (z + 1), z -> -1, Direction -> Complexes]

可视化从四个实方向和虚方向上逼近时函数的相对大小：

Wolfram Language code:

Plot[{Abs[ (-1 + Δz/(Sqrt[-1 + Δz] - I)^3)], Abs[ (-1 + I Δz/(Sqrt[-1 + I Δz] - I)^3)]}, {Δz, -1, 1}, IconizedObject[«plot options»]]

比较多变量函数：

Wolfram Language code: AsymptoticLess[(x - 1)^2(y - 2), Sin[ x]Cos[3y / 4], {x, y} -> {1, 2}]

可视化两个函数的范数：

Wolfram Language code: Plot3D[{Abs[(x - 1)^2(y - 2)], Abs[Sin[ x]Cos[ 3y / 2]]}, {x, y}∈Disk[{1, 2}, .9], PlotTheme -> "Detailed"]

在无穷大处比较多变量函数：

Wolfram Language code: AsymptoticLess[ Exp[x]Log[y], x y, {x, y} -> {-∞, ∞}]

在比较多变量函数时使用参数：

Wolfram Language code: AsymptoticLess[Sinh[x]y, Sinh[a x]y ^ n, {x, y} -> {∞, 1}]

选项 (10)

Assumptions (1)

用 Assumptions 为参数指定条件：

Wolfram Language code: AsymptoticLess[1, x ^ a, x -> 0, Assumptions -> a ≥ 0]

不同的假设给出不同的结果：

Wolfram Language code: AsymptoticLess[1, x ^ a, x -> 0, Assumptions -> a < 0]

Direction (5)

从下方测试函数之间的关系：

Wolfram Language code: AsymptoticLess[x Sin[x], x UnitStep[x], x -> 0, Direction -> "FromBelow"]

等价于：

Wolfram Language code: AsymptoticLess[x Sin[x], x UnitStep[x], x -> 0, Direction -> 1]

从上方测试函数之间的关系：

Wolfram Language code: AsymptoticLess[x Sin[x], x UnitStep[x], x -> 0, Direction -> "FromAbove"]

等价于：

Wolfram Language code: AsymptoticLess[x Sin[x], x UnitStep[x], x -> 0, Direction -> -1]

测试分段不连续处的关系：

Wolfram Language code: AsymptoticLess[4Cos[x / 2](x - 2), FractionalPart[x ^ 2]Sin[x], x -> 2, Direction -> "FromBelow"]

Wolfram Language code: AsymptoticLess[4Cos[x / 2](x - 2), FractionalPart[x ^ 2]Sin[x], x -> 2, Direction -> "FromAbove"]

由于在一个方向上不成立，两个方向上同样不成立：

Wolfram Language code: AsymptoticLess[4Cos[x / 2](x - 2), FractionalPart[x ^ 2]Sin[x], x -> 2, Direction -> "TwoSided"]

可视化两个函数及它们的比值：

Wolfram Language code:

Plot[{4Cos[x / 2](x - 2), FractionalPart[x ^ 2]Sin[x], Abs[4Cos[x / 2](x - 2) / FractionalPart[x ^ 2]Sin[x]]}, {x, 1.5, 2.5}, PlotLegends -> "Expressions"]

在极点处的关系与逼近的方向无关：

Wolfram Language code: AsymptoticLess[Tan[x], ((2/2x - π))^2, x -> π / 2, Direction -> "FromBelow"]

Wolfram Language code: AsymptoticLessEqual[Tan[x], ((2/2x - π))^2, x -> π / 2, Direction -> "FromAbove"]

Wolfram Language code: AsymptoticLessEqual[Tan[x], ((2/2x - π))^2, x -> π / 2, Direction -> ℝ]

Wolfram Language code: AsymptoticLessEqual[Tan[x], ((2/2x - π))^2, x -> π / 2, Direction -> ℂ]

测试分支切割处的关系：

Wolfram Language code: AsymptoticLess[ Sqrt[x - 1] - I, Sqrt[Tanh[x]], x -> 0, Direction -> +I]

Wolfram Language code: AsymptoticLess[ Sqrt[x - 1] - I, Sqrt[Tanh[x]], x -> 0, Direction -> -I]

Wolfram Language code: AsymptoticLess[ Sqrt[x - 1] - I, Sqrt[Tanh[x]], x -> 0, Direction -> Reals]

Wolfram Language code: AsymptoticLess[ Sqrt[x - 1] - I, Sqrt[Tanh[x]], x -> 0, Direction -> Complexes]

从不同象限逼近，计算函数之间的关系：

Wolfram Language code: f[x_, y_] := Sin[x y]

Wolfram Language code: g[x_, y_] := x + Abs[y]

从第一象限逼近原点：

Wolfram Language code: AsymptoticLess[f[x, y], g[x, y], {x, y} -> {0, 0}, Direction -> "FromAbove"]

等价于：

Wolfram Language code: AsymptoticLess[f[x, y], g[x, y], {x, y} -> {0, 0}, Direction -> {"FromAbove", "FromAbove"}]

从第二象限逼近原点：

Wolfram Language code: AsymptoticLess[f[x, y], g[x, y], {x, y} -> {0, 0}, Direction -> {"FromBelow", "FromAbove"}]

从右半平面逼近原点：

Wolfram Language code: AsymptoticLess[f[x, y], g[x, y], {x, y} -> {0, 0}, Direction -> {"FromAbove", Reals}]

从下半平面逼近原点：

Wolfram Language code: AsymptoticLess[f[x, y], g[x, y], {x, y} -> {0, 0}, Direction -> {Reals, "FromBelow"}]

可视化函数的比值，在靠近原点时变得较小，除了上的值：

Wolfram Language code: DensityPlot[Abs[f[x, y] / g[x, y]], {x, -1, 1}, {y, -1, 1}, PlotLegends -> Automatic, ClippingStyle -> Automatic]//Quiet

GenerateConditions (3)

返回结果，不给出条件：

Wolfram Language code: AsymptoticLess[x ^ n, 1, x -> 0, GenerateConditions -> False]

只有在 n>0 时结果才有效：

Wolfram Language code: AsymptoticLessEqual[x ^ n, 1, x -> 0]

如果结果取决于参数的值，不计算，直接返回：

Wolfram Language code: AsymptoticLess[Exp[-a x], 1, x -> ∞, GenerateConditions -> None]

缺省情况下，对能给出结果的情况产生条件：

Wolfram Language code: AsymptoticLess[Exp[-a x], 1, x -> ∞]

缺省情况下，如果结果只在特殊值的时候才无效，不给出条件：

Wolfram Language code: AsymptoticLess[x y, (x - a)^2 + y^2, {x, y} -> {0, 0}]

当 GenerateConditions->True 时，非通用条件也要报告：

Wolfram Language code: AsymptoticLess[x y, (x - a)^2 + y^2, {x, y} -> {0, 0}, GenerateConditions -> True]

PerformanceGoal (1)

用 PerformanceGoal 来避免潜在的巨量计算：

Wolfram Language code:

f = 2 y z^2 - z^3 + y (x - 2 y + 3 z)^2 - z (x - 2 y + 3 z)^2;
g = y^2 - 2 y z + z^2 - y (x - 2 y + 3 z) + z (x - 2 y + 3 z) + (x - 2 y + 3 z)^2;

Wolfram Language code: AsymptoticLess[f, g, {x, y, z} -> {0, 0, 0}, PerformanceGoal -> "Speed"]//AbsoluteTiming

默认设置使用所有可用技术来尝试给出结果：

Wolfram Language code: AsymptoticEqual[f, g, {x, y, z} -> {0, 0, 0}]//AbsoluteTiming

应用 (18)

基本应用 (4)

证明在 0 处：

Wolfram Language code: {AsymptoticLess[x^3, x^2, x -> 0], AsymptoticLess[x^2, x, x -> 0], AsymptoticLess[x^1, x^0, x -> 0]}

用符号方式证明：

Wolfram Language code: AsymptoticLess[x^k, x^l, x -> 0, Assumptions -> {k, l}∈ℤ && k > l ≥ 0]

可视化函数：

Wolfram Language code: Plot[{1, Abs[x], Abs[x^2], Abs[x^3]}, {x, -1, 1}, PlotLegends -> "Expressions"]

这种关系对所有实数幂都成立：

Wolfram Language code: AsymptoticLess[x^k, x^l, x -> 0, Assumptions -> k > l]

可视化指数为分数和负数的函数：

Wolfram Language code: Plot[{Abs[1 / x], Abs[1 / Sqrt[x]], 1, Abs[Sqrt[x]], Abs[x]}, {x, -1, 1}, PlotLegends -> "Expressions"]

证明在 ∞ 处：

Wolfram Language code: {AsymptoticLess[1, x, x -> ∞], AsymptoticLess[x, x^2, x -> ∞], AsymptoticLess[x^2, x^3, x -> ∞]}

用符号方式证明：

Wolfram Language code: AsymptoticLess[x^k, x^l, x -> ∞, Assumptions -> {k, l}∈ℤ && 0 ≤ k < l]

用对数图可视化这种关系：

Wolfram Language code: LogPlot[{1, Abs[x], Abs[x^2], Abs[x^3]}, {x, 10, 100}, PlotLegends -> "Expressions"]

这种关系对所有实数幂都成立：

Wolfram Language code: AsymptoticLess[x^k, x^l, x -> ∞, Assumptions -> k < l]

可视化指数为分数和负数的函数：

Wolfram Language code: LogPlot[{Abs[1 / x], Abs[1 / Sqrt[x]], 1, Abs[Sqrt[x]], Abs[x]}, {x, 10, 100}, PlotLegends -> "Expressions"]

证明在 0 处：

Wolfram Language code: AsymptoticLess[x^2Sin[1 / x], x, x -> 0]

可从 $TemplateBox[{{{x, ^, 2}, , {sin, (, {1, /, x}, )}}}, Abs]<=x^2$ 推导出上述关系：

Wolfram Language code:

Plot[{Abs[x^2Sin[1 / x]], Abs[x], x^2}, {x, -2 / 3, 2 / 3}, PlotStyle -> {Automatic, Automatic, Dashed}, PlotLegends -> "Expressions"]

证明在 ∞ 处：

Wolfram Language code: AsymptoticLess[x, x^2(Sin[x] + 2), x -> ∞]

Wolfram Language code: LogPlot[{x, x^2(Sin[x] + 2)}, {x, 1, 100}, PlotLegends -> "Expressions"]

绝对误差和相对误差 (2)

当时，如果，则函数以较小的绝对误差逼近 . 证明当时，以较小的绝对误差逼近：

Wolfram Language code: AsymptoticLess[Exp[x] - 1, 1, x -> 0]

证明当时，也以较小的绝对误差逼近：

Wolfram Language code: AsymptoticLess[Exp[x] - (1 + x), 1, x -> 0]

证明当时，以较小的绝对误差逼近：

Wolfram Language code: AsymptoticLess[Cosh[x] - Exp[x] / 2, 1, x -> ∞]

证明当时，以较小的绝对误差逼近：

Wolfram Language code: AsymptoticLess[Cosh[x] - Exp[-x] / 2, 1, x -> -∞]

当时，如果，则函数以较小的相对误差逼近 . 证明当时，以较小的相对误差逼近：

Wolfram Language code: AsymptoticLess[Exp[x] - (1 + x), 1 + x, x -> 0]

证明当时，以较小的相对误差逼近：

Wolfram Language code: AsymptoticLess[((1/x) + (1/x^2)) - (1/x^2), (1/x^2), x -> 0]

但上述近似的绝对误差并不小：

Wolfram Language code: AsymptoticLess[((1/x) + (1/x^2)) - (1/x^2), 1, x -> 0]

同样，时，用 Stirling 公式近似相对误差较小：

Wolfram Language code: AsymptoticLess[n! - Sqrt[2π n](n / E)^n, Sqrt[2π n](n / E)^n, n -> ∞]

但绝对误差较大：

Wolfram Language code: AsymptoticLess[n! - Sqrt[2π n](n / E)^n, 1, n -> ∞]

渐近近似 (6)

设为一个函数，在靠近时逼近 . 如果在处，则逼近是渐近的. 换句话说，余数或误差渐近地小于近似值. 证明是在处的渐近近似：

Wolfram Language code: AsymptoticLess[(x^2 + x + 1) - 1, 1, x -> 0]

证明是在处的渐近近似：

Wolfram Language code: AsymptoticLess[(x^2 + x + 1) - (x + 1), x + 1, x -> 0]

证明不是在处的渐近近似：

Wolfram Language code: AsymptoticLess[(x^2 + x + 1) - 1.5, 1.5, x -> 0]

证明 Stirling 公式是在时的渐近近似：

Wolfram Language code: AsymptoticLess[n! - Sqrt[2π n](n / E)^n, Sqrt[2π n](n / E)^n, n -> ∞]

证明是在时的渐近近似：

Wolfram Language code: AsymptoticLess[PrimePi[x] - x / Log[x], x / Log[x], x -> ∞]

Series 可以生成基本函数和特殊函数的渐近近似. 例如，生成在处的 10 次 (degree-10) 近似：

Wolfram Language code: sin = Normal@Series[Sin[x], {x, 0, 10}]

证明级数是渐近的：

Wolfram Language code: AsymptoticLess[Sin[x] - sin, sin, x -> 0]

给出 Cot[x] 在 0 处的渐近级数：

Wolfram Language code: cot = Normal@Series[Cot[x], {x, 0, 5}]

Wolfram Language code: AsymptoticLess[Cot[x] - cot, cot, x -> 0]

证明 Gamma[x] 的级数在 -1 处是渐近级数：

Wolfram Language code: gamma = Normal@Series[Gamma[x], {x, -1, 2}]

Wolfram Language code: AsymptoticLess[Gamma[x] - gamma, gamma, x -> -1]

求在 0 处的渐近逼近：

Wolfram Language code: expr = Normal@Series[Log[Sin[x]]^1 / 3, {x, 0, 3}]

Wolfram Language code: AsymptoticLess[Log[Sin[x]]^1 / 3 - expr, expr, x -> 0]

当要近似的函数在近似点的每个邻域中无限多次逼近于零时，渐近近似可能会有微妙的变化. 作为一个例子，我们来考虑在附近的渐近展开式：

Wolfram Language code: besselJ = Normal@Series[BesselJ[1, x], {x, ∞, 2}]

近似不是渐近的，因为在贝塞尔函数的每个零点上近似值都不是零：

Wolfram Language code: {BesselJ[1, x], besselJ} /. x -> BesselJZero[1, 25]//N

尽管总的来说比值是接近于零的，但无数次地不成立：

Wolfram Language code: Plot[(besselJ - BesselJ[1, x]/besselJ), {x, 1, 40}, PlotTheme -> "Detailed", PlotPoints -> 200, PlotRange -> 0.003]

另一方面，我们来考虑永远非零的 Hankel 函数的近似：

Wolfram Language code: hankel1 = Normal@Series[HankelH1[1, x], {x, ∞, 2}]//Expand

近似是渐近的：

Wolfram Language code: AsymptoticLess[HankelH1[1, x] - hankel1, hankel1, x -> ∞]

第二类 Hankel 函数的近似也是渐近的：

Wolfram Language code: hankel2 = Normal@Series[HankelH2[1, x], {x, ∞, 2}]//Expand

Wolfram Language code: AsymptoticLess[HankelH2[1, x] - hankel2, hankel2, x -> ∞]//Quiet

由于，作为两个这种近似的和，它的近似可以理解为几乎是渐近的：

Wolfram Language code: FullSimplify[besselJ == (hankel1 + hankel2/2)]

或者，来考虑在附近的渐近近似：

Wolfram Language code: besselJP1 = Normal@Series[1 + BesselJ[1, x], {x, ∞, 2}]//Expand

这是真正的渐近近似：

Wolfram Language code: AsymptoticLess[1 + BesselJ[1, x] - besselJP1, besselJP1, x -> ∞]

近似与函数的比值的极限始终接近于：

Wolfram Language code: Plot[Abs[(1 + BesselJ[1, x] - besselJP1/besselJP1)], {x, 1, 40}, PlotTheme -> "Detailed"]

用 AsymptoticIntegrate 生成定积分的渐近近似. 例如，求当时的渐近近似，并与精确值相比较：

Wolfram Language code: {approx, exact} = {AsymptoticIntegrate[E ^ (t x), {t, 0, 1}, {x, 0, 3}] , Integrate[E ^ (t x), {t, 0, 1}]}

Wolfram Language code: AsymptoticLess[exact - approx, approx, x -> 0]

用更少的项给出渐近近似：

Wolfram Language code: approx2 = AsymptoticIntegrate[E ^ (t x), {t, 0, 1}, {x, 0, 1}]

上述近似渐近逼近于精确积分和第一个近似：

Wolfram Language code: AsymptoticLess[exact - approx2, approx2, x -> 0]

Wolfram Language code: AsymptoticLess[approx - approx2, approx2, x -> 0]

用 AsymptoticIntegrate 来生成不定积分的渐近近似，尽管要考虑积分常数. 求在时的近似：

Wolfram Language code: {approx, exact} = {AsymptoticIntegrate[Sin[x], x, {x, 0, 3}], Integrate[Sin[x], x]}

证明近似是渐近的：

Wolfram Language code: AsymptoticLess[exact - approx, approx, x -> 0]

然而，在扩展点匹配值后，近似是渐进的：

Wolfram Language code: AsymptoticLess[exact - approx - (exact - approx /. x -> 0), approx, x -> 0]

计算在时两个不同的渐近近似：

Wolfram Language code: approx2 = AsymptoticIntegrate[x^x, x, {x, 0, 2}]

Wolfram Language code: approx1 = AsymptoticIntegrate[x^x, x, {x, 0, 1}]

没有符号结果可供比较，但可以证明过程是渐近的：

Wolfram Language code: AsymptoticLess[approx2 - approx1, approx1, x -> 0]

用 AsymptoticDSolveValue 生成微分方程的渐近逼近：

Wolfram Language code: deqn = {y''[x] - (x ^ 4 + E ^ x Sin[x]) y[x] == 0 == 0, y[0] == 0, y'[0] == 2};

Wolfram Language code: approx = AsymptoticDSolveValue[deqn, y[x], {x, 0, 8}]

没有精确的结果可供比较，但过程可以显示出是渐近的：

Wolfram Language code: approx2 = AsymptoticDSolveValue[deqn, y[x], {x, 0, 12}]

Wolfram Language code: AsymptoticLess[approx2 - approx, approx, x -> 0]

与使用 NDSolveValue 获得的数值解相比较：

Wolfram Language code: nsol = NDSolveValue[deqn, y[x], {x, 0, 0.5}]

Wolfram Language code: Table[nsol - approx2, {x, 0, 0.5, 0.1}]

渐近尺度和级数 (2)

当且仅当在处时，函数序列为处的渐近尺度. 编写一个函数，查看一个有限的函数列表是否为渐近尺度：

Wolfram Language code:

AsymptoticScaleQ[list_, x_ -> x0_, o : OptionsPattern[]] := BlockMap[AsymptoticLess[#[[2]], #[[1]], x -> x0, o]&, list, 2, 1]

整数幂给出处的渐近尺度，时 $TemplateBox[{≻, "≻", {1, /, {(, {x, ^, 3}, )}}, {1, /, {(, {x, ^, 2}, )}}, {1, /, x}, 1, x, {x, ^, 2}, {x, ^, 3}}, RowWithSeparators]$ :

Wolfram Language code: AsymptoticScaleQ[{1 / x^3, 1 / x^2, 1 / x, 1, x, x ^ 2, x ^ 3}, x -> 0]

它们也形成了处的渐近尺度，但是顺序相反：

Wolfram Language code: AsymptoticScaleQ[{x^3, x^2, x, 1, (1/x), (1/x^2), (1/x^3)}, x -> ∞]

的幂形成了渐近尺度，时 $TemplateBox[{≻, "≻", 1, {1, /, {(, {log, (, x, )}, )}}, {1, /, {(, {{log, ^, 2}, (, x, )}, )}}, {1, /, {(, {{log, ^, 3}, (, x, )}, )}}}, RowWithSeparators]$ :

Wolfram Language code: AsymptoticScaleQ[{1, 1 / Log[x], 1 / Log[x]^2, 1 / Log[x]^3}, x -> ∞]

用和形成一个渐近尺度，时 $TemplateBox[{≻, "≻", 1, x, {{x, ^, 2}, , {log, (, x, )}}, {x, ^, 2}, {{x, ^, 3}, , {log, (, x, )}}, {x, ^, 3}, {{x, ^, 4}, , {log, (, x, )}}}, RowWithSeparators]$ :

Wolfram Language code: AsymptoticScaleQ[{1, x, x^2 Log[x], x^2, x^3Log[x], x^3, x^4Log[x]}, x -> 0, Direction -> -1]

如果，证明当时：

Wolfram Language code: Table[Exp[x]x^-α, {α, Sort[RandomReal[10, 5]]}]

Wolfram Language code: AsymptoticScaleQ[%, x -> ∞]

编写一个函数，按在点处的渐近程度对函数进行排序：

Wolfram Language code:

AsymptoticSort[list_List, x_ -> x0_, o : OptionsPattern[]] := 
	Sort[list, AsymptoticLess[#1, #2, x -> x0, o]&]

生成随机整数幂函数列表：

Wolfram Language code: pows = RandomSample[Table[x^i, {i, -3, 3}]]

在处按渐近程度对函数进行排序：

Wolfram Language code: AsymptoticSort[pows, x -> 0]

Wolfram Language code: LogPlot[Evaluate[Abs[%]], {x, -1 / 2, 1 / 2}, PlotLegends -> "Expressions"]

在处按渐近程度对同一组函数进行排序：

Wolfram Language code: AsymptoticSort[pows, x -> ∞]

Wolfram Language code: LogPlot[Evaluate[Abs[%]], {x, 10, 100}, PlotLegends -> "Expressions"]

计算复杂度 (4)

简单的排序算法（冒泡排序，插入排序）需要大约 a n² 个步骤对 n 个对象进行排序，而最优通用算法（堆排序，合并排序）大约需要 b n Log[n] 个步骤来进行排序. 证明对足够大的对象集合进行排序时，最优算法总是花费更少的时间：

Wolfram Language code: AsymptoticLess[b n Log[n], a n^2, n -> ∞]

某些特殊的算法（计数排序，基数排序），在有关可能的输入的信息提前存在的情况下，可在 c n 时间内完成. 当可以使用这些算法时，它们甚至比最优算法更快：

Wolfram Language code: AsymptoticLess[c n, b n Log[n], n -> ∞]

可视化这三种算法计算时间的增长：

Wolfram Language code:

LogPlot[{n^2, n Log[n], n}, {n, 10, 1000}, PlotLegends -> "Expressions", PlotLabel -> Row[{n∈o[n Log[n]], n Log[n]∈o[n^2]}, Spacer[10]]]

在冒泡排序中，对相邻的项进行比较，如果顺序不对即进行交换. 经过 n-1 次比较后，最大的元素在最后. 然后在剩余的 n-1 个元素上重复该过程，直到开头处只剩下两个元素. 如果比较和交换需要 c 个步骤，则排序需要的总步骤数为：

Wolfram Language code: Sum[c(i - 1), {i, n, 2, -1}]

可以只用二次项对多项式进行渐近近似：

Wolfram Language code: AsymptoticLess[(1/2) (-c n + c n^2) - (c n^2/2), (c n^2/2), n -> ∞]

在合并排序中，元素列表被分成两部分，分别对每部分进行排序，然后合并两个部分. 因此，进行排序的总时间 T[n] 将是用于计算中值的某个固定时间 b 加上对每一半元素进行排序的时间 2T[n/2]，再加上用于将两部分元素合并在一起的时间，即元素个数的倍数 a n：

Wolfram Language code: reqn = T[n] == 2T[n / 2] + a n + b

求解循环方程，计算对 n 个元素进行排序所需的时间 t：

Wolfram Language code: t = RSolveValue[reqn, T[n], n]//Expand

可以用表达式的最后一项对表达式进行渐近近似：

Wolfram Language code: AsymptoticLess[t - n (a Log[n]/Log[2]), n(a Log[n]/Log[2]), n -> ∞]

旅行推销员问题 (TSP) 需要找到连接个城市的最短路线. 一个朴素的算法是尝试所有个路线. Held–Karp 算法将其减少到大约个步骤. 证明，因此 Held–Karp 算法更快：

Wolfram Language code: AsymptoticLess[n ^ 2 2^n, n!, n -> ∞]

这两种算法都表明，TSP 的计算复杂度类不比 EXPTIME 难，EXPTIME 问题是可以在时间内解决的问题. 对于 Held–Karp 算法，使用就可以了，其中：

Wolfram Language code: AsymptoticLess[n^2 2^n, 2^2n, n -> ∞]

对于阶乘，必须使用高次多项式，如：

Wolfram Language code: AsymptoticLess[n!, 2^n^2, n -> ∞]

可以在时间内找到近似解，所以近似 TSP 属于复杂度类 P 问题，是在多项式时间内可以解决的问题. 任何多项式算法都比指数型算法快，或：

Wolfram Language code: AsymptoticLess[n^k, 2^n, n -> ∞]

属性和关系 (10)

AsymptoticLess 是不自反的，即：

Wolfram Language code: AsymptoticLess[f[x], f[x], x -> x0]

它是一种传递关系，即若和成立，则有：

Wolfram Language code: {f, g, h} = {x, x^2, x^3};

Wolfram Language code: {AsymptoticLess[f, g, x -> ∞], AsymptoticLess[g, h, x -> ∞], AsymptoticLess[f, h, x -> ∞]}

也是一种对称关系，即意味着：

Wolfram Language code: {f, g} = {x, x^2};

Wolfram Language code: {AsymptoticLess[f, g, x -> ∞], AsymptoticLess[g, f, x -> ∞]}

当且仅当 Limit[Abs[f[x]/g[x]],xx₀]0 时，AsymptoticLess[f[x],g[x],xx₀] 的结果为：

Wolfram Language code: {f, g} = {x, x^2};

Wolfram Language code: {AsymptoticLess[f, g, x -> ∞], Limit[Abs[f / g], x -> ∞]}

Wolfram Language code: {f, g} = {x^2, x^3 / (1 + x)};

Wolfram Language code: {AsymptoticLess[f, g, x -> ∞], Limit[Abs[f / g], x -> ∞]}

具体来讲，极限必须存在：

Wolfram Language code: {f, g} = {Sin[x], x Cos[x]};

Wolfram Language code: {AsymptoticLess[f, g, x -> ∞], Limit[Abs[f / g], x -> ∞]}

如果，则：

Wolfram Language code: {f, g} = {x, x^2};

Wolfram Language code: {AsymptoticLess[f, g, x -> ∞], AsymptoticLessEqual[f, g, x -> ∞]}

如果，则：

Wolfram Language code: {f, g} = {x, x^2};

Wolfram Language code: {AsymptoticLess[f, g, x -> ∞], AsymptoticGreater[g, f, x -> ∞]}

如果，则：

Wolfram Language code: {f, g} = {x, x^2};

Wolfram Language code: {AsymptoticLess[f, g, x -> ∞], AsymptoticGreaterEqual[g, f, x -> ∞]}

如果，则：

Wolfram Language code: {f, g} = {x, x^2};

Wolfram Language code: {AsymptoticLess[f, g, x -> ∞], !AsymptoticEquivalent[f, g, x -> ∞]}

如果，则：

Wolfram Language code: {f, g} = {x, x^2};

Wolfram Language code: {AsymptoticLess[f, g, x -> ∞], !AsymptoticEqual[f, g, x -> ∞]}

如果和，则：

Wolfram Language code: {f, g, h} = {x, x^2, x^3 / (1 + x)};

Wolfram Language code: {AsymptoticLess[f, g, x -> ∞], AsymptoticLessEqual[g, h, x -> ∞], AsymptoticLess[f, h, x -> ∞]}

如果和，则：

Wolfram Language code: {f, g, h} = {x, x^2, x^3 / (1 + x)};

Wolfram Language code: {AsymptoticLess[f, g, x -> ∞], AsymptoticEqual[g, h, x -> ∞], AsymptoticLess[f, h, x -> ∞]}

如果和，则：

Wolfram Language code: {f, g, h} = {x, x^2, x^3 / (1 + x)};

Wolfram Language code: {AsymptoticLess[f, g, x -> ∞], AsymptoticEquivalent[g, h, x -> ∞], AsymptoticLess[f, h, x -> ∞]}

Top

	AsymptoticLess[f[x],g[x],xx^*]	对于所有的，存在使得 $0<TemplateBox[{{x, -, {x, ^, }}}, Abs]<delta(c,x^)$ 意味着成立
	AsymptoticLess[f[x₁,…,x_n],g[x₁,…,x_n],{x₁,…,x_n}{,…,}]	对于所有的，存在使得 $0<TemplateBox[{{{, {{{x, _, 1}, -, {x, _, {(, 1, )}, ^, }}, ,, ..., ,, {{x, _, n}, -, {x, _, {(, n, )}, ^, }}}, }}}, Norm]<delta(epsilon,x^*)$ 意味着 $TemplateBox[{{f, (, {{x, _, 1}, ,, ..., ,, {x, _, n}}, )}}, Abs]<=c TemplateBox[{{g, (, {{x, _, 1}, ,, ..., ,, {x, _, n}}, )}}, Abs]$ 成立

	AsymptoticLess[f[x],g[x],x∞]	对于所有的，存在使得意味着成立
	AsymptoticLess[f[x₁,…,x_n],g[x₁,…,x_n],{x₁,…,x_n}{∞,…,∞}]	对于所有的，存在使得意味着 $TemplateBox[{{f, (, {{x, _, 1}, ,, ..., ,, {x, _, n}}, )}}, Abs]<=c TemplateBox[{{g, (, {{x, _, 1}, ,, ..., ,, {x, _, n}}, )}}, Abs]$ 成立

Assumptions	$Assumptions	对参数的设定
Direction	Reals	趋近极限点的方向
GenerateConditions	Automatic	对参数生成条件
Method	Automatic	所使用的方法
PerformanceGoal	"Quality"	优化目标

	Reals or "TwoSided"	从两个实方向
	"FromAbove" or -1	从上面或较大的值
	"FromBelow" or +1	从下面或较小的值
	Complexes	从所有复方向
	Exp[ θ]	从方向
	{dir₁,…,dir_n}	对变量 x_i 分别使用方向 dir_i

更多学习资源

技术支持

Wolfram 解决方案

Wolfram 的教育解决方案

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

AsymptoticLess

更多信息和选项

范例

基本范例 (2)

范围 (9)

选项 (10)

Assumptions (1)

Direction (5)

GenerateConditions (3)

PerformanceGoal (1)

应用 (18)

基本应用 (4)

绝对误差和相对误差 (2)

渐近近似 (6)

渐近尺度和级数 (2)

计算复杂度 (4)

属性和关系 (10)

文本

CMS

APA

BibTeX

BibLaTeX

	Automatic	只给出非通用条件
	True	所有条件
	False	不给出条件
	None	如果需要条件则不经计算直接返回

AsymptoticLess

更多信息和选项

范例

基本范例 (2)

范围 (9)

选项 (10)

Assumptions (1)

Direction (5)

GenerateConditions (3)

PerformanceGoal (1)

应用 (18)

基本应用 (4)

绝对误差和相对误差 (2)

渐近近似 (6)

渐近尺度和级数 (2)

计算复杂度 (4)

属性和关系 (10)

参见

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX